[sigrok-cli.git] / contrib / sigrok-cli_cross.nsi.in

##
## This file is part of the sigrok-cli project.
##
## Copyright (C) 2011-2014 Uwe Hermann <uwe@hermann-uwe.de>
##
## This program is free software; you can redistribute it and/or modify
## it under the terms of the GNU General Public License as published by
## the Free Software Foundation; either version 2 of the License, or
## (at your option) any later version.
##
## This program is distributed in the hope that it will be useful,
## but WITHOUT ANY WARRANTY; without even the implied warranty of
## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
## GNU General Public License for more details.
##
## You should have received a copy of the GNU General Public License
## along with this program; if not, write to the Free Software
## Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA  02110-1301 USA
##

#
# This file is used to create the sigrok-cli Windows installer via NSIS.
# It is meant for use in a cross-compile setup (not for native builds).
# See the 'sigrok-cross-mingw' script in the sigrok-util repo for details.
#
# NSIS documentation:
# http://nsis.sourceforge.net/Docs/
# http://nsis.sourceforge.net/Docs/Modern%20UI%202/Readme.html
#

# Include the "Modern UI" header, which gives us the usual Windows look-n-feel.
!include "MUI2.nsh"


# --- Global stuff ------------------------------------------------------------

# Installer/product name.
Name "@PACKAGE_NAME@"

# Filename of the installer executable.
OutFile "@PACKAGE_NAME@-@SC_PACKAGE_VERSION@-installer.exe"

# Where to install the application.
InstallDir "$PROGRAMFILES\sigrok\@PACKAGE_NAME@"

# Request admin privileges for Windows Vista and Windows 7.
# http://nsis.sourceforge.net/Docs/Chapter4.html
RequestExecutionLevel admin

# Local helper definitions.
!define REGSTR "Software\Microsoft\Windows\CurrentVersion\Uninstall\@PACKAGE_NAME@"


# --- MUI interface configuration ---------------------------------------------

# Use the following icon for the installer EXE file.
!define MUI_ICON "@top_srcdir@/contrib/sigrok-logo-notext.ico"

# Show a nice image at the top of each installer page.
!define MUI_HEADERIMAGE

# Don't automatically go to the Finish page so the user can check the log.
!define MUI_FINISHPAGE_NOAUTOCLOSE

# Upon "cancel", ask the user if he really wants to abort the installer.
!define MUI_ABORTWARNING

# Don't force the user to accept the license, just show it.
# Details: http://trac.videolan.org/vlc/ticket/3124
!define MUI_LICENSEPAGE_BUTTON $(^NextBtn)
!define MUI_LICENSEPAGE_TEXT_BOTTOM "Click Next to continue."

# Path where the cross-compiled sigrok tools and libraries are located.
# Change this to where-ever you installed libsigrok.a and so on.
!define CROSS "@prefix@"


# --- MUI pages ---------------------------------------------------------------

# Show a nice "Welcome to the ... Setup Wizard" page.
!insertmacro MUI_PAGE_WELCOME

# Show the license of the project.
!insertmacro MUI_PAGE_LICENSE "@top_srcdir@/COPYING"

# Show a screen which allows the user to select which components to install.
!insertmacro MUI_PAGE_COMPONENTS

# Allow the user to select a different install directory.
!insertmacro MUI_PAGE_DIRECTORY

# Perform the actual installation, i.e. install the files.
!insertmacro MUI_PAGE_INSTFILES

# Show a final "We're done, click Finish to close this wizard" message.
!insertmacro MUI_PAGE_FINISH

# Pages used for the uninstaller.
!insertmacro MUI_UNPAGE_WELCOME
!insertmacro MUI_UNPAGE_CONFIRM
!insertmacro MUI_UNPAGE_INSTFILES
!insertmacro MUI_UNPAGE_FINISH


# --- MUI language files ------------------------------------------------------

# Select an installer language (required!).
!insertmacro MUI_LANGUAGE "English"


# --- Default section ---------------------------------------------------------

