[libsigrok.git] / configure.ac

##
## This file is part of the libsigrok project.
##
## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
##
## This program is free software: you can redistribute it and/or modify
## it under the terms of the GNU General Public License as published by
## the Free Software Foundation, either version 3 of the License, or
## (at your option) any later version.
##
## This program is distributed in the hope that it will be useful,
## but WITHOUT ANY WARRANTY; without even the implied warranty of
## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
## GNU General Public License for more details.
##
## You should have received a copy of the GNU General Public License
## along with this program.  If not, see <http://www.gnu.org/licenses/>.
##

# We require at least autoconf 2.63 (AC_INIT format changed there).
AC_PREREQ([2.63])

AC_INIT([libsigrok], [0.4.0],
	[sigrok-devel@lists.sourceforge.net],
	[libsigrok], [http://www.sigrok.org])
AC_CONFIG_MACRO_DIR([m4])
AC_CONFIG_AUX_DIR([autostuff])
AC_CONFIG_HEADERS([config.h include/libsigrok/version.h])

# We require at least automake 1.11 (needed for 'silent rules').
AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define nostdinc subdir-objects check-news color-tests])
m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
m4_ifdef([AM_PROG_AR], [AM_PROG_AR])

AH_TOP([#ifndef SR_CONFIG_H
#define SR_CONFIG_H    /* To stop multiple inclusions. */])
AH_BOTTOM([#endif /* SR_CONFIG_H */])

# Checks for programs.
AC_PROG_CC
AC_PROG_CPP
AC_PROG_CXX
AC_PROG_INSTALL
AC_PROG_LN_S

# Required for per-target flags or subdir-objects with C sources.
AM_PROG_CC_C_O

# Initialize libtool.
LT_INIT

# Set up the libsigrok version defines.
SR_PKG_VERSION_SET([SR_PACKAGE_VERSION], [AC_PACKAGE_VERSION])

# Library version for libsigrok (NOT the same as the package version).
# Carefully read the libtool docs before updating these numbers!
# The algorithm for determining which number to change (and how) is nontrivial!
# http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
SR_LIB_VERSION_SET([SR_LIB_VERSION], [2:0:0])

#############################
##  Optional dependencies  ##
#############################

# Initialize pkg-config.
# We require at least 0.22, as "Requires.private" behaviour changed there.
PKG_PROG_PKG_CONFIG([0.22])

# Keep track of all checked modules so we can list them at the end.
SR_PKG_CHECK_SUMMARY([sr_pkglibs_summary])

# Collect the pkg-config module names of all dependencies in SR_PKGLIBS.
# These are used to derive the compiler flags and for the "Requires.private"
# field in the generated libsigrok.pc file.
SR_VAR_OPT_PKG([SR_PKGLIBS], [sr_deps_avail])
SR_PKGLIBS_CHECK=
SR_PKGLIBS_CXX=
SR_PKGLIBS_PYTHON=

SR_ARG_OPT_PKG([libserialport], [LIBSERIALPORT], [NEED_SERIAL],
	[libserialport >= 0.1.1])

SR_ARG_OPT_PKG([libftdi], [LIBFTDI],,
	[libftdi >= 0.16], [libftdi1 >= 1.0])

# FreeBSD comes with an "integrated" libusb-1.0-style USB API.
# This means libusb-1.0 is always available; no need to check for it.
AS_CASE([$host], [*freebsd*], [sr_have_libusb=yes])

SR_ARG_OPT_PKG([libusb], [LIBUSB_1_0], [NEED_USB],
	[libusb-1.0 >= 1.0.16])

SR_ARG_OPT_PKG([librevisa], [LIBREVISA], [NEED_VISA],
	[librevisa >= 0.0.20130412])

SR_ARG_OPT_PKG([libgpib], [LIBGPIB], [NEED_GPIB],
	[libgpib])

######################
##  Feature checks  ##
######################

# The Check unit testing framework is optional. Disable if not found.
SR_PKG_CHECK([check], [SR_PKGLIBS_CHECK], [check >= 0.9.4])
AM_CONDITIONAL([HAVE_CHECK], [test "x$sr_have_check" = xyes])

AC_LANG([C])

# Enable the C11 standard if possible, and enforce the use
# of SR_API to explicitly mark all public API functions.
SR_EXTRA_CFLAGS=
SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [C11], [-std=gnu11 -std=c11])
SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [visibility], [-fvisibility=hidden])

SR_ARG_ENABLE_WARNINGS([SR_WFLAGS], [-Wall], [-Wall -Wextra -Wmissing-prototypes])

# Check host characteristics.
AC_C_BIGENDIAN

AC_CHECK_HEADERS([sys/mman.h], [SR_APPEND([sr_deps_avail], [sys_mman_h])])
AC_CHECK_HEADERS([sys/ioctl.h], [SR_APPEND([sr_deps_avail], [sys_ioctl_h])])
AC_CHECK_HEADERS([sys/timerfd.h], [SR_APPEND([sr_deps_avail], [sys_timerfd_h])])

# RPC is only needed for VXI support.
AC_CACHE_CHECK([for RPC support], [sr_cv_have_rpc],
	[AC_LINK_IFELSE([AC_LANG_PROGRAM(
			[[#include <rpc/rpc.h>]m4_newline[CLIENT *rpc_test(void);]],
			[[(void) clnt_create("", 0, 0, "");]])],
		[sr_cv_have_rpc=yes], [sr_cv_have_rpc=no])])
AS_IF([test "x$sr_cv_have_rpc" = xyes],
	[AC_DEFINE([HAVE_RPC], [1], [Specifies whether we have RPC support.])])
# VXI support is only compiled if RPC support was found.
AM_CONDITIONAL([NEED_RPC], [test "x$sr_cv_have_rpc" = xyes])

########################
##  Hardware drivers  ##
########################

# Keep track of all drivers so we can list them at the end.
SR_VAR_SUMMARY([sr_driver_summary])

# Check whether the sr_deps_avail list contains all of the arguments.
# Unavailable dependencies are collected in sr_deps_missing.
sr_check_driver_deps() {
	sr_deps_missing=
	for sr_dep
	do
		AS_CASE([" $sr_deps_avail "], [*" $sr_dep "*],,
			[SR_APPEND([sr_deps_missing], [', '], [$sr_dep])])
	done
}

AC_ARG_ENABLE([all-drivers],
	[AS_HELP_STRING([--enable-all-drivers],
			[enable all drivers by default [default=yes]])],
	[], [enable_all_drivers=yes])

## _SR_DRIVER(Device name, driver-name, var-name, [dependencies...])
m4_define([_SR_DRIVER], [
	AC_ARG_ENABLE([$2],
		[AS_HELP_STRING([--enable-$2], [enable $1 support])],
		[$3=$enableval], [$3=$enable_all_drivers])

	AS_IF([test "x[$]$3" = xyes], [sr_hw_info=yes[]m4_ifval([$4], [
		sr_check_driver_deps $4
		AS_IF([test -n "$sr_deps_missing"],
			[$3=no sr_hw_info="no (missing: $sr_deps_missing)"])
	])], [sr_hw_info='no (disabled)'])
	sr_driver_summary_append "$2" "$sr_hw_info"

	AM_CONDITIONAL([$3], [test "x[$]$3" = xyes])
	AM_COND_IF([$3], [AC_DEFINE([HAVE_$3], [1], [Whether to support $1 device.])])
])

## SR_DRIVER(Device name, driver-name, [dependencies...])
m4_define([SR_DRIVER],
	[_SR_DRIVER([$1], [$2], m4_expand([AS_TR_CPP([HW_$2])]), [$3])])

SR_DRIVER([Agilent DMM], [agilent-dmm], [libserialport])
SR_DRIVER([Appa 55II], [appa-55ii], [libserialport])
SR_DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma], [libftdi])
SR_DRIVER([Atten PPS3xxx], [atten-pps3xxx], [libserialport])
SR_DRIVER([BayLibre ACME], [baylibre-acme], [sys_timerfd_h])
SR_DRIVER([BeagleLogic], [beaglelogic], [sys_mman_h sys_ioctl_h])
SR_DRIVER([Brymen BM86x], [brymen-bm86x], [libusb])
SR_DRIVER([Brymen DMM], [brymen-dmm], [libserialport])
SR_DRIVER([CEM DT-885x], [cem-dt-885x], [libserialport])
SR_DRIVER([Center 3xx], [center-3xx], [libserialport])
SR_DRIVER([ChronoVu LA], [chronovu-la], [libftdi])
SR_DRIVER([Colead SLM], [colead-slm], [libserialport])
SR_DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu], [libserialport])
SR_DRIVER([DER EE DE-5000], [deree-de5000], [libserialport])
SR_DRIVER([demo], [demo])
SR_DRIVER([Fluke DMM], [fluke-dmm], [libserialport])
SR_DRIVER([fx2lafw], [fx2lafw], [libusb])
SR_DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x], [libserialport])
SR_DRIVER([Hameg HMO], [hameg-hmo], [libserialport])
SR_DRIVER([Hantek DSO], [hantek-dso], [libusb])
SR_DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2], [libusb])
SR_DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus], [libftdi])
SR_DRIVER([Kecheng KC-330B], [kecheng-kc-330b], [libusb])
SR_DRIVER([Lascar EL-USB], [lascar-el-usb], [libusb])
SR_DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx], [libserialport])
SR_DRIVER([maynuo-m97], [maynuo-m97])
SR_DRIVER([MIC 985xx], [mic-985xx], [libserialport])
SR_DRIVER([Motech LPS 30x], [motech-lps-30x], [libserialport])
SR_DRIVER([Norma DMM], [norma-dmm], [libserialport])
SR_DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer], [libserialport])
SR_DRIVER([Pipistrello-OLS], [pipistrello-ols], [libftdi])
SR_DRIVER([Rigol DS], [rigol-ds])
SR_DRIVER([Saleae Logic16], [saleae-logic16], [libusb])
SR_DRIVER([SCPI PPS], [scpi-pps])
SR_DRIVER([serial DMM], [serial-dmm], [libserialport])
SR_DRIVER([Sysclk LWLA], [sysclk-lwla], [libusb])
SR_DRIVER([Teleinfo], [teleinfo], [libserialport])
SR_DRIVER([Testo], [testo], [libusb])
SR_DRIVER([Tondaj SL-814], [tondaj-sl-814], [libserialport])
SR_DRIVER([UNI-T DMM], [uni-t-dmm], [libusb])
SR_DRIVER([UNI-T UT32x], [uni-t-ut32x], [libusb])
SR_DRIVER([Victor DMM], [victor-dmm], [libusb])
SR_DRIVER([Yokogawa DL/DLM], [yokogawa-dlm])
SR_DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube], [libusb])

