[libsigrok.git] / configure.ac

##
## This file is part of the libsigrok project.
##
## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
##
## This program is free software: you can redistribute it and/or modify
## it under the terms of the GNU General Public License as published by
## the Free Software Foundation, either version 3 of the License, or
## (at your option) any later version.
##
## This program is distributed in the hope that it will be useful,
## but WITHOUT ANY WARRANTY; without even the implied warranty of
## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
## GNU General Public License for more details.
##
## You should have received a copy of the GNU General Public License
## along with this program.  If not, see <http://www.gnu.org/licenses/>.
##

# We require at least autoconf 2.63 (AC_INIT format changed there).
AC_PREREQ([2.63])

AC_INIT([libsigrok], [0.4.0],
	[sigrok-devel@lists.sourceforge.net],
	[libsigrok], [http://www.sigrok.org])
AC_CONFIG_MACRO_DIR([m4])
AC_CONFIG_AUX_DIR([autostuff])
AC_CONFIG_HEADERS([config.h include/libsigrok/version.h])

# We require at least automake 1.11 (needed for 'silent rules').
AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define nostdinc subdir-objects check-news color-tests])
AM_SILENT_RULES([yes])
m4_ifdef([AM_PROG_AR], [AM_PROG_AR])

AH_TOP([#ifndef SR_CONFIG_H
#define SR_CONFIG_H    /* To stop multiple inclusions. */])
AH_BOTTOM([#endif /* SR_CONFIG_H */])

# Checks for programs.
AC_PROG_CC
AC_PROG_CXX
AC_PROG_INSTALL
AC_PROG_LN_S

# Required for per-target flags or subdir-objects with C sources.
AM_PROG_CC_C_O

# Initialize libtool.
LT_INIT

# Set up the libsigrok version defines.
SR_PKG_VERSION_SET([SR_PACKAGE_VERSION], [AC_PACKAGE_VERSION])

# Library version for libsigrok (NOT the same as the package version).
# Carefully read the libtool docs before updating these numbers!
# The algorithm for determining which number to change (and how) is nontrivial!
# http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
SR_LIB_VERSION_SET([SR_LIB_VERSION], [2:0:0])

#############################
##  Optional dependencies  ##
#############################

# Initialize pkg-config.
# We require at least 0.22, as "Requires.private" behaviour changed there.
PKG_PROG_PKG_CONFIG([0.22])

# Keep track of all checked modules so we can list them at the end.
SR_PKG_CHECK_SUMMARY([sr_pkglibs_summary])

# Collect the pkg-config module names of all dependencies in SR_PKGLIBS.
# These are used to derive the compiler flags and for the "Requires.private"
# field in the generated libsigrok.pc file.
SR_VAR_OPT_PKG([SR_PKGLIBS], [sr_deps_avail])
SR_PKGLIBS_TESTS=
SR_PKGLIBS_CXX=
SR_PKGLIBS_PYTHON=

SR_ARG_OPT_PKG([libserialport], [LIBSERIALPORT], [NEED_SERIAL],
	[libserialport >= 0.1.1])

SR_ARG_OPT_PKG([libftdi], [LIBFTDI],,
	[libftdi1 >= 1.0], [libftdi >= 0.16])

# FreeBSD comes with an "integrated" libusb-1.0-style USB API.
# This means libusb-1.0 is always available; no need to check for it.
AS_CASE([$host], [*freebsd*], [sr_have_libusb=yes])

SR_ARG_OPT_PKG([libusb], [LIBUSB_1_0], [NEED_USB],
	[libusb-1.0 >= 1.0.16])

SR_ARG_OPT_PKG([librevisa], [LIBREVISA], [NEED_VISA],
	[librevisa >= 0.0.20130412])

SR_ARG_OPT_PKG([libgpib], [LIBGPIB], [NEED_GPIB],
	[libgpib])

######################
##  Feature checks  ##
######################

# The Check unit testing framework is optional. Disable if not found.
SR_PKG_CHECK([check], [SR_PKGLIBS_TESTS], [check >= 0.9.4])
AM_CONDITIONAL([HAVE_CHECK], [test "x$sr_have_check" = xyes])

AC_LANG([C])

# Enable the C99 standard if possible, and enforce the use
# of SR_API to explicitly mark all public API functions.
SR_EXTRA_CFLAGS=
SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [C99], [-std=c99 -c99 -AC99 -qlanglvl=extc99])
SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [visibility], [-fvisibility=hidden])

SR_ARG_ENABLE_WARNINGS([SR_WFLAGS], [-Wall], [-Wall -Wextra -Wmissing-prototypes])

# Check host characteristics.
AC_SYS_LARGEFILE
AC_C_BIGENDIAN

AC_CHECK_HEADERS([sys/mman.h], [SR_APPEND([sr_deps_avail], [sys_mman_h])])
AC_CHECK_HEADERS([sys/ioctl.h], [SR_APPEND([sr_deps_avail], [sys_ioctl_h])])
AC_CHECK_HEADERS([sys/timerfd.h], [SR_APPEND([sr_deps_avail], [sys_timerfd_h])])

# We need to link against the Winsock2 library for SCPI over TCP.
AS_CASE([$host], [*-mingw*], [SR_EXTRA_LIBS='-lws2_32'], [SR_EXTRA_LIBS=])

# libm (the standard math library) is always needed.
SR_SEARCH_LIBS([SR_EXTRA_LIBS], [pow], [m])

AC_ARG_WITH([libieee1284], [AS_HELP_STRING([--without-libieee1284],
				[disable libieee1284 support [default=detect]])])
sr_have_libieee1284=no
AS_IF([test "x$with_libieee1284" != xno], [
	AC_CHECK_HEADER([ieee1284.h], [
		SR_SEARCH_LIBS([SR_EXTRA_LIBS], [ieee1284_open], [ieee1284], [
			sr_have_libieee1284=yes
			SR_APPEND([sr_deps_avail], [libieee1284])
			sr_pkg_check_summary_append "libieee1284" yes
		])
	])
	AS_IF([test "$sr_have_libieee1284" = no], [
		AS_IF([test "x$with_libieee1284" = xyes], [
			AC_MSG_ERROR([libieee1284 support requested, but it was not found.])
		])
		sr_pkg_check_summary_append "libieee1284" no
	])
])

# RPC is only needed for VXI support.
AC_CACHE_CHECK([for RPC support], [sr_cv_have_rpc],
	[AC_LINK_IFELSE([AC_LANG_PROGRAM(
			[[#include <rpc/rpc.h>]m4_newline[CLIENT *rpc_test(void);]],
			[[(void) clnt_create("", 0, 0, "");]])],
		[sr_cv_have_rpc=yes], [sr_cv_have_rpc=no])])
AS_IF([test "x$sr_cv_have_rpc" = xyes],
	[AC_DEFINE([HAVE_RPC], [1], [Specifies whether we have RPC support.])])
# VXI support is only compiled if RPC support was found.
AM_CONDITIONAL([NEED_RPC], [test "x$sr_cv_have_rpc" = xyes])

########################
##  Hardware drivers  ##
########################

# Keep track of all drivers so we can list them at the end.
SR_VAR_SUMMARY([sr_driver_summary])

# Check whether the sr_deps_avail list contains all of the arguments.
# Unavailable dependencies are collected in sr_deps_missing.
sr_check_driver_deps() {
	sr_deps_missing=
	for sr_dep
	do
		AS_CASE([" $sr_deps_avail "], [*" $sr_dep "*],,
			[SR_APPEND([sr_deps_missing], [', '], [$sr_dep])])
	done
	test -z "$sr_deps_missing" || return 1
}

AC_ARG_ENABLE([all-drivers],
	[AS_HELP_STRING([--enable-all-drivers],
			[enable all drivers by default [default=yes]])],
	[], [enable_all_drivers=yes])

## _SR_DRIVER(Device name, driver-name, var-name, [dependencies...])
m4_define([_SR_DRIVER], [
	AC_ARG_ENABLE([$2],
		[AS_HELP_STRING([--enable-$2], [enable $1 support])],
		[$3=$enableval], [$3=$enable_all_drivers])

	AS_IF([test "x[$]$3" = xyes], [sr_hw_info=yes[]m4_ifval([$4], [
		sr_check_driver_deps $4 \
			|| $3=no sr_hw_info="no (missing: $sr_deps_missing)"
	])], [sr_hw_info='no (disabled)'])
	sr_driver_summary_append "$2" "$sr_hw_info"

	AM_CONDITIONAL([$3], [test "x[$]$3" = xyes])
	AM_COND_IF([$3], [AC_DEFINE([HAVE_$3], [1], [Whether to support $1 device.])])
])

## SR_DRIVER(Device name, driver-name, [dependencies...])
m4_define([SR_DRIVER],
	[_SR_DRIVER([$1], [$2], m4_expand([AS_TR_CPP([HW_$2])]), [$3])])

SR_DRIVER([Agilent DMM], [agilent-dmm], [libserialport])
SR_DRIVER([Appa 55II], [appa-55ii], [libserialport])
SR_DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma], [libftdi])
SR_DRIVER([Atten PPS3xxx], [atten-pps3xxx], [libserialport])
SR_DRIVER([BayLibre ACME], [baylibre-acme], [sys_timerfd_h])
SR_DRIVER([BeagleLogic], [beaglelogic], [sys_mman_h sys_ioctl_h])
SR_DRIVER([Brymen BM86x], [brymen-bm86x], [libusb])
SR_DRIVER([Brymen DMM], [brymen-dmm], [libserialport])
SR_DRIVER([CEM DT-885x], [cem-dt-885x], [libserialport])
SR_DRIVER([Center 3xx], [center-3xx], [libserialport])
SR_DRIVER([ChronoVu LA], [chronovu-la], [libftdi])
SR_DRIVER([Colead SLM], [colead-slm], [libserialport])
SR_DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu], [libserialport])
SR_DRIVER([DER EE DE-5000], [deree-de5000], [libserialport])
SR_DRIVER([demo], [demo])
SR_DRIVER([Fluke DMM], [fluke-dmm], [libserialport])
SR_DRIVER([fx2lafw], [fx2lafw], [libusb])
SR_DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x], [libserialport])
SR_DRIVER([Hameg HMO], [hameg-hmo], [libserialport])
SR_DRIVER([Hantek DSO], [hantek-dso], [libusb])
SR_DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2], [libusb])
SR_DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus], [libftdi])
SR_DRIVER([Kecheng KC-330B], [kecheng-kc-330b], [libusb])
SR_DRIVER([KERN scale], [kern-scale], [libserialport])
SR_DRIVER([Lascar EL-USB], [lascar-el-usb], [libusb])
SR_DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx], [libserialport])
SR_DRIVER([maynuo-m97], [maynuo-m97])
SR_DRIVER([MIC 985xx], [mic-985xx], [libserialport])
SR_DRIVER([Motech LPS 30x], [motech-lps-30x], [libserialport])
SR_DRIVER([Norma DMM], [norma-dmm], [libserialport])
SR_DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer], [libserialport])
SR_DRIVER([Pipistrello-OLS], [pipistrello-ols], [libftdi])
SR_DRIVER([Rigol DS], [rigol-ds])
SR_DRIVER([Saleae Logic16], [saleae-logic16], [libusb])
SR_DRIVER([SCPI PPS], [scpi-pps])
SR_DRIVER([serial DMM], [serial-dmm], [libserialport])
SR_DRIVER([Sysclk LWLA], [sysclk-lwla], [libusb])
SR_DRIVER([Teleinfo], [teleinfo], [libserialport])
SR_DRIVER([Testo], [testo], [libusb])
SR_DRIVER([Tondaj SL-814], [tondaj-sl-814], [libserialport])
SR_DRIVER([UNI-T DMM], [uni-t-dmm], [libusb])
SR_DRIVER([UNI-T UT32x], [uni-t-ut32x], [libusb])
SR_DRIVER([Victor DMM], [victor-dmm], [libusb])
SR_DRIVER([Yokogawa DL/DLM], [yokogawa-dlm])
SR_DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube], [libusb])

