[libsigrokdecode.git] / configure.ac

##
## This file is part of the libsigrokdecode project.
##
## Copyright (C) 2010 Bert Vermeulen <bert@biot.com>
##
## This program is free software: you can redistribute it and/or modify
## it under the terms of the GNU General Public License as published by
## the Free Software Foundation, either version 3 of the License, or
## (at your option) any later version.
##
## This program is distributed in the hope that it will be useful,
## but WITHOUT ANY WARRANTY; without even the implied warranty of
## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
## GNU General Public License for more details.
##
## You should have received a copy of the GNU General Public License
## along with this program.  If not, see <http://www.gnu.org/licenses/>.
##

# We require at least autoconf 2.63 (AC_INIT format changed there).
AC_PREREQ([2.63])

# libsigrokdecode package version number (NOT the same as shared lib version!).
m4_define([srd_package_version_major], [0])
m4_define([srd_package_version_minor], [2])
m4_define([srd_package_version_micro], [0])
m4_define([srd_package_version], [srd_package_version_major.srd_package_version_minor.srd_package_version_micro])

AC_INIT([libsigrokdecode], [srd_package_version],
	[sigrok-devel@lists.sourceforge.net], [libsigrokdecode],
	[http://www.sigrok.org])
AC_CONFIG_HEADER([config.h])
AC_CONFIG_MACRO_DIR([autostuff])
AC_CONFIG_AUX_DIR([autostuff])

# We require at least automake 1.11 (needed for 'silent rules').
AM_INIT_AUTOMAKE([1.11 -Wall -Werror check-news color-tests])
m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
m4_ifdef([AM_PROG_AR], [AM_PROG_AR])

AH_TOP([#ifndef SRD_CONFIG_H
#define SRD_CONFIG_H    /* To stop multiple inclusions. */])
AH_BOTTOM([#endif /* SRD_CONFIG_H */])

# Enable more compiler warnings via -Wall and -Wextra. Add -fvisibility=hidden
# and enforce use of SRD_API to explicitly mark all public API functions.
CFLAGS="$CFLAGS -Wall -Wextra -Wmissing-prototypes -fvisibility=hidden"

# Checks for programs.
AC_PROG_CC
AC_PROG_CPP
AC_PROG_INSTALL
AC_PROG_LN_S

# Required for per-target flags or subdir-objects with C sources.
AM_PROG_CC_C_O

# Initialize libtool.
LT_INIT

# Initialize pkg-config.
# We require at least 0.22, as "Requires.private" behaviour changed there.
PKG_PROG_PKG_CONFIG([0.22])

# Library version for libsigrokdecode (NOT the same as the package version).
# Carefully read the libtool docs before updating these numbers!
# The algorithm for determining which number to change (and how) is nontrivial!
# http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
SRD_LIB_VERSION_CURRENT=1
SRD_LIB_VERSION_REVISION=0
SRD_LIB_VERSION_AGE=0
SRD_LIB_VERSION="$SRD_LIB_VERSION_CURRENT:$SRD_LIB_VERSION_REVISION:$SRD_LIB_VERSION_AGE"
SRD_LIB_LDFLAGS="-version-info $SRD_LIB_VERSION"
AC_SUBST(SRD_LIB_VERSION_CURRENT)
AC_SUBST(SRD_LIB_VERSION_REVISION)
AC_SUBST(SRD_LIB_VERSION_AGE)
AC_SUBST(SRD_LIB_VERSION)
AC_SUBST(SRD_LIB_LDFLAGS)

# assume we can build tests/runtc unless proven otherwise
build_runtc="yes"

# Checks for libraries.

# libglib-2.0 is always needed.
# Note: glib-2.0 is part of the libsigrokdecode API
# (hard pkg-config requirement).
AM_PATH_GLIB_2_0([2.24.0],
        [CFLAGS="$CFLAGS $GLIB_CFLAGS"; LIBS="$LIBS $GLIB_LIBS"])

# Python 3 is always needed.
# Note: We need to try a few different variants, since some systems have a
# python3.pc file, others have a python-3.3.pc file, and so on.
# See also: http://sigrok.org/wiki/Libsigrokdecode/Python
CPPFLAGS_PYTHON=""
LDFLAGS_PYTHON=""
PKG_CHECK_MODULES([python3], [python3 >= 3.2],
	[CPPFLAGS_PYTHON="$CPPFLAGS_PYTHON $python3_CFLAGS";
	LDFLAGS_PYTHON="$LDFLAGS_PYTHON $python3_LIBS"],
[PKG_CHECK_MODULES([python33], [python-3.3 >= 3.2],
	[CPPFLAGS_PYTHON="$CPPFLAGS_PYTHON $python33_CFLAGS";
	LDFLAGS_PYTHON="$LDFLAGS_PYTHON $python33_LIBS"],
[PKG_CHECK_MODULES([python32], [python-3.2 >= 3.2],
	[CPPFLAGS_PYTHON="$CPPFLAGS_PYTHON $python32_CFLAGS";
	LDFLAGS_PYTHON="$LDFLAGS_PYTHON $python32_LIBS"],
)])])
AC_SUBST(CPPFLAGS_PYTHON)
AC_SUBST(LDFLAGS_PYTHON)

# Link against libm, this is required (among other things) by Python.
AC_SEARCH_LIBS([pow], [m])

# The Check unit testing framework is optional. Disable if not found.
PKG_CHECK_MODULES([check], [check >= 0.9.4],
	[have_check="yes"; CFLAGS="$CFLAGS $check_CFLAGS";
	LIBS="$LIBS $check_LIBS"], [have_check="no"])
AM_CONDITIONAL(HAVE_CHECK, test x"$have_check" = "xyes")

# libsigrok is optional (only used for the protocol decoder test framework).
# Disable if not found.
PKG_CHECK_MODULES([libsigrok], [libsigrok >= 0.2.0],
	[LIBSIGROK_CFLAGS="$libsigrok_CFLAGS"; LIBSIGROK_LIBS="$libsigrok_LIBS"],
	[build_runtc="no"])
AC_SUBST([LIBSIGROK_CFLAGS])
AC_SUBST([LIBSIGROK_LIBS])

# Checks for header files.
# These are already checked: inttypes.h stdint.h stdlib.h string.h unistd.h.
AC_CHECK_HEADER([sys/resource.h], [], [build_runtc="no"])

AC_SUBST(DECODERS_DIR, "$datadir/libsigrokdecode/decoders")
AC_SUBST(MAKEFLAGS, '--no-print-directory')
AC_SUBST(AM_LIBTOOLFLAGS, '--silent')

SRD_PACKAGE_VERSION_MAJOR=srd_package_version_major
SRD_PACKAGE_VERSION_MINOR=srd_package_version_minor
SRD_PACKAGE_VERSION_MICRO=srd_package_version_micro
SRD_PACKAGE_VERSION=srd_package_version

AC_SUBST(SRD_PACKAGE_VERSION_MAJOR)
AC_SUBST(SRD_PACKAGE_VERSION_MINOR)
AC_SUBST(SRD_PACKAGE_VERSION_MICRO)
AC_SUBST(SRD_PACKAGE_VERSION)

AM_CONDITIONAL(BUILD_RUNTC, test x"$build_runtc" = "xyes")

AC_CONFIG_FILES([Makefile
		 version.h
		 libsigrokdecode.pc
		 contrib/Makefile
		 tests/Makefile
		])

AC_OUTPUT

echo
echo "libsigrokdecode configuration summary:"
echo
echo "  - Package version (major.minor.micro):    $SRD_PACKAGE_VERSION"
echo "  - Library version (current:revision:age): $SRD_LIB_VERSION"
echo "  - Prefix: $prefix"
echo "  - Building on: $build"
echo "  - Building for: $host"
echo "  - Building protocol decoder test framework: $build_runtc"
echo
echo "Detected libraries:"
echo

# Note: This only works for libs with pkg-config integration.
for lib in "glib-2.0 >= 2.24.0" "check >= 0.9.4" "libsigrok >= 0.2.0"; do
        if `$PKG_CONFIG --exists $lib`; then
                ver=`$PKG_CONFIG --modversion $lib`
                answer="yes ($ver)"
        else
                answer="no"
        fi
        echo "  - $lib: $answer"
done

echo
echo "Detected Python:"
echo
echo "  - Python CPPFLAGS: $CPPFLAGS_PYTHON"
echo "  - Python LDFLAGS: $LDFLAGS_PYTHON"
echo
Commit	Line	Data
	1	##
	2	## This file is part of the libsigrokdecode project.
	3	##
	4	## Copyright (C) 2010 Bert Vermeulen <bert@biot.com>
	5	##
	6	## This program is free software: you can redistribute it and/or modify
	7	## it under the terms of the GNU General Public License as published by
	8	## the Free Software Foundation, either version 3 of the License, or
	9	## (at your option) any later version.
	10	##
	11	## This program is distributed in the hope that it will be useful,
	12	## but WITHOUT ANY WARRANTY; without even the implied warranty of
	13	## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	14	## GNU General Public License for more details.
	15	##
	16	## You should have received a copy of the GNU General Public License
	17	## along with this program. If not, see <http://www.gnu.org/licenses/>.
	18	##
	19
	20	# We require at least autoconf 2.63 (AC_INIT format changed there).
	21	AC_PREREQ([2.63])
	22
	23	# libsigrokdecode package version number (NOT the same as shared lib version!).
	24	m4_define([srd_package_version_major], [0])
	25	m4_define([srd_package_version_minor], [2])
	26	m4_define([srd_package_version_micro], [0])
	27	m4_define([srd_package_version], [srd_package_version_major.srd_package_version_minor.srd_package_version_micro])
	28
	29	AC_INIT([libsigrokdecode], [srd_package_version],
	30	[sigrok-devel@lists.sourceforge.net], [libsigrokdecode],
	31	[http://www.sigrok.org])
	32	AC_CONFIG_HEADER([config.h])
	33	AC_CONFIG_MACRO_DIR([autostuff])
	34	AC_CONFIG_AUX_DIR([autostuff])
	35
	36	# We require at least automake 1.11 (needed for 'silent rules').
	37	AM_INIT_AUTOMAKE([1.11 -Wall -Werror check-news color-tests])
	38	m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
	39	m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
	40
	41	AH_TOP([#ifndef SRD_CONFIG_H
	42	#define SRD_CONFIG_H /* To stop multiple inclusions. */])
	43	AH_BOTTOM([#endif /* SRD_CONFIG_H */])
	44
	45	# Enable more compiler warnings via -Wall and -Wextra. Add -fvisibility=hidden
	46	# and enforce use of SRD_API to explicitly mark all public API functions.
	47	CFLAGS="$CFLAGS -Wall -Wextra -Wmissing-prototypes -fvisibility=hidden"
	48
	49	# Checks for programs.
	50	AC_PROG_CC
	51	AC_PROG_CPP
	52	AC_PROG_INSTALL
	53	AC_PROG_LN_S
	54
	55	# Required for per-target flags or subdir-objects with C sources.
	56	AM_PROG_CC_C_O
	57
	58	# Initialize libtool.
	59	LT_INIT
	60
	61	# Initialize pkg-config.
	62	# We require at least 0.22, as "Requires.private" behaviour changed there.
	63	PKG_PROG_PKG_CONFIG([0.22])
	64
	65	# Library version for libsigrokdecode (NOT the same as the package version).
	66	# Carefully read the libtool docs before updating these numbers!
	67	# The algorithm for determining which number to change (and how) is nontrivial!
	68	# http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
	69	SRD_LIB_VERSION_CURRENT=1
	70	SRD_LIB_VERSION_REVISION=0
	71	SRD_LIB_VERSION_AGE=0
	72	SRD_LIB_VERSION="$SRD_LIB_VERSION_CURRENT:$SRD_LIB_VERSION_REVISION:$SRD_LIB_VERSION_AGE"
	73	SRD_LIB_LDFLAGS="-version-info $SRD_LIB_VERSION"
	74	AC_SUBST(SRD_LIB_VERSION_CURRENT)
	75	AC_SUBST(SRD_LIB_VERSION_REVISION)
	76	AC_SUBST(SRD_LIB_VERSION_AGE)
	77	AC_SUBST(SRD_LIB_VERSION)
	78	AC_SUBST(SRD_LIB_LDFLAGS)
	79
	80	# assume we can build tests/runtc unless proven otherwise
	81	build_runtc="yes"
	82
	83	# Checks for libraries.
	84
	85	# libglib-2.0 is always needed.
	86	# Note: glib-2.0 is part of the libsigrokdecode API
	87	# (hard pkg-config requirement).
	88	AM_PATH_GLIB_2_0([2.24.0],
	89	[CFLAGS="$CFLAGS $GLIB_CFLAGS"; LIBS="$LIBS $GLIB_LIBS"])
	90
	91	# Python 3 is always needed.
	92	# Note: We need to try a few different variants, since some systems have a
	93	# python3.pc file, others have a python-3.3.pc file, and so on.
	94	# See also: http://sigrok.org/wiki/Libsigrokdecode/Python
	95	CPPFLAGS_PYTHON=""
	96	LDFLAGS_PYTHON=""
	97	PKG_CHECK_MODULES([python3], [python3 >= 3.2],
	98	[CPPFLAGS_PYTHON="$CPPFLAGS_PYTHON $python3_CFLAGS";
	99	LDFLAGS_PYTHON="$LDFLAGS_PYTHON $python3_LIBS"],
	100	[PKG_CHECK_MODULES([python33], [python-3.3 >= 3.2],
	101	[CPPFLAGS_PYTHON="$CPPFLAGS_PYTHON $python33_CFLAGS";
	102	LDFLAGS_PYTHON="$LDFLAGS_PYTHON $python33_LIBS"],
	103	[PKG_CHECK_MODULES([python32], [python-3.2 >= 3.2],
	104	[CPPFLAGS_PYTHON="$CPPFLAGS_PYTHON $python32_CFLAGS";
	105	LDFLAGS_PYTHON="$LDFLAGS_PYTHON $python32_LIBS"],
	106	)])])
	107	AC_SUBST(CPPFLAGS_PYTHON)
	108	AC_SUBST(LDFLAGS_PYTHON)
	109
	110	# Link against libm, this is required (among other things) by Python.
	111	AC_SEARCH_LIBS([pow], [m])
	112
	113	# The Check unit testing framework is optional. Disable if not found.
	114	PKG_CHECK_MODULES([check], [check >= 0.9.4],
	115	[have_check="yes"; CFLAGS="$CFLAGS $check_CFLAGS";
	116	LIBS="$LIBS $check_LIBS"], [have_check="no"])
	117	AM_CONDITIONAL(HAVE_CHECK, test x"$have_check" = "xyes")
	118
	119	# libsigrok is optional (only used for the protocol decoder test framework).
	120	# Disable if not found.
	121	PKG_CHECK_MODULES([libsigrok], [libsigrok >= 0.2.0],
	122	[LIBSIGROK_CFLAGS="$libsigrok_CFLAGS"; LIBSIGROK_LIBS="$libsigrok_LIBS"],
	123	[build_runtc="no"])
	124	AC_SUBST([LIBSIGROK_CFLAGS])
	125	AC_SUBST([LIBSIGROK_LIBS])
	126
	127	# Checks for header files.
	128	# These are already checked: inttypes.h stdint.h stdlib.h string.h unistd.h.
	129	AC_CHECK_HEADER([sys/resource.h], [], [build_runtc="no"])
	130
	131	AC_SUBST(DECODERS_DIR, "$datadir/libsigrokdecode/decoders")
	132	AC_SUBST(MAKEFLAGS, '--no-print-directory')
	133	AC_SUBST(AM_LIBTOOLFLAGS, '--silent')
	134
	135	SRD_PACKAGE_VERSION_MAJOR=srd_package_version_major
	136	SRD_PACKAGE_VERSION_MINOR=srd_package_version_minor
	137	SRD_PACKAGE_VERSION_MICRO=srd_package_version_micro
	138	SRD_PACKAGE_VERSION=srd_package_version
	139
	140	AC_SUBST(SRD_PACKAGE_VERSION_MAJOR)
	141	AC_SUBST(SRD_PACKAGE_VERSION_MINOR)
	142	AC_SUBST(SRD_PACKAGE_VERSION_MICRO)
	143	AC_SUBST(SRD_PACKAGE_VERSION)
	144
	145	AM_CONDITIONAL(BUILD_RUNTC, test x"$build_runtc" = "xyes")
	146
	147	AC_CONFIG_FILES([Makefile
	148	version.h
	149	libsigrokdecode.pc
	150	contrib/Makefile
	151	tests/Makefile
	152	])
	153
	154	AC_OUTPUT
	155
	156	echo
	157	echo "libsigrokdecode configuration summary:"
	158	echo
	159	echo " - Package version (major.minor.micro): $SRD_PACKAGE_VERSION"
	160	echo " - Library version (current:revision:age): $SRD_LIB_VERSION"
	161	echo " - Prefix: $prefix"
	162	echo " - Building on: $build"
	163	echo " - Building for: $host"
	164	echo " - Building protocol decoder test framework: $build_runtc"
	165	echo
	166	echo "Detected libraries:"
	167	echo
	168
	169	# Note: This only works for libs with pkg-config integration.
	170	for lib in "glib-2.0 >= 2.24.0" "check >= 0.9.4" "libsigrok >= 0.2.0"; do
	171	if `$PKG_CONFIG --exists $lib`; then
	172	ver=`$PKG_CONFIG --modversion $lib`
	173	answer="yes ($ver)"
	174	else
	175	answer="no"
	176	fi
	177	echo " - $lib: $answer"
	178	done
	179
	180	echo
	181	echo "Detected Python:"
	182	echo
	183	echo " - Python CPPFLAGS: $CPPFLAGS_PYTHON"
	184	echo " - Python LDFLAGS: $LDFLAGS_PYTHON"
	185	echo
	186