###############################
##  Language bindings setup  ##
###############################

AC_LANG([C++])
SR_ARG_ENABLE_WARNINGS([SR_WXXFLAGS], [-Wall], [-Wall -Wextra])

AC_ARG_ENABLE([bindings],
	[AS_HELP_STRING([--enable-bindings], [build language bindings [default=yes]])],
	[], [enable_bindings=yes])

AC_ARG_ENABLE([cxx],
	[AS_HELP_STRING([--enable-cxx], [build C++ bindings [default=yes]])],
	[], [enable_cxx=$enable_bindings])

AC_ARG_ENABLE([python],
	[AS_HELP_STRING([--enable-python], [build Python bindings [default=yes]])],
	[], [enable_python=$enable_bindings])

AC_ARG_ENABLE([java],
	[AS_HELP_STRING([--enable-java], [build Java bindings [default=yes]])],
	[], [enable_java=$enable_bindings])

####################
##  C++ bindings  ##
####################

sr_cxx_missing=

# Check if the C++ compiler supports the C++11 standard.
m4_ifdef([AX_CXX_COMPILE_STDCXX_11],
	[AX_CXX_COMPILE_STDCXX_11(, [optional])],
	[m4_warn([unsupported], [Missing macro AX_CXX_COMPILE_STDCXX_11: no C++11 check possible])])
AS_IF([test "x$HAVE_CXX11" != x1],
	[SR_APPEND([sr_cxx_missing], [', '], ['C++11'])])

# The C++ bindings need glibmm.
SR_PKG_CHECK([glibmm], [SR_PKGLIBS_CXX], [glibmm-2.4 >= 2.32.0])
AS_IF([test "x$sr_have_glibmm" != xyes],
	[SR_APPEND([sr_cxx_missing], [', '], [glibmm])])