Section "@PACKAGE_NAME@ (required)" Section1

	# This section is gray (can't be disabled) in the component list.
	SectionIn RO

	# Install the file(s) specified below into the specified directory.
	SetOutPath "$INSTDIR"

	# License file.
	File "@top_srcdir@/COPYING"

	# sigrok-cli.exe.
	File "${CROSS}/bin/@PACKAGE_NAME@.exe"

	# Zadig (used for installing WinUSB drivers).
	File "${CROSS}/zadig.exe"
	File "${CROSS}/zadig_xp.exe"

	# Python
	File "${CROSS}/python32.dll"
	File "${CROSS}/python32.zip"

	SetOutPath "$INSTDIR\share"

	# Protocol decoders.
	File /r /x "__pycache__" /x "*.pyc" "${CROSS}/share/libsigrokdecode"

	# Firmware files.
	File /r "${CROSS}/share/sigrok-firmware"

	# Example *.sr files.
	SetOutPath "$INSTDIR\examples"
	File /r "${CROSS}/share/sigrok-dumps/*"

	# Generate the uninstaller executable.
	WriteUninstaller "$INSTDIR\Uninstall.exe"

	# Create a sub-directory in the start menu.
	CreateDirectory "$SMPROGRAMS\sigrok"
	CreateDirectory "$SMPROGRAMS\sigrok\@PACKAGE_NAME@"

	# Create a shortcut for sigrok-cli (this merely opens a "DOS box").
	# Set the working directory (where the user will be placed into when
	# the DOS box starts) to the installation directory.
	SetOutPath "$INSTDIR"
	CreateShortCut "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\sigrok command-line tool.lnk" \
		"$SYSDIR\cmd.exe" \
		"/K echo For instructions run @PACKAGE_NAME@ --help." \
		"$SYSDIR\cmd.exe" 0 \
		SW_SHOWNORMAL "" "Run @PACKAGE_NAME@"

	# Create a shortcut for the uninstaller.
	CreateShortCut "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\Uninstall.lnk" \
		"$INSTDIR\Uninstall.exe" "" "$INSTDIR\Uninstall.exe" 0 \
		SW_SHOWNORMAL "" "Uninstall @PACKAGE_NAME@"

	# Create a shortcut for the Zadig executable.
	CreateShortCut "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\Zadig.lnk" \
		"$INSTDIR\zadig.exe" "" "$INSTDIR\zadig.exe" 0 \
		SW_SHOWNORMAL "" "Zadig"

	# Create a shortcut for the Zadig executable (for Win XP).
	CreateShortCut "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\Zadig (Win XP).lnk" \
		"$INSTDIR\zadig_xp.exe" "" "$INSTDIR\zadig_xp.exe" 0 \
		SW_SHOWNORMAL "" "Zadig (Win XP)"

	# Create registry keys for "Add/remove programs" in the control panel.
	WriteRegStr HKLM "${REGSTR}" "DisplayName" "@PACKAGE_STRING@"
	WriteRegStr HKLM "${REGSTR}" "UninstallString" \
		"$\"$INSTDIR\Uninstall.exe$\""
	WriteRegStr HKLM "${REGSTR}" "InstallLocation" "$\"$INSTDIR$\""
	WriteRegStr HKLM "${REGSTR}" "DisplayIcon" \
		"$\"$INSTDIR\sigrok-logo-notext.ico$\""
	WriteRegStr HKLM "${REGSTR}" "Publisher" "sigrok"
	WriteRegStr HKLM "${REGSTR}" "HelpLink" \
		"http://sigrok.org/wiki/Sigrok-cli"
	WriteRegStr HKLM "${REGSTR}" "URLUpdateInfo" \
		"http://sigrok.org/wiki/Downloads"
	WriteRegStr HKLM "${REGSTR}" "URLInfoAbout" "http://sigrok.org"
	WriteRegStr HKLM "${REGSTR}" "DisplayVersion" "@SC_PACKAGE_VERSION@"
	WriteRegStr HKLM "${REGSTR}" "Contact" \
		"sigrok-devel@lists.sourceforge.org"
	WriteRegStr HKLM "${REGSTR}" "Comments" \
		"This is the sigrok command-line application."

	# Display "Remove" instead of "Modify/Remove" in the control panel.
	WriteRegDWORD HKLM "${REGSTR}" "NoModify" 1
	WriteRegDWORD HKLM "${REGSTR}" "NoRepair" 1

	# TODO: Add sigrok-cli directory to the PATH env. variable.