###############################
##  Language bindings setup  ##
###############################

AC_LANG([C++])
SR_ARG_ENABLE_WARNINGS([SR_WXXFLAGS], [-Wall], [-Wall -Wextra])

AC_ARG_ENABLE([bindings],
	[AS_HELP_STRING([--enable-bindings], [build language bindings [default=yes]])],
	[], [enable_bindings=yes])

AC_ARG_ENABLE([cxx],
	[AS_HELP_STRING([--enable-cxx], [build C++ bindings [default=yes]])],
	[], [enable_cxx=$enable_bindings])

AC_ARG_ENABLE([python],
	[AS_HELP_STRING([--enable-python], [build Python bindings [default=yes]])],
	[], [enable_python=$enable_bindings])

AC_ARG_ENABLE([java],
	[AS_HELP_STRING([--enable-java], [build Java bindings [default=yes]])],
	[], [enable_java=$enable_bindings])

####################
##  C++ bindings  ##
####################

sr_cxx_missing=

# Check if the C++ compiler supports the C++11 standard.
AX_CXX_COMPILE_STDCXX_11([noext], [optional])
AS_IF([test "x$HAVE_CXX11" != x1],
	[SR_APPEND([sr_cxx_missing], [', '], ['C++11'])])

# The C++ bindings need glibmm.
SR_PKG_CHECK([glibmm], [SR_PKGLIBS_CXX], [glibmm-2.4 >= 2.32.0])
AS_IF([test "x$sr_have_glibmm" != xyes],
	[SR_APPEND([sr_cxx_missing], [', '], [glibmm])])

