]>
Commit | Line | Data |
---|---|---|
826938d8 | 1 | ## |
50985c20 | 2 | ## This file is part of the libsigrok project. |
826938d8 | 3 | ## |
c73d2ea4 | 4 | ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com> |
d375b3c3 | 5 | ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com> |
826938d8 UH |
6 | ## |
7 | ## This program is free software: you can redistribute it and/or modify | |
8 | ## it under the terms of the GNU General Public License as published by | |
9 | ## the Free Software Foundation, either version 3 of the License, or | |
10 | ## (at your option) any later version. | |
11 | ## | |
12 | ## This program is distributed in the hope that it will be useful, | |
13 | ## but WITHOUT ANY WARRANTY; without even the implied warranty of | |
14 | ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the | |
15 | ## GNU General Public License for more details. | |
16 | ## | |
17 | ## You should have received a copy of the GNU General Public License | |
18 | ## along with this program. If not, see <http://www.gnu.org/licenses/>. | |
19 | ## | |
20 | ||
ef7228ba UH |
21 | # We require at least autoconf 2.63 (AC_INIT format changed there). |
22 | AC_PREREQ([2.63]) | |
826938d8 | 23 | |
24138539 | 24 | AC_INIT([libsigrok], [0.4.0], |
7f289d14 | 25 | [sigrok-devel@lists.sourceforge.net], |
db8ae7b9 | 26 | [libsigrok], [http://www.sigrok.org]) |
ea1d5351 | 27 | AC_CONFIG_MACRO_DIR([m4]) |
d8521c93 | 28 | AC_CONFIG_AUX_DIR([autostuff]) |
24138539 | 29 | AC_CONFIG_HEADERS([config.h include/libsigrok/version.h]) |
826938d8 | 30 | |
ef7228ba | 31 | # We require at least automake 1.11 (needed for 'silent rules'). |
9ac018d0 | 32 | AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define nostdinc subdir-objects check-news color-tests]) |
bbb3996c | 33 | AM_SILENT_RULES([yes]) |
432e5e95 | 34 | m4_ifdef([AM_PROG_AR], [AM_PROG_AR]) |
826938d8 | 35 | |
6dddd902 UH |
36 | AH_TOP([#ifndef SR_CONFIG_H |
37 | #define SR_CONFIG_H /* To stop multiple inclusions. */]) | |
38 | AH_BOTTOM([#endif /* SR_CONFIG_H */]) | |
826938d8 | 39 | |
826938d8 | 40 | # Checks for programs. |
826938d8 | 41 | AC_PROG_CC |
c23c8659 | 42 | AC_PROG_CXX |
826938d8 UH |
43 | AC_PROG_INSTALL |
44 | AC_PROG_LN_S | |
45 | ||
bb203cde UH |
46 | # Required for per-target flags or subdir-objects with C sources. |
47 | AM_PROG_CC_C_O | |
48 | ||
3841c4c5 DE |
49 | # Check for optional make features. |
50 | SR_PROG_MAKE_NO_PRINT_DIRECTORY | |
5b9e9bba DE |
51 | SR_PROG_MAKE_ORDER_ONLY |
52 | ||
826938d8 UH |
53 | # Initialize libtool. |
54 | LT_INIT | |
55 | ||
24138539 DE |
56 | # Set up the libsigrok version defines. |
57 | SR_PKG_VERSION_SET([SR_PACKAGE_VERSION], [AC_PACKAGE_VERSION]) | |
b2478a23 | 58 | |
3af71f0d | 59 | # Library version for libsigrok (NOT the same as the package version). |
826938d8 UH |
60 | # Carefully read the libtool docs before updating these numbers! |
61 | # The algorithm for determining which number to change (and how) is nontrivial! | |
62 | # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info | |
24138539 | 63 | SR_LIB_VERSION_SET([SR_LIB_VERSION], [2:0:0]) |
826938d8 | 64 | |
1f61c22f DE |
65 | ############################# |
66 | ## Optional dependencies ## | |
67 | ############################# | |
de44e114 | 68 | |
8c2024e0 DE |
69 | AC_LANG([C]) |
70 | ||
1f61c22f DE |
71 | # Initialize pkg-config. |
72 | # We require at least 0.22, as "Requires.private" behaviour changed there. | |
73 | PKG_PROG_PKG_CONFIG([0.22]) | |
bcacb863 | 74 | |
1bb196e4 DE |
75 | # Keep track of all checked modules so we can list them at the end. |
76 | SR_PKG_CHECK_SUMMARY([sr_pkglibs_summary]) | |
77 | ||
78 | # Collect the pkg-config module names of all dependencies in SR_PKGLIBS. | |
1f61c22f DE |
79 | # These are used to derive the compiler flags and for the "Requires.private" |
80 | # field in the generated libsigrok.pc file. | |
1bb196e4 | 81 | SR_VAR_OPT_PKG([SR_PKGLIBS], [sr_deps_avail]) |
65489c1a | 82 | SR_PKGLIBS_TESTS= |
1f61c22f DE |
83 | SR_PKGLIBS_CXX= |
84 | SR_PKGLIBS_PYTHON= | |
8c2024e0 | 85 | SR_EXTRA_LIBS= |
1f61c22f | 86 | |
2cbde151 | 87 | SR_ARG_OPT_PKG([libserialport], [LIBSERIALPORT], [NEED_SERIAL], |
1f61c22f | 88 | [libserialport >= 0.1.1]) |
1f61c22f | 89 | |
2cbde151 | 90 | SR_ARG_OPT_PKG([libftdi], [LIBFTDI],, |
0ab8386a | 91 | [libftdi1 >= 1.0], [libftdi >= 0.16]) |
1f61c22f DE |
92 | |
93 | # FreeBSD comes with an "integrated" libusb-1.0-style USB API. | |
94 | # This means libusb-1.0 is always available; no need to check for it. | |
c1adbb1e DE |
95 | # On Windows, require the latest version we can get our hands on, |
96 | # until the new generic event handling has seen an official release. | |
97 | AS_CASE([$host_os], | |
98 | [freebsd*], [sr_libusb_req='libusb-1.0' sr_have_libusb=yes], | |
99 | [mingw*], [sr_libusb_req='libusb-1.0 >= 1.0.20'], | |
100 | [sr_libusb_req='libusb-1.0 >= 1.0.16']) | |
1f61c22f | 101 | |
2cbde151 | 102 | SR_ARG_OPT_PKG([libusb], [LIBUSB_1_0], [NEED_USB], |
c1adbb1e | 103 | [$sr_libusb_req]) |
c23c8659 | 104 | |
2cbde151 | 105 | SR_ARG_OPT_PKG([librevisa], [LIBREVISA], [NEED_VISA], |
1f61c22f | 106 | [librevisa >= 0.0.20130412]) |
d92de05a | 107 | |
2cbde151 | 108 | SR_ARG_OPT_PKG([libgpib], [LIBGPIB], [NEED_GPIB], |
1f61c22f DE |
109 | [libgpib]) |
110 | ||
8c2024e0 DE |
111 | SR_ARG_OPT_CHECK([libieee1284], [LIBIEEE1284],, [ |
112 | sr_save_LIBS=$LIBS | |
113 | LIBS="-lieee1284 $LIBS" | |
114 | AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <ieee1284.h>]], | |
115 | [[(void) ieee1284_open(0, 0, 0);]])], | |
116 | [sr_have_libieee1284=yes], [sr_have_libieee1284=no]) | |
39cf2004 | 117 | LIBS=$sr_save_LIBS |
8c2024e0 DE |
118 | ]) |
119 | AS_IF([test "x$sr_have_libieee1284" = xyes], | |
120 | [SR_PREPEND([SR_EXTRA_LIBS], [-lieee1284])]) | |
121 | ||
1f61c22f DE |
122 | ###################### |
123 | ## Feature checks ## | |
124 | ###################### | |
f7740954 | 125 | |
aba69262 | 126 | # The Check unit testing framework is optional. Disable if not found. |
65489c1a | 127 | SR_PKG_CHECK([check], [SR_PKGLIBS_TESTS], [check >= 0.9.4]) |
1f61c22f DE |
128 | AM_CONDITIONAL([HAVE_CHECK], [test "x$sr_have_check" = xyes]) |
129 | ||
e662d9e8 | 130 | # Enable the C99 standard if possible, and enforce the use |
b84a7331 DE |
131 | # of SR_API to explicitly mark all public API functions. |
132 | SR_EXTRA_CFLAGS= | |
e662d9e8 | 133 | SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [C99], [-std=c99 -c99 -AC99 -qlanglvl=extc99]) |
b84a7331 DE |
134 | SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [visibility], [-fvisibility=hidden]) |
135 | ||
4cf2f34f | 136 | SR_ARG_ENABLE_WARNINGS([SR_WFLAGS], [-Wall], [-Wall -Wextra -Wmissing-prototypes]) |
1f61c22f DE |
137 | |
138 | # Check host characteristics. | |
bbb3996c | 139 | AC_SYS_LARGEFILE |
1f61c22f | 140 | AC_C_BIGENDIAN |
79bb0e97 | 141 | |
1bb196e4 DE |
142 | AC_CHECK_HEADERS([sys/mman.h], [SR_APPEND([sr_deps_avail], [sys_mman_h])]) |
143 | AC_CHECK_HEADERS([sys/ioctl.h], [SR_APPEND([sr_deps_avail], [sys_ioctl_h])]) | |
144 | AC_CHECK_HEADERS([sys/timerfd.h], [SR_APPEND([sr_deps_avail], [sys_timerfd_h])]) | |
1f61c22f | 145 | |
bc8ff24d | 146 | # We need to link against the Winsock2 library for SCPI over TCP. |
8c2024e0 | 147 | AS_CASE([$host_os], [mingw*], [SR_PREPEND([SR_EXTRA_LIBS], [-lws2_32])]) |
bc8ff24d DE |
148 | |
149 | # libm (the standard math library) is always needed. | |
150 | SR_SEARCH_LIBS([SR_EXTRA_LIBS], [pow], [m]) | |
151 | ||
1f61c22f DE |
152 | # RPC is only needed for VXI support. |
153 | AC_CACHE_CHECK([for RPC support], [sr_cv_have_rpc], | |
154 | [AC_LINK_IFELSE([AC_LANG_PROGRAM( | |
155 | [[#include <rpc/rpc.h>]m4_newline[CLIENT *rpc_test(void);]], | |
156 | [[(void) clnt_create("", 0, 0, "");]])], | |
157 | [sr_cv_have_rpc=yes], [sr_cv_have_rpc=no])]) | |
158 | AS_IF([test "x$sr_cv_have_rpc" = xyes], | |
159 | [AC_DEFINE([HAVE_RPC], [1], [Specifies whether we have RPC support.])]) | |
160 | # VXI support is only compiled if RPC support was found. | |
161 | AM_CONDITIONAL([NEED_RPC], [test "x$sr_cv_have_rpc" = xyes]) | |
162 | ||
d37c7109 DE |
163 | ######################## |
164 | ## Hardware drivers ## | |
165 | ######################## | |
166 | ||
167 | # Keep track of all drivers so we can list them at the end. | |
1bb196e4 | 168 | SR_VAR_SUMMARY([sr_driver_summary]) |
d37c7109 DE |
169 | |
170 | # Check whether the sr_deps_avail list contains all of the arguments. | |
171 | # Unavailable dependencies are collected in sr_deps_missing. | |
172 | sr_check_driver_deps() { | |
173 | sr_deps_missing= | |
174 | for sr_dep | |
175 | do | |
176 | AS_CASE([" $sr_deps_avail "], [*" $sr_dep "*],, | |
26b67f11 | 177 | [SR_APPEND([sr_deps_missing], [', '], [$sr_dep])]) |
d37c7109 | 178 | done |
4ed3d9b6 | 179 | test -z "$sr_deps_missing" || return 1 |
d37c7109 DE |
180 | } |
181 | ||
182 | AC_ARG_ENABLE([all-drivers], | |
183 | [AS_HELP_STRING([--enable-all-drivers], | |
184 | [enable all drivers by default [default=yes]])], | |
185 | [], [enable_all_drivers=yes]) | |
186 | ||
187 | ## _SR_DRIVER(Device name, driver-name, var-name, [dependencies...]) | |
188 | m4_define([_SR_DRIVER], [ | |
b8b727e4 | 189 | AC_ARG_ENABLE([$2], |
d37c7109 DE |
190 | [AS_HELP_STRING([--enable-$2], [enable $1 support])], |
191 | [$3=$enableval], [$3=$enable_all_drivers]) | |
192 | ||
193 | AS_IF([test "x[$]$3" = xyes], [sr_hw_info=yes[]m4_ifval([$4], [ | |
4ed3d9b6 DE |
194 | sr_check_driver_deps $4 \ |
195 | || $3=no sr_hw_info="no (missing: $sr_deps_missing)" | |
d37c7109 | 196 | ])], [sr_hw_info='no (disabled)']) |
1bb196e4 | 197 | sr_driver_summary_append "$2" "$sr_hw_info" |
d37c7109 DE |
198 | |
199 | AM_CONDITIONAL([$3], [test "x[$]$3" = xyes]) | |
200 | AM_COND_IF([$3], [AC_DEFINE([HAVE_$3], [1], [Whether to support $1 device.])]) | |
201 | ]) | |
202 | ||
203 | ## SR_DRIVER(Device name, driver-name, [dependencies...]) | |
204 | m4_define([SR_DRIVER], | |
205 | [_SR_DRIVER([$1], [$2], m4_expand([AS_TR_CPP([HW_$2])]), [$3])]) | |
206 | ||
207 | SR_DRIVER([Agilent DMM], [agilent-dmm], [libserialport]) | |
208 | SR_DRIVER([Appa 55II], [appa-55ii], [libserialport]) | |
209 | SR_DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma], [libftdi]) | |
210 | SR_DRIVER([Atten PPS3xxx], [atten-pps3xxx], [libserialport]) | |
211 | SR_DRIVER([BayLibre ACME], [baylibre-acme], [sys_timerfd_h]) | |
212 | SR_DRIVER([BeagleLogic], [beaglelogic], [sys_mman_h sys_ioctl_h]) | |
213 | SR_DRIVER([Brymen BM86x], [brymen-bm86x], [libusb]) | |
214 | SR_DRIVER([Brymen DMM], [brymen-dmm], [libserialport]) | |
215 | SR_DRIVER([CEM DT-885x], [cem-dt-885x], [libserialport]) | |
216 | SR_DRIVER([Center 3xx], [center-3xx], [libserialport]) | |
217 | SR_DRIVER([ChronoVu LA], [chronovu-la], [libftdi]) | |
218 | SR_DRIVER([Colead SLM], [colead-slm], [libserialport]) | |
219 | SR_DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu], [libserialport]) | |
220 | SR_DRIVER([DER EE DE-5000], [deree-de5000], [libserialport]) | |
221 | SR_DRIVER([demo], [demo]) | |
222 | SR_DRIVER([Fluke DMM], [fluke-dmm], [libserialport]) | |
223 | SR_DRIVER([fx2lafw], [fx2lafw], [libusb]) | |
224 | SR_DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x], [libserialport]) | |
225 | SR_DRIVER([Hameg HMO], [hameg-hmo], [libserialport]) | |
226 | SR_DRIVER([Hantek DSO], [hantek-dso], [libusb]) | |
227 | SR_DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2], [libusb]) | |
228 | SR_DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus], [libftdi]) | |
229 | SR_DRIVER([Kecheng KC-330B], [kecheng-kc-330b], [libusb]) | |
8006cdc5 | 230 | SR_DRIVER([KERN scale], [kern-scale], [libserialport]) |
d37c7109 DE |
231 | SR_DRIVER([Lascar EL-USB], [lascar-el-usb], [libusb]) |
232 | SR_DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx], [libserialport]) | |
233 | SR_DRIVER([maynuo-m97], [maynuo-m97]) | |
234 | SR_DRIVER([MIC 985xx], [mic-985xx], [libserialport]) | |
235 | SR_DRIVER([Motech LPS 30x], [motech-lps-30x], [libserialport]) | |
236 | SR_DRIVER([Norma DMM], [norma-dmm], [libserialport]) | |
237 | SR_DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer], [libserialport]) | |
238 | SR_DRIVER([Pipistrello-OLS], [pipistrello-ols], [libftdi]) | |
239 | SR_DRIVER([Rigol DS], [rigol-ds]) | |
240 | SR_DRIVER([Saleae Logic16], [saleae-logic16], [libusb]) | |
241 | SR_DRIVER([SCPI PPS], [scpi-pps]) | |
242 | SR_DRIVER([serial DMM], [serial-dmm], [libserialport]) | |
243 | SR_DRIVER([Sysclk LWLA], [sysclk-lwla], [libusb]) | |
244 | SR_DRIVER([Teleinfo], [teleinfo], [libserialport]) | |
245 | SR_DRIVER([Testo], [testo], [libusb]) | |
246 | SR_DRIVER([Tondaj SL-814], [tondaj-sl-814], [libserialport]) | |
247 | SR_DRIVER([UNI-T DMM], [uni-t-dmm], [libusb]) | |
248 | SR_DRIVER([UNI-T UT32x], [uni-t-ut32x], [libusb]) | |
249 | SR_DRIVER([Victor DMM], [victor-dmm], [libusb]) | |
250 | SR_DRIVER([Yokogawa DL/DLM], [yokogawa-dlm]) | |
251 | SR_DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube], [libusb]) | |
1f61c22f DE |
252 | |
253 | ############################### | |
254 | ## Language bindings setup ## | |
255 | ############################### | |
256 | ||
d37c7109 | 257 | AC_LANG([C++]) |
4cf2f34f | 258 | SR_ARG_ENABLE_WARNINGS([SR_WXXFLAGS], [-Wall], [-Wall -Wextra]) |
d37c7109 | 259 | |
1f61c22f DE |
260 | AC_ARG_ENABLE([bindings], |
261 | [AS_HELP_STRING([--enable-bindings], [build language bindings [default=yes]])], | |
262 | [], [enable_bindings=yes]) | |
176c7219 | 263 | |
1f61c22f DE |
264 | AC_ARG_ENABLE([cxx], |
265 | [AS_HELP_STRING([--enable-cxx], [build C++ bindings [default=yes]])], | |
266 | [], [enable_cxx=$enable_bindings]) | |
a0b277ba | 267 | |
1f61c22f DE |
268 | AC_ARG_ENABLE([python], |
269 | [AS_HELP_STRING([--enable-python], [build Python bindings [default=yes]])], | |
270 | [], [enable_python=$enable_bindings]) | |
826938d8 | 271 | |
1f61c22f DE |
272 | AC_ARG_ENABLE([java], |
273 | [AS_HELP_STRING([--enable-java], [build Java bindings [default=yes]])], | |
274 | [], [enable_java=$enable_bindings]) | |
275 | ||
276 | #################### | |
277 | ## C++ bindings ## | |
278 | #################### | |
279 | ||
280 | sr_cxx_missing= | |
281 | ||
282 | # Check if the C++ compiler supports the C++11 standard. | |
e662d9e8 | 283 | AX_CXX_COMPILE_STDCXX_11([noext], [optional]) |
26b67f11 DE |
284 | AS_IF([test "x$HAVE_CXX11" != x1], |
285 | [SR_APPEND([sr_cxx_missing], [', '], ['C++11'])]) | |
1f61c22f DE |
286 | |
287 | # The C++ bindings need glibmm. | |
288 | SR_PKG_CHECK([glibmm], [SR_PKGLIBS_CXX], [glibmm-2.4 >= 2.32.0]) | |
26b67f11 DE |
289 | AS_IF([test "x$sr_have_glibmm" != xyes], |
290 | [SR_APPEND([sr_cxx_missing], [', '], [glibmm])]) | |
1f61c22f DE |
291 | |
292 | # The C++ bindings use Doxygen to parse libsigrok symbols. | |
293 | AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes], [no]) | |
26b67f11 DE |
294 | AS_IF([test "x$HAVE_DOXYGEN" != xyes], |
295 | [SR_APPEND([sr_cxx_missing], [', '], [Doxygen])]) | |
1f61c22f DE |
296 | |
297 | # Python is needed for the C++ bindings. | |
298 | AM_PATH_PYTHON([2.7], | |
299 | [HAVE_PYTHON=yes], | |
26b67f11 DE |
300 | [HAVE_PYTHON=no |
301 | SR_APPEND([sr_cxx_missing], [', '], [Python])]) | |
1f61c22f DE |
302 | |
303 | AS_IF([test -z "$sr_cxx_missing"], | |
304 | [BINDINGS_CXX=$enable_cxx], [BINDINGS_CXX=no]) | |
305 | AM_CONDITIONAL([BINDINGS_CXX], [test "x$BINDINGS_CXX" = xyes]) | |
306 | ||
307 | # C++ bindings want stoi and stod. | |
308 | AM_COND_IF([BINDINGS_CXX], [ | |
309 | AC_CACHE_CHECK([for stoi and stod], [sr_cv_have_stoi_stod], | |
310 | [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string>]], | |
311 | [[(void) std::stoi("1"); (void) std::stod("1.0");]])], | |
312 | [sr_cv_have_stoi_stod=yes], [sr_cv_have_stoi_stod=no])]) | |
313 | AS_IF([test "x$sr_cv_have_stoi_stod" = xyes], | |
314 | [AC_DEFINE([HAVE_STOI_STOD], [1], | |
315 | [Specifies whether we have the stoi and stod functions.])]) | |
316 | ]) | |
317 | ||
318 | ####################### | |
319 | ## Python bindings ## | |
320 | ####################### | |
321 | ||
26b67f11 DE |
322 | AS_IF([test "x$BINDINGS_CXX" = xyes], |
323 | [sr_python_missing=], | |
324 | [sr_python_missing='C++ bindings']) | |
1f61c22f DE |
325 | |
326 | # The Python bindings need Python development files. | |
327 | SR_PKG_CHECK([python_dev], [SR_PKGLIBS_PYTHON], | |
328 | [python >= 2.7], [python2 >= 2.7], [python27 >= 2.7]) | |
26b67f11 DE |
329 | AS_IF([test "x$sr_have_python_dev" != xyes], |
330 | [SR_APPEND([sr_python_missing], [', '], [Headers])]) | |
1f61c22f DE |
331 | |
332 | # PyGObject is needed for the Python bindings. | |
333 | SR_PKG_CHECK([pygobject], [SR_PKGLIBS_PYTHON], [pygobject-3.0 >= 3.0.0]) | |
26b67f11 DE |
334 | AS_IF([test "x$sr_have_pygobject" != xyes], |
335 | [SR_APPEND([sr_python_missing], [', '], [PyGObject])]) | |
1f61c22f DE |
336 | |
337 | PKG_CHECK_EXISTS([pygobject-3.0 < 3.7.91], | |
338 | [AC_DEFINE([PYGOBJECT_FLAGS_SIGNED], [1], | |
339 | [Whether last argument to pyg_flags_get_value() is signed.])]) | |
340 | ||
341 | # The Python bindings need the setuptools Python module. | |
342 | # We'll let it go through even if the AX macro wasn't found, | |
343 | # as the Python module may still be there. | |
344 | HAVE_PYMOD_SETUPTOOLS=yes | |
345 | m4_ifdef([AX_PYTHON_MODULE], | |
346 | [AX_PYTHON_MODULE([setuptools])], | |
cb4d28ef | 347 | [m4_warn([unsupported], [Missing macro AX_PYTHON_MODULE: no setuptools check])]) |
26b67f11 DE |
348 | AS_IF([test "x$HAVE_PYMOD_SETUPTOOLS" != xyes], |
349 | [SR_APPEND([sr_python_missing], [', '], [setuptools])]) | |
1f61c22f DE |
350 | |
351 | # The Python bindings use SWIG to generate code. | |
0ab8386a | 352 | AC_CHECK_PROGS([SWIG], [swig swig3.0 swig2.0]) |
26b67f11 DE |
353 | AS_IF([test "x$SWIG" = x], |
354 | [SR_APPEND([sr_python_missing], [', '], [SWIG])]) | |
1f61c22f DE |
355 | |
356 | AS_IF([test -z "$sr_python_missing"], | |
357 | [BINDINGS_PYTHON=$enable_python], [BINDINGS_PYTHON=no]) | |
358 | AM_CONDITIONAL([BINDINGS_PYTHON], [test "x$BINDINGS_PYTHON" = xyes]) | |
359 | ||
360 | #################### | |
361 | ## Java bindings ## | |
362 | #################### | |
363 | ||
26b67f11 DE |
364 | AS_IF([test "x$BINDINGS_CXX" = xyes], |
365 | [sr_java_missing=], | |
366 | [sr_java_missing='C++ bindings']) | |
1f61c22f DE |
367 | |
368 | # The Java bindings use SWIG to generate code. | |
26b67f11 DE |
369 | AS_IF([test "x$SWIG" = x], |
370 | [SR_APPEND([sr_java_missing], [', '], [SWIG])]) | |
4f10853e | 371 | |
9fcf4d0b | 372 | # Find Java compiler and JNI includes for Java bindings. |
9fcf4d0b | 373 | AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no]) |
26b67f11 DE |
374 | AS_IF([test "x$HAVE_JAVAC" = xno], |
375 | [SR_APPEND([sr_java_missing], [', '], [JavaC])]) | |
1f61c22f DE |
376 | |
377 | AC_ARG_WITH([jni-include-path], | |
378 | [AS_HELP_STRING([[--with-jni-include-path=DIR-LIST (space-separated)]], | |
379 | [specify JNI include directories [default=detect]])], | |
380 | [JNI_INCLUDE_DIRS=" $withval"], [JNI_INCLUDE_DIRS=]) | |
381 | ||
382 | JNI_CPPFLAGS= | |
383 | AS_IF([test "x$enable_java$HAVE_JAVAC" = xyesyes], [ | |
9fcf4d0b | 384 | AX_PROG_JAVAC |
1f61c22f DE |
385 | AS_IF([test -z "$JNI_INCLUDE_DIRS" && test "x$cross_compiling" != xyes], [ |
386 | ## Work around the totally broken logic in AX_JNI_INCLUDE_DIR: | |
387 | ## If we can find jni.h without any special search path, skip | |
388 | ## the execution of the broken macro to increase our chances of | |
389 | ## success. | |
390 | AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <jni.h>]], [])],, | |
391 | [AX_JNI_INCLUDE_DIR]) | |
392 | ]) | |
393 | ]) | |
394 | for sr_dir in $JNI_INCLUDE_DIRS | |
395 | do | |
26b67f11 | 396 | SR_APPEND([JNI_CPPFLAGS], ["-I$sr_dir"]) |
1f61c22f DE |
397 | done |
398 | AC_SUBST([JNI_CPPFLAGS]) | |
399 | ||
400 | sr_save_cppflags=$CPPFLAGS | |
26b67f11 DE |
401 | SR_APPEND([CPPFLAGS], [$JNI_CPPFLAGS]) |
402 | AC_CHECK_HEADER([jni.h],, | |
403 | [SR_APPEND([sr_java_missing], [', '], ['JNI headers'])]) | |
1f61c22f DE |
404 | CPPFLAGS=$sr_save_cppflags |
405 | ||
406 | AS_IF([test -z "$sr_java_missing"], | |
407 | [BINDINGS_JAVA=$enable_java], [BINDINGS_JAVA=no]) | |
408 | AM_CONDITIONAL([BINDINGS_JAVA], [test "x$BINDINGS_JAVA" = xyes]) | |
409 | ||
410 | ############################## | |
411 | ## Finalize configuration ## | |
412 | ############################## | |
413 | ||
414 | # Add mandatory dependencies to module list. | |
26b67f11 | 415 | SR_APPEND([SR_PKGLIBS], ['libzip >= 0.10']) |
1f61c22f DE |
416 | AC_SUBST([SR_PKGLIBS]) |
417 | ||
418 | # Retrieve the compile and link flags for all modules combined. | |
419 | # Also, bail out at this point if any module dependency is not met. | |
420 | PKG_CHECK_MODULES([LIBSIGROK], [glib-2.0 >= 2.32.0 $SR_PKGLIBS]) | |
65489c1a | 421 | PKG_CHECK_MODULES([TESTS], [$SR_PKGLIBS_TESTS glib-2.0 $SR_PKGLIBS]) |
1f61c22f | 422 | |
da0763d0 DE |
423 | # SR_PKGLIBS_CXX may be empty, so only invoke these checks when |
424 | # the C++ bindings are enabled. | |
425 | AM_COND_IF([BINDINGS_CXX], [ | |
426 | PKG_CHECK_MODULES([LIBSIGROKCXX], [$SR_PKGLIBS_CXX]) | |
427 | PKG_CHECK_MODULES([PYSIGROK], [$SR_PKGLIBS_PYTHON $SR_PKGLIBS_CXX]) | |
428 | ]) | |
c1adbb1e DE |
429 | |
430 | # Check for specific libusb features, now that we know the CFLAGS. | |
431 | AC_LANG([C]) | |
432 | sr_save_cflags=$CFLAGS | |
433 | CFLAGS="$LIBSIGROK_CFLAGS $CFLAGS" | |
434 | AC_CHECK_TYPES([libusb_os_handle], | |
435 | [sr_have_libusb_os_handle=yes], [sr_have_libusb_os_handle=no], | |
436 | [[#include <libusb.h>]]) | |
437 | CFLAGS=$sr_save_cflags | |
438 | AM_COND_IF([NEED_USB], [AS_CASE([$sr_have_libusb_os_handle:$host_os], [no:mingw*], | |
439 | [AC_MSG_ERROR([Windows builds require the event-abstraction branch of libusb])])]) | |
440 | ||
1f61c22f DE |
441 | sr_glib_version=`$PKG_CONFIG --modversion glib-2.0 2>&AS_MESSAGE_LOG_FD` |
442 | sr_libzip_version=`$PKG_CONFIG --modversion libzip 2>&AS_MESSAGE_LOG_FD` | |
443 | ||
2cbde151 DE |
444 | AC_DEFINE_UNQUOTED([CONF_LIBZIP_VERSION], ["$sr_libzip_version"], |
445 | [Build-time version of libzip.]) | |
446 | AC_DEFINE_UNQUOTED([CONF_HOST], ["$host"], | |
447 | [The canonical host libsigrok will run on.]) | |
1f61c22f | 448 | |
b2478a23 | 449 | AC_CONFIG_FILES([Makefile libsigrok.pc bindings/cxx/libsigrokcxx.pc]) |
826938d8 UH |
450 | |
451 | AC_OUTPUT | |
452 | ||
1f61c22f | 453 | # Prepare bindings report messages. |
d37c7109 DE |
454 | m4_define([SR_PREPARE_BINDING_REPORT], [ |
455 | sr_report_$1= | |
26b67f11 | 456 | test -z "$sr_$1_missing" || sr_report_$1=" (missing: $sr_$1_missing)" |
d37c7109 | 457 | test "x$enable_$1" = xyes || sr_report_$1=' (disabled)' |
1f61c22f | 458 | ]) |
d37c7109 | 459 | m4_map_args([SR_PREPARE_BINDING_REPORT], [cxx], [python], [java]) |
45aed072 | 460 | |
1f61c22f DE |
461 | cat >&AS_MESSAGE_FD <<_EOF |
462 | ||
463 | libsigrok configuration summary: | |
464 | - Package version................. $SR_PACKAGE_VERSION | |
465 | - Library ABI version............. $SR_LIB_VERSION | |
466 | - Prefix.......................... $prefix | |
467 | - Building on..................... $build | |
468 | - Building for.................... $host | |
6aa7fcf1 DE |
469 | - C compiler...................... $CC |
470 | - C compiler flags................ $CFLAGS | |
b84a7331 | 471 | - Additional C compiler flags..... $SR_EXTRA_CFLAGS |
4cf2f34f | 472 | - C compiler warnings............. $SR_WFLAGS |
6aa7fcf1 DE |
473 | - C++ compiler.................... $CXX |
474 | - C++ compiler flags.............. $CXXFLAGS | |
4cf2f34f | 475 | - C++ compiler warnings........... $SR_WXXFLAGS |
1f61c22f DE |
476 | |
477 | Detected libraries (required): | |
965d6889 UH |
478 | - glib-2.0 >= 2.32.0.............. $sr_glib_version |
479 | - libzip >= 0.10.................. $sr_libzip_version | |
1f61c22f DE |
480 | |
481 | Detected libraries (optional): | |
482 | $sr_pkglibs_summary | |
c5f179a9 | 483 | Enabled hardware drivers: |
d37c7109 | 484 | $sr_driver_summary |
1f61c22f DE |
485 | Enabled SCPI backends: |
486 | - TCP............................. yes | |
487 | - RPC............................. $sr_cv_have_rpc | |
488 | - serial.......................... $sr_have_libserialport | |
489 | - VISA............................ $sr_have_librevisa | |
490 | - GPIB............................ $sr_have_libgpib | |
491 | - USBTMC.......................... $sr_have_libusb | |
492 | ||
493 | Enabled language bindings: | |
494 | - C++............................. $BINDINGS_CXX$sr_report_cxx | |
495 | - Python.......................... $BINDINGS_PYTHON$sr_report_python | |
496 | - Java............................ $BINDINGS_JAVA$sr_report_java | |
826938d8 | 497 | |
1f61c22f | 498 | _EOF |