sigrok-qt.pro

   1 ##
   2 ## This file is part of the sigrok-qt project.
   3 ##
   4 ## Copyright (C) 2010-2011 Uwe Hermann <uwe@hermann-uwe.de>
   5 ##
   6 ## This program is free software; you can redistribute it and/or modify
   7 ## it under the terms of the GNU General Public License as published by
   8 ## the Free Software Foundation; either version 2 of the License, or
   9 ## (at your option) any later version.
  10 ##
  11 ## This program is distributed in the hope that it will be useful,
  12 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ## GNU General Public License for more details.
  15 ##
  16 ## You should have received a copy of the GNU General Public License
  17 ## along with this program; if not, write to the Free Software
  18 ## Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA  02110-1301 USA
  19 ##
  20
  21 TARGET        = sigrok-qt
  22 TEMPLATE      = app
  23
  24 # The sigrok-qt version number. Define APP_VERSION macro for use in the code.
  25 VERSION       = 0.1.0
  26 DEFINES      += APP_VERSION=\\\"$$VERSION\\\"
  27
  28 UNAME         = $$system(uname -s)
  29
  30 SOURCES      += main.cpp \
  31                 mainwindow.cpp \
  32                 configform.cpp \
  33                 channelform.cpp \
  34                 decodersform.cpp \
  35                 decoderstackform.cpp
  36
  37 HEADERS      += mainwindow.h \
  38                 configform.h \
  39                 channelform.h \
  40                 decodersform.h \
  41                 decoderstackform.h
  42
  43 FORMS        += mainwindow.ui \
  44                 configform.ui \
  45                 channelform.ui \
  46                 decodersform.ui \
  47                 decoderstackform.ui
  48
  49 TRANSLATIONS  = locale/sigrok-qt_de_DE.ts \
  50                 locale/sigrok-qt_nl_NL.ts \
  51                 locale/sigrok-qt_fr_FR.ts
  52
  53 CONFIG       += release warn_on
  54
  55 RESOURCES    += sigrok-qt.qrc
  56
  57 # libsigrok and libsigrokdecode
  58 # TODO: Check for the minimum versions of libsigrok/libsigrokdecode we need.
  59 win32 {
  60         # On Windows/MinGW we need to use '--libs --static'.
  61         # We also need to strip some stray '\n' characters here.
  62         QMAKE_CXXFLAGS += $$system(pkg-config --cflags libsigrokdecode \
  63                           libsigrok | sed s/\n//g)
  64         LIBS           += $$system(pkg-config --libs --static libsigrokdecode \
  65                           libsigrok | sed s/\n//g)
  66 } else {
  67         QMAKE_CXXFLAGS += $$system(pkg-config --cflags libsigrokdecode)
  68         QMAKE_CXXFLAGS += $$system(pkg-config --cflags libsigrok)
  69         LIBS           += $$system(pkg-config --libs libsigrokdecode)
  70         LIBS           += $$system(pkg-config --libs libsigrok)
  71 }
  72
  73 # Installation
  74 PREFIX        = /usr/local
  75 target.path   = $$PREFIX/bin
  76 locale.path   = $$PREFIX/share/sigrok-qt/translations
  77 locale.extra  = lrelease sigrok-qt.pro
  78 locale.files  = locale/*.qm
  79 man.path      = $$PREFIX/man/man1
  80 man.files     = doc/sigrok-qt.1
  81 INSTALLS     += target locale man
  82
  83 win32 {
  84         RC_FILE = sigrok-qt.rc
  85 }
  86
  87 # TODO: This may need fixes.
  88 macx {
  89         ICON = icons/sigrok-qt.icns
  90         #FILETYPES.files = ../lib/libsigrok.dylib
  91         #FILETYPES.path = Contents/Frameworks
  92         #QMAKE_BUNDLE_DATA += FILETYPES
  93 }