]>
Commit | Line | Data |
---|---|---|
1 | ## | |
2 | ## This file is part of the libsigrok project. | |
3 | ## | |
4 | ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com> | |
5 | ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com> | |
6 | ## | |
7 | ## This program is free software: you can redistribute it and/or modify | |
8 | ## it under the terms of the GNU General Public License as published by | |
9 | ## the Free Software Foundation, either version 3 of the License, or | |
10 | ## (at your option) any later version. | |
11 | ## | |
12 | ## This program is distributed in the hope that it will be useful, | |
13 | ## but WITHOUT ANY WARRANTY; without even the implied warranty of | |
14 | ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the | |
15 | ## GNU General Public License for more details. | |
16 | ## | |
17 | ## You should have received a copy of the GNU General Public License | |
18 | ## along with this program. If not, see <http://www.gnu.org/licenses/>. | |
19 | ## | |
20 | ||
21 | # We require at least autoconf 2.63 (AC_INIT format changed there). | |
22 | AC_PREREQ([2.63]) | |
23 | ||
24 | AC_INIT([libsigrok], [0.4.0], | |
25 | [sigrok-devel@lists.sourceforge.net], | |
26 | [libsigrok], [http://www.sigrok.org]) | |
27 | AC_CONFIG_MACRO_DIR([m4]) | |
28 | AC_CONFIG_AUX_DIR([autostuff]) | |
29 | AC_CONFIG_HEADERS([config.h include/libsigrok/version.h]) | |
30 | ||
31 | # We require at least automake 1.11 (needed for 'silent rules'). | |
32 | AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define nostdinc subdir-objects check-news color-tests]) | |
33 | m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])]) | |
34 | m4_ifdef([AM_PROG_AR], [AM_PROG_AR]) | |
35 | ||
36 | AH_TOP([#ifndef SR_CONFIG_H | |
37 | #define SR_CONFIG_H /* To stop multiple inclusions. */]) | |
38 | AH_BOTTOM([#endif /* SR_CONFIG_H */]) | |
39 | ||
40 | # Checks for programs. | |
41 | AC_PROG_CC | |
42 | AC_PROG_CXX | |
43 | AC_PROG_INSTALL | |
44 | AC_PROG_LN_S | |
45 | ||
46 | # Required for per-target flags or subdir-objects with C sources. | |
47 | AM_PROG_CC_C_O | |
48 | ||
49 | # Initialize libtool. | |
50 | LT_INIT | |
51 | ||
52 | # Set up the libsigrok version defines. | |
53 | SR_PKG_VERSION_SET([SR_PACKAGE_VERSION], [AC_PACKAGE_VERSION]) | |
54 | ||
55 | # Library version for libsigrok (NOT the same as the package version). | |
56 | # Carefully read the libtool docs before updating these numbers! | |
57 | # The algorithm for determining which number to change (and how) is nontrivial! | |
58 | # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info | |
59 | SR_LIB_VERSION_SET([SR_LIB_VERSION], [2:0:0]) | |
60 | ||
61 | ############################# | |
62 | ## Optional dependencies ## | |
63 | ############################# | |
64 | ||
65 | # Initialize pkg-config. | |
66 | # We require at least 0.22, as "Requires.private" behaviour changed there. | |
67 | PKG_PROG_PKG_CONFIG([0.22]) | |
68 | ||
69 | # Keep track of all checked modules so we can list them at the end. | |
70 | SR_PKG_CHECK_SUMMARY([sr_pkglibs_summary]) | |
71 | ||
72 | # Collect the pkg-config module names of all dependencies in SR_PKGLIBS. | |
73 | # These are used to derive the compiler flags and for the "Requires.private" | |
74 | # field in the generated libsigrok.pc file. | |
75 | SR_VAR_OPT_PKG([SR_PKGLIBS], [sr_deps_avail]) | |
76 | SR_PKGLIBS_CHECK= | |
77 | SR_PKGLIBS_CXX= | |
78 | SR_PKGLIBS_PYTHON= | |
79 | ||
80 | SR_ARG_OPT_PKG([libserialport], [LIBSERIALPORT], [NEED_SERIAL], | |
81 | [libserialport >= 0.1.1]) | |
82 | ||
83 | SR_ARG_OPT_PKG([libftdi], [LIBFTDI],, | |
84 | [libftdi1 >= 1.0], [libftdi >= 0.16]) | |
85 | ||
86 | # FreeBSD comes with an "integrated" libusb-1.0-style USB API. | |
87 | # This means libusb-1.0 is always available; no need to check for it. | |
88 | AS_CASE([$host], [*freebsd*], [sr_have_libusb=yes]) | |
89 | ||
90 | SR_ARG_OPT_PKG([libusb], [LIBUSB_1_0], [NEED_USB], | |
91 | [libusb-1.0 >= 1.0.16]) | |
92 | ||
93 | SR_ARG_OPT_PKG([librevisa], [LIBREVISA], [NEED_VISA], | |
94 | [librevisa >= 0.0.20130412]) | |
95 | ||
96 | SR_ARG_OPT_PKG([libgpib], [LIBGPIB], [NEED_GPIB], | |
97 | [libgpib]) | |
98 | ||
99 | ###################### | |
100 | ## Feature checks ## | |
101 | ###################### | |
102 | ||
103 | # The Check unit testing framework is optional. Disable if not found. | |
104 | SR_PKG_CHECK([check], [SR_PKGLIBS_CHECK], [check >= 0.9.4]) | |
105 | AM_CONDITIONAL([HAVE_CHECK], [test "x$sr_have_check" = xyes]) | |
106 | ||
107 | AC_LANG([C]) | |
108 | ||
109 | # Enable the C99 standard if possible, and enforce the use | |
110 | # of SR_API to explicitly mark all public API functions. | |
111 | SR_EXTRA_CFLAGS= | |
112 | SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [C99], [-std=c99 -c99 -AC99 -qlanglvl=extc99]) | |
113 | SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [visibility], [-fvisibility=hidden]) | |
114 | ||
115 | SR_ARG_ENABLE_WARNINGS([SR_WFLAGS], [-Wall], [-Wall -Wextra -Wmissing-prototypes]) | |
116 | ||
117 | # Check host characteristics. | |
118 | AC_C_BIGENDIAN | |
119 | ||
120 | AC_CHECK_HEADERS([sys/mman.h], [SR_APPEND([sr_deps_avail], [sys_mman_h])]) | |
121 | AC_CHECK_HEADERS([sys/ioctl.h], [SR_APPEND([sr_deps_avail], [sys_ioctl_h])]) | |
122 | AC_CHECK_HEADERS([sys/timerfd.h], [SR_APPEND([sr_deps_avail], [sys_timerfd_h])]) | |
123 | ||
124 | # We need to link against the Winsock2 library for SCPI over TCP. | |
125 | AS_CASE([$host], [*-mingw*], [SR_EXTRA_LIBS='-lws2_32'], [SR_EXTRA_LIBS=]) | |
126 | ||
127 | # libm (the standard math library) is always needed. | |
128 | SR_SEARCH_LIBS([SR_EXTRA_LIBS], [pow], [m]) | |
129 | ||
130 | # RPC is only needed for VXI support. | |
131 | AC_CACHE_CHECK([for RPC support], [sr_cv_have_rpc], | |
132 | [AC_LINK_IFELSE([AC_LANG_PROGRAM( | |
133 | [[#include <rpc/rpc.h>]m4_newline[CLIENT *rpc_test(void);]], | |
134 | [[(void) clnt_create("", 0, 0, "");]])], | |
135 | [sr_cv_have_rpc=yes], [sr_cv_have_rpc=no])]) | |
136 | AS_IF([test "x$sr_cv_have_rpc" = xyes], | |
137 | [AC_DEFINE([HAVE_RPC], [1], [Specifies whether we have RPC support.])]) | |
138 | # VXI support is only compiled if RPC support was found. | |
139 | AM_CONDITIONAL([NEED_RPC], [test "x$sr_cv_have_rpc" = xyes]) | |
140 | ||
141 | ######################## | |
142 | ## Hardware drivers ## | |
143 | ######################## | |
144 | ||
145 | # Keep track of all drivers so we can list them at the end. | |
146 | SR_VAR_SUMMARY([sr_driver_summary]) | |
147 | ||
148 | # Check whether the sr_deps_avail list contains all of the arguments. | |
149 | # Unavailable dependencies are collected in sr_deps_missing. | |
150 | sr_check_driver_deps() { | |
151 | sr_deps_missing= | |
152 | for sr_dep | |
153 | do | |
154 | AS_CASE([" $sr_deps_avail "], [*" $sr_dep "*],, | |
155 | [SR_APPEND([sr_deps_missing], [', '], [$sr_dep])]) | |
156 | done | |
157 | test -z "$sr_deps_missing" || return 1 | |
158 | } | |
159 | ||
160 | AC_ARG_ENABLE([all-drivers], | |
161 | [AS_HELP_STRING([--enable-all-drivers], | |
162 | [enable all drivers by default [default=yes]])], | |
163 | [], [enable_all_drivers=yes]) | |
164 | ||
165 | ## _SR_DRIVER(Device name, driver-name, var-name, [dependencies...]) | |
166 | m4_define([_SR_DRIVER], [ | |
167 | AC_ARG_ENABLE([$2], | |
168 | [AS_HELP_STRING([--enable-$2], [enable $1 support])], | |
169 | [$3=$enableval], [$3=$enable_all_drivers]) | |
170 | ||
171 | AS_IF([test "x[$]$3" = xyes], [sr_hw_info=yes[]m4_ifval([$4], [ | |
172 | sr_check_driver_deps $4 \ | |
173 | || $3=no sr_hw_info="no (missing: $sr_deps_missing)" | |
174 | ])], [sr_hw_info='no (disabled)']) | |
175 | sr_driver_summary_append "$2" "$sr_hw_info" | |
176 | ||
177 | AM_CONDITIONAL([$3], [test "x[$]$3" = xyes]) | |
178 | AM_COND_IF([$3], [AC_DEFINE([HAVE_$3], [1], [Whether to support $1 device.])]) | |
179 | ]) | |
180 | ||
181 | ## SR_DRIVER(Device name, driver-name, [dependencies...]) | |
182 | m4_define([SR_DRIVER], | |
183 | [_SR_DRIVER([$1], [$2], m4_expand([AS_TR_CPP([HW_$2])]), [$3])]) | |
184 | ||
185 | SR_DRIVER([Agilent DMM], [agilent-dmm], [libserialport]) | |
186 | SR_DRIVER([Appa 55II], [appa-55ii], [libserialport]) | |
187 | SR_DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma], [libftdi]) | |
188 | SR_DRIVER([Atten PPS3xxx], [atten-pps3xxx], [libserialport]) | |
189 | SR_DRIVER([BayLibre ACME], [baylibre-acme], [sys_timerfd_h]) | |
190 | SR_DRIVER([BeagleLogic], [beaglelogic], [sys_mman_h sys_ioctl_h]) | |
191 | SR_DRIVER([Brymen BM86x], [brymen-bm86x], [libusb]) | |
192 | SR_DRIVER([Brymen DMM], [brymen-dmm], [libserialport]) | |
193 | SR_DRIVER([CEM DT-885x], [cem-dt-885x], [libserialport]) | |
194 | SR_DRIVER([Center 3xx], [center-3xx], [libserialport]) | |
195 | SR_DRIVER([ChronoVu LA], [chronovu-la], [libftdi]) | |
196 | SR_DRIVER([Colead SLM], [colead-slm], [libserialport]) | |
197 | SR_DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu], [libserialport]) | |
198 | SR_DRIVER([DER EE DE-5000], [deree-de5000], [libserialport]) | |
199 | SR_DRIVER([demo], [demo]) | |
200 | SR_DRIVER([Fluke DMM], [fluke-dmm], [libserialport]) | |
201 | SR_DRIVER([fx2lafw], [fx2lafw], [libusb]) | |
202 | SR_DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x], [libserialport]) | |
203 | SR_DRIVER([Hameg HMO], [hameg-hmo], [libserialport]) | |
204 | SR_DRIVER([Hantek DSO], [hantek-dso], [libusb]) | |
205 | SR_DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2], [libusb]) | |
206 | SR_DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus], [libftdi]) | |
207 | SR_DRIVER([Kecheng KC-330B], [kecheng-kc-330b], [libusb]) | |
208 | SR_DRIVER([Lascar EL-USB], [lascar-el-usb], [libusb]) | |
209 | SR_DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx], [libserialport]) | |
210 | SR_DRIVER([maynuo-m97], [maynuo-m97]) | |
211 | SR_DRIVER([MIC 985xx], [mic-985xx], [libserialport]) | |
212 | SR_DRIVER([Motech LPS 30x], [motech-lps-30x], [libserialport]) | |
213 | SR_DRIVER([Norma DMM], [norma-dmm], [libserialport]) | |
214 | SR_DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer], [libserialport]) | |
215 | SR_DRIVER([Pipistrello-OLS], [pipistrello-ols], [libftdi]) | |
216 | SR_DRIVER([Rigol DS], [rigol-ds]) | |
217 | SR_DRIVER([Saleae Logic16], [saleae-logic16], [libusb]) | |
218 | SR_DRIVER([SCPI PPS], [scpi-pps]) | |
219 | SR_DRIVER([serial DMM], [serial-dmm], [libserialport]) | |
220 | SR_DRIVER([Sysclk LWLA], [sysclk-lwla], [libusb]) | |
221 | SR_DRIVER([Teleinfo], [teleinfo], [libserialport]) | |
222 | SR_DRIVER([Testo], [testo], [libusb]) | |
223 | SR_DRIVER([Tondaj SL-814], [tondaj-sl-814], [libserialport]) | |
224 | SR_DRIVER([UNI-T DMM], [uni-t-dmm], [libusb]) | |
225 | SR_DRIVER([UNI-T UT32x], [uni-t-ut32x], [libusb]) | |
226 | SR_DRIVER([Victor DMM], [victor-dmm], [libusb]) | |
227 | SR_DRIVER([Yokogawa DL/DLM], [yokogawa-dlm]) | |
228 | SR_DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube], [libusb]) | |
229 | ||
230 | ############################### | |
231 | ## Language bindings setup ## | |
232 | ############################### | |
233 | ||
234 | AC_LANG([C++]) | |
235 | SR_ARG_ENABLE_WARNINGS([SR_WXXFLAGS], [-Wall], [-Wall -Wextra]) | |
236 | ||
237 | AC_ARG_ENABLE([bindings], | |
238 | [AS_HELP_STRING([--enable-bindings], [build language bindings [default=yes]])], | |
239 | [], [enable_bindings=yes]) | |
240 | ||
241 | AC_ARG_ENABLE([cxx], | |
242 | [AS_HELP_STRING([--enable-cxx], [build C++ bindings [default=yes]])], | |
243 | [], [enable_cxx=$enable_bindings]) | |
244 | ||
245 | AC_ARG_ENABLE([python], | |
246 | [AS_HELP_STRING([--enable-python], [build Python bindings [default=yes]])], | |
247 | [], [enable_python=$enable_bindings]) | |
248 | ||
249 | AC_ARG_ENABLE([java], | |
250 | [AS_HELP_STRING([--enable-java], [build Java bindings [default=yes]])], | |
251 | [], [enable_java=$enable_bindings]) | |
252 | ||
253 | #################### | |
254 | ## C++ bindings ## | |
255 | #################### | |
256 | ||
257 | sr_cxx_missing= | |
258 | ||
259 | # Check if the C++ compiler supports the C++11 standard. | |
260 | AX_CXX_COMPILE_STDCXX_11([noext], [optional]) | |
261 | AS_IF([test "x$HAVE_CXX11" != x1], | |
262 | [SR_APPEND([sr_cxx_missing], [', '], ['C++11'])]) | |
263 | ||
264 | # The C++ bindings need glibmm. | |
265 | SR_PKG_CHECK([glibmm], [SR_PKGLIBS_CXX], [glibmm-2.4 >= 2.32.0]) | |
266 | AS_IF([test "x$sr_have_glibmm" != xyes], | |
267 | [SR_APPEND([sr_cxx_missing], [', '], [glibmm])]) | |
268 | ||
269 | # The C++ bindings use Doxygen to parse libsigrok symbols. | |
270 | AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes], [no]) | |
271 | AS_IF([test "x$HAVE_DOXYGEN" != xyes], | |
272 | [SR_APPEND([sr_cxx_missing], [', '], [Doxygen])]) | |
273 | ||
274 | # Python is needed for the C++ bindings. | |
275 | AM_PATH_PYTHON([2.7], | |
276 | [HAVE_PYTHON=yes], | |
277 | [HAVE_PYTHON=no | |
278 | SR_APPEND([sr_cxx_missing], [', '], [Python])]) | |
279 | ||
280 | AS_IF([test -z "$sr_cxx_missing"], | |
281 | [BINDINGS_CXX=$enable_cxx], [BINDINGS_CXX=no]) | |
282 | AM_CONDITIONAL([BINDINGS_CXX], [test "x$BINDINGS_CXX" = xyes]) | |
283 | ||
284 | # C++ bindings want stoi and stod. | |
285 | AM_COND_IF([BINDINGS_CXX], [ | |
286 | AC_CACHE_CHECK([for stoi and stod], [sr_cv_have_stoi_stod], | |
287 | [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string>]], | |
288 | [[(void) std::stoi("1"); (void) std::stod("1.0");]])], | |
289 | [sr_cv_have_stoi_stod=yes], [sr_cv_have_stoi_stod=no])]) | |
290 | AS_IF([test "x$sr_cv_have_stoi_stod" = xyes], | |
291 | [AC_DEFINE([HAVE_STOI_STOD], [1], | |
292 | [Specifies whether we have the stoi and stod functions.])]) | |
293 | ]) | |
294 | ||
295 | ####################### | |
296 | ## Python bindings ## | |
297 | ####################### | |
298 | ||
299 | AS_IF([test "x$BINDINGS_CXX" = xyes], | |
300 | [sr_python_missing=], | |
301 | [sr_python_missing='C++ bindings']) | |
302 | ||
303 | # The Python bindings need Python development files. | |
304 | SR_PKG_CHECK([python_dev], [SR_PKGLIBS_PYTHON], | |
305 | [python >= 2.7], [python2 >= 2.7], [python27 >= 2.7]) | |
306 | AS_IF([test "x$sr_have_python_dev" != xyes], | |
307 | [SR_APPEND([sr_python_missing], [', '], [Headers])]) | |
308 | ||
309 | # PyGObject is needed for the Python bindings. | |
310 | SR_PKG_CHECK([pygobject], [SR_PKGLIBS_PYTHON], [pygobject-3.0 >= 3.0.0]) | |
311 | AS_IF([test "x$sr_have_pygobject" != xyes], | |
312 | [SR_APPEND([sr_python_missing], [', '], [PyGObject])]) | |
313 | ||
314 | PKG_CHECK_EXISTS([pygobject-3.0 < 3.7.91], | |
315 | [AC_DEFINE([PYGOBJECT_FLAGS_SIGNED], [1], | |
316 | [Whether last argument to pyg_flags_get_value() is signed.])]) | |
317 | ||
318 | # The Python bindings need the setuptools Python module. | |
319 | # We'll let it go through even if the AX macro wasn't found, | |
320 | # as the Python module may still be there. | |
321 | HAVE_PYMOD_SETUPTOOLS=yes | |
322 | m4_ifdef([AX_PYTHON_MODULE], | |
323 | [AX_PYTHON_MODULE([setuptools])], | |
324 | [m4_warn([unsupported], [Missing macro AX_PYTHON_MODULE: no setuptools check])]) | |
325 | AS_IF([test "x$HAVE_PYMOD_SETUPTOOLS" != xyes], | |
326 | [SR_APPEND([sr_python_missing], [', '], [setuptools])]) | |
327 | ||
328 | # The Python bindings use SWIG to generate code. | |
329 | AC_CHECK_PROGS([SWIG], [swig swig3.0 swig2.0]) | |
330 | AS_IF([test "x$SWIG" = x], | |
331 | [SR_APPEND([sr_python_missing], [', '], [SWIG])]) | |
332 | ||
333 | AS_IF([test -z "$sr_python_missing"], | |
334 | [BINDINGS_PYTHON=$enable_python], [BINDINGS_PYTHON=no]) | |
335 | AM_CONDITIONAL([BINDINGS_PYTHON], [test "x$BINDINGS_PYTHON" = xyes]) | |
336 | ||
337 | #################### | |
338 | ## Java bindings ## | |
339 | #################### | |
340 | ||
341 | AS_IF([test "x$BINDINGS_CXX" = xyes], | |
342 | [sr_java_missing=], | |
343 | [sr_java_missing='C++ bindings']) | |
344 | ||
345 | # The Java bindings use SWIG to generate code. | |
346 | AS_IF([test "x$SWIG" = x], | |
347 | [SR_APPEND([sr_java_missing], [', '], [SWIG])]) | |
348 | ||
349 | # Find Java compiler and JNI includes for Java bindings. | |
350 | AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no]) | |
351 | AS_IF([test "x$HAVE_JAVAC" = xno], | |
352 | [SR_APPEND([sr_java_missing], [', '], [JavaC])]) | |
353 | ||
354 | AC_ARG_WITH([jni-include-path], | |
355 | [AS_HELP_STRING([[--with-jni-include-path=DIR-LIST (space-separated)]], | |
356 | [specify JNI include directories [default=detect]])], | |
357 | [JNI_INCLUDE_DIRS=" $withval"], [JNI_INCLUDE_DIRS=]) | |
358 | ||
359 | JNI_CPPFLAGS= | |
360 | AS_IF([test "x$enable_java$HAVE_JAVAC" = xyesyes], [ | |
361 | AX_PROG_JAVAC | |
362 | AS_IF([test -z "$JNI_INCLUDE_DIRS" && test "x$cross_compiling" != xyes], [ | |
363 | ## Work around the totally broken logic in AX_JNI_INCLUDE_DIR: | |
364 | ## If we can find jni.h without any special search path, skip | |
365 | ## the execution of the broken macro to increase our chances of | |
366 | ## success. | |
367 | AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <jni.h>]], [])],, | |
368 | [AX_JNI_INCLUDE_DIR]) | |
369 | ]) | |
370 | ]) | |
371 | for sr_dir in $JNI_INCLUDE_DIRS | |
372 | do | |
373 | SR_APPEND([JNI_CPPFLAGS], ["-I$sr_dir"]) | |
374 | done | |
375 | AC_SUBST([JNI_CPPFLAGS]) | |
376 | ||
377 | sr_save_cppflags=$CPPFLAGS | |
378 | SR_APPEND([CPPFLAGS], [$JNI_CPPFLAGS]) | |
379 | AC_CHECK_HEADER([jni.h],, | |
380 | [SR_APPEND([sr_java_missing], [', '], ['JNI headers'])]) | |
381 | CPPFLAGS=$sr_save_cppflags | |
382 | ||
383 | AS_IF([test -z "$sr_java_missing"], | |
384 | [BINDINGS_JAVA=$enable_java], [BINDINGS_JAVA=no]) | |
385 | AM_CONDITIONAL([BINDINGS_JAVA], [test "x$BINDINGS_JAVA" = xyes]) | |
386 | ||
387 | ############################## | |
388 | ## Finalize configuration ## | |
389 | ############################## | |
390 | ||
391 | # Add mandatory dependencies to module list. | |
392 | SR_APPEND([SR_PKGLIBS], ['libzip >= 0.10']) | |
393 | AC_SUBST([SR_PKGLIBS]) | |
394 | ||
395 | # Retrieve the compile and link flags for all modules combined. | |
396 | # Also, bail out at this point if any module dependency is not met. | |
397 | PKG_CHECK_MODULES([LIBSIGROK], [glib-2.0 >= 2.32.0 $SR_PKGLIBS]) | |
398 | PKG_CHECK_MODULES([CHECK], [$SR_PKGLIBS_CHECK glib-2.0 $SR_PKGLIBS]) | |
399 | ||
400 | # SR_PKGLIBS_CXX may be empty, so only invoke these checks when | |
401 | # the C++ bindings are enabled. | |
402 | AM_COND_IF([BINDINGS_CXX], [ | |
403 | PKG_CHECK_MODULES([LIBSIGROKCXX], [$SR_PKGLIBS_CXX]) | |
404 | PKG_CHECK_MODULES([PYSIGROK], [$SR_PKGLIBS_PYTHON $SR_PKGLIBS_CXX]) | |
405 | ]) | |
406 | sr_glib_version=`$PKG_CONFIG --modversion glib-2.0 2>&AS_MESSAGE_LOG_FD` | |
407 | sr_libzip_version=`$PKG_CONFIG --modversion libzip 2>&AS_MESSAGE_LOG_FD` | |
408 | ||
409 | AC_DEFINE_UNQUOTED([CONF_LIBZIP_VERSION], ["$sr_libzip_version"], | |
410 | [Build-time version of libzip.]) | |
411 | AC_DEFINE_UNQUOTED([CONF_HOST], ["$host"], | |
412 | [The canonical host libsigrok will run on.]) | |
413 | ||
414 | AC_CONFIG_FILES([Makefile libsigrok.pc bindings/cxx/libsigrokcxx.pc]) | |
415 | ||
416 | AC_OUTPUT | |
417 | ||
418 | # Prepare bindings report messages. | |
419 | m4_define([SR_PREPARE_BINDING_REPORT], [ | |
420 | sr_report_$1= | |
421 | test -z "$sr_$1_missing" || sr_report_$1=" (missing: $sr_$1_missing)" | |
422 | test "x$enable_$1" = xyes || sr_report_$1=' (disabled)' | |
423 | ]) | |
424 | m4_map_args([SR_PREPARE_BINDING_REPORT], [cxx], [python], [java]) | |
425 | ||
426 | cat >&AS_MESSAGE_FD <<_EOF | |
427 | ||
428 | libsigrok configuration summary: | |
429 | - Package version................. $SR_PACKAGE_VERSION | |
430 | - Library ABI version............. $SR_LIB_VERSION | |
431 | - Prefix.......................... $prefix | |
432 | - Building on..................... $build | |
433 | - Building for.................... $host | |
434 | - Additional C compiler flags..... $SR_EXTRA_CFLAGS | |
435 | - C compiler warnings............. $SR_WFLAGS | |
436 | - C++ compiler warnings........... $SR_WXXFLAGS | |
437 | ||
438 | Detected libraries (required): | |
439 | - glib-2.0 >= 2.32.0.............. $sr_glib_version | |
440 | - libzip >= 0.10.................. $sr_libzip_version | |
441 | ||
442 | Detected libraries (optional): | |
443 | $sr_pkglibs_summary | |
444 | Enabled hardware drivers: | |
445 | $sr_driver_summary | |
446 | Enabled SCPI backends: | |
447 | - TCP............................. yes | |
448 | - RPC............................. $sr_cv_have_rpc | |
449 | - serial.......................... $sr_have_libserialport | |
450 | - VISA............................ $sr_have_librevisa | |
451 | - GPIB............................ $sr_have_libgpib | |
452 | - USBTMC.......................... $sr_have_libusb | |
453 | ||
454 | Enabled language bindings: | |
455 | - C++............................. $BINDINGS_CXX$sr_report_cxx | |
456 | - Python.......................... $BINDINGS_PYTHON$sr_report_python | |
457 | - Java............................ $BINDINGS_JAVA$sr_report_java | |
458 | ||
459 | _EOF |