SectionEnd


# --- Uninstaller section -----------------------------------------------------

Section "Uninstall"

	# Always delete the uninstaller first (yes, this really works).
	Delete "$INSTDIR\Uninstall.exe"

	# Delete the application, the application data, and related libs.
	Delete "$INSTDIR\COPYING"
	Delete "$INSTDIR\@PACKAGE_NAME@.exe"
	Delete "$INSTDIR\zadig.exe"
	Delete "$INSTDIR\zadig_xp.exe"
	Delete "$INSTDIR\python32.dll"
	Delete "$INSTDIR\python32.zip"

	# Delete all decoders and everything else in libsigrokdecode/.
	# There could be *.pyc files or __pycache__ subdirs and so on.
	RMDir /r "$INSTDIR\share\libsigrokdecode"

	# Delete the firmware files.
	RMDir /r "$INSTDIR\share\sigrok-firmware"

	# Delete the example *.sr files.
	RMDir /r "$INSTDIR\examples\*"

	# Delete the install directory and its sub-directories.
	RMDir "$INSTDIR\share"
	RMDir "$INSTDIR\examples"
	RMDir "$INSTDIR"

	# Delete the links from the start menu.
	Delete "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\sigrok command-line tool.lnk"
	Delete "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\Uninstall.lnk"
	Delete "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\Zadig.lnk"
	Delete "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\Zadig (Win XP).lnk"

	# Delete the sub-directory in the start menu.
	RMDir "$SMPROGRAMS\sigrok\@PACKAGE_NAME@"
	RMDir "$SMPROGRAMS\sigrok"

	# Delete the registry key(s).
	DeleteRegKey HKLM "${REGSTR}"

SectionEnd


# --- Component selection section descriptions --------------------------------

LangString DESC_Section1 ${LANG_ENGLISH} "This installs the sigrok command-line tool, some firmware files, the protocol decoders, some example files, and all required libraries."

!insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
!insertmacro MUI_DESCRIPTION_TEXT ${Section1} $(DESC_Section1)
!insertmacro MUI_FUNCTION_DESCRIPTION_END
Commit	Line	Data
58b03628 UH	1	##
	2	## This file is part of the sigrok-cli project.
	3	##
01833aec	4	## Copyright (C) 2011-2014 Uwe Hermann <uwe@hermann-uwe.de>
58b03628 UH	5	##
	6	## This program is free software; you can redistribute it and/or modify
	7	## it under the terms of the GNU General Public License as published by
	8	## the Free Software Foundation; either version 2 of the License, or
	9	## (at your option) any later version.
	10	##
	11	## This program is distributed in the hope that it will be useful,
	12	## but WITHOUT ANY WARRANTY; without even the implied warranty of
	13	## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	14	## GNU General Public License for more details.
	15	##
	16	## You should have received a copy of the GNU General Public License
	17	## along with this program; if not, write to the Free Software
	18	## Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA
	19	##
	20
	21	#
	22	# This file is used to create the sigrok-cli Windows installer via NSIS.
	23	# It is meant for use in a cross-compile setup (not for native builds).
	24	# See the 'sigrok-cross-mingw' script in the sigrok-util repo for details.
	25	#
	26	# NSIS documentation:
	27	# http://nsis.sourceforge.net/Docs/
	28	# http://nsis.sourceforge.net/Docs/Modern%20UI%202/Readme.html
	29	#
	30
	31	# Include the "Modern UI" header, which gives us the usual Windows look-n-feel.
	32	!include "MUI2.nsh"
	33
	34
	35	# --- Global stuff ------------------------------------------------------------
	36
	37	# Installer/product name.
	38	Name "@PACKAGE_NAME@"
	39
	40	# Filename of the installer executable.
