configure.ac

   1 ##
   2 ## This file is part of the libsigrok project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 3 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 # libsigrok package version number (NOT the same as shared lib version!).
  25 m4_define([sr_package_version_major], [0])
  26 m4_define([sr_package_version_minor], [3])
  27 m4_define([sr_package_version_micro], [0])
  28 m4_define([sr_package_version], [sr_package_version_major.sr_package_version_minor.sr_package_version_micro])
  29
  30 AC_INIT([libsigrok], [sr_package_version], [sigrok-devel@lists.sourceforge.net],
  31         [libsigrok], [http://www.sigrok.org])
  32 AC_CONFIG_HEADER([config.h])
  33 AC_CONFIG_MACRO_DIR([autostuff])
  34 AC_CONFIG_AUX_DIR([autostuff])
  35
  36 # We require at least automake 1.11 (needed for 'silent rules').
  37 AM_INIT_AUTOMAKE([1.11 -Wall -Werror subdir-objects check-news color-tests])
  38 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  39 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  40
  41 AH_TOP([#ifndef SR_CONFIG_H
  42 #define SR_CONFIG_H    /* To stop multiple inclusions. */])
  43 AH_BOTTOM([#endif /* SR_CONFIG_H */])
  44
  45 # Enable more compiler warnings via -Wall and -Wextra. Add -fvisibility=hidden
  46 # and enforce use of SR_API to explicitly mark all public API functions.
  47 COMMON_FLAGS="$CFLAGS -Wall -Wextra -fvisibility=hidden"
  48 CFLAGS="$COMMON_FLAGS -Wmissing-prototypes"
  49 CXXFLAGS="-std=c++11 $COMMON_FLAGS"
  50
  51 # Checks for programs.
  52 AC_PROG_CC
  53 AC_PROG_CPP
  54 AC_PROG_CXX
  55 AC_PROG_INSTALL
  56 AC_PROG_LN_S
  57
  58 # Required for per-target flags or subdir-objects with C sources.
  59 AM_PROG_CC_C_O
  60
  61 # Initialize libtool.
  62 LT_INIT
  63
  64 # Initialize pkg-config.
  65 # We require at least 0.22, as "Requires.private" behaviour changed there.
  66 PKG_PROG_PKG_CONFIG([0.22])
  67
  68 # Library version for libsigrok (NOT the same as the package version).
  69 # Carefully read the libtool docs before updating these numbers!
  70 # The algorithm for determining which number to change (and how) is nontrivial!
  71 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  72 SR_LIB_VERSION_CURRENT=2
  73 SR_LIB_VERSION_REVISION=0
  74 SR_LIB_VERSION_AGE=0
  75 SR_LIB_VERSION="$SR_LIB_VERSION_CURRENT:$SR_LIB_VERSION_REVISION:$SR_LIB_VERSION_AGE"
  76 SR_LIB_LDFLAGS="-version-info $SR_LIB_VERSION"
  77 AC_SUBST(SR_LIB_VERSION_CURRENT)
  78 AC_SUBST(SR_LIB_VERSION_REVISION)
  79 AC_SUBST(SR_LIB_VERSION_AGE)
  80 AC_SUBST(SR_LIB_VERSION)
  81 AC_SUBST(SR_LIB_LDFLAGS)
  82
  83 AC_ARG_ENABLE(all-drivers, AC_HELP_STRING([--enable-all-drivers],
  84         [enable all drivers by default [default=yes]]),
  85         [HW_ENABLED_DEFAULT="$enableval"],
  86         [HW_ENABLED_DEFAULT="yes"])
  87
  88 # Usage: DRIVER([Device name], [driver-name])
  89 # An optional third argument [no] disables that driver.
  90 m4_define([driverize], [m4_tolower(m4_bpatsubst([$1], [[^0-9a-zA-Z-]+], [-]))])
  91 m4_define([upperize], [m4_toupper(m4_bpatsubst([$1], [[^0-9a-zA-Z_]+], [_]))])
  92 AC_DEFUN([DRIVER], [
  93         if test -z "$3"; then
  94                 default=$HW_ENABLED_DEFAULT
  95         else
  96                 default="$3"
  97         fi
  98         AC_ARG_ENABLE($2, AC_HELP_STRING([--enable-$2], [enable $1 support]),
  99                 [m4_join([], [HW_], upperize([$2]))="$enableval"],
 100                 [m4_join([], [HW_], upperize([$2]))=$default])
 101         dots=$(echo -n ".............................." | cut -c 1-$(expr 32 - $(echo -n $2|wc -c)))
 102         driver_summary="${driver_summary}  - $2${dots} \${m4_join([], [HW_], upperize([$2]))}@"
 103 ])
 104
 105 DRIVER([Agilent DMM], [agilent-dmm])
 106 DRIVER([Appa 55II], [appa-55ii])
 107 DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma])
 108 DRIVER([Atten PPS3xxx], [atten-pps3xxx])
 109 DRIVER([BeagleLogic], [beaglelogic])
 110 DRIVER([Brymen BM86x], [brymen-bm86x])
 111 DRIVER([Brymen DMM], [brymen-dmm])
 112 DRIVER([CEM DT-885x], [cem-dt-885x])
 113 DRIVER([Center 3xx], [center-3xx])
 114 DRIVER([ChronoVu LA], [chronovu-la])
 115 DRIVER([Colead SLM], [colead-slm])
 116 DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu])
 117 DRIVER([demo], [demo])
 118 DRIVER([Fluke DMM], [fluke-dmm])
 119 DRIVER([fx2lafw], [fx2lafw])
 120 DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x])
 121 DRIVER([Hameg HMO], [hameg-hmo])
 122 DRIVER([Hantek DSO], [hantek-dso])
 123 DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2])
 124 DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus])
 125 DRIVER([Kecheng KC-330B], [kecheng-kc-330b])
 126 DRIVER([Lascar EL-USB], [lascar-el-usb])
 127 DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx])
 128 DRIVER([MIC 985xx], [mic-985xx])
 129 DRIVER([Motech LPS 30x], [motech-lps-30x])
 130 DRIVER([Norma DMM], [norma-dmm])
 131 DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer])
 132 DRIVER([Pipistrello-OLS], [pipistrello-ols])
 133 DRIVER([Rigol DS], [rigol-ds])
 134 DRIVER([Saleae Logic16], [saleae-logic16])
 135 DRIVER([serial DMM], [serial-dmm])
 136 DRIVER([Sysclk LWLA], [sysclk-lwla])
 137 DRIVER([Teleinfo], [teleinfo])
 138 DRIVER([Testo], [testo])
 139 DRIVER([Tondaj SL-814], [tondaj-sl-814])
 140 DRIVER([UNI-T DMM], [uni-t-dmm])
 141 DRIVER([UNI-T UT32x], [uni-t-ut32x])
 142 DRIVER([Victor DMM], [victor-dmm])
 143 DRIVER([Yokogawa DL/DLM], [yokogawa-dlm])
 144 DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube])
 145
 146 AC_ARG_ENABLE(libserialport,
 147         AC_HELP_STRING([--disable-libserialport],
 148         [disable libserialport support [default=detect]]))
 149
 150 AC_ARG_ENABLE(libftdi,
 151         AC_HELP_STRING([--disable-libftdi],
 152         [disable libftdi support [default=detect]]))
 153
 154 AC_ARG_ENABLE(libusb,
 155         AC_HELP_STRING([--disable-libusb],
 156         [disable libusb support [default=detect]]))
 157
 158 # Language binding '--enable' options
 159
 160 AC_ARG_ENABLE(bindings,
 161         AC_HELP_STRING([--enable-bindings],
 162         [build language bindings [default=yes]]),
 163         [BINDINGS_ALL="$enableval"], [BINDINGS_ALL="yes"])
 164
 165 AC_ARG_ENABLE(cxx,
 166         AC_HELP_STRING([--enable-cxx],
 167         [build C++ bindings [default=yes]]),
 168         [BINDINGS_CXX="$enableval"], [BINDINGS_CXX=$BINDINGS_ALL])
 169
 170 AC_ARG_ENABLE(python,
 171         AC_HELP_STRING([--enable-python],
 172         [build Python bindings [default=yes]]),
 173         [BINDINGS_PYTHON="$enableval"], [BINDINGS_PYTHON=$BINDINGS_ALL])
 174
 175 AC_ARG_ENABLE(java,
 176         AC_HELP_STRING([--enable-java],
 177         [build Java bindings [default=yes]]),
 178         [BINDINGS_JAVA="$enableval"], [BINDINGS_JAVA=$BINDINGS_ALL])
 179
 180 AC_ARG_WITH(jni-include-path,
 181         AC_HELP_STRING([--with-jni-include-path=path],
 182         [specify include path for JNI [default=autodetect]]),
 183         [JNI_INCLUDE_DIRS="$withval"], [JNI_INCLUDE_DIRS=auto])
 184
 185 # Check if the C++ compiler supports the C++11 standard.
 186
 187 m4_ifdef([AX_CXX_COMPILE_STDCXX_11], [AX_CXX_COMPILE_STDCXX_11(,[optional])],
 188         [AC_MSG_NOTICE([Missing macro m4_toupper(aX_CXX_COMPILE_STDCXX_11), no C++11 check])])
 189
 190 if test "x$HAVE_CXX11" != "x1"; then
 191         BINDINGS_CXX="no"; cxx_msg="C++11 compiler required"
 192 fi
 193
 194 # The C++ bindings use doxygen to parse libsigrok symbols.
 195 AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes])
 196 if test "x$HAVE_DOXYGEN" != "xyes"; then
 197         BINDINGS_CXX="no"; cxx_msg="doxygen required"
 198 fi
 199
 200 # Python is needed for the C++ bindings.
 201 AC_CHECK_PROG([HAVE_PYTHON], [python], [yes])
 202 if test "x$HAVE_PYTHON" != "xyes"; then
 203         BINDINGS_CXX="no"; cxx_msg="Python required"
 204 fi
 205
 206 # The Python bindings need Python development files
 207 PKG_CHECK_MODULES([python], [python >= 2.7],
 208         [CXXFLAGS="$CXXFLAGS $python_CFLAGS";
 209         CXXLIBS="$CXXLIBS $python_LIBS"],
 210 [PKG_CHECK_MODULES([python27], [python-2.7 >= 2.7],
 211         [CXXFLAGS="$CXXFLAGS $python27_CFLAGS";
 212         CXXLIBS="$CXXLIBS $python27_LIBS"],
 213                 [BINDINGS_PYTHON="no"; python_msg="Python headers required"])])
 214
 215 # The Python bindings need the setuptools Python module.
 216 m4_ifdef([AX_PYTHON_MODULE], [AX_PYTHON_MODULE([setuptools])],
 217         # We'll let it go through even if the macro wasn't found, the python
 218         # module may still be there.
 219         [HAVE_PYTHON_SETUPTOOLS="yes";
 220                 AC_MSG_NOTICE([Missing macro m4_toupper(aX_PYTHON_MODULE), no setuptools check])]
 221 )
 222 if test "x$HAVE_PYMOD_SETUPTOOLS" != "xyes"; then
 223         BINDINGS_PYTHON="no"; python_msg="Python setuptools module required"
 224 fi
 225
 226 # The Python and Java bindings use swig to generate code.
 227 AC_CHECK_PROG([HAVE_SWIG], [swig], [yes])
 228 if test "x$HAVE_SWIG" != "xyes"; then
 229         BINDINGS_PYTHON="no"; python_msg="swig required"
 230         BINDINGS_JAVA="no"; java_msg="swig required"
 231 fi
 232
 233 # Checks for libraries.
 234
 235 case "$host" in
 236 *mingw*)
 237         # We need to link against the Winsock2 library for SCPI over TCP.
 238         LIBS="$LIBS -lws2_32";;
 239 esac
 240
 241 # This variable collects the pkg-config names of all detected libs.
 242 # It is then used to construct the "Requires.private:" field in the
 243 # libsigrok.pc file.
 244 SR_PKGLIBS=""
 245
 246 # libm (the standard math library) is always needed.
 247 AC_SEARCH_LIBS([pow], [m])
 248
 249 # RPC is only needed for VXI support.
 250 AC_MSG_CHECKING([for RPC support])
 251 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <rpc/rpc.h>],
 252                                 [CLIENT *rpc_test(void)],
 253                                 [{ return clnt_create("", 0, 0, ""); }])],
 254                [AC_MSG_RESULT([yes]); have_rpc=1],
 255                [AC_MSG_RESULT([no]);  have_rpc=0])
 256 # Define HAVE_RPC in config.h if we found RPC support.
 257 AC_DEFINE_UNQUOTED(HAVE_RPC, [$have_rpc], [Specifies whether we have RPC support.])
 258 # VXI support is only compiled if RPC support was found.
 259 AM_CONDITIONAL(NEED_RPC, test "x$have_rpc" != "x0")
 260
 261 # libglib-2.0 is always needed. Abort if it's not found.
 262 # Note: glib-2.0 is part of the libsigrok API (hard pkg-config requirement).
 263 # We require at least 2.32.0 due to e.g. g_variant_new_fixed_array().
 264 AM_PATH_GLIB_2_0([2.32.0],
 265         [LIB_CFLAGS="$LIB_CFLAGS $GLIB_CFLAGS"; LIBS="$LIBS $GLIB_LIBS"])
 266
 267 # libzip is always needed. Abort if it's not found.
 268 PKG_CHECK_MODULES([libzip], [libzip >= 0.10],
 269         [LIB_CFLAGS="$LIB_CFLAGS $libzip_CFLAGS"; LIBS="$LIBS $libzip_LIBS";
 270         SR_PKGLIBS="$SR_PKGLIBS libzip"])
 271
 272 # libserialport is only needed for some hardware drivers. Disable the
 273 # respective drivers if it is not found.
 274 if test "x$enable_libserialport" != "xno"; then
 275         PKG_CHECK_MODULES([libserialport], [libserialport >= 0.2.0],
 276                 [have_libserialport="yes"; LIB_CFLAGS="$LIB_CFLAGS $libserialport_CFLAGS";
 277                 LIBS="$LIBS $libserialport_LIBS";
 278                 SR_PKGLIBS="$SR_PKGLIBS libserialport"],
 279                 [have_libserialport="no"])
 280         if test "x$enable_libserialport$have_libserialport" = "xyesno"; then
 281                 AC_MSG_ERROR([libserialport support requested, but it was not found])
 282         fi
 283 else
 284         have_libserialport="no"
 285 fi
 286
 287 # Define HAVE_LIBSERIALPORT in config.h if we found libserialport.
 288 if test "x$have_libserialport" = "xno"; then
 289         HW_AGILENT_DMM="no"; HW_APPA_55II="no";
 290         HW_ATTEN_PPS3XXX="no"; HW_BRYMEN_DMM="no"; HW_CEM_DT_885X="no";
 291         HW_CENTER_3XX="no"; HW_COLEAD_SLM="no"; HW_CONRAD_DIGI_35_CPU="no";
 292         HW_FLUKE_DMM="no"; HW_GMC_MH_1X_2X="no"; HW_HAMEG_HMO="no";
 293         HW_MANSON_HCS_3XXX="no"; HW_MIC_985XX="no"; HW_MOTECH_LPS_30X="no";
 294         HW_NORMA_DMM="no"; HW_OPENBENCH_LOGIC_SNIFFER="no"; HW_SERIAL_DMM="no";
 295         HW_TELEINFO="no"; HW_TONDAJ_SL_814="no";
 296 else
 297         AC_DEFINE_UNQUOTED(HAVE_LIBSERIALPORT, [1],
 298                 [Specifies whether we have libserialport.])
 299 fi
 300
 301 # Serial port helper code is only compiled in if libserialport was found.
 302 AM_CONDITIONAL(NEED_SERIAL, test "x$have_libserialport" != xno)
 303
 304 PKG_CHECK_MODULES([librevisa], [librevisa >= 0.0.20130812],
 305         [have_librevisa="yes"; LIB_CFLAGS="$LIB_CFLAGS $librevisa_CFLAGS";
 306         LIBS="$LIBS $librevisa_LIBS";
 307         SR_PKGLIBS="$SR_PKGLIBS librevisa"],
 308         [have_librevisa="no"])
 309
 310 # VISA SCPI backend is only compiled in if librevisa was found.
 311 AM_CONDITIONAL(NEED_VISA, test "x$have_librevisa" != xno)
 312
 313 # Define HAVE_LIBREVISA in config.h if we found librevisa.
 314 if test "x$have_librevisa" != "xno"; then
 315         AC_DEFINE_UNQUOTED(HAVE_LIBREVISA, [1],
 316                 [Specifies whether we have librevisa.])
 317 fi
 318
 319 # libusb-1.0 is only needed for some hardware drivers. Disable the respective
 320 # drivers if it is not found.
 321 if test "x$enable_libusb" != "xno"; then
 322         case "$host" in
 323         *freebsd*)
 324                 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
 325                 # This means libusb-1.0 is always available, no need to check for it,
 326                 # and no need to (potentially) disable any drivers if it's not found.
 327                 have_libusb1_0="yes"
 328                 ;;
 329         *)
 330                 PKG_CHECK_MODULES([libusb], [libusb-1.0 >= 1.0.16],
 331                         [have_libusb1_0="yes"; LIB_CFLAGS="$LIB_CFLAGS $libusb_CFLAGS";
 332                         LIBS="$LIBS $libusb_LIBS";
 333                         SR_PKGLIBS="$SR_PKGLIBS libusb-1.0"],
 334                         [have_libusb1_0="no"])
 335                 if test "x$enable_libusb$have_libusb1_0" = "xyesno"; then
 336                         AC_MSG_ERROR([libusb support requested, but it was not found])
 337                 fi
 338                 ;;
 339         esac
 340 else
 341         have_libusb1_0="no"
 342 fi
 343
 344 # Define HAVE_LIBUSB_1_0 in config.h if we found libusb-1.0.
 345 if test "x$have_libusb1_0" = "xno"; then
 346         HW_BRYMEN_BM86X="no"; HW_FX2LAFW="no";
 347         HW_HANTEK_DSO="no"; HW_IKALOGIC_SCANALOGIC2="no";
 348         HW_KECHENG_KC_330B="no"; HW_LASCAR_EL_USB="no";
 349         HW_SYSCLK_LWLA="no"; HW_TESTO="no"; HW_UNI_T_DMM="no";
 350         HW_UNI_T_UT32X="no"; HW_VICTOR_DMM="no";
 351         HW_ZEROPLUS_LOGIC_CUBE="no"; HW_SALEAE_LOGIC16="no";
 352 else
 353         AC_DEFINE_UNQUOTED(HAVE_LIBUSB_1_0, [1],
 354                 [Specifies whether we have a libusb.h header.])
 355 fi
 356
 357 # USB + FX2 firmware helper code is only compiled in if libusb-1.0 was found.
 358 AM_CONDITIONAL(NEED_USB, test "x$have_libusb1_0" != xno)
 359
 360 # libftdi is only needed for some hardware drivers. Disable them if not found.
 361 if test "x$enable_libftdi" != "xno"; then
 362         PKG_CHECK_MODULES([libftdi], [libftdi >= 0.16],
 363                 [have_libftdi="yes"; LIB_CFLAGS="$LIB_CFLAGS $libftdi_CFLAGS";
 364                 LIBS="$LIBS $libftdi_LIBS";
 365                 SR_PKGLIBS="$SR_PKGLIBS libftdi"],
 366                 [PKG_CHECK_MODULES([libftdi1], [libftdi1 >= 1.0],
 367                         [LIB_CFLAGS="$LIB_CFLAGS $libftdi1_CFLAGS";
 368                         LIBS="$LIBS $libftdi1_LIBS";
 369                         SR_PKGLIBS="$SR_PKGLIBS libftdi1"],
 370                         [have_libftdi="no"])])
 371         if test "x$enable_libftdi$have_libftdi" = "xyesno"; then
 372                 AC_MSG_ERROR([libftdi support requested, but it was not found])
 373         fi
 374 else
 375         have_libftdi="no"
 376 fi
 377
 378 if test "x$have_libftdi" = "xno"; then
 379         HW_ASIX_SIGMA="no"; HW_CHRONOVU_LA="no"; HW_IKALOGIC_SCANAPLUS="no";
 380         HW_PIPISTRELLO_OLS="no";
 381 fi
 382
 383 # glibmm-2.4 is needed for the C++ bindings.
 384 PKG_CHECK_MODULES([glibmm], [glibmm-2.4 >= 2.32.0],
 385         [CXXFLAGS="$CXXFLAGS $glibmm_CFLAGS";
 386         CXXLIBS="$CXXLIBS $glibmm_LIBS"],
 387         [BINDINGS_CXX="no"; cxx_msg="glibmm required"])
 388
 389 # C++ bindings want stoi and stod
 390 if test "x$BINDINGS_CXX" == "xyes"; then
 391         AC_LANG_PUSH([C++])
 392         AC_MSG_CHECKING([for stoi and stod])
 393         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <string>],
 394                                            [{ return std::stoi("1")+std::stod("1.0"); }])],
 395                [AC_MSG_RESULT([yes]);
 396                 AC_DEFINE_UNQUOTED(HAVE_STOI_STOD, [1],
 397                 [Specifies whether we have the stoi and stod functions.])],
 398                [AC_MSG_RESULT([no])])
 399         AC_LANG_POP([C++])
 400 fi
 401
 402 # PyGObject is needed for the Python bindings.
 403 PKG_CHECK_MODULES([pygobject], [pygobject-3.0 >= 3.0.0],
 404         [CXXFLAGS="$CXXFLAGS $pygobject_CFLAGS";
 405         CXXLIBS="$CXXLIBS $pygobject_LIBS";
 406         PKG_CHECK_MODULES([pygobject_3_7_91], [pygobject-3.0 >= 3.7.91],
 407                 [pyg_flags_signed=0], [pyg_flags_signed=1]);
 408         AC_DEFINE_UNQUOTED(PYGOBJECT_FLAGS_SIGNED, [$pyg_flags_signed],
 409                 [Whether last argument to pyg_flags_get_value() is signed])],
 410         [BINDINGS_PYTHON="no"; python_msg="Python pygobject module required"])
 411
 412 # The Check unit testing framework is optional. Disable if not found.
 413 PKG_CHECK_MODULES([check], [check >= 0.9.4],
 414         [have_check="yes"], [have_check="no"])
 415 AM_CONDITIONAL(HAVE_CHECK, test x"$have_check" = "xyes")
 416
 417 # The OLS driver uses serial port file descriptors directly, and therefore
 418 # will not currently work on Windows.
 419 case "$host" in
 420 *mingw*)
 421         HW_OPENBENCH_LOGIC_SNIFFER="no"
 422         ;;
 423 esac
 424
 425 # The BeagleLogic driver needs sys/mman.h and sys/ioctl.h. Don't try to
 426 # build it if these headers aren't available.
 427 AC_CHECK_HEADERS([sys/mman.h sys/ioctl.h], [], [HW_BEAGLELOGIC="no"])
 428
 429 AC_SUBST(SR_PKGLIBS)
 430
 431 CFLAGS="$CFLAGS -Iinclude/libsigrok -I${srcdir}/include/libsigrok $LIB_CFLAGS"
 432 CXXFLAGS="$CXXFLAGS -Iinclude/libsigrok -I${srcdir}/include -Ibindings/cxx -Ibindings/cxx/include/libsigrok -I${srcdir}/bindings/cxx/include $LIB_CFLAGS"
 433
 434 # Find Java compiler and JNI includes for Java bindings.
 435
 436 AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no])
 437
 438 if test "x$HAVE_JAVAC" = "xyes"; then
 439         AX_PROG_JAVAC
 440         if test "x$JNI_INCLUDE_DIRS" = "xauto"; then
 441                 if test "x$cross_compiling" = "xyes"; then
 442                         JNI_INCLUDE_DIRS=
 443                 else
 444                         AX_JNI_INCLUDE_DIR
 445                 fi
 446         fi
 447         for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS; do
 448                 CXXFLAGS="$CXXFLAGS -I$JNI_INCLUDE_DIR"
 449         done
 450         AC_LANG_PUSH([C++])
 451         AC_CHECK_HEADERS([jni.h], [], [BINDINGS_JAVA="no"; java_msg="Java JNI headers required"])
 452         AC_LANG_POP([C++])
 453 else
 454         BINDINGS_JAVA="no"; java_msg="Java compiler required"
 455 fi
 456
 457 # Python and Java bindings depend on C++ bindings.
 458 if test "x$BINDINGS_CXX" != "xyes"; then
 459         BINDINGS_PYTHON="no"; python_msg="C++ bindings required"
 460         BINDINGS_JAVA="no"; java_msg="C++ bindings required"
 461 fi
 462
 463 # Now set AM_CONDITIONALs and AC_DEFINEs for the enabled/disabled drivers.
 464
 465 AM_CONDITIONAL(HW_AGILENT_DMM, test x$HW_AGILENT_DMM = xyes)
 466 if test "x$HW_AGILENT_DMM" = "xyes"; then
 467         AC_DEFINE(HAVE_HW_AGILENT_DMM, 1, [Agilent DMM support])
 468 fi
 469
 470 AM_CONDITIONAL(HW_APPA_55II, test x$HW_APPA_55II = xyes)
 471 if test "x$HW_APPA_55II" = "xyes"; then
 472         AC_DEFINE(HAVE_HW_APPA_55II, 1, [APPA 55II support])
 473 fi
 474
 475 AM_CONDITIONAL(HW_ASIX_SIGMA, test x$HW_ASIX_SIGMA = xyes)
 476 if test "x$HW_ASIX_SIGMA" = "xyes"; then
 477         AC_DEFINE(HAVE_HW_ASIX_SIGMA, 1, [ASIX SIGMA/SIGMA2 support])
 478 fi
 479
 480 AM_CONDITIONAL(HW_ATTEN_PPS3XXX, test x$HW_ATTEN_PPS3XXX = xyes)
 481 if test "x$HW_ATTEN_PPS3XXX" = "xyes"; then
 482         AC_DEFINE(HAVE_HW_ATTEN_PPS3XXX, 1, [Atten PPS3xxx support])
 483 fi
 484
 485 AM_CONDITIONAL(HW_BEAGLELOGIC, test x$HW_BEAGLELOGIC = xyes)
 486 if test "x$HW_BEAGLELOGIC" = "xyes"; then
 487         AC_DEFINE(HAVE_HW_BEAGLELOGIC, 1, [BeagleLogic support])
 488 fi
 489
 490 AM_CONDITIONAL(HW_BRYMEN_BM86X, test x$HW_BRYMEN_BM86X = xyes)
 491 if test "x$HW_BRYMEN_BM86X" = "xyes"; then
 492         AC_DEFINE(HAVE_HW_BRYMEN_BM86X, 1, [Brymen BM86X support])
 493 fi
 494
 495 AM_CONDITIONAL(HW_BRYMEN_DMM, test x$HW_BRYMEN_DMM = xyes)
 496 if test "x$HW_BRYMEN_DMM" = "xyes"; then
 497         AC_DEFINE(HAVE_HW_BRYMEN_DMM, 1, [Brymen DMM support])
 498 fi
 499
 500 AM_CONDITIONAL(HW_CEM_DT_885X, test x$HW_CEM_DT_885X = xyes)
 501 if test "x$HW_CEM_DT_885X" = "xyes"; then
 502         AC_DEFINE(HAVE_HW_CEM_DT_885X, 1, [CEM DT-885x support])
 503 fi
 504
 505 AM_CONDITIONAL(HW_CENTER_3XX, test x$HW_CENTER_3XX = xyes)
 506 if test "x$HW_CENTER_3XX" = "xyes"; then
 507         AC_DEFINE(HAVE_HW_CENTER_3XX, 1, [Center 3xx support])
 508 fi
 509
 510 AM_CONDITIONAL(HW_CHRONOVU_LA, test x$HW_CHRONOVU_LA = xyes)
 511 if test "x$HW_CHRONOVU_LA" = "xyes"; then
 512         AC_DEFINE(HAVE_HW_CHRONOVU_LA, 1, [ChronoVu LA support])
 513 fi
 514
 515 AM_CONDITIONAL(HW_COLEAD_SLM, test x$HW_COLEAD_SLM = xyes)
 516 if test "x$HW_COLEAD_SLM" = "xyes"; then
 517         AC_DEFINE(HAVE_HW_COLEAD_SLM, 1, [Colead SLM support])
 518 fi
 519
 520 AM_CONDITIONAL(HW_CONRAD_DIGI_35_CPU, test x$HW_CONRAD_DIGI_35_CPU = xyes)
 521 if test "x$HW_CONRAD_DIGI_35_CPU" = "xyes"; then
 522         AC_DEFINE(HAVE_HW_CONRAD_DIGI_35_CPU, 1, [Conrad DIGI 35 CPU support])
 523 fi
 524
 525 AM_CONDITIONAL(HW_DEMO, test x$HW_DEMO = xyes)
 526 if test "x$HW_DEMO" = "xyes"; then
 527         AC_DEFINE(HAVE_HW_DEMO, 1, [Demo driver support])
 528 fi
 529
 530 AM_CONDITIONAL(HW_FLUKE_DMM, test x$HW_FLUKE_DMM = xyes)
 531 if test "x$HW_FLUKE_DMM" = "xyes"; then
 532         AC_DEFINE(HAVE_HW_FLUKE_DMM, 1, [Fluke DMM support])
 533 fi
 534
 535 AM_CONDITIONAL(HW_FX2LAFW, test x$HW_FX2LAFW = xyes)
 536 if test "x$HW_FX2LAFW" = "xyes"; then
 537         AC_DEFINE(HAVE_HW_FX2LAFW, 1, [fx2lafw support])
 538 fi
 539
 540 AM_CONDITIONAL(HW_GMC_MH_1X_2X, test x$HW_GMC_MH_1X_2X = xyes)
 541 if test "x$HW_GMC_MH_1X_2X" = "xyes"; then
 542         AC_DEFINE(HAVE_HW_GMC_MH_1X_2X, 1, [gmc-mh-1x-2x support])
 543 fi
 544
 545 AM_CONDITIONAL(HW_HANTEK_DSO, test x$HW_HANTEK_DSO = xyes)
 546 if test "x$HW_HANTEK_DSO" = "xyes"; then
 547         AC_DEFINE(HAVE_HW_HANTEK_DSO, 1, [Hantek DSO support])
 548 fi
 549
 550 AM_CONDITIONAL(HW_HAMEG_HMO, test x$HW_HAMEG_HMO = xyes)
 551 if test "x$HW_HAMEG_HMO" = "xyes"; then
 552         AC_DEFINE(HAVE_HW_HAMEG_HMO, 1, [Hameg HMO support])
 553 fi
 554
 555 AM_CONDITIONAL(HW_IKALOGIC_SCANALOGIC2, test x$HW_IKALOGIC_SCANALOGIC2 = xyes)
 556 if test "x$HW_IKALOGIC_SCANALOGIC2" = "xyes"; then
 557         AC_DEFINE(HAVE_HW_IKALOGIC_SCANALOGIC2, 1, [IKALOGIC Scanalogic-2 support])
 558 fi
 559
 560 AM_CONDITIONAL(HW_IKALOGIC_SCANAPLUS, test x$HW_IKALOGIC_SCANAPLUS = xyes)
 561 if test "x$HW_IKALOGIC_SCANAPLUS" = "xyes"; then
 562         AC_DEFINE(HAVE_HW_IKALOGIC_SCANAPLUS, 1, [IKALOGIC ScanaPLUS support])
 563 fi
 564
 565 AM_CONDITIONAL(HW_KECHENG_KC_330B, test x$HW_KECHENG_KC_330B = xyes)
 566 if test "x$HW_KECHENG_KC_330B" = "xyes"; then
 567         AC_DEFINE(HAVE_HW_KECHENG_KC_330B, 1, [Kecheng KC-330B support])
 568 fi
 569
 570 AM_CONDITIONAL(HW_LASCAR_EL_USB, test x$HW_LASCAR_EL_USB = xyes)
 571 if test "x$HW_LASCAR_EL_USB" = "xyes"; then
 572         AC_DEFINE(HAVE_HW_LASCAR_EL_USB, 1, [Lascar EL-USB support])
 573 fi
 574
 575 AM_CONDITIONAL(HW_MANSON_HCS_3XXX, test x$HW_MANSON_HCS_3XXX = xyes)
 576 if test "x$HW_MANSON_HCS_3XXX" = "xyes"; then
 577         AC_DEFINE(HAVE_HW_MANSON_HCS_3XXX, 1, [Manson HCS-3xxx support])
 578 fi
 579
 580 AM_CONDITIONAL(HW_MIC_985XX, test x$HW_MIC_985XX = xyes)
 581 if test "x$HW_MIC_985XX" = "xyes"; then
 582         AC_DEFINE(HAVE_HW_MIC_985XX, 1, [MIC 985xx support])
 583 fi
 584
 585 AM_CONDITIONAL(HW_MOTECH_LPS_30X, test x$HW_MOTECH_LPS_30X = xyes)
 586 if test "x$HW_MOTECH_LPS_30X" = "xyes"; then
 587         AC_DEFINE(HAVE_HW_MOTECH_LPS_30X, 1, [motech-lps-30x support])
 588 fi
 589
 590 AM_CONDITIONAL(HW_NORMA_DMM, test x$HW_NORMA_DMM = xyes)
 591 if test "x$HW_NORMA_DMM" = "xyes"; then
 592         AC_DEFINE(HAVE_HW_NORMA_DMM, 1, [Norma DMM support])
 593 fi
 594
 595 AM_CONDITIONAL(HW_OPENBENCH_LOGIC_SNIFFER, test x$HW_OPENBENCH_LOGIC_SNIFFER = xyes)
 596 if test "x$HW_OPENBENCH_LOGIC_SNIFFER" = "xyes"; then
 597         AC_DEFINE(HAVE_HW_OPENBENCH_LOGIC_SNIFFER, 1, [OpenBench Logic Sniffer (OLS) support])
 598 fi
 599
 600 AM_CONDITIONAL(HW_PIPISTRELLO_OLS, test x$HW_PIPISTRELLO_OLS = xyes)
 601 if test "x$HW_PIPISTRELLO_OLS" = "xyes"; then
 602         AC_DEFINE(HAVE_HW_PIPISTRELLO_OLS, 1, [Pipistrello OLS support])
 603 fi
 604
 605 AM_CONDITIONAL(HW_RIGOL_DS, test x$HW_RIGOL_DS = xyes)
 606 if test "x$HW_RIGOL_DS" = "xyes"; then
 607         AC_DEFINE(HAVE_HW_RIGOL_DS, 1, [Rigol DS support])
 608 fi
 609
 610 AM_CONDITIONAL(HW_SALEAE_LOGIC16, test x$HW_SALEAE_LOGIC16 = xyes)
 611 if test "x$HW_SALEAE_LOGIC16" = "xyes"; then
 612         AC_DEFINE(HAVE_HW_SALEAE_LOGIC16, 1, [Saleae Logic16 support])
 613 fi
 614
 615 AM_CONDITIONAL(HW_SERIAL_DMM, test x$HW_SERIAL_DMM = xyes)
 616 if test "x$HW_SERIAL_DMM" = "xyes"; then
 617         AC_DEFINE(HAVE_HW_SERIAL_DMM, 1, [Serial DMM support])
 618 fi
 619
 620 AM_CONDITIONAL(HW_SYSCLK_LWLA, test x$HW_SYSCLK_LWLA = xyes)
 621 if test "x$HW_SYSCLK_LWLA" = "xyes"; then
 622         AC_DEFINE(HAVE_HW_SYSCLK_LWLA, 1, [Sysclk LWLA support])
 623 fi
 624
 625 AM_CONDITIONAL(HW_TELEINFO, test x$HW_TELEINFO = xyes)
 626 if test "x$HW_TELEINFO" = "xyes"; then
 627         AC_DEFINE(HAVE_HW_TELEINFO, 1, [Teleinfo support])
 628 fi
 629
 630 AM_CONDITIONAL(HW_TESTO, test x$HW_TESTO = xyes)
 631 if test "x$HW_TESTO" = "xyes"; then
 632         AC_DEFINE(HAVE_HW_TESTO, 1, [Testo support])
 633 fi
 634
 635 AM_CONDITIONAL(HW_TONDAJ_SL_814, test x$HW_TONDAJ_SL_814 = xyes)
 636 if test "x$HW_TONDAJ_SL_814" = "xyes"; then
 637         AC_DEFINE(HAVE_HW_TONDAJ_SL_814, 1, [Tondaj SL-814 support])
 638 fi
 639
 640 AM_CONDITIONAL(HW_UNI_T_DMM, test x$HW_UNI_T_DMM = xyes)
 641 if test "x$HW_UNI_T_DMM" = "xyes"; then
 642         AC_DEFINE(HAVE_HW_UNI_T_DMM, 1, [UNI-T DMM support])
 643 fi
 644
 645 AM_CONDITIONAL(HW_UNI_T_UT32X, test x$HW_UNI_T_UT32X = xyes)
 646 if test "x$HW_UNI_T_UT32X" = "xyes"; then
 647         AC_DEFINE(HAVE_HW_UNI_T_UT32X, 1, [UNI-T UT32x support])
 648 fi
 649
 650 AM_CONDITIONAL(HW_VICTOR_DMM, test x$HW_VICTOR_DMM = xyes)
 651 if test "x$HW_VICTOR_DMM" = "xyes"; then
 652         AC_DEFINE(HAVE_HW_VICTOR_DMM, 1, [Victor DMM support])
 653 fi
 654
 655 AM_CONDITIONAL(HW_YOKOGAWA_DLM, test x$HW_YOKOGAWA_DLM = xyes)
 656 if test "x$HW_YOKOGAWA_DLM" = "xyes"; then
 657         AC_DEFINE(HAVE_HW_YOKOGAWA_DLM, 1, [Yokogawa DL/DLM support])
 658 fi
 659
 660 AM_CONDITIONAL(HW_ZEROPLUS_LOGIC_CUBE, test x$HW_ZEROPLUS_LOGIC_CUBE = xyes)
 661 if test "x$HW_ZEROPLUS_LOGIC_CUBE" = "xyes"; then
 662         AC_DEFINE(HAVE_HW_ZEROPLUS_LOGIC_CUBE, 1, [ZEROPLUS Logic Cube support])
 663 fi
 664
 665 AM_CONDITIONAL(BINDINGS_CXX, test x$BINDINGS_CXX = xyes)
 666
 667 AM_CONDITIONAL(BINDINGS_PYTHON, test x$BINDINGS_PYTHON = xyes)
 668
 669 AM_CONDITIONAL(BINDINGS_JAVA, test x$BINDINGS_JAVA = xyes)
 670
 671 # Checks for header files.
 672 # These are already implicitly checked: inttypes.h stdint.h stdlib.h string.h
 673 # unistd.h memory.h strings.h dlfcn.h sys/types.h sys/stat.h.
 674
 675 # Checks for typedefs, structures, and compiler characteristics.
 676 AC_C_BIGENDIAN
 677
 678 AC_SUBST(FIRMWARE_DIR, "$datadir/sigrok-firmware")
 679 AC_SUBST(MAKEFLAGS, '--no-print-directory')
 680 AC_SUBST(AM_LIBTOOLFLAGS, '--silent')
 681
 682 SR_PACKAGE_VERSION_MAJOR=sr_package_version_major
 683 SR_PACKAGE_VERSION_MINOR=sr_package_version_minor
 684 SR_PACKAGE_VERSION_MICRO=sr_package_version_micro
 685 SR_PACKAGE_VERSION=sr_package_version
 686
 687 AC_SUBST(SR_PACKAGE_VERSION_MAJOR)
 688 AC_SUBST(SR_PACKAGE_VERSION_MINOR)
 689 AC_SUBST(SR_PACKAGE_VERSION_MICRO)
 690 AC_SUBST(SR_PACKAGE_VERSION)
 691
 692 AC_CONFIG_FILES([Makefile include/libsigrok/version.h libsigrok.pc
 693         bindings/cxx/libsigrokxx.pc])
 694
 695 AC_OUTPUT
 696
 697 echo
 698 echo "libsigrok configuration summary:"
 699 echo
 700 echo "  - Package version (major.minor.micro):    $SR_PACKAGE_VERSION"
 701 echo "  - Library version (current:revision:age): $SR_LIB_VERSION"
 702 echo "  - Prefix: $prefix"
 703 echo "  - Building on: $build"
 704 echo "  - Building for: $host"
 705 echo
 706 echo "Detected libraries:"
 707 echo
 708
 709 # Note: This only works for libs with pkg-config integration.
 710 for lib in "glib-2.0 >= 2.32.0" "libzip >= 0.10" "libserialport >= 0.2.0" "librevisa >= 0.0.20130812" "libusb-1.0 >= 1.0.16" "libftdi >= 0.16" "libftdi1 >= 1.0" "glibmm-2.4 >= 2.32.0" "pygobject-3.0 >= 3.0.0" "check >= 0.9.4"; do
 711         optional="OPTIONAL"
 712         if test "x$lib" = "xglib-2.0 >= 2.32.0"; then optional="REQUIRED"; fi
 713         if test "x$lib" = "xlibzip >= 0.10"; then optional="REQUIRED"; fi
 714         if `$PKG_CONFIG --exists $lib`; then
 715                 ver=`$PKG_CONFIG --modversion $lib`
 716                 answer="yes ($ver)"
 717         else
 718                 answer="no"
 719         fi
 720         echo "  - ($optional) $lib: $answer"
 721 done
 722
 723 eval echo -e "@Enabled hardware drivers:@@${driver_summary}" | tr @ \\n
 724
 725 # Prepare final bindings report messages
 726 final_cxx=""
 727 final_python=""
 728 final_java=""
 729 if test "$enable_bindings" = "no"; then
 730         final_cxx=" (disabled)"
 731         final_python=" (disabled)"
 732         final_java=" (disabled)"
 733 else
 734         if test "$enable_cxx" = "no"; then
 735                 final_cxx=" (disabled)"
 736         elif test "$BINDINGS_CXX" = "no"; then
 737                 final_cxx=" ($cxx_msg)"
 738         fi
 739         if test "$enable_python" = "no"; then
 740                 final_python=" (disabled)"
 741         elif test "$BINDINGS_PYTHON" = "no"; then
 742                 final_python=" ($python_msg)"
 743         fi
 744         if test "$enable_java" = "no"; then
 745                 final_java=" (disabled)"
 746         elif test "$BINDINGS_JAVA" = "no"; then
 747                 final_java=" ($java_msg)"
 748         fi
 749 fi
 750
 751 echo -e "Enabled language bindings:\n"
 752 echo " - C++............................. $BINDINGS_CXX$final_cxx"
 753 echo " - Python.......................... $BINDINGS_PYTHON$final_python"
 754 echo " - Java............................ $BINDINGS_JAVA$final_java"
 755 echo