# The C++ bindings use Doxygen to parse libsigrok symbols.
AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes], [no])
AS_IF([test "x$HAVE_DOXYGEN" != xyes],
	[SR_APPEND([sr_cxx_missing], [', '], [Doxygen])])

# Python is needed for the C++ bindings.
AM_PATH_PYTHON([2.7],
	[HAVE_PYTHON=yes],
	[HAVE_PYTHON=no
	SR_APPEND([sr_cxx_missing], [', '], [Python])])

AS_IF([test -z "$sr_cxx_missing"],
	[BINDINGS_CXX=$enable_cxx], [BINDINGS_CXX=no])
AM_CONDITIONAL([BINDINGS_CXX], [test "x$BINDINGS_CXX" = xyes])

# C++ bindings want stoi and stod.
AM_COND_IF([BINDINGS_CXX], [
	AC_CACHE_CHECK([for stoi and stod], [sr_cv_have_stoi_stod],
		[AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string>]],
				[[(void) std::stoi("1"); (void) std::stod("1.0");]])],
			[sr_cv_have_stoi_stod=yes], [sr_cv_have_stoi_stod=no])])
	AS_IF([test "x$sr_cv_have_stoi_stod" = xyes],
		[AC_DEFINE([HAVE_STOI_STOD], [1],
			[Specifies whether we have the stoi and stod functions.])])
])

#######################
##  Python bindings  ##
#######################

AS_IF([test "x$BINDINGS_CXX" = xyes],
	[sr_python_missing=],
	[sr_python_missing='C++ bindings'])

# The Python bindings need Python development files.
SR_PKG_CHECK([python_dev], [SR_PKGLIBS_PYTHON],
	[python >= 2.7], [python2 >= 2.7], [python27 >= 2.7])
AS_IF([test "x$sr_have_python_dev" != xyes],
	[SR_APPEND([sr_python_missing], [', '], [Headers])])

# PyGObject is needed for the Python bindings.
SR_PKG_CHECK([pygobject], [SR_PKGLIBS_PYTHON], [pygobject-3.0 >= 3.0.0])
AS_IF([test "x$sr_have_pygobject" != xyes],
	[SR_APPEND([sr_python_missing], [', '], [PyGObject])])

PKG_CHECK_EXISTS([pygobject-3.0 < 3.7.91],
	[AC_DEFINE([PYGOBJECT_FLAGS_SIGNED], [1],
		[Whether last argument to pyg_flags_get_value() is signed.])])

# The Python bindings need the setuptools Python module.
# We'll let it go through even if the AX macro wasn't found,
# as the Python module may still be there.
HAVE_PYMOD_SETUPTOOLS=yes
m4_ifdef([AX_PYTHON_MODULE],
	[AX_PYTHON_MODULE([setuptools])],
	[m4_warn([unsupported], [Missing macro AX_PYTHON_MODULE: no setuptools check])])
AS_IF([test "x$HAVE_PYMOD_SETUPTOOLS" != xyes],
	[SR_APPEND([sr_python_missing], [', '], [setuptools])])

# The Python bindings use SWIG to generate code.
AC_CHECK_PROGS([SWIG], [swig swig3.0 swig2.0])
AS_IF([test "x$SWIG" = x],
	[SR_APPEND([sr_python_missing], [', '], [SWIG])])

AS_IF([test -z "$sr_python_missing"],
	[BINDINGS_PYTHON=$enable_python], [BINDINGS_PYTHON=no])
AM_CONDITIONAL([BINDINGS_PYTHON], [test "x$BINDINGS_PYTHON" = xyes])

####################
##  Java bindings ##
####################

AS_IF([test "x$BINDINGS_CXX" = xyes],
	[sr_java_missing=],
	[sr_java_missing='C++ bindings'])

# The Java bindings use SWIG to generate code.
AS_IF([test "x$SWIG" = x],
	[SR_APPEND([sr_java_missing], [', '], [SWIG])])

# Find Java compiler and JNI includes for Java bindings.
AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no])
AS_IF([test "x$HAVE_JAVAC" = xno],
	[SR_APPEND([sr_java_missing], [', '], [JavaC])])

AC_ARG_WITH([jni-include-path],
	[AS_HELP_STRING([[--with-jni-include-path=DIR-LIST (space-separated)]],
		[specify JNI include directories [default=detect]])],
	[JNI_INCLUDE_DIRS=" $withval"], [JNI_INCLUDE_DIRS=])

JNI_CPPFLAGS=
AS_IF([test "x$enable_java$HAVE_JAVAC" = xyesyes], [
	AX_PROG_JAVAC
	AS_IF([test -z "$JNI_INCLUDE_DIRS" && test "x$cross_compiling" != xyes], [
		## Work around the totally broken logic in AX_JNI_INCLUDE_DIR:
		## If we can find jni.h without any special search path, skip
		## the execution of the broken macro to increase our chances of
		## success.
		AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <jni.h>]], [])],,
			[AX_JNI_INCLUDE_DIR])
	])
])
for sr_dir in $JNI_INCLUDE_DIRS
do
	SR_APPEND([JNI_CPPFLAGS], ["-I$sr_dir"])
done
AC_SUBST([JNI_CPPFLAGS])

sr_save_cppflags=$CPPFLAGS
SR_APPEND([CPPFLAGS], [$JNI_CPPFLAGS])
AC_CHECK_HEADER([jni.h],,
	[SR_APPEND([sr_java_missing], [', '], ['JNI headers'])])
CPPFLAGS=$sr_save_cppflags

AS_IF([test -z "$sr_java_missing"],
	[BINDINGS_JAVA=$enable_java], [BINDINGS_JAVA=no])
AM_CONDITIONAL([BINDINGS_JAVA], [test "x$BINDINGS_JAVA" = xyes])

##############################
##  Finalize configuration  ##
##############################