9d642270	41	OutFile "@PACKAGE_NAME@-@SC_PACKAGE_VERSION@-installer.exe"
58b03628 UH	42
	43	# Where to install the application.
	44	InstallDir "$PROGRAMFILES\sigrok\@PACKAGE_NAME@"
	45
	46	# Request admin privileges for Windows Vista and Windows 7.
	47	# http://nsis.sourceforge.net/Docs/Chapter4.html
	48	RequestExecutionLevel admin
	49
	50	# Local helper definitions.
	51	!define REGSTR "Software\Microsoft\Windows\CurrentVersion\Uninstall\@PACKAGE_NAME@"
	52
	53
	54	# --- MUI interface configuration ---------------------------------------------
	55
	56	# Use the following icon for the installer EXE file.
4c6bfc08	57	!define MUI_ICON "@top_srcdir@/contrib/sigrok-logo-notext.ico"
58b03628 UH	58
	59	# Show a nice image at the top of each installer page.
	60	!define MUI_HEADERIMAGE
	61
	62	# Don't automatically go to the Finish page so the user can check the log.
	63	!define MUI_FINISHPAGE_NOAUTOCLOSE
	64
	65	# Upon "cancel", ask the user if he really wants to abort the installer.
	66	!define MUI_ABORTWARNING
	67
	68	# Don't force the user to accept the license, just show it.
	69	# Details: http://trac.videolan.org/vlc/ticket/3124
	70	!define MUI_LICENSEPAGE_BUTTON $(^NextBtn)
	71	!define MUI_LICENSEPAGE_TEXT_BOTTOM "Click Next to continue."
	72
58b03628 UH	73	# Path where the cross-compiled sigrok tools and libraries are located.
58b03628 UH	74	# Change this to where-ever you installed libsigrok.a and so on.
4c6bfc08	75	!define CROSS "@prefix@"
58b03628 UH	76
	77
	78	# --- MUI pages ---------------------------------------------------------------
	79
	80	# Show a nice "Welcome to the ... Setup Wizard" page.
	81	!insertmacro MUI_PAGE_WELCOME
	82
	83	# Show the license of the project.
4c6bfc08	84	!insertmacro MUI_PAGE_LICENSE "@top_srcdir@/COPYING"
58b03628 UH	85
	86	# Show a screen which allows the user to select which components to install.
	87	!insertmacro MUI_PAGE_COMPONENTS
	88
	89	# Allow the user to select a different install directory.
	90	!insertmacro MUI_PAGE_DIRECTORY
	91
	92	# Perform the actual installation, i.e. install the files.
	93	!insertmacro MUI_PAGE_INSTFILES
	94
	95	# Show a final "We're done, click Finish to close this wizard" message.
	96	!insertmacro MUI_PAGE_FINISH
	97
	98	# Pages used for the uninstaller.
	99	!insertmacro MUI_UNPAGE_WELCOME
	100	!insertmacro MUI_UNPAGE_CONFIRM
	101	!insertmacro MUI_UNPAGE_INSTFILES
	102	!insertmacro MUI_UNPAGE_FINISH
	103
	104
	105	# --- MUI language files ------------------------------------------------------
	106
	107	# Select an installer language (required!).
	108	!insertmacro MUI_LANGUAGE "English"
	109
	110
	111	# --- Default section ---------------------------------------------------------
	112
	113	Section "@PACKAGE_NAME@ (required)" Section1
	114
	115	# This section is gray (can't be disabled) in the component list.
	116	SectionIn RO
	117
	118	# Install the file(s) specified below into the specified directory.
	119	SetOutPath "$INSTDIR"
	120
