| | 1 | ## |
| | 2 | ## This file is part of the libsigrok project. |
| | 3 | ## |
| | 4 | ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com> |
| | 5 | ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com> |
| | 6 | ## |
| | 7 | ## This program is free software: you can redistribute it and/or modify |
| | 8 | ## it under the terms of the GNU General Public License as published by |
| | 9 | ## the Free Software Foundation, either version 3 of the License, or |
| | 10 | ## (at your option) any later version. |
| | 11 | ## |
| | 12 | ## This program is distributed in the hope that it will be useful, |
| | 13 | ## but WITHOUT ANY WARRANTY; without even the implied warranty of |
| | 14 | ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| | 15 | ## GNU General Public License for more details. |
| | 16 | ## |
| | 17 | ## You should have received a copy of the GNU General Public License |
| | 18 | ## along with this program. If not, see <http://www.gnu.org/licenses/>. |
| | 19 | ## |
| | 20 | |
| | 21 | # We require at least autoconf 2.63 (AC_INIT format changed there). |
| | 22 | AC_PREREQ([2.63]) |
| | 23 | |
| | 24 | AC_INIT([libsigrok], [0.6.0], |
| | 25 | [sigrok-devel@lists.sourceforge.net], |
| | 26 | [libsigrok], [http://www.sigrok.org]) |
| | 27 | AC_CONFIG_MACRO_DIR([m4]) |
| | 28 | AC_CONFIG_AUX_DIR([autostuff]) |
| | 29 | AC_CONFIG_HEADERS([config.h include/libsigrok/version.h]) |
| | 30 | |
| | 31 | # We require at least automake 1.11 (needed for 'silent rules'). |
| | 32 | AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define nostdinc subdir-objects check-news color-tests]) |
| | 33 | AM_SILENT_RULES([yes]) |
| | 34 | m4_ifdef([AM_PROG_AR], [AM_PROG_AR]) |
| | 35 | |
| | 36 | AC_CANONICAL_HOST |
| | 37 | |
| | 38 | # Checks for programs. |
| | 39 | AC_PROG_CC |
| | 40 | AC_PROG_CXX |
| | 41 | AC_PROG_INSTALL |
| | 42 | AC_PROG_LN_S |
| | 43 | |
| | 44 | # Required for per-target flags or subdir-objects with C sources. |
| | 45 | AM_PROG_CC_C_O |
| | 46 | |
| | 47 | # Set the standard the C library headers should conform to. |
| | 48 | AH_VERBATIM([_POSIX_C_SOURCE], [/* The targeted POSIX standard. */ |
| | 49 | #ifndef _POSIX_C_SOURCE |
| | 50 | # define _POSIX_C_SOURCE 200112L |
| | 51 | #endif]) |
| | 52 | |
| | 53 | # Get compiler versions. |
| | 54 | SR_PROG_VERSION([$CC], [sr_cc_version]) |
| | 55 | SR_PROG_VERSION([$CXX], [sr_cxx_version]) |
| | 56 | |
| | 57 | # Check for optional make features. |
| | 58 | SR_PROG_MAKE_ORDER_ONLY |
| | 59 | |
| | 60 | # Initialize libtool. |
| | 61 | LT_INIT |
| | 62 | |
| | 63 | # Set up the libsigrok version defines. |
| | 64 | SR_PKG_VERSION_SET([SR_PACKAGE_VERSION], [AC_PACKAGE_VERSION]) |
| | 65 | |
| | 66 | # Library version for libsigrok (NOT the same as the package version). |
| | 67 | # Carefully read the libtool docs before updating these numbers! |
| | 68 | # The algorithm for determining which number to change (and how) is nontrivial! |
| | 69 | # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info |
| | 70 | # Format: current:revision:age. |
| | 71 | SR_LIB_VERSION_SET([SR_LIB_VERSION], [4:0:0]) |
| | 72 | |
| | 73 | AM_CONDITIONAL([WIN32], [test -z "${host_os##mingw*}" || test -z "${host_os##cygwin*}"]) |
| | 74 | |
| | 75 | ############################# |
| | 76 | ## Optional dependencies ## |
| | 77 | ############################# |
| | 78 | |
| | 79 | AC_LANG([C]) |
| | 80 | |
| | 81 | # Initialize pkg-config. |
| | 82 | # We require at least 0.22, as "Requires.private" behaviour changed there. |
| | 83 | PKG_PROG_PKG_CONFIG([0.22]) |
| | 84 | |
| | 85 | # Keep track of all checked modules so we can list them at the end. |
| | 86 | SR_PKG_CHECK_SUMMARY([sr_pkglibs_summary]) |
| | 87 | |
| | 88 | # Collect the pkg-config module names of all dependencies in SR_PKGLIBS. |
| | 89 | # These are used to derive the compiler flags and for the "Requires.private" |
| | 90 | # field in the generated libsigrok.pc file. |
| | 91 | SR_VAR_OPT_PKG([SR_PKGLIBS], [sr_deps_avail]) |
| | 92 | SR_PKGLIBS_TESTS= |
| | 93 | SR_PKGLIBS_CXX= |
| | 94 | SR_PKGLIBS_PYTHON= |
| | 95 | SR_PKGLIBS_RUBY= |
| | 96 | SR_EXTRA_LIBS= |
| | 97 | SR_EXTRA_CXX_LIBS= |
| | 98 | |
| | 99 | SR_ARG_OPT_PKG([zlib], [ZLIB], , [zlib]) |
| | 100 | AM_CONDITIONAL([HAVE_ZLIB], [test "x$sr_have_zlib" = xyes]) |
| | 101 | AM_COND_IF([HAVE_ZLIB], [ |
| | 102 | SR_APPEND([sr_deps_avail], [crc32 zlib]) |
| | 103 | SR_PREPEND([SR_EXTRA_LIBS], [-lz]) |
| | 104 | ]) |
| | 105 | |
| | 106 | AM_CONDITIONAL([HAVE_INPUT_STF], [test "x$sr_have_zlib" = xyes]) |
| | 107 | AM_COND_IF([HAVE_INPUT_STF], [ |
| | 108 | AC_DEFINE([HAVE_INPUT_STF], [1], [Is the STF input module supported?]) |
| | 109 | ]) |
| | 110 | |
| | 111 | SR_ARG_OPT_PKG([libserialport], [LIBSERIALPORT], , |
| | 112 | [libserialport >= 0.1.1]) |
| | 113 | |
| | 114 | SR_ARG_OPT_PKG([libftdi], [LIBFTDI], , [libftdi1 >= 1.0]) |
| | 115 | |
| | 116 | # pkg-config file names: MinGW/MacOSX: hidapi; Linux: hidapi-hidraw/-libusb |
| | 117 | SR_ARG_OPT_PKG([libhidapi], [LIBHIDAPI], , |
| | 118 | [hidapi >= 0.8.0], [hidapi-hidraw >= 0.8.0], [hidapi-libusb >= 0.8.0]) |
| | 119 | |
| | 120 | SR_ARG_OPT_PKG([libbluez], [LIBBLUEZ], , [bluez >= 4.0]) |
| | 121 | |
| | 122 | SR_ARG_OPT_PKG([libnettle], [LIBNETTLE], , [nettle]) |
| | 123 | |
| | 124 | # FreeBSD comes with an "integrated" libusb-1.0-style USB API. |
| | 125 | # This means libusb-1.0 is always available; no need to check for it. |
| | 126 | # On Windows, require the latest version we can get our hands on, |
| | 127 | # until the new generic event handling has seen an official release. |
| | 128 | AS_CASE([$host_os], |
| | 129 | [freebsd*], [sr_libusb_req='libusb-1.0' sr_have_libusb=yes], |
| | 130 | [mingw*], [sr_libusb_req='libusb-1.0 >= 1.0.20'], |
| | 131 | [sr_libusb_req='libusb-1.0 >= 1.0.16']) |
| | 132 | |
| | 133 | SR_ARG_OPT_PKG([libusb], [LIBUSB_1_0], [NEED_USB], |
| | 134 | [$sr_libusb_req]) |
| | 135 | |
| | 136 | SR_ARG_OPT_PKG([librevisa], [LIBREVISA], [NEED_VISA], |
| | 137 | [librevisa >= 0.0.20130412]) |
| | 138 | |
| | 139 | SR_ARG_OPT_PKG([libgpib], [LIBGPIB], [NEED_GPIB], |
| | 140 | [libgpib]) |
| | 141 | |
| | 142 | SR_ARG_OPT_CHECK([libieee1284], [LIBIEEE1284],, [ |
| | 143 | sr_save_LIBS=$LIBS |
| | 144 | LIBS="-lieee1284 $LIBS" |
| | 145 | AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <ieee1284.h>]], |
| | 146 | [[(void) ieee1284_open(0, 0, 0);]])], |
| | 147 | [sr_have_libieee1284=yes], [sr_have_libieee1284=no]) |
| | 148 | LIBS=$sr_save_LIBS |
| | 149 | ]) |
| | 150 | AS_IF([test "x$sr_have_libieee1284" = xyes], |
| | 151 | [SR_PREPEND([SR_EXTRA_LIBS], [-lieee1284])]) |
| | 152 | |
| | 153 | SR_ARG_OPT_PKG([libgio], [LIBGIO], , [gio-2.0 >= 2.24.0]) |
| | 154 | |
| | 155 | # See if any of the (potentially platform specific) libs are available |
| | 156 | # which provide some means of Bluetooth communication. |
| | 157 | AS_IF([test "x$sr_have_libbluez" = xyes], |
| | 158 | sr_have_bluetooth=yes, sr_have_bluetooth=no) |
| | 159 | AS_IF([test "x$sr_have_bluetooth" = xyes], |
| | 160 | [AC_DEFINE([HAVE_BLUETOOTH], [1], [Specifies whether Bluetooth communication is supported.])]) |
| | 161 | AS_IF([test "x$sr_have_bluetooth" = xyes], |
| | 162 | [SR_APPEND([sr_deps_avail], [bluetooth_comm])]) |
| | 163 | |
| | 164 | AS_IF([test "x$sr_have_libserialport" = xyes -o "x$sr_have_libhidapi" = xyes -o "x$sr_have_bluetooth" = xyes], |
| | 165 | sr_have_serial_comm=yes, sr_have_serial_comm=no) |
| | 166 | AS_IF([test "x$sr_have_serial_comm" = xyes], |
| | 167 | [AC_DEFINE([HAVE_SERIAL_COMM], [1], [Specifies whether serial communication is supported.])]) |
| | 168 | AS_IF([test "x$sr_have_serial_comm" = xyes], |
| | 169 | [SR_APPEND([sr_deps_avail], [serial_comm])]) |
| | 170 | AM_CONDITIONAL([NEED_SERIAL], [test "x$sr_have_serial_comm" = xyes]) |
| | 171 | |
| | 172 | ###################### |
| | 173 | ## Feature checks ## |
| | 174 | ###################### |
| | 175 | |
| | 176 | # The Check unit testing framework is optional. Disable if not found. |
| | 177 | SR_PKG_CHECK([check], [SR_PKGLIBS_TESTS], [check >= 0.9.4]) |
| | 178 | AM_CONDITIONAL([HAVE_CHECK], [test "x$sr_have_check" = xyes]) |
| | 179 | |
| | 180 | # Enable the C99 standard if possible, and enforce the use |
| | 181 | # of SR_API to explicitly mark all public API functions. |
| | 182 | SR_EXTRA_CFLAGS= |
| | 183 | SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [C99], [-std=c99 -c99 -AC99 -qlanglvl=extc99]) |
| | 184 | SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [visibility], [-fvisibility=hidden]) |
| | 185 | |
| | 186 | SR_ARG_ENABLE_WARNINGS([SR_WFLAGS], [-Wall], [-Wall -Wextra -Wmissing-prototypes]) |
| | 187 | |
| | 188 | # Check host characteristics. |
| | 189 | AC_SYS_LARGEFILE |
| | 190 | AC_C_BIGENDIAN |
| | 191 | |
| | 192 | AC_CHECK_HEADERS([sys/mman.h], [SR_APPEND([sr_deps_avail], [sys_mman_h])]) |
| | 193 | AC_CHECK_HEADERS([sys/ioctl.h], [SR_APPEND([sr_deps_avail], [sys_ioctl_h])]) |
| | 194 | AC_CHECK_HEADERS([sys/timerfd.h], [SR_APPEND([sr_deps_avail], [sys_timerfd_h])]) |
| | 195 | |
| | 196 | # We need to link against the Winsock2 library for SCPI over TCP. |
| | 197 | AS_CASE([$host_os], [mingw*], [SR_PREPEND([SR_EXTRA_LIBS], [-lws2_32])]) |
| | 198 | |
| | 199 | # libm (the standard math library) is always needed. |
| | 200 | SR_SEARCH_LIBS([SR_EXTRA_LIBS], [pow], [m]) |
| | 201 | |
| | 202 | # RPC is only needed for VXI support. |
| | 203 | AC_CACHE_CHECK([for SunRPC support], [sr_cv_have_sunrpc], |
| | 204 | [AC_LINK_IFELSE([AC_LANG_PROGRAM( |
| | 205 | [[#include <rpc/rpc.h>]m4_newline[CLIENT *rpc_test(void);]], |
| | 206 | [[(void) clnt_create("", 0, 0, "");]])], |
| | 207 | [RPC_CFLAGS=""; RPC_LIBS=""; sr_cv_have_sunrpc=yes], |
| | 208 | [sr_cv_have_sunrpc=no])]) |
| | 209 | PKG_CHECK_MODULES([TIRPC], |
| | 210 | [libtirpc], |
| | 211 | [RPC_CFLAGS=$TIRPC_CFLAGS; SR_PREPEND([SR_EXTRA_LIBS], [$TIRPC_LIBS]); sr_cv_have_tirpc=yes], |
| | 212 | [sr_cv_have_tirpc=no]) |
| | 213 | AS_IF([test "x$sr_cv_have_sunrpc" = xyes -o "x$sr_cv_have_tirpc" = xyes], |
| | 214 | [sr_cv_have_rpc=yes], [sr_cv_have_rpc=no]) |
| | 215 | |
| | 216 | AC_SUBST(RPC_CFLAGS) |
| | 217 | AC_SUBST(RPC_LIBS) |
| | 218 | |
| | 219 | AS_IF([test "x$sr_cv_have_rpc" = xyes], |
| | 220 | [AC_DEFINE([HAVE_RPC], [1], [Specifies whether we have RPC support (either by SunRPC or libtirpc).])]) |
| | 221 | |
| | 222 | # VXI support is only compiled if RPC support was found. |
| | 223 | AM_CONDITIONAL([NEED_RPC], [test "x$sr_cv_have_rpc" = xyes]) |
| | 224 | |
| | 225 | # Check for compiler support of 128 bit integers |
| | 226 | AC_CHECK_TYPES([__int128_t, __uint128_t], [], [], []) |
| | 227 | |
| | 228 | AC_CACHE_CHECK([for poll], [sr_cv_have_poll], |
| | 229 | [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <poll.h>]], |
| | 230 | [[(void) poll(0, 0, -1);]])], |
| | 231 | [sr_cv_have_poll=yes], [sr_cv_have_poll=no])]) |
| | 232 | AS_IF([test "x$sr_cv_have_poll" = xyes], |
| | 233 | [AC_DEFINE([HAVE_POLL], [1], |
| | 234 | [Specifies whether we have the poll(2) function.])]) |
| | 235 | AC_CACHE_CHECK([for select], [sr_cv_have_select], |
| | 236 | [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/select.h>]], |
| | 237 | [[(void) select(0, 0, 0, 0, 0);]])], |
| | 238 | [sr_cv_have_select=yes], [sr_cv_have_select=no])]) |
| | 239 | AS_IF([test "x$sr_cv_have_select" = xyes], |
| | 240 | [AC_DEFINE([HAVE_SELECT], [1], |
| | 241 | [Specifies whether we have the select(2) function.])]) |
| | 242 | |
| | 243 | ####################### |
| | 244 | ## miniLZO related ## |
| | 245 | ####################### |
| | 246 | # These were taken from the README.LZO file in the miniLZO archive. |
| | 247 | |
| | 248 | AC_CHECK_TYPE(ptrdiff_t,long) |
| | 249 | AC_TYPE_SIZE_T |
| | 250 | AC_CHECK_SIZEOF(short) |
| | 251 | AC_CHECK_SIZEOF(int) |
| | 252 | AC_CHECK_SIZEOF(long) |
| | 253 | AC_CHECK_SIZEOF(long long) |
| | 254 | AC_CHECK_SIZEOF(__int64) |
| | 255 | AC_CHECK_SIZEOF(void *) |
| | 256 | AC_CHECK_SIZEOF(size_t) |
| | 257 | AC_CHECK_SIZEOF(ptrdiff_t) |
| | 258 | |
| | 259 | AC_C_CONST |
| | 260 | |
| | 261 | AC_CHECK_FUNCS(memcmp memcpy memmove memset) |
| | 262 | |
| | 263 | ######################## |
| | 264 | ## Hardware drivers ## |
| | 265 | ######################## |
| | 266 | |
| | 267 | # Keep track of all drivers so we can list them at the end. |
| | 268 | SR_VAR_SUMMARY([sr_driver_summary]) |
| | 269 | |
| | 270 | # Check whether the sr_deps_avail list contains all of the arguments. |
| | 271 | # Unavailable dependencies are collected in sr_deps_missing. |
| | 272 | sr_check_driver_deps() { |
| | 273 | sr_deps_missing= |
| | 274 | for sr_dep |
| | 275 | do |
| | 276 | AS_CASE([" $sr_deps_avail "], [*" $sr_dep "*],, |
| | 277 | [SR_APPEND([sr_deps_missing], [', '], [$sr_dep])]) |
| | 278 | done |
| | 279 | test -z "$sr_deps_missing" || return 1 |
| | 280 | } |
| | 281 | |
| | 282 | AC_ARG_ENABLE([all-drivers], |
| | 283 | [AS_HELP_STRING([--enable-all-drivers], |
| | 284 | [enable all drivers by default [default=yes]])], |
| | 285 | [], [enable_all_drivers=yes]) |
| | 286 | |
| | 287 | ## _SR_DRIVER(Device name, driver-name, var-name, [dependencies...]) |
| | 288 | m4_define([_SR_DRIVER], [ |
| | 289 | AC_ARG_ENABLE([$2], |
| | 290 | [AS_HELP_STRING([--enable-$2], [enable $1 support])], |
| | 291 | [$3=$enableval], [$3=$enable_all_drivers]) |
| | 292 | |
| | 293 | AS_IF([test "x[$]$3" = xyes], [sr_hw_info=yes[]m4_ifval([$4], [ |
| | 294 | sr_check_driver_deps $4 \ |
| | 295 | || $3=no sr_hw_info="no (missing: $sr_deps_missing)" |
| | 296 | ])], [sr_hw_info='no (disabled)']) |
| | 297 | sr_driver_summary_append "$2" "$sr_hw_info" |
| | 298 | |
| | 299 | AM_CONDITIONAL([$3], [test "x[$]$3" = xyes]) |
| | 300 | AM_COND_IF([$3], [AC_DEFINE([HAVE_$3], [1], [Whether to support $1 device.]) AC_DEFINE([HAVE_DRIVERS], [1], [Whether at least one driver is enabled.])]) |
| | 301 | ]) |
| | 302 | |
| | 303 | ## SR_DRIVER(Device name, driver-name, [dependencies...]) |
| | 304 | m4_define([SR_DRIVER], |
| | 305 | [_SR_DRIVER([$1], [$2], m4_expand([AS_TR_CPP([HW_$2])]), [$3])]) |
| | 306 | |
| | 307 | SR_DRIVER([Agilent DMM], [agilent-dmm], [serial_comm]) |
| | 308 | SR_DRIVER([Appa 55II], [appa-55ii], [serial_comm]) |
| | 309 | SR_DRIVER([Arachnid Labs Re:load Pro], [arachnid-labs-re-load-pro], [serial_comm]) |
| | 310 | SR_DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma], [libftdi]) |
| | 311 | SR_DRIVER([ASIX OMEGA RTM CLI], [asix-omega-rtm-cli]) |
| | 312 | SR_DRIVER([Atorch], [atorch], [serial_comm]) |
| | 313 | SR_DRIVER([Atten PPS3xxx], [atten-pps3xxx], [serial_comm]) |
| | 314 | SR_DRIVER([BayLibre ACME], [baylibre-acme], [sys_timerfd_h]) |
| | 315 | SR_DRIVER([BeagleLogic], [beaglelogic], [sys_mman_h sys_ioctl_h]) |
| | 316 | SR_DRIVER([CEM DT-885x], [cem-dt-885x], [serial_comm]) |
| | 317 | SR_DRIVER([Center 3xx], [center-3xx], [serial_comm]) |
| | 318 | SR_DRIVER([ChronoVu LA], [chronovu-la], [libusb libftdi]) |
| | 319 | SR_DRIVER([Colead SLM], [colead-slm], [serial_comm]) |
| | 320 | SR_DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu], [serial_comm]) |
| | 321 | SR_DRIVER([dcttech usbrelay], [dcttech-usbrelay], [libhidapi]) |
| | 322 | SR_DRIVER([demo], [demo]) |
| | 323 | SR_DRIVER([Devantech ETH008], [devantech-eth008], [serial_comm]) |
| | 324 | SR_DRIVER([DreamSourceLab DSLogic], [dreamsourcelab-dslogic], [libusb]) |
| | 325 | SR_DRIVER([Fluke 45], [fluke-45]) |
| | 326 | SR_DRIVER([Fluke DMM], [fluke-dmm], [serial_comm]) |
| | 327 | SR_DRIVER([FTDI LA], [ftdi-la], [libusb libftdi]) |
| | 328 | SR_DRIVER([fx2lafw], [fx2lafw], [libusb]) |
| | 329 | SR_DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x], [serial_comm]) |
| | 330 | SR_DRIVER([GW Instek GDS-800], [gwinstek-gds-800], [serial_comm]) |
| | 331 | SR_DRIVER([GW Instek GPD], [gwinstek-gpd], [serial_comm]) |
| | 332 | SR_DRIVER([Hameg HMO], [hameg-hmo]) |
| | 333 | SR_DRIVER([Hantek 4032L], [hantek-4032l], [libusb]) |
| | 334 | SR_DRIVER([Hantek 6xxx], [hantek-6xxx], [libusb]) |
| | 335 | SR_DRIVER([Hantek DSO], [hantek-dso], [libusb]) |
| | 336 | SR_DRIVER([HP 3457A], [hp-3457a]) |
| | 337 | SR_DRIVER([HP 3478A], [hp-3478a], [libgpib]) |
| | 338 | SR_DRIVER([hp-59306a], [hp-59306a]) |
| | 339 | SR_DRIVER([Hung-Chang DSO-2100], [hung-chang-dso-2100], [libieee1284]) |
| | 340 | SR_DRIVER([ICStation USBRelay], [icstation-usbrelay], [serial_comm]) |
| | 341 | SR_DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2], [libusb]) |
| | 342 | SR_DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus], [libftdi]) |
| | 343 | SR_DRIVER([IPDBG LA], [ipdbg-la]) |
| | 344 | SR_DRIVER([ITECH IT8500], [itech-it8500], [serial_comm]) |
| | 345 | SR_DRIVER([Kecheng KC-330B], [kecheng-kc-330b], [libusb]) |
| | 346 | SR_DRIVER([KERN scale], [kern-scale], [serial_comm]) |
| | 347 | SR_DRIVER([Kingst LA2016], [kingst-la2016], [libusb]) |
| | 348 | SR_DRIVER([Korad KAxxxxP], [korad-kaxxxxp], [serial_comm]) |
| | 349 | SR_DRIVER([Lascar EL-USB], [lascar-el-usb], [libusb]) |
| | 350 | SR_DRIVER([LeCroy LogicStudio], [lecroy-logicstudio], [libusb]) |
| | 351 | SR_DRIVER([LeCroy X-Stream], [lecroy-xstream]) |
| | 352 | SR_DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx], [serial_comm]) |
| | 353 | SR_DRIVER([Mastech MS6514], [mastech-ms6514], [serial_comm]) |
| | 354 | SR_DRIVER([maynuo-m97], [maynuo-m97]) |
| | 355 | SR_DRIVER([MIC 985xx], [mic-985xx], [serial_comm]) |
| | 356 | SR_DRIVER([Microchip PICkit2], [microchip-pickit2], [libusb]) |
| | 357 | SR_DRIVER([Mooshimeter DMM], [mooshimeter-dmm], [bluetooth_comm libgio]) |
| | 358 | SR_DRIVER([Motech LPS 30x], [motech-lps-30x], [serial_comm]) |
| | 359 | SR_DRIVER([Norma DMM], [norma-dmm], [serial_comm]) |
| | 360 | SR_DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer], [serial_comm]) |
| | 361 | SR_DRIVER([PCE PCE-322A], [pce-322a], [serial_comm]) |
| | 362 | SR_DRIVER([Pipistrello-OLS], [pipistrello-ols], [libftdi]) |
| | 363 | SR_DRIVER([RaspberryPI PICO], [raspberrypi-pico]) |
| | 364 | SR_DRIVER([RDTech DPSxxxx/DPHxxxx], [rdtech-dps], [serial_comm]) |
| | 365 | SR_DRIVER([RDTech UMXX], [rdtech-um], [serial_comm]) |
| | 366 | SR_DRIVER([RDTech TCXX], [rdtech-tc], [serial_comm libnettle]) |
| | 367 | SR_DRIVER([Rigol DS], [rigol-ds]) |
| | 368 | SR_DRIVER([Rigol DG], [rigol-dg]) |
| | 369 | SR_DRIVER([Rohde&Schwarz SME-0x], [rohde-schwarz-sme-0x], [serial_comm]) |
| | 370 | SR_DRIVER([Saleae Logic16], [saleae-logic16], [libusb]) |
| | 371 | SR_DRIVER([Saleae Logic Pro], [saleae-logic-pro], [libusb]) |
| | 372 | SR_DRIVER([SCPI DMM], [scpi-dmm]) |
| | 373 | SR_DRIVER([SCPI PPS], [scpi-pps]) |
| | 374 | SR_DRIVER([serial DMM], [serial-dmm], [serial_comm]) |
| | 375 | SR_DRIVER([serial LCR], [serial-lcr], [serial_comm]) |
| | 376 | SR_DRIVER([Siglent SDS], [siglent-sds]) |
| | 377 | SR_DRIVER([Sysclk LWLA], [sysclk-lwla], [libusb]) |
| | 378 | SR_DRIVER([Sysclk SLA5032], [sysclk-sla5032], [libusb]) |
| | 379 | SR_DRIVER([Teleinfo], [teleinfo], [serial_comm]) |
| | 380 | SR_DRIVER([Testo], [testo], [libusb]) |
| | 381 | SR_DRIVER([Tondaj SL-814], [tondaj-sl-814], [serial_comm]) |
| | 382 | SR_DRIVER([UNI-T DMM], [uni-t-dmm], [libusb]) |
| | 383 | SR_DRIVER([UNI-T UT181A], [uni-t-ut181a], [serial_comm]) |
| | 384 | SR_DRIVER([UNI-T UT32x], [uni-t-ut32x], [serial_comm]) |
| | 385 | SR_DRIVER([Yokogawa DL/DLM], [yokogawa-dlm]) |
| | 386 | SR_DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube], [libusb]) |
| | 387 | SR_DRIVER([ZKETECH EBD-USB], [zketech-ebd-usb], [serial_comm]) |
| | 388 | |
| | 389 | ############################### |
| | 390 | ## Language bindings setup ## |
| | 391 | ############################### |
| | 392 | |
| | 393 | AC_LANG([C++]) |
| | 394 | SR_ARG_ENABLE_WARNINGS([SR_WXXFLAGS], [-Wall], [-Wall -Wextra]) |
| | 395 | |
| | 396 | AC_ARG_ENABLE([bindings], |
| | 397 | [AS_HELP_STRING([--enable-bindings], [build language bindings [default=yes]])], |
| | 398 | [], [enable_bindings=yes]) |
| | 399 | |
| | 400 | AC_ARG_ENABLE([cxx], |
| | 401 | [AS_HELP_STRING([--enable-cxx], [build C++ bindings [default=yes]])], |
| | 402 | [], [enable_cxx=$enable_bindings]) |
| | 403 | |
| | 404 | AC_ARG_ENABLE([python], |
| | 405 | [AS_HELP_STRING([--enable-python], [build Python bindings [default=yes]])], |
| | 406 | [], [enable_python=$enable_bindings]) |
| | 407 | |
| | 408 | AC_ARG_ENABLE([ruby], |
| | 409 | [AS_HELP_STRING([--enable-ruby], [build Ruby bindings [default=yes]])], |
| | 410 | [], [enable_ruby=$enable_bindings]) |
| | 411 | |
| | 412 | AC_ARG_ENABLE([java], |
| | 413 | [AS_HELP_STRING([--enable-java], [build Java bindings [default=yes]])], |
| | 414 | [], [enable_java=$enable_bindings]) |
| | 415 | |
| | 416 | #################### |
| | 417 | ## C++ bindings ## |
| | 418 | #################### |
| | 419 | |
| | 420 | sr_cxx_missing= |
| | 421 | |
| | 422 | # Check if the C++ compiler supports at least the C++11 standard. |
| | 423 | # Get the highest of the available C++17/C++14/C++11 standards. |
| | 424 | # This transparently amends CXXFLAGS to pick the detected standard. |
| | 425 | HAVE_MODERN_CXX= |
| | 426 | AS_IF([test "x$HAVE_MODERN_CXX" = x], |
| | 427 | [AX_CXX_COMPILE_STDCXX([17], [noext], [optional])]) |
| | 428 | AS_IF([test "x$HAVE_CXX17" = x1], |
| | 429 | [HAVE_MODERN_CXX=yes]) |
| | 430 | AS_IF([test "x$HAVE_MODERN_CXX" = x], |
| | 431 | [AX_CXX_COMPILE_STDCXX([14], [noext], [optional])]) |
| | 432 | AS_IF([test "x$HAVE_CXX14" = x1], |
| | 433 | [HAVE_MODERN_CXX=yes]) |
| | 434 | AS_IF([test "x$HAVE_MODERN_CXX" = x], |
| | 435 | [AX_CXX_COMPILE_STDCXX([11], [noext], [optional])]) |
| | 436 | AS_IF([test "x$HAVE_CXX11" = x1], |
| | 437 | [HAVE_MODERN_CXX=yes]) |
| | 438 | AS_IF([test "x$HAVE_MODERN_CXX" = x], |
| | 439 | [SR_APPEND([sr_cxx_missing], [', '], ['C++11'])]) |
| | 440 | |
| | 441 | # The C++ bindings need glibmm. |
| | 442 | # Prefer glibmm-2.4 for backwards compatibility. |
| | 443 | # Accept glibmm-2.68 when glibmm-2.4 is not available. |
| | 444 | sr_have_glibmm=no |
| | 445 | AS_IF([test "x$sr_have_glibmm" != xyes], |
| | 446 | [SR_PKG_CHECK([glibmm24], [SR_PKGLIBS_CXX], [glibmm-2.4 >= 2.32.0])]) |
| | 447 | AS_IF([test "x$sr_have_glibmm24" = xyes], |
| | 448 | [SR_APPEND([SR_GLIBMM_REQUIRES], ['glibmm-2.4 >= 2.32.0']) |
| | 449 | sr_have_glibmm=yes]) |
| | 450 | AS_IF([test "x$sr_have_glibmm" != xyes], |
| | 451 | [SR_PKG_CHECK([glibmm268], [SR_PKGLIBS_CXX], [glibmm-2.68 >= 2.68.0])]) |
| | 452 | AS_IF([test "x$sr_have_glibmm268" = xyes], |
| | 453 | [SR_APPEND([SR_GLIBMM_REQUIRES], ['glibmm-2.68 >= 2.68.0']) |
| | 454 | sr_have_glibmm=yes]) |
| | 455 | AS_IF([test "x$sr_have_glibmm" = xyes], |
| | 456 | [AC_SUBST(SR_GLIBMM_REQUIRES)], |
| | 457 | [SR_APPEND([sr_cxx_missing], [', '], [glibmm])]) |
| | 458 | |
| | 459 | # The C++ bindings use Doxygen to parse libsigrok symbols. |
| | 460 | AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes], [no]) |
| | 461 | AS_IF([test "x$HAVE_DOXYGEN" != xyes], |
| | 462 | [SR_APPEND([sr_cxx_missing], [', '], [Doxygen])]) |
| | 463 | |
| | 464 | # Link C++ code with gnustl_shared if it exists (Android) |
| | 465 | SR_SEARCH_LIBS([SR_EXTRA_CXX_LIBS], [__cxa_throw], [gnustl_shared]) |
| | 466 | |
| | 467 | # Python is needed for the C++ bindings. |
| | 468 | AM_PATH_PYTHON([2.7], |
| | 469 | [HAVE_PYTHON=yes], |
| | 470 | [HAVE_PYTHON=no |
| | 471 | SR_APPEND([sr_cxx_missing], [', '], [Python])]) |
| | 472 | |
| | 473 | AS_IF([test -z "$sr_cxx_missing"], |
| | 474 | [BINDINGS_CXX=$enable_cxx], [BINDINGS_CXX=no]) |
| | 475 | AM_CONDITIONAL([BINDINGS_CXX], [test "x$BINDINGS_CXX" = xyes]) |
| | 476 | |
| | 477 | # C++ bindings want stoi and stod. |
| | 478 | AM_COND_IF([BINDINGS_CXX], [ |
| | 479 | AC_CACHE_CHECK([for stoi and stod], [sr_cv_have_stoi_stod], |
| | 480 | [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string>]], |
| | 481 | [[(void) std::stoi("1"); (void) std::stod("1.0");]])], |
| | 482 | [sr_cv_have_stoi_stod=yes], [sr_cv_have_stoi_stod=no])]) |
| | 483 | AS_IF([test "x$sr_cv_have_stoi_stod" = xyes], |
| | 484 | [AC_DEFINE([HAVE_STOI_STOD], [1], |
| | 485 | [Specifies whether we have the stoi and stod functions.])]) |
| | 486 | # In theory std::stoul() should have identical availability |
| | 487 | # as std::stoi() and std::stod() have. All of them are C++11. |
| | 488 | # But we play it safe here, and check support individually. |
| | 489 | AC_CACHE_CHECK([for stoul], [sr_cv_have_stoul], |
| | 490 | [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string>]], |
| | 491 | [[(void) std::stoul("1");]])], |
| | 492 | [sr_cv_have_stoul=yes], [sr_cv_have_stoul=no])]) |
| | 493 | AS_IF([test "x$sr_cv_have_stoul" = xyes], |
| | 494 | [AC_DEFINE([HAVE_STOUL], [1], |
| | 495 | [Specifies whether we have the std::stoul function.])]) |
| | 496 | ]) |
| | 497 | |
| | 498 | ####################### |
| | 499 | ## Python bindings ## |
| | 500 | ####################### |
| | 501 | |
| | 502 | AS_IF([test "x$BINDINGS_CXX" = xyes], |
| | 503 | [sr_python_missing=], |
| | 504 | [sr_python_missing='C++ bindings']) |
| | 505 | |
| | 506 | # Extract major and minor version number of the Python interpreter. |
| | 507 | sr_pymajor=${PYTHON_VERSION%%.*} |
| | 508 | sr_pyminor=${PYTHON_VERSION#*.} |
| | 509 | |
| | 510 | # The Python bindings need Python development files. Check for either |
| | 511 | # Python 3 or Python 2 headers depending on the interpreter version. |
| | 512 | SR_PKG_CHECK([python_dev], [SR_PKGLIBS_PYTHON], |
| | 513 | [python = $PYTHON_VERSION], |
| | 514 | [python$sr_pymajor = $PYTHON_VERSION], |
| | 515 | [python$sr_pymajor$sr_pyminor = $PYTHON_VERSION], |
| | 516 | [python-$PYTHON_VERSION = $PYTHON_VERSION]) |
| | 517 | |
| | 518 | AS_IF([test "x$sr_have_python_dev" != xyes], |
| | 519 | [SR_APPEND([sr_python_missing], [', '], [Headers])]) |
| | 520 | |
| | 521 | # PyGObject is needed for the Python bindings. |
| | 522 | SR_PKG_CHECK([pygobject], [SR_PKGLIBS_PYTHON], [pygobject-3.0 >= 3.0.0]) |
| | 523 | AS_IF([test "x$sr_have_pygobject" != xyes], |
| | 524 | [SR_APPEND([sr_python_missing], [', '], [PyGObject])]) |
| | 525 | |
| | 526 | PKG_CHECK_EXISTS([pygobject-3.0 < 3.7.91], |
| | 527 | [AC_DEFINE([PYGOBJECT_FLAGS_SIGNED], [1], |
| | 528 | [Whether last argument to pyg_flags_get_value() is signed.])]) |
| | 529 | |
| | 530 | # The Python bindings need the setuptools and numpy Python modules. |
| | 531 | # We'll let it go through even if the AX macro wasn't found, as the |
| | 532 | # Python modules may still be there. |
| | 533 | m4_ifdef([AX_PYTHON_MODULE], [ |
| | 534 | AX_PYTHON_MODULE([setuptools]) |
| | 535 | AX_PYTHON_MODULE([numpy]) |
| | 536 | ], [ |
| | 537 | HAVE_PYMOD_SETUPTOOLS=yes |
| | 538 | HAVE_PYMOD_NUMPY=yes |
| | 539 | m4_warn([unsupported], |
| | 540 | [Missing macro AX_PYTHON_MODULE: no check for setuptools and numpy]) |
| | 541 | ]) |
| | 542 | AS_IF([test "x$HAVE_PYMOD_SETUPTOOLS" != xyes], |
| | 543 | [SR_APPEND([sr_python_missing], [', '], [setuptools])]) |
| | 544 | AS_IF([test "x$HAVE_PYMOD_NUMPY" != xyes], |
| | 545 | [SR_APPEND([sr_python_missing], [', '], [numpy])]) |
| | 546 | |
| | 547 | # The Python bindings use SWIG to generate code. |
| | 548 | AC_CHECK_PROGS([SWIG], [swig swig4.0 swig3.0 swig2.0]) |
| | 549 | AS_IF([test "x$SWIG" != x], |
| | 550 | AC_MSG_CHECKING([for $SWIG version]) |
| | 551 | [SWIG_VERSION=`$SWIG -version 2>&1 | sed -n 's/SWIG Version //p'`] |
| | 552 | AC_MSG_RESULT([$SWIG_VERSION])) |
| | 553 | AS_IF([test "x$SWIG" = x], |
| | 554 | [SR_APPEND([sr_python_missing], [', '], [SWIG])]) |
| | 555 | |
| | 556 | AS_IF([test -z "$sr_python_missing"], |
| | 557 | [BINDINGS_PYTHON=$enable_python], [BINDINGS_PYTHON=no]) |
| | 558 | AM_CONDITIONAL([BINDINGS_PYTHON], [test "x$BINDINGS_PYTHON" = xyes]) |
| | 559 | |
| | 560 | ##################### |
| | 561 | ## Ruby bindings ## |
| | 562 | ##################### |
| | 563 | |
| | 564 | AS_IF([test "x$BINDINGS_CXX" = xyes], |
| | 565 | [sr_ruby_missing=], |
| | 566 | [sr_ruby_missing='C++ bindings']) |
| | 567 | |
| | 568 | AC_PATH_PROGS(RUBY, ["${RUBY-ruby}"], []) |
| | 569 | AS_IF([test "x$RUBY" != x], |
| | 570 | AC_MSG_CHECKING([for Ruby version]) |
| | 571 | [RUBY_VERSION=`$RUBY -e 'puts RUBY_VERSION'`] |
| | 572 | AC_MSG_RESULT([$RUBY_VERSION]) |
| | 573 | [RUBY_DLEXT=`$RUBY -rrbconfig -e 'puts RbConfig::CONFIG[["DLEXT"]]'`] |
| | 574 | AC_SUBST(RUBY_DLEXT)) |
| | 575 | |
| | 576 | AS_IF([test "x$RUBY" = x], |
| | 577 | [SR_APPEND([sr_ruby_missing], [', '], [Ruby])]) |
| | 578 | |
| | 579 | # Extract major and minor version number of the Ruby interpreter. |
| | 580 | sr_rbmajor=${RUBY_VERSION%%.*} |
| | 581 | sr_rbminor=${RUBY_VERSION#*.} |
| | 582 | sr_rbminor=${sr_rbminor%%.*} |
| | 583 | |
| | 584 | # The Ruby bindings need Ruby development files. |
| | 585 | SR_PKG_CHECK([ruby_dev], [SR_PKGLIBS_RUBY], |
| | 586 | [ruby >= 2.5.0], |
| | 587 | [ruby-$sr_rbmajor.$sr_rbminor >= 2.5.0]) |
| | 588 | |
| | 589 | AS_IF([test "x$sr_have_ruby_dev" != xyes], |
| | 590 | [SR_APPEND([sr_ruby_missing], [', '], [Headers])]) |
| | 591 | |
| | 592 | # The Ruby bindings use SWIG >= 3.0.8 to generate code. |
| | 593 | AS_IF([test "x$SWIG" = x], |
| | 594 | [SR_APPEND([sr_ruby_missing], [', '], [SWIG])], |
| | 595 | [AS_VERSION_COMPARE($SWIG_VERSION, "3.0.8", |
| | 596 | [SR_APPEND([sr_ruby_missing], [', '], ['SWIG >= 3.0.8'])])]) |
| | 597 | |
| | 598 | AS_IF([test -z "$sr_ruby_missing"], |
| | 599 | [BINDINGS_RUBY=$enable_ruby], [BINDINGS_RUBY=no]) |
| | 600 | AM_CONDITIONAL([BINDINGS_RUBY], [test "x$BINDINGS_RUBY" = xyes]) |
| | 601 | |
| | 602 | #################### |
| | 603 | ## Java bindings ## |
| | 604 | #################### |
| | 605 | |
| | 606 | AS_IF([test "x$BINDINGS_CXX" = xyes], |
| | 607 | [sr_java_missing=], |
| | 608 | [sr_java_missing='C++ bindings']) |
| | 609 | |
| | 610 | # The Java bindings use SWIG to generate code. |
| | 611 | AS_IF([test "x$SWIG" = x], |
| | 612 | [SR_APPEND([sr_java_missing], [', '], [SWIG])]) |
| | 613 | |
| | 614 | # Find Java compiler and JNI includes for Java bindings. |
| | 615 | AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no]) |
| | 616 | AS_IF([test "x$HAVE_JAVAC" = xno], |
| | 617 | [SR_APPEND([sr_java_missing], [', '], [JavaC])]) |
| | 618 | |
| | 619 | AC_ARG_WITH([jni-include-path], |
| | 620 | [AS_HELP_STRING([[--with-jni-include-path=DIR-LIST (space-separated)]], |
| | 621 | [specify JNI include directories [default=detect]])], |
| | 622 | [JNI_INCLUDE_DIRS=" $withval"], [JNI_INCLUDE_DIRS=]) |
| | 623 | |
| | 624 | JNI_CPPFLAGS= |
| | 625 | AS_IF([test "x$enable_java$HAVE_JAVAC" = xyesyes], [ |
| | 626 | AX_PROG_JAVAC |
| | 627 | AS_IF([test -z "$JNI_INCLUDE_DIRS" && test "x$cross_compiling" != xyes], [ |
| | 628 | ## Work around the totally broken logic in AX_JNI_INCLUDE_DIR: |
| | 629 | ## If we can find jni.h without any special search path, skip |
| | 630 | ## the execution of the broken macro to increase our chances of |
| | 631 | ## success. |
| | 632 | AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <jni.h>]], [])],, |
| | 633 | [AX_JNI_INCLUDE_DIR]) |
| | 634 | ]) |
| | 635 | ]) |
| | 636 | for sr_dir in $JNI_INCLUDE_DIRS |
| | 637 | do |
| | 638 | SR_APPEND([JNI_CPPFLAGS], ["-I$sr_dir"]) |
| | 639 | done |
| | 640 | AC_SUBST([JNI_CPPFLAGS]) |
| | 641 | |
| | 642 | sr_save_cppflags=$CPPFLAGS |
| | 643 | SR_APPEND([CPPFLAGS], [$JNI_CPPFLAGS]) |
| | 644 | AC_CHECK_HEADER([jni.h],, |
| | 645 | [SR_APPEND([sr_java_missing], [', '], ['JNI headers'])]) |
| | 646 | CPPFLAGS=$sr_save_cppflags |
| | 647 | |
| | 648 | AS_IF([test -z "$sr_java_missing"], |
| | 649 | [BINDINGS_JAVA=$enable_java], [BINDINGS_JAVA=no]) |
| | 650 | AM_CONDITIONAL([BINDINGS_JAVA], [test "x$BINDINGS_JAVA" = xyes]) |
| | 651 | |
| | 652 | ############################## |
| | 653 | ## Finalize configuration ## |
| | 654 | ############################## |
| | 655 | |
| | 656 | # Add mandatory dependencies to module list. |
| | 657 | SR_APPEND([SR_PKGLIBS], ['libzip >= 0.10']) |
| | 658 | AC_SUBST([SR_PKGLIBS]) |
| | 659 | |
| | 660 | # Retrieve the compile and link flags for all modules combined. |
| | 661 | # Also, bail out at this point if any module dependency is not met. |
| | 662 | PKG_CHECK_MODULES([LIBSIGROK], [glib-2.0 >= 2.32.0 $SR_PKGLIBS]) |
| | 663 | PKG_CHECK_MODULES([TESTS], [$SR_PKGLIBS_TESTS glib-2.0 $SR_PKGLIBS]) |
| | 664 | |
| | 665 | # SR_PKGLIBS_CXX may be empty, so only invoke these checks when |
| | 666 | # the C++ bindings are enabled. |
| | 667 | AM_COND_IF([BINDINGS_CXX], [ |
| | 668 | PKG_CHECK_MODULES([LIBSIGROKCXX], [$SR_PKGLIBS_CXX]) |
| | 669 | PKG_CHECK_MODULES([PYSIGROK], [$SR_PKGLIBS_PYTHON $SR_PKGLIBS_CXX]) |
| | 670 | PKG_CHECK_MODULES([RBSIGROK], [$SR_PKGLIBS_RUBY $SR_PKGLIBS_CXX], [AC_SUBST(RBSIGROK_EXTDIR, "lib/$($PKG_CONFIG --variable=sitearch $SR_PKGLIBS_RUBY)/$($PKG_CONFIG --variable=RUBY_BASE_NAME $SR_PKGLIBS_RUBY)/vendor_ruby/$($PKG_CONFIG --variable=ruby_version $SR_PKGLIBS_RUBY)")]) |
| | 671 | ]) |
| | 672 | |
| | 673 | # Check for specific libusb features, now that we know the CFLAGS. |
| | 674 | # Also check for version dependent libftdi features. |
| | 675 | AC_LANG([C]) |
| | 676 | sr_save_cflags=$CFLAGS |
| | 677 | sr_save_libs=$LIBS |
| | 678 | CFLAGS="$LIBSIGROK_CFLAGS $CFLAGS" |
| | 679 | LIBS="$LIBSIGROK_LIBS $LIBS" |
| | 680 | AC_CHECK_TYPES([libusb_os_handle], |
| | 681 | [sr_have_libusb_os_handle=yes], [sr_have_libusb_os_handle=no], |
| | 682 | [[#include <libusb.h>]]) |
| | 683 | AC_CHECK_FUNCS([zip_discard]) |
| | 684 | AC_CHECK_FUNCS([ftdi_tciflush ftdi_tcoflush ftdi_tcioflush]) |
| | 685 | LIBS=$sr_save_libs |
| | 686 | CFLAGS=$sr_save_cflags |
| | 687 | |
| | 688 | sr_glib_version=`$PKG_CONFIG --modversion glib-2.0 2>&AS_MESSAGE_LOG_FD` |
| | 689 | sr_libzip_version=`$PKG_CONFIG --modversion libzip 2>&AS_MESSAGE_LOG_FD` |
| | 690 | sr_zlib_version=`$PKG_CONFIG --modversion zlib 2>&AS_MESSAGE_LOG_FD` |
| | 691 | |
| | 692 | AC_DEFINE_UNQUOTED([CONF_LIBZIP_VERSION], ["$sr_libzip_version"], |
| | 693 | [Build-time version of libzip.]) |
| | 694 | AC_DEFINE_UNQUOTED([CONF_ZLIB_VERSION], ["$sr_zlib_version"], |
| | 695 | [Build-time version of zlib.]) |
| | 696 | AC_DEFINE_UNQUOTED([CONF_HOST], ["$host"], |
| | 697 | [The canonical host libsigrok will run on.]) |
| | 698 | |
| | 699 | AC_CONFIG_FILES([Makefile libsigrok.pc bindings/cxx/libsigrokcxx.pc]) |
| | 700 | |
| | 701 | AC_OUTPUT |
| | 702 | |
| | 703 | # Prepare bindings report messages. |
| | 704 | m4_define([SR_PREPARE_BINDING_REPORT], [ |
| | 705 | sr_report_$1= |
| | 706 | test -z "$sr_$1_missing" || sr_report_$1=" (missing: $sr_$1_missing)" |
| | 707 | test "x$enable_$1" = xyes || sr_report_$1=' (disabled)' |
| | 708 | ]) |
| | 709 | m4_map_args([SR_PREPARE_BINDING_REPORT], [cxx], [python], [ruby], [java]) |
| | 710 | |
| | 711 | cat >&AS_MESSAGE_FD <<_EOF |
| | 712 | |
| | 713 | libsigrok configuration summary: |
| | 714 | - Package version................. $SR_PACKAGE_VERSION |
| | 715 | - Version string suffix .......... $SR_PACKAGE_VERSION_STRING_SUFFIX |
| | 716 | - Library ABI version............. $SR_LIB_VERSION |
| | 717 | - Prefix.......................... $prefix |
| | 718 | - Building on..................... $build |
| | 719 | - Building for.................... $host |
| | 720 | - Building shared / static........ $enable_shared / $enable_static |
| | 721 | |
| | 722 | Compile configuration: |
| | 723 | - C compiler...................... $CC |
| | 724 | - C compiler version.............. $sr_cc_version |
| | 725 | - C compiler flags................ $CFLAGS |
| | 726 | - Additional C compiler flags..... $SR_EXTRA_CFLAGS |
| | 727 | - C compiler warnings............. $SR_WFLAGS |
| | 728 | - C++ compiler.................... $CXX |
| | 729 | - C++ compiler version............ $sr_cxx_version |
| | 730 | - C++ compiler flags.............. $CXXFLAGS |
| | 731 | - C++ compiler warnings........... $SR_WXXFLAGS |
| | 732 | - Linker flags.................... $LDFLAGS |
| | 733 | |
| | 734 | Detected libraries (required): |
| | 735 | - glib-2.0 >= 2.32.0.............. $sr_glib_version |
| | 736 | - libzip >= 0.10.................. $sr_libzip_version |
| | 737 | |
| | 738 | Detected libraries (optional): |
| | 739 | $sr_pkglibs_summary |
| | 740 | Enabled hardware drivers: |
| | 741 | $sr_driver_summary |
| | 742 | Enabled serial communication transports: |
| | 743 | - serial comm ................... $sr_have_serial_comm |
| | 744 | - libserialport ................. $sr_have_libserialport |
| | 745 | - hidapi ........................ $sr_have_libhidapi |
| | 746 | - bluetooth ..................... $sr_have_bluetooth |
| | 747 | - bluez ......................... $sr_have_libbluez |
| | 748 | |
| | 749 | Enabled SCPI backends: |
| | 750 | - TCP............................. yes |
| | 751 | - SunRPC ......................... $sr_cv_have_sunrpc |
| | 752 | - TI-RPC ......................... $sr_cv_have_tirpc |
| | 753 | - RPC............................. $sr_cv_have_rpc |
| | 754 | - serial.......................... $sr_have_serial_comm |
| | 755 | - VISA............................ $sr_have_librevisa |
| | 756 | - GPIB............................ $sr_have_libgpib |
| | 757 | - USBTMC.......................... $sr_have_libusb |
| | 758 | |
| | 759 | Enabled language bindings: |
| | 760 | - C++............................. $BINDINGS_CXX$sr_report_cxx |
| | 761 | - Python.......................... $BINDINGS_PYTHON$sr_report_python |
| | 762 | - Ruby............................ $BINDINGS_RUBY$sr_report_ruby |
| | 763 | - Java............................ $BINDINGS_JAVA$sr_report_java |
| | 764 | |
| | 765 | _EOF |
| | 766 | |
| | 767 | # Emit a warning if the C++ bindings are not being built. |
| | 768 | AM_COND_IF([BINDINGS_CXX], [], [ |
| | 769 | cat >&AS_MESSAGE_FD <<_EOF |
| | 770 | =============================================================================== |
| | 771 | WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING |
| | 772 | =============================================================================== |
| | 773 | === === |
| | 774 | === The libsigrok C++ bindings are not being built since you === |
| | 775 | === are missing one or more dependencies (see above)! === |
| | 776 | === === |
| | 777 | === This means you won't be able to compile frontends that require === |
| | 778 | === the C++ bindings (such as PulseView)! You also won't be able to build === |
| | 779 | === other bindings and frontends using those (such as sigrok-meter)! === |
| | 780 | === === |
| | 781 | =============================================================================== |
| | 782 | WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING |
| | 783 | =============================================================================== |
| | 784 | |
| | 785 | _EOF |
| | 786 | ]) |
projects / libsigrok.git / blame_incremental