+# Usage: DRIVER([Device name], [driver-name])
+# An optional third argument [no] disables that driver.
+m4_define([driverize], [m4_tolower(m4_bpatsubst([$1], [[^0-9a-zA-Z-]+], [-]))])
+m4_define([upperize], [m4_toupper(m4_bpatsubst([$1], [[^0-9a-zA-Z_]+], [_]))])
+AC_DEFUN([DRIVER], [
+ if test -z "$3"; then
+ default=$HW_ENABLED_DEFAULT
+ else
+ default="$3"
+ fi
+ AC_ARG_ENABLE($2, AC_HELP_STRING([--enable-$2], [enable $1 support]),
+ [m4_join([], [HW_], upperize([$2]))="$enableval"],
+ [m4_join([], [HW_], upperize([$2]))=$default])
+ dots=$(expr substr ".............................." 1 $(expr 32 - length $2))
+ driver_summary="${driver_summary} - $2${dots} ${m4_join([], [HW_], upperize([$2]))}\n"
+])
+
+DRIVER([Agilent DMM], [agilent-dmm])
+DRIVER([Appa 55II], [appa-55ii])
+DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma])
+DRIVER([Atten PPS3xxx], [atten-pps3xxx])
+DRIVER([Brymen BM86x], [brymen-bm86x])
+DRIVER([Brymen DMM], [brymen-dmm])
+DRIVER([CEM DT-885x], [cem-dt-885x])
+DRIVER([Center 3xx], [center-3xx])
+DRIVER([ChronoVu LA], [chronovu-la])
+DRIVER([Colead SLM], [colead-slm])
+DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu])
+DRIVER([demo], [demo])
+DRIVER([Fluke DMM], [fluke-dmm])
+DRIVER([fx2lafw], [fx2lafw])
+DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x])
+DRIVER([Hameg HMO], [hameg-hmo])
+DRIVER([Hantek DSO], [hantek-dso])
+DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2])
+DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus])
+DRIVER([Kecheng KC-330B], [kecheng-kc-330b])
+DRIVER([Lascar EL-USB], [lascar-el-usb])
+DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx])
+DRIVER([MIC 985xx], [mic-985xx])
+DRIVER([Motech LPS 30x], [motech-lps-30x])
+DRIVER([Norma DMM], [norma-dmm])
+DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer])
+DRIVER([Rigol DS], [rigol-ds])
+DRIVER([Saleae Logic16], [saleae-logic16])
+DRIVER([serial DMM], [serial-dmm])
+DRIVER([Sysclk LWLA], [sysclk-lwla])
+DRIVER([Teleinfo], [teleinfo])
+DRIVER([Testo], [testo])
+DRIVER([Tondaj SL-814], [tondaj-sl-814])
+DRIVER([UNI-T DMM], [uni-t-dmm])
+DRIVER([UNI-T UT32x], [uni-t-ut32x])
+DRIVER([Victor DMM], [victor-dmm])
+DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube])
+
+AC_ARG_ENABLE(libserialport,
+ AC_HELP_STRING([--disable-libserialport],
+ [disable libserialport support [default=detect]]))
+
+AC_ARG_ENABLE(libftdi,
+ AC_HELP_STRING([--disable-libftdi],
+ [disable libftdi support [default=detect]]))
+
+AC_ARG_ENABLE(libusb,
+ AC_HELP_STRING([--disable-libusb],
+ [disable libusb support [default=detect]]))
+
+# Checks for libraries.
+
+case "$host" in
+*mingw*)
+ # We need to link against the Winsock2 library for SCPI over TCP.
+ LIBS="$LIBS -lws2_32";;
+esac
+
+# This variable collects the pkg-config names of all detected libs.
+# It is then used to construct the "Requires.private:" field in the
+# libsigrok.pc file.
+SR_PKGLIBS=""
+
+# libm (the standard math library) is always needed.
+AC_SEARCH_LIBS([pow], [m])
+
+# RPC is only needed for VXI support.
+AC_MSG_CHECKING([for RPC support])
+AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <rpc/rpc.h>],
+ [CLIENT *rpc_test(void)],
+ [{ return clnt_create("", 0, 0, ""); }])],
+ [AC_MSG_RESULT([yes]); have_rpc=1],
+ [AC_MSG_RESULT([no]); have_rpc=0])
+# Define HAVE_RPC in config.h if we found RPC support.
+AC_DEFINE_UNQUOTED(HAVE_RPC, [$have_rpc], [Specifies whether we have RPC support.])
+# VXI support is only compiled if RPC support was found.
+AM_CONDITIONAL(NEED_RPC, test "x$have_rpc" != "x0")
+
+# libglib-2.0 is always needed. Abort if it's not found.
+# Note: glib-2.0 is part of the libsigrok API (hard pkg-config requirement).
+# We require at least 2.32.0 due to e.g. g_variant_new_fixed_array().
+AM_PATH_GLIB_2_0([2.32.0],
+ [LIB_CFLAGS="$LIB_CFLAGS $GLIB_CFLAGS"; LIBS="$LIBS $GLIB_LIBS"])
+
+# libzip is always needed. Abort if it's not found.
+PKG_CHECK_MODULES([libzip], [libzip >= 0.10],
+ [LIB_CFLAGS="$LIB_CFLAGS $libzip_CFLAGS"; LIBS="$LIBS $libzip_LIBS";
+ SR_PKGLIBS="$SR_PKGLIBS libzip"])
+
+# libserialport is only needed for some hardware drivers. Disable the
+# respective drivers if it is not found.
+if test "x$enable_libserialport" != "xno"; then
+ PKG_CHECK_MODULES([libserialport], [libserialport >= 0.1.0],
+ [have_libserialport="yes"; LIB_CFLAGS="$LIB_CFLAGS $libserialport_CFLAGS";
+ LIBS="$LIBS $libserialport_LIBS";
+ SR_PKGLIBS="$SR_PKGLIBS libserialport"],
+ [have_libserialport="no"])
+ if test "x$enable_libserialport$have_libserialport" = "xyesno"; then
+ AC_MSG_ERROR([libserialport support requested, but it was not found])
+ fi
+else
+ have_libserialport="no"
+fi
+
+# Define HAVE_LIBSERIALPORT in config.h if we found libserialport.
+if test "x$have_libserialport" = "xno"; then
+ HW_AGILENT_DMM="no"; HW_APPA_55II="no";
+ HW_ATTEN_PPS3XXX="no"; HW_BRYMEN_DMM="no"; HW_CEM_DT_885X="no";
+ HW_CENTER_3XX="no"; HW_COLEAD_SLM="no"; HW_CONRAD_DIGI_35_CPU="no";
+ HW_FLUKE_DMM="no"; HW_GMC_MH_1X_2X="no"; HW_HAMEG_HMO="no";
+ HW_MANSON_HCS_3XXX="no"; HW_MIC_985XX="no"; HW_MOTECH_LPS_30X="no";
+ HW_NORMA_DMM="no"; HW_OPENBENCH_LOGIC_SNIFFER="no"; HW_SERIAL_DMM="no";
+ HW_TELEINFO="no"; HW_TONDAJ_SL_814="no";
+else
+ AC_DEFINE_UNQUOTED(HAVE_LIBSERIALPORT, [1],
+ [Specifies whether we have libserialport.])
+fi
+
+# Serial port helper code is only compiled in if libserialport was found.
+AM_CONDITIONAL(NEED_SERIAL, test "x$have_libserialport" != xno)
+
+PKG_CHECK_MODULES([librevisa], [librevisa >= 0.0.20130812],
+ [have_librevisa="yes"; LIB_CFLAGS="$LIB_CFLAGS $librevisa_CFLAGS";
+ LIBS="$LIBS $librevisa_LIBS";
+ SR_PKGLIBS="$SR_PKGLIBS librevisa"],
+ [have_librevisa="no"])
+
+# VISA SCPI backend is only compiled in if librevisa was found.
+AM_CONDITIONAL(NEED_VISA, test "x$have_librevisa" != xno)
+
+# Define HAVE_LIBREVISA in config.h if we found librevisa.
+if test "x$have_librevisa" != "xno"; then
+ AC_DEFINE_UNQUOTED(HAVE_LIBREVISA, [1],
+ [Specifies whether we have librevisa.])
+fi
+
+# libusb-1.0 is only needed for some hardware drivers. Disable the respective
+# drivers if it is not found.
+if test "x$enable_libusb" != "xno"; then
+ case "$host" in
+ *freebsd*)
+ # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
+ # This means libusb-1.0 is always available, no need to check for it,
+ # and no need to (potentially) disable any drivers if it's not found.
+ have_libusb1_0="yes"
+ ;;
+ *)
+ PKG_CHECK_MODULES([libusb], [libusb-1.0 >= 1.0.16],
+ [have_libusb1_0="yes"; LIB_CFLAGS="$LIB_CFLAGS $libusb_CFLAGS";
+ LIBS="$LIBS $libusb_LIBS";
+ SR_PKGLIBS="$SR_PKGLIBS libusb-1.0"],
+ [have_libusb1_0="no"])
+ if test "x$enable_libusb$have_libusb1_0" = "xyesno"; then
+ AC_MSG_ERROR([libusb support requested, but it was not found])
+ fi
+ ;;
+ esac
+else
+ have_libusb1_0="no"
+fi
+
+# Define HAVE_LIBUSB_1_0 in config.h if we found libusb-1.0.
+if test "x$have_libusb1_0" = "xno"; then
+ HW_BRYMEN_BM86X="no"; HW_FX2LAFW="no";
+ HW_HANTEK_DSO="no"; HW_IKALOGIC_SCANALOGIC2="no";
+ HW_KECHENG_KC_330B="no"; HW_LASCAR_EL_USB="no";
+ HW_SYSCLK_LWLA="no"; HW_TESTO="no"; HW_UNI_T_DMM="no";
+ HW_UNI_T_UT32X="no"; HW_VICTOR_DMM="no";
+ HW_ZEROPLUS_LOGIC_CUBE="no"; HW_SALEAE_LOGIC16="no";
+else
+ AC_DEFINE_UNQUOTED(HAVE_LIBUSB_1_0, [1],
+ [Specifies whether we have a libusb.h header.])
+fi
+
+# USB + FX2 firmware helper code is only compiled in if libusb-1.0 was found.
+AM_CONDITIONAL(NEED_USB, test "x$have_libusb1_0" != xno)
+
+# libftdi is only needed for some hardware drivers. Disable them if not found.
+if test "x$enable_libftdi" != "xno"; then
+ PKG_CHECK_MODULES([libftdi], [libftdi >= 0.16],
+ [have_libftdi="yes"; LIB_CFLAGS="$LIB_CFLAGS $libftdi_CFLAGS";
+ LIBS="$LIBS $libftdi_LIBS";
+ SR_PKGLIBS="$SR_PKGLIBS libftdi"],
+ [PKG_CHECK_MODULES([libftdi1], [libftdi1 >= 1.0],
+ [LIB_CFLAGS="$LIB_CFLAGS $libftdi1_CFLAGS";
+ LIBS="$LIBS $libftdi1_LIBS";
+ SR_PKGLIBS="$SR_PKGLIBS libftdi1"],
+ [have_libftdi="no"])])
+ if test "x$enable_libftdi$have_libftdi" = "xyesno"; then
+ AC_MSG_ERROR([libftdi support requested, but it was not found])
+ fi
+else
+ have_libftdi="no"
+fi
+
+if test "x$have_libftdi" = "xno"; then
+ HW_ASIX_SIGMA="no"; HW_CHRONOVU_LA="no"; HW_IKALOGIC_SCANAPLUS="no";
+fi
+
+# The Check unit testing framework is optional. Disable if not found.
+PKG_CHECK_MODULES([check], [check >= 0.9.4],
+ [have_check="yes"], [have_check="no"])
+AM_CONDITIONAL(HAVE_CHECK, test x"$have_check" = "xyes")
+
+# The OLS driver uses serial port file descriptors directly, and therefore
+# will not currently work on Windows.
+case "$host" in
+*mingw*)
+ HW_OPENBENCH_LOGIC_SNIFFER="no"
+ ;;
+esac
+
+AC_SUBST(SR_PKGLIBS)
+
+CFLAGS="$CFLAGS -I./include/libsigrok $LIB_CFLAGS"
+
+# Now set AM_CONDITIONALs and AC_DEFINEs for the enabled/disabled drivers.
+