01833aec	121	# License file.
4c6bfc08	122	File "@top_srcdir@/COPYING"
58b03628	123
0b34fecd	124	# sigrok-cli.exe.
58b03628 UH	125	File "${CROSS}/bin/@PACKAGE_NAME@.exe"
58b03628 UH	126
5b1a6c2a	127	# Zadig (used for installing WinUSB drivers).
7d8068f8 UH	128	File "${CROSS}/zadig.exe"
	129	File "${CROSS}/zadig_xp.exe"
	130
0b34fecd UH	131	# Python
	132	File "${CROSS}/python32.dll"
	133	File "${CROSS}/python32.zip"
	134
a5396d7b DE	135	SetOutPath "$INSTDIR\share"
a5396d7b DE	136
01833aec	137	# Protocol decoders.
a5396d7b	138	File /r /x "__pycache__" /x "*.pyc" "${CROSS}/share/libsigrokdecode"
58b03628	139
01833aec	140	# Firmware files.
a5396d7b	141	File /r "${CROSS}/share/sigrok-firmware"
01833aec	142
72db8c56 UH	143	# Example *.sr files.
	144	SetOutPath "$INSTDIR\examples"
	145	File /r "${CROSS}/share/sigrok-dumps/*"
	146
58b03628 UH	147	# Generate the uninstaller executable.
	148	WriteUninstaller "$INSTDIR\Uninstall.exe"
	149
	150	# Create a sub-directory in the start menu.
	151	CreateDirectory "$SMPROGRAMS\sigrok"
	152	CreateDirectory "$SMPROGRAMS\sigrok\@PACKAGE_NAME@"
	153
	154	# Create a shortcut for sigrok-cli (this merely opens a "DOS box").
	155	# Set the working directory (where the user will be placed into when
1afa97c5 UH	156	# the DOS box starts) to the installation directory.
1afa97c5 UH	157	SetOutPath "$INSTDIR"
58b03628 UH	158	CreateShortCut "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\sigrok command-line tool.lnk" \
	159	"$SYSDIR\cmd.exe" \
	160	"/K echo For instructions run @PACKAGE_NAME@ --help." \
	161	"$SYSDIR\cmd.exe" 0 \
	162	SW_SHOWNORMAL "" "Run @PACKAGE_NAME@"
	163
	164	# Create a shortcut for the uninstaller.
	165	CreateShortCut "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\Uninstall.lnk" \
	166	"$INSTDIR\Uninstall.exe" "" "$INSTDIR\Uninstall.exe" 0 \
	167	SW_SHOWNORMAL "" "Uninstall @PACKAGE_NAME@"
	168
6ffb6577 UH	169	# Create a shortcut for the Zadig executable.
	170	CreateShortCut "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\Zadig.lnk" \
	171	"$INSTDIR\zadig.exe" "" "$INSTDIR\zadig.exe" 0 \
	172	SW_SHOWNORMAL "" "Zadig"
	173
	174	# Create a shortcut for the Zadig executable (for Win XP).
	175	CreateShortCut "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\Zadig (Win XP).lnk" \
	176	"$INSTDIR\zadig_xp.exe" "" "$INSTDIR\zadig_xp.exe" 0 \
	177	SW_SHOWNORMAL "" "Zadig (Win XP)"
	178
58b03628 UH	179	# Create registry keys for "Add/remove programs" in the control panel.
	180	WriteRegStr HKLM "${REGSTR}" "DisplayName" "@PACKAGE_STRING@"
	181	WriteRegStr HKLM "${REGSTR}" "UninstallString" \
	182	"$\"$INSTDIR\Uninstall.exe$\""
	183	WriteRegStr HKLM "${REGSTR}" "InstallLocation" "$\"$INSTDIR$\""
	184	WriteRegStr HKLM "${REGSTR}" "DisplayIcon" \
	185	"$\"$INSTDIR\sigrok-logo-notext.ico$\""
	186	WriteRegStr HKLM "${REGSTR}" "Publisher" "sigrok"
	187	WriteRegStr HKLM "${REGSTR}" "HelpLink" \
	188	"http://sigrok.org/wiki/Sigrok-cli"
	189	WriteRegStr HKLM "${REGSTR}" "URLUpdateInfo" \
	190	"http://sigrok.org/wiki/Downloads"
	191	WriteRegStr HKLM "${REGSTR}" "URLInfoAbout" "http://sigrok.org"