# Add mandatory dependencies to module list.
SR_APPEND([SR_PKGLIBS], ['libzip >= 0.10'])
AC_SUBST([SR_PKGLIBS])

# Retrieve the compile and link flags for all modules combined.
# Also, bail out at this point if any module dependency is not met.
PKG_CHECK_MODULES([LIBSIGROK], [glib-2.0 >= 2.32.0 $SR_PKGLIBS])
PKG_CHECK_MODULES([TESTS], [$SR_PKGLIBS_TESTS glib-2.0 $SR_PKGLIBS])

# SR_PKGLIBS_CXX may be empty, so only invoke these checks when
# the C++ bindings are enabled.
AM_COND_IF([BINDINGS_CXX], [
	PKG_CHECK_MODULES([LIBSIGROKCXX], [$SR_PKGLIBS_CXX])
	PKG_CHECK_MODULES([PYSIGROK], [$SR_PKGLIBS_PYTHON $SR_PKGLIBS_CXX])
])
sr_glib_version=`$PKG_CONFIG --modversion glib-2.0 2>&AS_MESSAGE_LOG_FD`
sr_libzip_version=`$PKG_CONFIG --modversion libzip 2>&AS_MESSAGE_LOG_FD`

AC_DEFINE_UNQUOTED([CONF_LIBZIP_VERSION], ["$sr_libzip_version"],
	[Build-time version of libzip.])
AC_DEFINE_UNQUOTED([CONF_HOST], ["$host"],
	[The canonical host libsigrok will run on.])

AC_CONFIG_FILES([Makefile libsigrok.pc bindings/cxx/libsigrokcxx.pc])

AC_OUTPUT

# Prepare bindings report messages.
m4_define([SR_PREPARE_BINDING_REPORT], [
	sr_report_$1=
	test -z "$sr_$1_missing" || sr_report_$1=" (missing: $sr_$1_missing)"
	test "x$enable_$1" = xyes || sr_report_$1=' (disabled)'
])
m4_map_args([SR_PREPARE_BINDING_REPORT], [cxx], [python], [java])

cat >&AS_MESSAGE_FD <<_EOF

libsigrok configuration summary:
 - Package version................. $SR_PACKAGE_VERSION
 - Library ABI version............. $SR_LIB_VERSION
 - Prefix.......................... $prefix
 - Building on..................... $build
 - Building for.................... $host
 - Additional C compiler flags..... $SR_EXTRA_CFLAGS
 - C compiler warnings............. $SR_WFLAGS
 - C++ compiler warnings........... $SR_WXXFLAGS

Detected libraries (required):
 - glib-2.0 >= 2.32.0.............. $sr_glib_version
 - libzip >= 0.10.................. $sr_libzip_version

Detected libraries (optional):
$sr_pkglibs_summary
Enabled hardware drivers:
$sr_driver_summary
Enabled SCPI backends:
 - TCP............................. yes
 - RPC............................. $sr_cv_have_rpc
 - serial.......................... $sr_have_libserialport
 - VISA............................ $sr_have_librevisa
 - GPIB............................ $sr_have_libgpib
 - USBTMC.......................... $sr_have_libusb

Enabled language bindings:
 - C++............................. $BINDINGS_CXX$sr_report_cxx
 - Python.......................... $BINDINGS_PYTHON$sr_report_python
 - Java............................ $BINDINGS_JAVA$sr_report_java

_EOF
Commit	Line	Data
826938d8	1	##
50985c20	2	## This file is part of the libsigrok project.
826938d8	3	##
c73d2ea4	4	## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
d375b3c3	5	## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
826938d8 UH	6	##
	7	## This program is free software: you can redistribute it and/or modify
	8	## it under the terms of the GNU General Public License as published by
	9	## the Free Software Foundation, either version 3 of the License, or
	10	## (at your option) any later version.
	11	##
	12	## This program is distributed in the hope that it will be useful,
	13	## but WITHOUT ANY WARRANTY; without even the implied warranty of
	14	## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	15	## GNU General Public License for more details.
	16	##
	17	## You should have received a copy of the GNU General Public License
	18	## along with this program. If not, see <http://www.gnu.org/licenses/>.
	19	##
	20