# The C++ bindings use Doxygen to parse libsigrok symbols.
AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes], [no])
AS_IF([test "x$HAVE_DOXYGEN" != xyes],
	[SR_APPEND([sr_cxx_missing], [', '], [Doxygen])])

# Python is needed for the C++ bindings.
AM_PATH_PYTHON([2.7],
	[HAVE_PYTHON=yes],
	[HAVE_PYTHON=no
	SR_APPEND([sr_cxx_missing], [', '], [Python])])

AS_IF([test -z "$sr_cxx_missing"],
	[BINDINGS_CXX=$enable_cxx], [BINDINGS_CXX=no])
AM_CONDITIONAL([BINDINGS_CXX], [test "x$BINDINGS_CXX" = xyes])

# C++ bindings want stoi and stod.
AM_COND_IF([BINDINGS_CXX], [
	AC_CACHE_CHECK([for stoi and stod], [sr_cv_have_stoi_stod],
		[AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string>]],
				[[(void) std::stoi("1"); (void) std::stod("1.0");]])],
			[sr_cv_have_stoi_stod=yes], [sr_cv_have_stoi_stod=no])])
	AS_IF([test "x$sr_cv_have_stoi_stod" = xyes],
		[AC_DEFINE([HAVE_STOI_STOD], [1],
			[Specifies whether we have the stoi and stod functions.])])
])

#######################
##  Python bindings  ##
#######################

AS_IF([test "x$BINDINGS_CXX" = xyes],
	[sr_python_missing=],
	[sr_python_missing='C++ bindings'])

# The Python bindings need Python development files.
SR_PKG_CHECK([python_dev], [SR_PKGLIBS_PYTHON],
	[python >= 2.7], [python2 >= 2.7], [python27 >= 2.7])
AS_IF([test "x$sr_have_python_dev" != xyes],
	[SR_APPEND([sr_python_missing], [', '], [Headers])])

# PyGObject is needed for the Python bindings.
SR_PKG_CHECK([pygobject], [SR_PKGLIBS_PYTHON], [pygobject-3.0 >= 3.0.0])
AS_IF([test "x$sr_have_pygobject" != xyes],
	[SR_APPEND([sr_python_missing], [', '], [PyGObject])])

PKG_CHECK_EXISTS([pygobject-3.0 < 3.7.91],
	[AC_DEFINE([PYGOBJECT_FLAGS_SIGNED], [1],
		[Whether last argument to pyg_flags_get_value() is signed.])])

# The Python bindings need the setuptools Python module.
# We'll let it go through even if the AX macro wasn't found,
# as the Python module may still be there.
HAVE_PYMOD_SETUPTOOLS=yes
m4_ifdef([AX_PYTHON_MODULE],
	[AX_PYTHON_MODULE([setuptools])],
	[m4_warn([unsupported], [Missing macro AX_PYTHON_MODULE: no setuptools check])])
AS_IF([test "x$HAVE_PYMOD_SETUPTOOLS" != xyes],
	[SR_APPEND([sr_python_missing], [', '], [setuptools])])

# The Python bindings use SWIG to generate code.
AC_CHECK_PROGS([SWIG], [swig swig2.0 swig3.0])
AS_IF([test "x$SWIG" = x],
	[SR_APPEND([sr_python_missing], [', '], [SWIG])])

AS_IF([test -z "$sr_python_missing"],
	[BINDINGS_PYTHON=$enable_python], [BINDINGS_PYTHON=no])
AM_CONDITIONAL([BINDINGS_PYTHON], [test "x$BINDINGS_PYTHON" = xyes])

####################
##  Java bindings ##
####################

AS_IF([test "x$BINDINGS_CXX" = xyes],
	[sr_java_missing=],
	[sr_java_missing='C++ bindings'])

# The Java bindings use SWIG to generate code.
AS_IF([test "x$SWIG" = x],
	[SR_APPEND([sr_java_missing], [', '], [SWIG])])

# Find Java compiler and JNI includes for Java bindings.
AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no])
AS_IF([test "x$HAVE_JAVAC" = xno],
	[SR_APPEND([sr_java_missing], [', '], [JavaC])])

AC_ARG_WITH([jni-include-path],
	[AS_HELP_STRING([[--with-jni-include-path=DIR-LIST (space-separated)]],
		[specify JNI include directories [default=detect]])],
	[JNI_INCLUDE_DIRS=" $withval"], [JNI_INCLUDE_DIRS=])

JNI_CPPFLAGS=
AS_IF([test "x$enable_java$HAVE_JAVAC" = xyesyes], [
	AX_PROG_JAVAC
	AS_IF([test -z "$JNI_INCLUDE_DIRS" && test "x$cross_compiling" != xyes], [
		## Work around the totally broken logic in AX_JNI_INCLUDE_DIR:
		## If we can find jni.h without any special search path, skip
		## the execution of the broken macro to increase our chances of
		## success.
		AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <jni.h>]], [])],,
			[AX_JNI_INCLUDE_DIR])
	])
])
for sr_dir in $JNI_INCLUDE_DIRS
do
	SR_APPEND([JNI_CPPFLAGS], ["-I$sr_dir"])
done
AC_SUBST([JNI_CPPFLAGS])

sr_save_cppflags=$CPPFLAGS
SR_APPEND([CPPFLAGS], [$JNI_CPPFLAGS])
AC_CHECK_HEADER([jni.h],,
	[SR_APPEND([sr_java_missing], [', '], ['JNI headers'])])
CPPFLAGS=$sr_save_cppflags

AS_IF([test -z "$sr_java_missing"],
	[BINDINGS_JAVA=$enable_java], [BINDINGS_JAVA=no])
AM_CONDITIONAL([BINDINGS_JAVA], [test "x$BINDINGS_JAVA" = xyes])

##############################
##  Finalize configuration  ##
##############################

# Add mandatory dependencies to module list.
SR_APPEND([SR_PKGLIBS], ['libzip >= 0.10'])
AC_SUBST([SR_PKGLIBS])

# Retrieve the compile and link flags for all modules combined.
# Also, bail out at this point if any module dependency is not met.
PKG_CHECK_MODULES([LIBSIGROK], [glib-2.0 >= 2.32.0 $SR_PKGLIBS])
PKG_CHECK_MODULES([CHECK], [$SR_PKGLIBS_CHECK glib-2.0 $SR_PKGLIBS])