9d642270	192	WriteRegStr HKLM "${REGSTR}" "DisplayVersion" "@SC_PACKAGE_VERSION@"
58b03628 UH	193	WriteRegStr HKLM "${REGSTR}" "Contact" \
	194	"sigrok-devel@lists.sourceforge.org"
	195	WriteRegStr HKLM "${REGSTR}" "Comments" \
	196	"This is the sigrok command-line application."
	197
	198	# Display "Remove" instead of "Modify/Remove" in the control panel.
	199	WriteRegDWORD HKLM "${REGSTR}" "NoModify" 1
	200	WriteRegDWORD HKLM "${REGSTR}" "NoRepair" 1
	201
	202	# TODO: Add sigrok-cli directory to the PATH env. variable.
	203
	204	SectionEnd
	205
	206
58b03628 UH	207	# --- Uninstaller section -----------------------------------------------------
	208
	209	Section "Uninstall"
	210
	211	# Always delete the uninstaller first (yes, this really works).
	212	Delete "$INSTDIR\Uninstall.exe"
	213
	214	# Delete the application, the application data, and related libs.
	215	Delete "$INSTDIR\COPYING"
	216	Delete "$INSTDIR\@PACKAGE_NAME@.exe"
7d8068f8 UH	217	Delete "$INSTDIR\zadig.exe"
7d8068f8 UH	218	Delete "$INSTDIR\zadig_xp.exe"
0b34fecd UH	219	Delete "$INSTDIR\python32.dll"
0b34fecd UH	220	Delete "$INSTDIR\python32.zip"
58b03628	221
a5396d7b	222	# Delete all decoders and everything else in libsigrokdecode/.
58b03628	223	# There could be *.pyc files or __pycache__ subdirs and so on.
a5396d7b	224	RMDir /r "$INSTDIR\share\libsigrokdecode"
58b03628	225
01833aec	226	# Delete the firmware files.
a5396d7b	227	RMDir /r "$INSTDIR\share\sigrok-firmware"
01833aec	228
72db8c56 UH	229	# Delete the example *.sr files.
	230	RMDir /r "$INSTDIR\examples\*"
	231
58b03628	232	# Delete the install directory and its sub-directories.
a5396d7b	233	RMDir "$INSTDIR\share"
72db8c56	234	RMDir "$INSTDIR\examples"
58b03628 UH	235	RMDir "$INSTDIR"
	236
	237	# Delete the links from the start menu.
	238	Delete "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\sigrok command-line tool.lnk"
	239	Delete "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\Uninstall.lnk"
6ffb6577 UH	240	Delete "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\Zadig.lnk"
6ffb6577 UH	241	Delete "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\Zadig (Win XP).lnk"
58b03628 UH	242
	243	# Delete the sub-directory in the start menu.
	244	RMDir "$SMPROGRAMS\sigrok\@PACKAGE_NAME@"
	245	RMDir "$SMPROGRAMS\sigrok"
	246
	247	# Delete the registry key(s).
	248	DeleteRegKey HKLM "${REGSTR}"
	249
	250	SectionEnd
	251
	252
	253	# --- Component selection section descriptions --------------------------------
	254
72db8c56	255	LangString DESC_Section1 ${LANG_ENGLISH} "This installs the sigrok command-line tool, some firmware files, the protocol decoders, some example files, and all required libraries."
58b03628 UH	256
	257	!insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
	258	!insertmacro MUI_DESCRIPTION_TEXT ${Section1} $(DESC_Section1)
58b03628 UH	259	!insertmacro MUI_FUNCTION_DESCRIPTION_END
58b03628 UH	260