ef7228ba UH	21	# We require at least autoconf 2.63 (AC_INIT format changed there).
ef7228ba UH	22	AC_PREREQ([2.63])
826938d8	23
24138539	24	AC_INIT([libsigrok], [0.4.0],
7f289d14	25	[sigrok-devel@lists.sourceforge.net],
db8ae7b9	26	[libsigrok], [http://www.sigrok.org])
ea1d5351	27	AC_CONFIG_MACRO_DIR([m4])
d8521c93	28	AC_CONFIG_AUX_DIR([autostuff])
24138539	29	AC_CONFIG_HEADERS([config.h include/libsigrok/version.h])
826938d8	30
ef7228ba	31	# We require at least automake 1.11 (needed for 'silent rules').
9ac018d0	32	AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define nostdinc subdir-objects check-news color-tests])
bbb3996c	33	AM_SILENT_RULES([yes])
432e5e95	34	m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
826938d8	35
6dddd902 UH	36	AH_TOP([#ifndef SR_CONFIG_H
	37	#define SR_CONFIG_H /* To stop multiple inclusions. */])
	38	AH_BOTTOM([#endif /* SR_CONFIG_H */])
826938d8	39
826938d8	40	# Checks for programs.
826938d8	41	AC_PROG_CC
c23c8659	42	AC_PROG_CXX
826938d8 UH	43	AC_PROG_INSTALL
	44	AC_PROG_LN_S
	45
bb203cde UH	46	# Required for per-target flags or subdir-objects with C sources.
	47	AM_PROG_CC_C_O
	48
826938d8 UH	49	# Initialize libtool.
	50	LT_INIT
	51
24138539 DE	52	# Set up the libsigrok version defines.
24138539 DE	53	SR_PKG_VERSION_SET([SR_PACKAGE_VERSION], [AC_PACKAGE_VERSION])
b2478a23	54
3af71f0d	55	# Library version for libsigrok (NOT the same as the package version).
826938d8 UH	56	# Carefully read the libtool docs before updating these numbers!
	57	# The algorithm for determining which number to change (and how) is nontrivial!
	58	# http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
24138539	59	SR_LIB_VERSION_SET([SR_LIB_VERSION], [2:0:0])
826938d8	60
1f61c22f DE	61	#############################
	62	## Optional dependencies ##
	63	#############################
de44e114	64
1f61c22f DE	65	# Initialize pkg-config.
	66	# We require at least 0.22, as "Requires.private" behaviour changed there.
	67	PKG_PROG_PKG_CONFIG([0.22])
bcacb863	68
1bb196e4 DE	69	# Keep track of all checked modules so we can list them at the end.
	70	SR_PKG_CHECK_SUMMARY([sr_pkglibs_summary])
	71
	72	# Collect the pkg-config module names of all dependencies in SR_PKGLIBS.
1f61c22f DE	73	# These are used to derive the compiler flags and for the "Requires.private"
1f61c22f DE	74	# field in the generated libsigrok.pc file.
1bb196e4	75	SR_VAR_OPT_PKG([SR_PKGLIBS], [sr_deps_avail])
65489c1a	76	SR_PKGLIBS_TESTS=
1f61c22f DE	77	SR_PKGLIBS_CXX=
	78	SR_PKGLIBS_PYTHON=
	79
2cbde151	80	SR_ARG_OPT_PKG([libserialport], [LIBSERIALPORT], [NEED_SERIAL],
1f61c22f	81	[libserialport >= 0.1.1])
1f61c22f	82
2cbde151	83	SR_ARG_OPT_PKG([libftdi], [LIBFTDI],,
0ab8386a	84	[libftdi1 >= 1.0], [libftdi >= 0.16])
1f61c22f DE	85
	86	# FreeBSD comes with an "integrated" libusb-1.0-style USB API.
	87	# This means libusb-1.0 is always available; no need to check for it.
	88	AS_CASE([$host], [freebsd], [sr_have_libusb=yes])
	89
2cbde151	90	SR_ARG_OPT_PKG([libusb], [LIBUSB_1_0], [NEED_USB],
1f61c22f	91	[libusb-1.0 >= 1.0.16])
c23c8659	92
2cbde151	93	SR_ARG_OPT_PKG([librevisa], [LIBREVISA], [NEED_VISA],
1f61c22f	94	[librevisa >= 0.0.20130412])
d92de05a	95
2cbde151	96	SR_ARG_OPT_PKG([libgpib], [LIBGPIB], [NEED_GPIB],
1f61c22f DE	97	[libgpib])
	98
	99	######################
	100	## Feature checks ##
	101	######################
f7740954	102
aba69262	103	# The Check unit testing framework is optional. Disable if not found.
65489c1a	104	SR_PKG_CHECK([check], [SR_PKGLIBS_TESTS], [check >= 0.9.4])
1f61c22f DE	105	AM_CONDITIONAL([HAVE_CHECK], [test "x$sr_have_check" = xyes])
	106
	107	AC_LANG([C])
b84a7331	108
e662d9e8	109	# Enable the C99 standard if possible, and enforce the use
b84a7331 DE	110	# of SR_API to explicitly mark all public API functions.
b84a7331 DE	111	SR_EXTRA_CFLAGS=
e662d9e8	112	SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [C99], [-std=c99 -c99 -AC99 -qlanglvl=extc99])
b84a7331 DE	113	SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [visibility], [-fvisibility=hidden])
b84a7331 DE	114
4cf2f34f	115	SR_ARG_ENABLE_WARNINGS([SR_WFLAGS], [-Wall], [-Wall -Wextra -Wmissing-prototypes])
1f61c22f DE	116
1f61c22f DE	117	# Check host characteristics.
bbb3996c	118	AC_SYS_LARGEFILE
1f61c22f	119	AC_C_BIGENDIAN
79bb0e97	120
1bb196e4 DE	121	AC_CHECK_HEADERS([sys/mman.h], [SR_APPEND([sr_deps_avail], [sys_mman_h])])
	122	AC_CHECK_HEADERS([sys/ioctl.h], [SR_APPEND([sr_deps_avail], [sys_ioctl_h])])
	123	AC_CHECK_HEADERS([sys/timerfd.h], [SR_APPEND([sr_deps_avail], [sys_timerfd_h])])
1f61c22f	124
bc8ff24d DE	125	# We need to link against the Winsock2 library for SCPI over TCP.
	126	AS_CASE([$host], [-mingw], [SR_EXTRA_LIBS='-lws2_32'], [SR_EXTRA_LIBS=])
	127
	128	# libm (the standard math library) is always needed.
	129	SR_SEARCH_LIBS([SR_EXTRA_LIBS], [pow], [m])
	130
28d86fa9 DG	131	AC_ARG_WITH([libieee1284], [AS_HELP_STRING([--without-libieee1284],
	132	[disable libieee1284 support [default=detect]])])
	133	sr_have_libieee1284=no
	134	AS_IF([test "x$with_libieee1284" != xno], [
	135	AC_CHECK_HEADER([ieee1284.h], [
	136	SR_SEARCH_LIBS([SR_EXTRA_LIBS], [ieee1284_open], [ieee1284], [
	137	sr_have_libieee1284=yes
	138	SR_APPEND([sr_deps_avail], [libieee1284])
	139	sr_pkg_check_summary_append "libieee1284" yes
	140	])
	141	])
	142	AS_IF([test "$sr_have_libieee1284" = no], [
	143	AS_IF([test "x$with_libieee1284" = xyes], [
	144	AC_MSG_ERROR([libieee1284 support requested, but it was not found.])
	145	])
	146	sr_pkg_check_summary_append "libieee1284" no
	147	])
	148	])
	149
1f61c22f DE	150	# RPC is only needed for VXI support.
	151	AC_CACHE_CHECK([for RPC support], [sr_cv_have_rpc],
	152	[AC_LINK_IFELSE([AC_LANG_PROGRAM(
	153	[[#include <rpc/rpc.h>]m4_newline[CLIENT *rpc_test(void);]],
	154	[[(void) clnt_create("", 0, 0, "");]])],
	155	[sr_cv_have_rpc=yes], [sr_cv_have_rpc=no])])
	156	AS_IF([test "x$sr_cv_have_rpc" = xyes],
	157	[AC_DEFINE([HAVE_RPC], [1], [Specifies whether we have RPC support.])])
	158	# VXI support is only compiled if RPC support was found.
	159	AM_CONDITIONAL([NEED_RPC], [test "x$sr_cv_have_rpc" = xyes])
	160
d37c7109 DE	161	########################
	162	## Hardware drivers ##
	163	########################
	164
	165	# Keep track of all drivers so we can list them at the end.
1bb196e4	166	SR_VAR_SUMMARY([sr_driver_summary])
d37c7109 DE	167
	168	# Check whether the sr_deps_avail list contains all of the arguments.
	169	# Unavailable dependencies are collected in sr_deps_missing.
	170	sr_check_driver_deps() {
	171	sr_deps_missing=
	172	for sr_dep
	173	do
	174	AS_CASE([" $sr_deps_avail "], [" $sr_dep "],,
26b67f11	175	[SR_APPEND([sr_deps_missing], [', '], [$sr_dep])])
d37c7109	176	done
4ed3d9b6	177	test -z "$sr_deps_missing" \|\| return 1
d37c7109 DE	178	}
	179
	180	AC_ARG_ENABLE([all-drivers],
	181	[AS_HELP_STRING([--enable-all-drivers],
	182	[enable all drivers by default [default=yes]])],
	183	[], [enable_all_drivers=yes])
	184
	185	## _SR_DRIVER(Device name, driver-name, var-name, [dependencies...])
	186	m4_define([_SR_DRIVER], [
b8b727e4	187	AC_ARG_ENABLE([$2],
d37c7109 DE	188	[AS_HELP_STRING([--enable-$2], [enable $1 support])],
	189	[$3=$enableval], [$3=$enable_all_drivers])
	190
	191	AS_IF([test "x[$]$3" = xyes], [sr_hw_info=yes[]m4_ifval([$4], [
4ed3d9b6 DE	192	sr_check_driver_deps $4 \
4ed3d9b6 DE	193	\|\| $3=no sr_hw_info="no (missing: $sr_deps_missing)"
d37c7109	194	])], [sr_hw_info='no (disabled)'])
1bb196e4	195	sr_driver_summary_append "$2" "$sr_hw_info"
d37c7109 DE	196
	197	AM_CONDITIONAL([$3], [test "x[$]$3" = xyes])
	198	AM_COND_IF([$3], [AC_DEFINE([HAVE_$3], [1], [Whether to support $1 device.])])
	199	])
	200
	201	## SR_DRIVER(Device name, driver-name, [dependencies...])
	202	m4_define([SR_DRIVER],
	203	[_SR_DRIVER([$1], [$2], m4_expand([AS_TR_CPP([HW_$2])]), [$3])])
	204
	205	SR_DRIVER([Agilent DMM], [agilent-dmm], [libserialport])
	206	SR_DRIVER([Appa 55II], [appa-55ii], [libserialport])
	207	SR_DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma], [libftdi])
	208	SR_DRIVER([Atten PPS3xxx], [atten-pps3xxx], [libserialport])
	209	SR_DRIVER([BayLibre ACME], [baylibre-acme], [sys_timerfd_h])
	210	SR_DRIVER([BeagleLogic], [beaglelogic], [sys_mman_h sys_ioctl_h])
	211	SR_DRIVER([Brymen BM86x], [brymen-bm86x], [libusb])
	212	SR_DRIVER([Brymen DMM], [brymen-dmm], [libserialport])
	213	SR_DRIVER([CEM DT-885x], [cem-dt-885x], [libserialport])
	214	SR_DRIVER([Center 3xx], [center-3xx], [libserialport])
	215	SR_DRIVER([ChronoVu LA], [chronovu-la], [libftdi])
	216	SR_DRIVER([Colead SLM], [colead-slm], [libserialport])
	217	SR_DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu], [libserialport])
	218	SR_DRIVER([DER EE DE-5000], [deree-de5000], [libserialport])
	219	SR_DRIVER([demo], [demo])
	220	SR_DRIVER([Fluke DMM], [fluke-dmm], [libserialport])
	221	SR_DRIVER([fx2lafw], [fx2lafw], [libusb])
	222	SR_DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x], [libserialport])
	223	SR_DRIVER([Hameg HMO], [hameg-hmo], [libserialport])
	224	SR_DRIVER([Hantek DSO], [hantek-dso], [libusb])
	225	SR_DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2], [libusb])
	226	SR_DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus], [libftdi])
	227	SR_DRIVER([Kecheng KC-330B], [kecheng-kc-330b], [libusb])