# SR_PKGLIBS_CXX may be empty, so only invoke these checks when
# the C++ bindings are enabled.
AM_COND_IF([BINDINGS_CXX], [
	PKG_CHECK_MODULES([LIBSIGROKCXX], [$SR_PKGLIBS_CXX])
	PKG_CHECK_MODULES([PYSIGROK], [$SR_PKGLIBS_PYTHON $SR_PKGLIBS_CXX])
])
sr_glib_version=`$PKG_CONFIG --modversion glib-2.0 2>&AS_MESSAGE_LOG_FD`
sr_libzip_version=`$PKG_CONFIG --modversion libzip 2>&AS_MESSAGE_LOG_FD`

AC_DEFINE_UNQUOTED([CONF_LIBZIP_VERSION], ["$sr_libzip_version"],
	[Build-time version of libzip.])
AC_DEFINE_UNQUOTED([CONF_HOST], ["$host"],
	[The canonical host libsigrok will run on.])

AC_LANG([C])

# libm (the standard math library) is always needed.
AC_SEARCH_LIBS([pow], [m])

# We need to link against the Winsock2 library for SCPI over TCP.
AS_CASE([$host], [*mingw*], [LIBS="$LIBS -lws2_32"])

AC_SUBST([FIRMWARE_DIR], ['$(datadir)/sigrok-firmware'])
AC_SUBST([MAKEFLAGS], ['--no-print-directory'])
AC_SUBST([AM_LIBTOOLFLAGS], ['--silent'])

AC_CONFIG_FILES([Makefile libsigrok.pc bindings/cxx/libsigrokcxx.pc])

AC_OUTPUT

# Prepare bindings report messages.
m4_define([SR_PREPARE_BINDING_REPORT], [
	sr_report_$1=
	test -z "$sr_$1_missing" || sr_report_$1=" (missing: $sr_$1_missing)"
	test "x$enable_$1" = xyes || sr_report_$1=' (disabled)'
])
m4_map_args([SR_PREPARE_BINDING_REPORT], [cxx], [python], [java])

cat >&AS_MESSAGE_FD <<_EOF

libsigrok configuration summary:
 - Package version................. $SR_PACKAGE_VERSION
 - Library ABI version............. $SR_LIB_VERSION
 - Prefix.......................... $prefix
 - Building on..................... $build
 - Building for.................... $host
 - Additional C compiler flags..... $SR_EXTRA_CFLAGS
 - C compiler warnings............. $SR_WFLAGS
 - C++ compiler warnings........... $SR_WXXFLAGS

Detected libraries (required):
 - glib-2.0 >= 2.32.0.............. $sr_glib_version
 - libzip >= 0.10.................. $sr_libzip_version

Detected libraries (optional):
$sr_pkglibs_summary
Enabled hardware drivers:
$sr_driver_summary
Enabled SCPI backends:
 - TCP............................. yes
 - RPC............................. $sr_cv_have_rpc
 - serial.......................... $sr_have_libserialport
 - VISA............................ $sr_have_librevisa
 - GPIB............................ $sr_have_libgpib
 - USBTMC.......................... $sr_have_libusb

Enabled language bindings:
 - C++............................. $BINDINGS_CXX$sr_report_cxx
 - Python.......................... $BINDINGS_PYTHON$sr_report_python
 - Java............................ $BINDINGS_JAVA$sr_report_java

_EOF
Commit	Line	Data
826938d8	1	##
50985c20	2	## This file is part of the libsigrok project.
826938d8	3	##
c73d2ea4	4	## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
d375b3c3	5	## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
826938d8 UH	6	##
	7	## This program is free software: you can redistribute it and/or modify
	8	## it under the terms of the GNU General Public License as published by
	9	## the Free Software Foundation, either version 3 of the License, or
	10	## (at your option) any later version.
	11	##
	12	## This program is distributed in the hope that it will be useful,
	13	## but WITHOUT ANY WARRANTY; without even the implied warranty of
	14	## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	15	## GNU General Public License for more details.
	16	##
	17	## You should have received a copy of the GNU General Public License
	18	## along with this program. If not, see <http://www.gnu.org/licenses/>.
	19	##
	20