8006cdc5	228	SR_DRIVER([KERN scale], [kern-scale], [libserialport])
d37c7109 DE	229	SR_DRIVER([Lascar EL-USB], [lascar-el-usb], [libusb])
	230	SR_DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx], [libserialport])
	231	SR_DRIVER([maynuo-m97], [maynuo-m97])
	232	SR_DRIVER([MIC 985xx], [mic-985xx], [libserialport])
	233	SR_DRIVER([Motech LPS 30x], [motech-lps-30x], [libserialport])
	234	SR_DRIVER([Norma DMM], [norma-dmm], [libserialport])
	235	SR_DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer], [libserialport])
	236	SR_DRIVER([Pipistrello-OLS], [pipistrello-ols], [libftdi])
	237	SR_DRIVER([Rigol DS], [rigol-ds])
	238	SR_DRIVER([Saleae Logic16], [saleae-logic16], [libusb])
	239	SR_DRIVER([SCPI PPS], [scpi-pps])
	240	SR_DRIVER([serial DMM], [serial-dmm], [libserialport])
	241	SR_DRIVER([Sysclk LWLA], [sysclk-lwla], [libusb])
	242	SR_DRIVER([Teleinfo], [teleinfo], [libserialport])
	243	SR_DRIVER([Testo], [testo], [libusb])
	244	SR_DRIVER([Tondaj SL-814], [tondaj-sl-814], [libserialport])
	245	SR_DRIVER([UNI-T DMM], [uni-t-dmm], [libusb])
	246	SR_DRIVER([UNI-T UT32x], [uni-t-ut32x], [libusb])
	247	SR_DRIVER([Victor DMM], [victor-dmm], [libusb])
	248	SR_DRIVER([Yokogawa DL/DLM], [yokogawa-dlm])
	249	SR_DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube], [libusb])
1f61c22f DE	250
	251	###############################
	252	## Language bindings setup ##
	253	###############################
	254
d37c7109	255	AC_LANG([C++])
4cf2f34f	256	SR_ARG_ENABLE_WARNINGS([SR_WXXFLAGS], [-Wall], [-Wall -Wextra])
d37c7109	257
1f61c22f DE	258	AC_ARG_ENABLE([bindings],
	259	[AS_HELP_STRING([--enable-bindings], [build language bindings [default=yes]])],
	260	[], [enable_bindings=yes])
176c7219	261
1f61c22f DE	262	AC_ARG_ENABLE([cxx],
	263	[AS_HELP_STRING([--enable-cxx], [build C++ bindings [default=yes]])],
	264	[], [enable_cxx=$enable_bindings])
a0b277ba	265
1f61c22f DE	266	AC_ARG_ENABLE([python],
	267	[AS_HELP_STRING([--enable-python], [build Python bindings [default=yes]])],
	268	[], [enable_python=$enable_bindings])
826938d8	269
1f61c22f DE	270	AC_ARG_ENABLE([java],
	271	[AS_HELP_STRING([--enable-java], [build Java bindings [default=yes]])],
	272	[], [enable_java=$enable_bindings])
	273
	274	####################
	275	## C++ bindings ##
	276	####################
	277
	278	sr_cxx_missing=
	279
	280	# Check if the C++ compiler supports the C++11 standard.
e662d9e8	281	AX_CXX_COMPILE_STDCXX_11([noext], [optional])
26b67f11 DE	282	AS_IF([test "x$HAVE_CXX11" != x1],
26b67f11 DE	283	[SR_APPEND([sr_cxx_missing], [', '], ['C++11'])])
1f61c22f DE	284
	285	# The C++ bindings need glibmm.
	286	SR_PKG_CHECK([glibmm], [SR_PKGLIBS_CXX], [glibmm-2.4 >= 2.32.0])
26b67f11 DE	287	AS_IF([test "x$sr_have_glibmm" != xyes],
26b67f11 DE	288	[SR_APPEND([sr_cxx_missing], [', '], [glibmm])])
1f61c22f DE	289
	290	# The C++ bindings use Doxygen to parse libsigrok symbols.
	291	AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes], [no])
26b67f11 DE	292	AS_IF([test "x$HAVE_DOXYGEN" != xyes],
26b67f11 DE	293	[SR_APPEND([sr_cxx_missing], [', '], [Doxygen])])
1f61c22f DE	294
	295	# Python is needed for the C++ bindings.
	296	AM_PATH_PYTHON([2.7],
	297	[HAVE_PYTHON=yes],
26b67f11 DE	298	[HAVE_PYTHON=no
26b67f11 DE	299	SR_APPEND([sr_cxx_missing], [', '], [Python])])
1f61c22f DE	300
	301	AS_IF([test -z "$sr_cxx_missing"],
	302	[BINDINGS_CXX=$enable_cxx], [BINDINGS_CXX=no])
	303	AM_CONDITIONAL([BINDINGS_CXX], [test "x$BINDINGS_CXX" = xyes])
	304
	305	# C++ bindings want stoi and stod.
	306	AM_COND_IF([BINDINGS_CXX], [
	307	AC_CACHE_CHECK([for stoi and stod], [sr_cv_have_stoi_stod],
	308	[AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string>]],
	309	[[(void) std::stoi("1"); (void) std::stod("1.0");]])],
	310	[sr_cv_have_stoi_stod=yes], [sr_cv_have_stoi_stod=no])])
	311	AS_IF([test "x$sr_cv_have_stoi_stod" = xyes],
	312	[AC_DEFINE([HAVE_STOI_STOD], [1],
	313	[Specifies whether we have the stoi and stod functions.])])
	314	])
	315
	316	#######################
	317	## Python bindings ##
	318	#######################
	319
26b67f11 DE	320	AS_IF([test "x$BINDINGS_CXX" = xyes],
	321	[sr_python_missing=],
	322	[sr_python_missing='C++ bindings'])
1f61c22f DE	323
	324	# The Python bindings need Python development files.
	325	SR_PKG_CHECK([python_dev], [SR_PKGLIBS_PYTHON],
	326	[python >= 2.7], [python2 >= 2.7], [python27 >= 2.7])
26b67f11 DE	327	AS_IF([test "x$sr_have_python_dev" != xyes],
26b67f11 DE	328	[SR_APPEND([sr_python_missing], [', '], [Headers])])
1f61c22f DE	329
	330	# PyGObject is needed for the Python bindings.
	331	SR_PKG_CHECK([pygobject], [SR_PKGLIBS_PYTHON], [pygobject-3.0 >= 3.0.0])
26b67f11 DE	332	AS_IF([test "x$sr_have_pygobject" != xyes],
26b67f11 DE	333	[SR_APPEND([sr_python_missing], [', '], [PyGObject])])
1f61c22f DE	334
	335	PKG_CHECK_EXISTS([pygobject-3.0 < 3.7.91],
	336	[AC_DEFINE([PYGOBJECT_FLAGS_SIGNED], [1],
	337	[Whether last argument to pyg_flags_get_value() is signed.])])
	338
	339	# The Python bindings need the setuptools Python module.
	340	# We'll let it go through even if the AX macro wasn't found,
	341	# as the Python module may still be there.
	342	HAVE_PYMOD_SETUPTOOLS=yes
	343	m4_ifdef([AX_PYTHON_MODULE],
	344	[AX_PYTHON_MODULE([setuptools])],
cb4d28ef	345	[m4_warn([unsupported], [Missing macro AX_PYTHON_MODULE: no setuptools check])])
26b67f11 DE	346	AS_IF([test "x$HAVE_PYMOD_SETUPTOOLS" != xyes],
26b67f11 DE	347	[SR_APPEND([sr_python_missing], [', '], [setuptools])])
1f61c22f DE	348
1f61c22f DE	349	# The Python bindings use SWIG to generate code.
0ab8386a	350	AC_CHECK_PROGS([SWIG], [swig swig3.0 swig2.0])
26b67f11 DE	351	AS_IF([test "x$SWIG" = x],
26b67f11 DE	352	[SR_APPEND([sr_python_missing], [', '], [SWIG])])
1f61c22f DE	353
	354	AS_IF([test -z "$sr_python_missing"],
	355	[BINDINGS_PYTHON=$enable_python], [BINDINGS_PYTHON=no])
	356	AM_CONDITIONAL([BINDINGS_PYTHON], [test "x$BINDINGS_PYTHON" = xyes])
	357
	358	####################
	359	## Java bindings ##
	360	####################
	361
26b67f11 DE	362	AS_IF([test "x$BINDINGS_CXX" = xyes],
	363	[sr_java_missing=],
	364	[sr_java_missing='C++ bindings'])