ef7228ba UH	21	# We require at least autoconf 2.63 (AC_INIT format changed there).
ef7228ba UH	22	AC_PREREQ([2.63])
826938d8	23
24138539	24	AC_INIT([libsigrok], [0.4.0],
7f289d14	25	[sigrok-devel@lists.sourceforge.net],
db8ae7b9	26	[libsigrok], [http://www.sigrok.org])
ea1d5351	27	AC_CONFIG_MACRO_DIR([m4])
d8521c93	28	AC_CONFIG_AUX_DIR([autostuff])
24138539	29	AC_CONFIG_HEADERS([config.h include/libsigrok/version.h])
826938d8	30
ef7228ba	31	# We require at least automake 1.11 (needed for 'silent rules').
9ac018d0	32	AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define nostdinc subdir-objects check-news color-tests])
826938d8	33	m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
432e5e95	34	m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
826938d8	35
6dddd902 UH	36	AH_TOP([#ifndef SR_CONFIG_H
	37	#define SR_CONFIG_H /* To stop multiple inclusions. */])
	38	AH_BOTTOM([#endif /* SR_CONFIG_H */])
826938d8	39
826938d8	40	# Checks for programs.
826938d8 UH	41	AC_PROG_CC
826938d8 UH	42	AC_PROG_CPP
c23c8659	43	AC_PROG_CXX
826938d8 UH	44	AC_PROG_INSTALL
	45	AC_PROG_LN_S
	46
bb203cde UH	47	# Required for per-target flags or subdir-objects with C sources.
	48	AM_PROG_CC_C_O
	49
826938d8 UH	50	# Initialize libtool.
	51	LT_INIT
	52
24138539 DE	53	# Set up the libsigrok version defines.
24138539 DE	54	SR_PKG_VERSION_SET([SR_PACKAGE_VERSION], [AC_PACKAGE_VERSION])
b2478a23	55
3af71f0d	56	# Library version for libsigrok (NOT the same as the package version).
826938d8 UH	57	# Carefully read the libtool docs before updating these numbers!
	58	# The algorithm for determining which number to change (and how) is nontrivial!
	59	# http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
24138539	60	SR_LIB_VERSION_SET([SR_LIB_VERSION], [2:0:0])
826938d8	61
1f61c22f DE	62	#############################
	63	## Optional dependencies ##
	64	#############################
de44e114	65
1f61c22f DE	66	# Initialize pkg-config.
	67	# We require at least 0.22, as "Requires.private" behaviour changed there.
	68	PKG_PROG_PKG_CONFIG([0.22])
bcacb863	69
1bb196e4 DE	70	# Keep track of all checked modules so we can list them at the end.
	71	SR_PKG_CHECK_SUMMARY([sr_pkglibs_summary])
	72
	73	# Collect the pkg-config module names of all dependencies in SR_PKGLIBS.
1f61c22f DE	74	# These are used to derive the compiler flags and for the "Requires.private"
1f61c22f DE	75	# field in the generated libsigrok.pc file.
1bb196e4	76	SR_VAR_OPT_PKG([SR_PKGLIBS], [sr_deps_avail])
1f61c22f DE	77	SR_PKGLIBS_CHECK=
	78	SR_PKGLIBS_CXX=
	79	SR_PKGLIBS_PYTHON=
	80
2cbde151	81	SR_ARG_OPT_PKG([libserialport], [LIBSERIALPORT], [NEED_SERIAL],
1f61c22f	82	[libserialport >= 0.1.1])
1f61c22f	83
2cbde151	84	SR_ARG_OPT_PKG([libftdi], [LIBFTDI],,
2700e63d	85	[libftdi >= 0.16], [libftdi1 >= 1.0])
1f61c22f DE	86
	87	# FreeBSD comes with an "integrated" libusb-1.0-style USB API.
	88	# This means libusb-1.0 is always available; no need to check for it.
	89	AS_CASE([$host], [freebsd], [sr_have_libusb=yes])
	90
2cbde151	91	SR_ARG_OPT_PKG([libusb], [LIBUSB_1_0], [NEED_USB],
1f61c22f	92	[libusb-1.0 >= 1.0.16])
c23c8659	93
2cbde151	94	SR_ARG_OPT_PKG([librevisa], [LIBREVISA], [NEED_VISA],
1f61c22f	95	[librevisa >= 0.0.20130412])
d92de05a	96
2cbde151	97	SR_ARG_OPT_PKG([libgpib], [LIBGPIB], [NEED_GPIB],
1f61c22f DE	98	[libgpib])
	99
	100	######################
	101	## Feature checks ##
	102	######################
f7740954	103
aba69262	104	# The Check unit testing framework is optional. Disable if not found.
1f61c22f DE	105	SR_PKG_CHECK([check], [SR_PKGLIBS_CHECK], [check >= 0.9.4])
	106	AM_CONDITIONAL([HAVE_CHECK], [test "x$sr_have_check" = xyes])
	107
	108	AC_LANG([C])
b84a7331 DE	109
	110	# Enable the C11 standard if possible, and enforce the use
	111	# of SR_API to explicitly mark all public API functions.
	112	SR_EXTRA_CFLAGS=
	113	SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [C11], [-std=gnu11 -std=c11])
	114	SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [visibility], [-fvisibility=hidden])
	115
4cf2f34f	116	SR_ARG_ENABLE_WARNINGS([SR_WFLAGS], [-Wall], [-Wall -Wextra -Wmissing-prototypes])
1f61c22f DE	117
	118	# Check host characteristics.
	119	AC_C_BIGENDIAN
79bb0e97	120
1bb196e4 DE	121	AC_CHECK_HEADERS([sys/mman.h], [SR_APPEND([sr_deps_avail], [sys_mman_h])])
	122	AC_CHECK_HEADERS([sys/ioctl.h], [SR_APPEND([sr_deps_avail], [sys_ioctl_h])])
	123	AC_CHECK_HEADERS([sys/timerfd.h], [SR_APPEND([sr_deps_avail], [sys_timerfd_h])])
1f61c22f DE	124
	125	# RPC is only needed for VXI support.
	126	AC_CACHE_CHECK([for RPC support], [sr_cv_have_rpc],
	127	[AC_LINK_IFELSE([AC_LANG_PROGRAM(
	128	[[#include <rpc/rpc.h>]m4_newline[CLIENT *rpc_test(void);]],
	129	[[(void) clnt_create("", 0, 0, "");]])],
	130	[sr_cv_have_rpc=yes], [sr_cv_have_rpc=no])])
	131	AS_IF([test "x$sr_cv_have_rpc" = xyes],
	132	[AC_DEFINE([HAVE_RPC], [1], [Specifies whether we have RPC support.])])
	133	# VXI support is only compiled if RPC support was found.
	134	AM_CONDITIONAL([NEED_RPC], [test "x$sr_cv_have_rpc" = xyes])
	135
d37c7109 DE	136	########################
	137	## Hardware drivers ##
	138	########################
	139
	140	# Keep track of all drivers so we can list them at the end.
1bb196e4	141	SR_VAR_SUMMARY([sr_driver_summary])
d37c7109 DE	142
	143	# Check whether the sr_deps_avail list contains all of the arguments.
	144	# Unavailable dependencies are collected in sr_deps_missing.
	145	sr_check_driver_deps() {
	146	sr_deps_missing=
	147	for sr_dep
	148	do
	149	AS_CASE([" $sr_deps_avail "], [" $sr_dep "],,
26b67f11	150	[SR_APPEND([sr_deps_missing], [', '], [$sr_dep])])
d37c7109 DE	151	done
	152	}
	153
	154	AC_ARG_ENABLE([all-drivers],
	155	[AS_HELP_STRING([--enable-all-drivers],
	156	[enable all drivers by default [default=yes]])],
	157	[], [enable_all_drivers=yes])
	158
	159	## _SR_DRIVER(Device name, driver-name, var-name, [dependencies...])
	160	m4_define([_SR_DRIVER], [
b8b727e4	161	AC_ARG_ENABLE([$2],
d37c7109 DE	162	[AS_HELP_STRING([--enable-$2], [enable $1 support])],
	163	[$3=$enableval], [$3=$enable_all_drivers])
	164
	165	AS_IF([test "x[$]$3" = xyes], [sr_hw_info=yes[]m4_ifval([$4], [
	166	sr_check_driver_deps $4
	167	AS_IF([test -n "$sr_deps_missing"],
26b67f11	168	[$3=no sr_hw_info="no (missing: $sr_deps_missing)"])
d37c7109	169	])], [sr_hw_info='no (disabled)'])
1bb196e4	170	sr_driver_summary_append "$2" "$sr_hw_info"
d37c7109 DE	171
	172	AM_CONDITIONAL([$3], [test "x[$]$3" = xyes])
	173	AM_COND_IF([$3], [AC_DEFINE([HAVE_$3], [1], [Whether to support $1 device.])])
	174	])
	175
	176	## SR_DRIVER(Device name, driver-name, [dependencies...])
	177	m4_define([SR_DRIVER],
	178	[_SR_DRIVER([$1], [$2], m4_expand([AS_TR_CPP([HW_$2])]), [$3])])
	179
	180	SR_DRIVER([Agilent DMM], [agilent-dmm], [libserialport])
	181	SR_DRIVER([Appa 55II], [appa-55ii], [libserialport])
	182	SR_DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma], [libftdi])
	183	SR_DRIVER([Atten PPS3xxx], [atten-pps3xxx], [libserialport])
	184	SR_DRIVER([BayLibre ACME], [baylibre-acme], [sys_timerfd_h])
	185	SR_DRIVER([BeagleLogic], [beaglelogic], [sys_mman_h sys_ioctl_h])
	186	SR_DRIVER([Brymen BM86x], [brymen-bm86x], [libusb])
	187	SR_DRIVER([Brymen DMM], [brymen-dmm], [libserialport])
	188	SR_DRIVER([CEM DT-885x], [cem-dt-885x], [libserialport])
	189	SR_DRIVER([Center 3xx], [center-3xx], [libserialport])
	190	SR_DRIVER([ChronoVu LA], [chronovu-la], [libftdi])
	191	SR_DRIVER([Colead SLM], [colead-slm], [libserialport])
	192	SR_DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu], [libserialport])
	193	SR_DRIVER([DER EE DE-5000], [deree-de5000], [libserialport])
	194	SR_DRIVER([demo], [demo])
	195	SR_DRIVER([Fluke DMM], [fluke-dmm], [libserialport])
	196	SR_DRIVER([fx2lafw], [fx2lafw], [libusb])
	197	SR_DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x], [libserialport])
	198	SR_DRIVER([Hameg HMO], [hameg-hmo], [libserialport])
	199	SR_DRIVER([Hantek DSO], [hantek-dso], [libusb])
	200	SR_DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2], [libusb])
	201	SR_DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus], [libftdi])
	202	SR_DRIVER([Kecheng KC-330B], [kecheng-kc-330b], [libusb])
	203	SR_DRIVER([Lascar EL-USB], [lascar-el-usb], [libusb])
	204	SR_DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx], [libserialport])
	205	SR_DRIVER([maynuo-m97], [maynuo-m97])
	206	SR_DRIVER([MIC 985xx], [mic-985xx], [libserialport])
	207	SR_DRIVER([Motech LPS 30x], [motech-lps-30x], [libserialport])
	208	SR_DRIVER([Norma DMM], [norma-dmm], [libserialport])
	209	SR_DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer], [libserialport])
	210	SR_DRIVER([Pipistrello-OLS], [pipistrello-ols], [libftdi])
	211	SR_DRIVER([Rigol DS], [rigol-ds])
	212	SR_DRIVER([Saleae Logic16], [saleae-logic16], [libusb])
	213	SR_DRIVER([SCPI PPS], [scpi-pps])
	214	SR_DRIVER([serial DMM], [serial-dmm], [libserialport])
	215	SR_DRIVER([Sysclk LWLA], [sysclk-lwla], [libusb])
	216	SR_DRIVER([Teleinfo], [teleinfo], [libserialport])
	217	SR_DRIVER([Testo], [testo], [libusb])
	218	SR_DRIVER([Tondaj SL-814], [tondaj-sl-814], [libserialport])
	219	SR_DRIVER([UNI-T DMM], [uni-t-dmm], [libusb])
	220	SR_DRIVER([UNI-T UT32x], [uni-t-ut32x], [libusb])
	221	SR_DRIVER([Victor DMM], [victor-dmm], [libusb])
	222	SR_DRIVER([Yokogawa DL/DLM], [yokogawa-dlm])
	223	SR_DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube], [libusb])
1f61c22f DE	224
	225	###############################
	226	## Language bindings setup ##
	227	###############################
	228
d37c7109	229	AC_LANG([C++])
4cf2f34f	230	SR_ARG_ENABLE_WARNINGS([SR_WXXFLAGS], [-Wall], [-Wall -Wextra])
d37c7109	231
1f61c22f DE	232	AC_ARG_ENABLE([bindings],
	233	[AS_HELP_STRING([--enable-bindings], [build language bindings [default=yes]])],
	234	[], [enable_bindings=yes])
176c7219	235
1f61c22f DE	236	AC_ARG_ENABLE([cxx],
	237	[AS_HELP_STRING([--enable-cxx], [build C++ bindings [default=yes]])],
	238	[], [enable_cxx=$enable_bindings])
a0b277ba	239
1f61c22f DE	240	AC_ARG_ENABLE([python],
	241	[AS_HELP_STRING([--enable-python], [build Python bindings [default=yes]])],
	242	[], [enable_python=$enable_bindings])
826938d8	243
1f61c22f DE	244	AC_ARG_ENABLE([java],
	245	[AS_HELP_STRING([--enable-java], [build Java bindings [default=yes]])],
	246	[], [enable_java=$enable_bindings])
	247
	248	####################
	249	## C++ bindings ##
	250	####################
	251
	252	sr_cxx_missing=
	253
	254	# Check if the C++ compiler supports the C++11 standard.
	255	m4_ifdef([AX_CXX_COMPILE_STDCXX_11],
	256	[AX_CXX_COMPILE_STDCXX_11(, [optional])],
cb4d28ef	257	[m4_warn([unsupported], [Missing macro AX_CXX_COMPILE_STDCXX_11: no C++11 check possible])])
26b67f11 DE	258	AS_IF([test "x$HAVE_CXX11" != x1],
26b67f11 DE	259	[SR_APPEND([sr_cxx_missing], [', '], ['C++11'])])
1f61c22f DE	260
	261	# The C++ bindings need glibmm.
	262	SR_PKG_CHECK([glibmm], [SR_PKGLIBS_CXX], [glibmm-2.4 >= 2.32.0])