1f61c22f DE	365
1f61c22f DE	366	# The Java bindings use SWIG to generate code.
26b67f11 DE	367	AS_IF([test "x$SWIG" = x],
26b67f11 DE	368	[SR_APPEND([sr_java_missing], [', '], [SWIG])])
4f10853e	369
9fcf4d0b	370	# Find Java compiler and JNI includes for Java bindings.
9fcf4d0b	371	AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no])
26b67f11 DE	372	AS_IF([test "x$HAVE_JAVAC" = xno],
26b67f11 DE	373	[SR_APPEND([sr_java_missing], [', '], [JavaC])])
1f61c22f DE	374
	375	AC_ARG_WITH([jni-include-path],
	376	[AS_HELP_STRING([[--with-jni-include-path=DIR-LIST (space-separated)]],
	377	[specify JNI include directories [default=detect]])],
	378	[JNI_INCLUDE_DIRS=" $withval"], [JNI_INCLUDE_DIRS=])
	379
	380	JNI_CPPFLAGS=
	381	AS_IF([test "x$enable_java$HAVE_JAVAC" = xyesyes], [
9fcf4d0b	382	AX_PROG_JAVAC
1f61c22f DE	383	AS_IF([test -z "$JNI_INCLUDE_DIRS" && test "x$cross_compiling" != xyes], [
	384	## Work around the totally broken logic in AX_JNI_INCLUDE_DIR:
	385	## If we can find jni.h without any special search path, skip
	386	## the execution of the broken macro to increase our chances of
	387	## success.
	388	AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <jni.h>]], [])],,
	389	[AX_JNI_INCLUDE_DIR])
	390	])
	391	])
	392	for sr_dir in $JNI_INCLUDE_DIRS
	393	do
26b67f11	394	SR_APPEND([JNI_CPPFLAGS], ["-I$sr_dir"])
1f61c22f DE	395	done
	396	AC_SUBST([JNI_CPPFLAGS])
	397
	398	sr_save_cppflags=$CPPFLAGS
26b67f11 DE	399	SR_APPEND([CPPFLAGS], [$JNI_CPPFLAGS])
	400	AC_CHECK_HEADER([jni.h],,
	401	[SR_APPEND([sr_java_missing], [', '], ['JNI headers'])])
1f61c22f DE	402	CPPFLAGS=$sr_save_cppflags
	403
	404	AS_IF([test -z "$sr_java_missing"],
	405	[BINDINGS_JAVA=$enable_java], [BINDINGS_JAVA=no])
	406	AM_CONDITIONAL([BINDINGS_JAVA], [test "x$BINDINGS_JAVA" = xyes])
	407
	408	##############################
	409	## Finalize configuration ##
	410	##############################
	411
	412	# Add mandatory dependencies to module list.
26b67f11	413	SR_APPEND([SR_PKGLIBS], ['libzip >= 0.10'])
1f61c22f DE	414	AC_SUBST([SR_PKGLIBS])
	415
	416	# Retrieve the compile and link flags for all modules combined.
	417	# Also, bail out at this point if any module dependency is not met.
	418	PKG_CHECK_MODULES([LIBSIGROK], [glib-2.0 >= 2.32.0 $SR_PKGLIBS])
65489c1a	419	PKG_CHECK_MODULES([TESTS], [$SR_PKGLIBS_TESTS glib-2.0 $SR_PKGLIBS])
1f61c22f	420
da0763d0 DE	421	# SR_PKGLIBS_CXX may be empty, so only invoke these checks when
	422	# the C++ bindings are enabled.
	423	AM_COND_IF([BINDINGS_CXX], [
	424	PKG_CHECK_MODULES([LIBSIGROKCXX], [$SR_PKGLIBS_CXX])
	425	PKG_CHECK_MODULES([PYSIGROK], [$SR_PKGLIBS_PYTHON $SR_PKGLIBS_CXX])
	426	])
1f61c22f DE	427	sr_glib_version=`$PKG_CONFIG --modversion glib-2.0 2>&AS_MESSAGE_LOG_FD`
	428	sr_libzip_version=`$PKG_CONFIG --modversion libzip 2>&AS_MESSAGE_LOG_FD`
	429
2cbde151 DE	430	AC_DEFINE_UNQUOTED([CONF_LIBZIP_VERSION], ["$sr_libzip_version"],
	431	[Build-time version of libzip.])
	432	AC_DEFINE_UNQUOTED([CONF_HOST], ["$host"],
	433	[The canonical host libsigrok will run on.])
1f61c22f	434
b2478a23	435	AC_CONFIG_FILES([Makefile libsigrok.pc bindings/cxx/libsigrokcxx.pc])
826938d8 UH	436
	437	AC_OUTPUT
	438
1f61c22f	439	# Prepare bindings report messages.
d37c7109 DE	440	m4_define([SR_PREPARE_BINDING_REPORT], [
d37c7109 DE	441	sr_report_$1=
26b67f11	442	test -z "$sr_$1_missing" \|\| sr_report_$1=" (missing: $sr_$1_missing)"
d37c7109	443	test "x$enable_$1" = xyes \|\| sr_report_$1=' (disabled)'
1f61c22f	444	])
d37c7109	445	m4_map_args([SR_PREPARE_BINDING_REPORT], [cxx], [python], [java])
45aed072	446
1f61c22f DE	447	cat >&AS_MESSAGE_FD <<_EOF
	448
	449	libsigrok configuration summary:
	450	- Package version................. $SR_PACKAGE_VERSION
	451	- Library ABI version............. $SR_LIB_VERSION
	452	- Prefix.......................... $prefix
	453	- Building on..................... $build
	454	- Building for.................... $host
b84a7331	455	- Additional C compiler flags..... $SR_EXTRA_CFLAGS
4cf2f34f DE	456	- C compiler warnings............. $SR_WFLAGS
4cf2f34f DE	457	- C++ compiler warnings........... $SR_WXXFLAGS
1f61c22f DE	458
1f61c22f DE	459	Detected libraries (required):
965d6889 UH	460	- glib-2.0 >= 2.32.0.............. $sr_glib_version
965d6889 UH	461	- libzip >= 0.10.................. $sr_libzip_version
1f61c22f DE	462
	463	Detected libraries (optional):
	464	$sr_pkglibs_summary
c5f179a9	465	Enabled hardware drivers:
d37c7109	466	$sr_driver_summary
1f61c22f DE	467	Enabled SCPI backends:
	468	- TCP............................. yes
	469	- RPC............................. $sr_cv_have_rpc
	470	- serial.......................... $sr_have_libserialport
	471	- VISA............................ $sr_have_librevisa
	472	- GPIB............................ $sr_have_libgpib
	473	- USBTMC.......................... $sr_have_libusb
	474
	475	Enabled language bindings:
	476	- C++............................. $BINDINGS_CXX$sr_report_cxx
	477	- Python.......................... $BINDINGS_PYTHON$sr_report_python
	478	- Java............................ $BINDINGS_JAVA$sr_report_java
826938d8	479
1f61c22f	480	_EOF