26b67f11 DE	263	AS_IF([test "x$sr_have_glibmm" != xyes],
26b67f11 DE	264	[SR_APPEND([sr_cxx_missing], [', '], [glibmm])])
1f61c22f DE	265
	266	# The C++ bindings use Doxygen to parse libsigrok symbols.
	267	AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes], [no])
26b67f11 DE	268	AS_IF([test "x$HAVE_DOXYGEN" != xyes],
26b67f11 DE	269	[SR_APPEND([sr_cxx_missing], [', '], [Doxygen])])
1f61c22f DE	270
	271	# Python is needed for the C++ bindings.
	272	AM_PATH_PYTHON([2.7],
	273	[HAVE_PYTHON=yes],
26b67f11 DE	274	[HAVE_PYTHON=no
26b67f11 DE	275	SR_APPEND([sr_cxx_missing], [', '], [Python])])
1f61c22f DE	276
	277	AS_IF([test -z "$sr_cxx_missing"],
	278	[BINDINGS_CXX=$enable_cxx], [BINDINGS_CXX=no])
	279	AM_CONDITIONAL([BINDINGS_CXX], [test "x$BINDINGS_CXX" = xyes])
	280
	281	# C++ bindings want stoi and stod.
	282	AM_COND_IF([BINDINGS_CXX], [
	283	AC_CACHE_CHECK([for stoi and stod], [sr_cv_have_stoi_stod],
	284	[AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string>]],
	285	[[(void) std::stoi("1"); (void) std::stod("1.0");]])],
	286	[sr_cv_have_stoi_stod=yes], [sr_cv_have_stoi_stod=no])])
	287	AS_IF([test "x$sr_cv_have_stoi_stod" = xyes],
	288	[AC_DEFINE([HAVE_STOI_STOD], [1],
	289	[Specifies whether we have the stoi and stod functions.])])
	290	])
	291
	292	#######################
	293	## Python bindings ##
	294	#######################
	295
26b67f11 DE	296	AS_IF([test "x$BINDINGS_CXX" = xyes],
	297	[sr_python_missing=],
	298	[sr_python_missing='C++ bindings'])
1f61c22f DE	299
	300	# The Python bindings need Python development files.
	301	SR_PKG_CHECK([python_dev], [SR_PKGLIBS_PYTHON],
	302	[python >= 2.7], [python2 >= 2.7], [python27 >= 2.7])
26b67f11 DE	303	AS_IF([test "x$sr_have_python_dev" != xyes],
26b67f11 DE	304	[SR_APPEND([sr_python_missing], [', '], [Headers])])
1f61c22f DE	305
	306	# PyGObject is needed for the Python bindings.
	307	SR_PKG_CHECK([pygobject], [SR_PKGLIBS_PYTHON], [pygobject-3.0 >= 3.0.0])
26b67f11 DE	308	AS_IF([test "x$sr_have_pygobject" != xyes],
26b67f11 DE	309	[SR_APPEND([sr_python_missing], [', '], [PyGObject])])
1f61c22f DE	310
	311	PKG_CHECK_EXISTS([pygobject-3.0 < 3.7.91],
	312	[AC_DEFINE([PYGOBJECT_FLAGS_SIGNED], [1],
	313	[Whether last argument to pyg_flags_get_value() is signed.])])
	314
	315	# The Python bindings need the setuptools Python module.
	316	# We'll let it go through even if the AX macro wasn't found,
	317	# as the Python module may still be there.
	318	HAVE_PYMOD_SETUPTOOLS=yes
	319	m4_ifdef([AX_PYTHON_MODULE],
	320	[AX_PYTHON_MODULE([setuptools])],
cb4d28ef	321	[m4_warn([unsupported], [Missing macro AX_PYTHON_MODULE: no setuptools check])])
26b67f11 DE	322	AS_IF([test "x$HAVE_PYMOD_SETUPTOOLS" != xyes],
26b67f11 DE	323	[SR_APPEND([sr_python_missing], [', '], [setuptools])])
1f61c22f DE	324
1f61c22f DE	325	# The Python bindings use SWIG to generate code.
26b67f11 DE	326	AC_CHECK_PROGS([SWIG], [swig swig2.0 swig3.0])
	327	AS_IF([test "x$SWIG" = x],
	328	[SR_APPEND([sr_python_missing], [', '], [SWIG])])
1f61c22f DE	329
	330	AS_IF([test -z "$sr_python_missing"],
	331	[BINDINGS_PYTHON=$enable_python], [BINDINGS_PYTHON=no])
	332	AM_CONDITIONAL([BINDINGS_PYTHON], [test "x$BINDINGS_PYTHON" = xyes])
	333
	334	####################
	335	## Java bindings ##
	336	####################
	337
26b67f11 DE	338	AS_IF([test "x$BINDINGS_CXX" = xyes],
	339	[sr_java_missing=],
	340	[sr_java_missing='C++ bindings'])
1f61c22f DE	341
1f61c22f DE	342	# The Java bindings use SWIG to generate code.
26b67f11 DE	343	AS_IF([test "x$SWIG" = x],
26b67f11 DE	344	[SR_APPEND([sr_java_missing], [', '], [SWIG])])
4f10853e	345
9fcf4d0b	346	# Find Java compiler and JNI includes for Java bindings.
9fcf4d0b	347	AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no])
26b67f11 DE	348	AS_IF([test "x$HAVE_JAVAC" = xno],
26b67f11 DE	349	[SR_APPEND([sr_java_missing], [', '], [JavaC])])
1f61c22f DE	350
	351	AC_ARG_WITH([jni-include-path],
	352	[AS_HELP_STRING([[--with-jni-include-path=DIR-LIST (space-separated)]],
	353	[specify JNI include directories [default=detect]])],
	354	[JNI_INCLUDE_DIRS=" $withval"], [JNI_INCLUDE_DIRS=])
	355
	356	JNI_CPPFLAGS=
	357	AS_IF([test "x$enable_java$HAVE_JAVAC" = xyesyes], [
9fcf4d0b	358	AX_PROG_JAVAC
1f61c22f DE	359	AS_IF([test -z "$JNI_INCLUDE_DIRS" && test "x$cross_compiling" != xyes], [
	360	## Work around the totally broken logic in AX_JNI_INCLUDE_DIR:
	361	## If we can find jni.h without any special search path, skip
	362	## the execution of the broken macro to increase our chances of
	363	## success.
	364	AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <jni.h>]], [])],,
	365	[AX_JNI_INCLUDE_DIR])
	366	])
	367	])
	368	for sr_dir in $JNI_INCLUDE_DIRS
	369	do
26b67f11	370	SR_APPEND([JNI_CPPFLAGS], ["-I$sr_dir"])
1f61c22f DE	371	done
	372	AC_SUBST([JNI_CPPFLAGS])
	373
	374	sr_save_cppflags=$CPPFLAGS
26b67f11 DE	375	SR_APPEND([CPPFLAGS], [$JNI_CPPFLAGS])
	376	AC_CHECK_HEADER([jni.h],,
	377	[SR_APPEND([sr_java_missing], [', '], ['JNI headers'])])
1f61c22f DE	378	CPPFLAGS=$sr_save_cppflags
	379
	380	AS_IF([test -z "$sr_java_missing"],
	381	[BINDINGS_JAVA=$enable_java], [BINDINGS_JAVA=no])
	382	AM_CONDITIONAL([BINDINGS_JAVA], [test "x$BINDINGS_JAVA" = xyes])
	383
	384	##############################
	385	## Finalize configuration ##
	386	##############################
	387
	388	# Add mandatory dependencies to module list.
26b67f11	389	SR_APPEND([SR_PKGLIBS], ['libzip >= 0.10'])
1f61c22f DE	390	AC_SUBST([SR_PKGLIBS])
	391
	392	# Retrieve the compile and link flags for all modules combined.
	393	# Also, bail out at this point if any module dependency is not met.
	394	PKG_CHECK_MODULES([LIBSIGROK], [glib-2.0 >= 2.32.0 $SR_PKGLIBS])
1f61c22f DE	395	PKG_CHECK_MODULES([CHECK], [$SR_PKGLIBS_CHECK glib-2.0 $SR_PKGLIBS])
1f61c22f DE	396
da0763d0 DE	397	# SR_PKGLIBS_CXX may be empty, so only invoke these checks when
	398	# the C++ bindings are enabled.
	399	AM_COND_IF([BINDINGS_CXX], [
	400	PKG_CHECK_MODULES([LIBSIGROKCXX], [$SR_PKGLIBS_CXX])
	401	PKG_CHECK_MODULES([PYSIGROK], [$SR_PKGLIBS_PYTHON $SR_PKGLIBS_CXX])
	402	])
1f61c22f DE	403	sr_glib_version=`$PKG_CONFIG --modversion glib-2.0 2>&AS_MESSAGE_LOG_FD`
	404	sr_libzip_version=`$PKG_CONFIG --modversion libzip 2>&AS_MESSAGE_LOG_FD`
	405
2cbde151 DE	406	AC_DEFINE_UNQUOTED([CONF_LIBZIP_VERSION], ["$sr_libzip_version"],
	407	[Build-time version of libzip.])
	408	AC_DEFINE_UNQUOTED([CONF_HOST], ["$host"],
	409	[The canonical host libsigrok will run on.])
1f61c22f DE	410
	411	AC_LANG([C])
	412
	413	# libm (the standard math library) is always needed.
	414	AC_SEARCH_LIBS([pow], [m])
	415
	416	# We need to link against the Winsock2 library for SCPI over TCP.
	417	AS_CASE([$host], [mingw], [LIBS="$LIBS -lws2_32"])
826938d8	418
27a2497d	419	AC_SUBST([FIRMWARE_DIR], ['$(datadir)/sigrok-firmware'])
1f61c22f DE	420	AC_SUBST([MAKEFLAGS], ['--no-print-directory'])
1f61c22f DE	421	AC_SUBST([AM_LIBTOOLFLAGS], ['--silent'])
826938d8	422
b2478a23	423	AC_CONFIG_FILES([Makefile libsigrok.pc bindings/cxx/libsigrokcxx.pc])
826938d8 UH	424
	425	AC_OUTPUT
	426
1f61c22f	427	# Prepare bindings report messages.
d37c7109 DE	428	m4_define([SR_PREPARE_BINDING_REPORT], [
d37c7109 DE	429	sr_report_$1=
26b67f11	430	test -z "$sr_$1_missing" \|\| sr_report_$1=" (missing: $sr_$1_missing)"
d37c7109	431	test "x$enable_$1" = xyes \|\| sr_report_$1=' (disabled)'
1f61c22f	432	])
d37c7109	433	m4_map_args([SR_PREPARE_BINDING_REPORT], [cxx], [python], [java])
45aed072	434
1f61c22f DE	435	cat >&AS_MESSAGE_FD <<_EOF
	436
	437	libsigrok configuration summary:
	438	- Package version................. $SR_PACKAGE_VERSION
	439	- Library ABI version............. $SR_LIB_VERSION
	440	- Prefix.......................... $prefix
	441	- Building on..................... $build
	442	- Building for.................... $host
b84a7331	443	- Additional C compiler flags..... $SR_EXTRA_CFLAGS
4cf2f34f DE	444	- C compiler warnings............. $SR_WFLAGS
4cf2f34f DE	445	- C++ compiler warnings........... $SR_WXXFLAGS
1f61c22f DE	446
1f61c22f DE	447	Detected libraries (required):
965d6889 UH	448	- glib-2.0 >= 2.32.0.............. $sr_glib_version
965d6889 UH	449	- libzip >= 0.10.................. $sr_libzip_version
1f61c22f DE	450
	451	Detected libraries (optional):
	452	$sr_pkglibs_summary
c5f179a9	453	Enabled hardware drivers:
d37c7109	454	$sr_driver_summary
1f61c22f DE	455	Enabled SCPI backends:
	456	- TCP............................. yes
	457	- RPC............................. $sr_cv_have_rpc
	458	- serial.......................... $sr_have_libserialport
	459	- VISA............................ $sr_have_librevisa
	460	- GPIB............................ $sr_have_libgpib
	461	- USBTMC.......................... $sr_have_libusb
	462
	463	Enabled language bindings:
	464	- C++............................. $BINDINGS_CXX$sr_report_cxx
	465	- Python.......................... $BINDINGS_PYTHON$sr_report_python
	466	- Java............................ $BINDINGS_JAVA$sr_report_java
826938d8	467
1f61c22f	468	_EOF