configure.ac

   1 ##
   2 ## This file is part of the libsigrok project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 3 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 # libsigrok package version number (NOT the same as shared lib version!).
  25 m4_define([sr_package_version_major], [0])
  26 m4_define([sr_package_version_minor], [4])
  27 m4_define([sr_package_version_micro], [0])
  28 m4_define([sr_package_version_suffix], [-git])
  29 m4_define([sr_package_version], [sr_package_version_major.sr_package_version_minor.sr_package_version_micro[]sr_package_version_suffix])
  30
  31 AC_INIT([libsigrok], [sr_package_version], [sigrok-devel@lists.sourceforge.net],
  32         [libsigrok], [http://www.sigrok.org])
  33 AC_CONFIG_HEADERS([config.h include/libsigrok/version.h])
  34 AC_CONFIG_MACRO_DIR([autostuff])
  35 AC_CONFIG_AUX_DIR([autostuff])
  36
  37 # We require at least automake 1.11 (needed for 'silent rules').
  38 AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define subdir-objects check-news color-tests])
  39 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  40 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  41
  42 AH_TOP([#ifndef SR_CONFIG_H
  43 #define SR_CONFIG_H    /* To stop multiple inclusions. */])
  44 AH_BOTTOM([#endif /* SR_CONFIG_H */])
  45
  46 # Enable more compiler warnings via -Wall and -Wextra. Add -fvisibility=hidden
  47 # and enforce use of SR_API to explicitly mark all public API functions.
  48 COMMON_FLAGS="$CFLAGS -Wall -Wextra -fvisibility=hidden"
  49 CFLAGS="$COMMON_FLAGS -std=c11 -D_POSIX_C_SOURCE=200112L -Wmissing-prototypes"
  50 CXXFLAGS="-std=c++11 $COMMON_FLAGS"
  51
  52 # Checks for programs.
  53 AC_PROG_CC
  54 AC_PROG_CPP
  55 AC_PROG_CXX
  56 AC_PROG_INSTALL
  57 AC_PROG_LN_S
  58
  59 # Required for per-target flags or subdir-objects with C sources.
  60 AM_PROG_CC_C_O
  61
  62 # Initialize libtool.
  63 LT_INIT
  64
  65 # Initialize pkg-config.
  66 # We require at least 0.22, as "Requires.private" behaviour changed there.
  67 PKG_PROG_PKG_CONFIG([0.22])
  68
  69 AC_SUBST([SR_PACKAGE_VERSION], [sr_package_version])
  70
  71 AC_DEFINE([SR_PACKAGE_VERSION_MAJOR], [sr_package_version_major], [.])
  72 AC_DEFINE([SR_PACKAGE_VERSION_MINOR], [sr_package_version_minor], [.])
  73 AC_DEFINE([SR_PACKAGE_VERSION_MICRO], [sr_package_version_micro], [.])
  74 AC_DEFINE_UNQUOTED([SR_PACKAGE_VERSION_STRING], ["$SR_PACKAGE_VERSION"], [.])
  75
  76 # Library version for libsigrok (NOT the same as the package version).
  77 # Carefully read the libtool docs before updating these numbers!
  78 # The algorithm for determining which number to change (and how) is nontrivial!
  79 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  80 SR_LIB_VERSION_CURRENT=2
  81 SR_LIB_VERSION_REVISION=0
  82 SR_LIB_VERSION_AGE=0
  83
  84 AC_SUBST([SR_LIB_VERSION], ["$SR_LIB_VERSION_CURRENT:$SR_LIB_VERSION_REVISION:$SR_LIB_VERSION_AGE"])
  85 AC_SUBST([SR_LIB_LDFLAGS], ["-version-info $SR_LIB_VERSION"])
  86
  87 AC_DEFINE_UNQUOTED([SR_LIB_VERSION_CURRENT], [$SR_LIB_VERSION_CURRENT], [.])
  88 AC_DEFINE_UNQUOTED([SR_LIB_VERSION_REVISION], [$SR_LIB_VERSION_REVISION], [.])
  89 AC_DEFINE_UNQUOTED([SR_LIB_VERSION_AGE], [$SR_LIB_VERSION_AGE], [.])
  90 AC_DEFINE_UNQUOTED([SR_LIB_VERSION_STRING], ["$SR_LIB_VERSION"], [.])
  91
  92 AC_ARG_ENABLE(all-drivers, AC_HELP_STRING([--enable-all-drivers],
  93         [enable all drivers by default [default=yes]]),
  94         [HW_ENABLED_DEFAULT="$enableval"],
  95         [HW_ENABLED_DEFAULT="yes"])
  96
  97 # Usage: DRIVER([Device name], [driver-name])
  98 # An optional third argument [no] disables that driver.
  99 m4_define([driverize], [m4_tolower(m4_bpatsubst([$1], [[^0-9a-zA-Z-]+], [-]))])
 100 m4_define([upperize], [m4_toupper(m4_bpatsubst([$1], [[^0-9a-zA-Z_]+], [_]))])
 101 AC_DEFUN([DRIVER], [
 102         if test -z "$3"; then
 103                 default=$HW_ENABLED_DEFAULT
 104         else
 105                 default="$3"
 106         fi
 107         AC_ARG_ENABLE($2, AC_HELP_STRING([--enable-$2], [enable $1 support]),
 108                 [m4_join([], [HW_], upperize([$2]))="$enableval"],
 109                 [m4_join([], [HW_], upperize([$2]))=$default])
 110         dots=$(echo -n ".............................." | cut -c 1-$(expr 32 - $(echo -n $2|wc -c)))
 111         driver_summary="${driver_summary}  - $2${dots} \${m4_join([], [HW_], upperize([$2]))}@"
 112 ])
 113
 114 DRIVER([Agilent DMM], [agilent-dmm])
 115 DRIVER([Appa 55II], [appa-55ii])
 116 DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma])
 117 DRIVER([Atten PPS3xxx], [atten-pps3xxx])
 118 DRIVER([BayLibre ACME], [baylibre-acme])
 119 DRIVER([BeagleLogic], [beaglelogic])
 120 DRIVER([Brymen BM86x], [brymen-bm86x])
 121 DRIVER([Brymen DMM], [brymen-dmm])
 122 DRIVER([CEM DT-885x], [cem-dt-885x])
 123 DRIVER([Center 3xx], [center-3xx])
 124 DRIVER([ChronoVu LA], [chronovu-la])
 125 DRIVER([Colead SLM], [colead-slm])
 126 DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu])
 127 DRIVER([DER EE DE-5000], [deree-de5000])
 128 DRIVER([demo], [demo])
 129 DRIVER([Fluke DMM], [fluke-dmm])
 130 DRIVER([fx2lafw], [fx2lafw])
 131 DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x])
 132 DRIVER([Hameg HMO], [hameg-hmo])
 133 DRIVER([Hantek DSO], [hantek-dso])
 134 DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2])
 135 DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus])
 136 DRIVER([Kecheng KC-330B], [kecheng-kc-330b])
 137 DRIVER([Lascar EL-USB], [lascar-el-usb])
 138 DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx])
 139 DRIVER([maynuo-m97], [maynuo-m97])
 140 DRIVER([MIC 985xx], [mic-985xx])
 141 DRIVER([Motech LPS 30x], [motech-lps-30x])
 142 DRIVER([Norma DMM], [norma-dmm])
 143 DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer])
 144 DRIVER([Pipistrello-OLS], [pipistrello-ols])
 145 DRIVER([Rigol DS], [rigol-ds])
 146 DRIVER([Saleae Logic16], [saleae-logic16])
 147 DRIVER([SCPI PPS], [scpi-pps])
 148 DRIVER([serial DMM], [serial-dmm])
 149 DRIVER([Sysclk LWLA], [sysclk-lwla])
 150 DRIVER([Teleinfo], [teleinfo])
 151 DRIVER([Testo], [testo])
 152 DRIVER([Tondaj SL-814], [tondaj-sl-814])
 153 DRIVER([UNI-T DMM], [uni-t-dmm])
 154 DRIVER([UNI-T UT32x], [uni-t-ut32x])
 155 DRIVER([Victor DMM], [victor-dmm])
 156 DRIVER([Yokogawa DL/DLM], [yokogawa-dlm])
 157 DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube])
 158
 159 AC_ARG_ENABLE(libserialport,
 160         AC_HELP_STRING([--disable-libserialport],
 161         [disable libserialport support [default=detect]]))
 162
 163 AC_ARG_ENABLE(libftdi,
 164         AC_HELP_STRING([--disable-libftdi],
 165         [disable libftdi support [default=detect]]))
 166
 167 AC_ARG_ENABLE(libusb,
 168         AC_HELP_STRING([--disable-libusb],
 169         [disable libusb support [default=detect]]))
 170
 171 # Language binding '--enable' options:
 172
 173 AC_ARG_ENABLE(bindings,
 174         AC_HELP_STRING([--enable-bindings],
 175         [build language bindings [default=yes]]),
 176         [BINDINGS_ALL="$enableval"], [BINDINGS_ALL="yes"])
 177
 178 AC_ARG_ENABLE(cxx,
 179         AC_HELP_STRING([--enable-cxx],
 180         [build C++ bindings [default=yes]]),
 181         [BINDINGS_CXX="$enableval"], [BINDINGS_CXX=$BINDINGS_ALL])
 182
 183 AC_ARG_ENABLE(python,
 184         AC_HELP_STRING([--enable-python],
 185         [build Python bindings [default=yes]]),
 186         [BINDINGS_PYTHON="$enableval"], [BINDINGS_PYTHON=$BINDINGS_ALL])
 187
 188 AC_ARG_ENABLE(java,
 189         AC_HELP_STRING([--enable-java],
 190         [build Java bindings [default=yes]]),
 191         [BINDINGS_JAVA="$enableval"], [BINDINGS_JAVA=$BINDINGS_ALL])
 192
 193 AC_ARG_WITH(jni-include-path,
 194         AC_HELP_STRING([--with-jni-include-path=path],
 195         [specify include path for JNI [default=autodetect]]),
 196         [JNI_INCLUDE_DIRS="$withval"], [JNI_INCLUDE_DIRS=auto])
 197
 198 # Check if the C++ compiler supports the C++11 standard.
 199
 200 m4_ifdef([AX_CXX_COMPILE_STDCXX_11], [AX_CXX_COMPILE_STDCXX_11(,[optional])],
 201         [AC_MSG_NOTICE([Missing macro m4_toupper(aX_CXX_COMPILE_STDCXX_11), no C++11 check])])
 202
 203 if test "x$HAVE_CXX11" != "x1"; then
 204         BINDINGS_CXX="no"; cxx_msg="C++11 compiler required"
 205 fi
 206
 207 # The C++ bindings use Doxygen to parse libsigrok symbols.
 208 AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes])
 209 if test "x$HAVE_DOXYGEN" != "xyes"; then
 210         BINDINGS_CXX="no"; cxx_msg="Doxygen required"
 211 fi
 212
 213 # Python is needed for the C++ bindings.
 214 AM_PATH_PYTHON([2.7], [HAVE_PYTHON="yes"],
 215         [HAVE_PYTHON="no"; BINDINGS_CXX="no"; cxx_msg="Python required"])
 216
 217 # The Python bindings need Python development files.
 218 PKG_CHECK_MODULES([python], [python >= 2.7],
 219         [CXXFLAGS="$CXXFLAGS $python_CFLAGS";
 220         CXXLIBS="$CXXLIBS $python_LIBS"],
 221 [PKG_CHECK_MODULES([python27], [python-2.7 >= 2.7],
 222         [CXXFLAGS="$CXXFLAGS $python27_CFLAGS";
 223         CXXLIBS="$CXXLIBS $python27_LIBS"],
 224                 [BINDINGS_PYTHON="no"; python_msg="Python headers required"])])
 225
 226 # The Python bindings need the setuptools Python module.
 227 m4_ifdef([AX_PYTHON_MODULE], [AX_PYTHON_MODULE([setuptools])],
 228         # We'll let it go through even if the macro wasn't found, the Python
 229         # module may still be there.
 230         [HAVE_PYTHON_SETUPTOOLS="yes";
 231                 AC_MSG_NOTICE([Missing macro m4_toupper(aX_PYTHON_MODULE), no setuptools check])]
 232 )
 233 if test "x$HAVE_PYMOD_SETUPTOOLS" != "xyes"; then
 234         BINDINGS_PYTHON="no"; python_msg="Python setuptools module required"
 235 fi
 236
 237 # The Python and Java bindings use SWIG to generate code.
 238 AC_CHECK_PROG([HAVE_SWIG], [swig], [yes])
 239 if test "x$HAVE_SWIG" != "xyes"; then
 240         BINDINGS_PYTHON="no"; python_msg="SWIG required"
 241         BINDINGS_JAVA="no"; java_msg="SWIG required"
 242 fi
 243
 244 # Checks for libraries.
 245
 246 case "$host" in
 247 *mingw*)
 248         # We need to link against the Winsock2 library for SCPI over TCP.
 249         LIBS="$LIBS -lws2_32";;
 250 esac
 251
 252 # This variable collects the pkg-config names of all detected libs.
 253 # It is then used to construct the "Requires.private:" field in the
 254 # libsigrok.pc file.
 255 SR_PKGLIBS=""
 256
 257 # libm (the standard math library) is always needed.
 258 AC_SEARCH_LIBS([pow], [m])
 259
 260 # RPC is only needed for VXI support.
 261 AC_MSG_CHECKING([for RPC support])
 262 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <rpc/rpc.h>],
 263                         [CLIENT *rpc_test(void)],
 264                         [{ return clnt_create("", 0, 0, ""); }])],
 265                 [AC_MSG_RESULT([yes]); have_rpc=1],
 266                 [AC_MSG_RESULT([no]);  have_rpc=0])
 267 # Define HAVE_RPC in config.h if we found RPC support.
 268 AC_DEFINE_UNQUOTED(HAVE_RPC, [$have_rpc], [Specifies whether we have RPC support.])
 269 # VXI support is only compiled if RPC support was found.
 270 AM_CONDITIONAL(NEED_RPC, test "x$have_rpc" != "x0")
 271
 272 AC_DEFINE_UNQUOTED(HOST, ["$host"], [.])
 273
 274 # libglib-2.0 is always needed. Abort if it's not found.
 275 # Note: glib-2.0 is part of the libsigrok API (hard pkg-config requirement).
 276 # We require at least 2.32.0 due to e.g. g_variant_new_fixed_array().
 277 AM_PATH_GLIB_2_0([2.32.0],
 278         [LIB_CFLAGS="$LIB_CFLAGS $GLIB_CFLAGS"; LIBS="$LIBS $GLIB_LIBS"])
 279
 280 # libzip is always needed. Abort if it's not found.
 281 PKG_CHECK_MODULES([libzip], [libzip >= 0.10],
 282         [LIB_CFLAGS="$LIB_CFLAGS $libzip_CFLAGS"; LIBS="$LIBS $libzip_LIBS";
 283         SR_PKGLIBS="$SR_PKGLIBS libzip"])
 284 libzip_ver=`$PKG_CONFIG --modversion libzip`
 285 AC_DEFINE_UNQUOTED(HAVE_LIBZIP_VER, ["$libzip_ver"], [.])
 286
 287 # libserialport is only needed for some hardware drivers. Disable the
 288 # respective drivers if it is not found.
 289 if test "x$enable_libserialport" != "xno"; then
 290         PKG_CHECK_MODULES([libserialport], [libserialport >= 0.1.1],
 291                 [have_libserialport="yes"; LIB_CFLAGS="$LIB_CFLAGS $libserialport_CFLAGS";
 292                 LIBS="$LIBS $libserialport_LIBS";
 293                 SR_PKGLIBS="$SR_PKGLIBS libserialport"],
 294                 [have_libserialport="no"])
 295         if test "x$enable_libserialport$have_libserialport" = "xyesno"; then
 296                 AC_MSG_ERROR([libserialport support requested, but it was not found.])
 297         fi
 298 else
 299         have_libserialport="no"
 300 fi
 301 if test "x$have_libserialport" = "xno"; then
 302         HW_AGILENT_DMM="no"; HW_APPA_55II="no";
 303         HW_ATTEN_PPS3XXX="no"; HW_BRYMEN_DMM="no"; HW_CEM_DT_885X="no";
 304         HW_CENTER_3XX="no"; HW_COLEAD_SLM="no"; HW_CONRAD_DIGI_35_CPU="no";
 305         HW_DEREE_DE5000="no"; HW_FLUKE_DMM="no"; HW_GMC_MH_1X_2X="no";
 306         HW_HAMEG_HMO="no"; HW_MANSON_HCS_3XXX="no"; HW_MIC_985XX="no";
 307         HW_MOTECH_LPS_30X="no"; HW_NORMA_DMM="no";
 308         HW_OPENBENCH_LOGIC_SNIFFER="no"; HW_SERIAL_DMM="no";
 309         HW_TELEINFO="no"; HW_TONDAJ_SL_814="no";
 310 else
 311         # Define HAVE_LIBSERIALPORT in config.h if we found libserialport.
 312         AC_DEFINE_UNQUOTED(HAVE_LIBSERIALPORT, [1],
 313                 [Specifies whether we have libserialport.])
 314 fi
 315
 316 # Serial port helper code is only compiled in if libserialport was found.
 317 AM_CONDITIONAL(NEED_SERIAL, test "x$have_libserialport" != xno)
 318
 319 # The VISA SCPI backend is only compiled in if librevisa was found.
 320 PKG_CHECK_MODULES([librevisa], [librevisa >= 0.0.20130412],
 321         [have_librevisa="yes"; LIB_CFLAGS="$LIB_CFLAGS $librevisa_CFLAGS";
 322         LIBS="$LIBS $librevisa_LIBS";
 323         SR_PKGLIBS="$SR_PKGLIBS librevisa"],
 324         [have_librevisa="no"])
 325 AM_CONDITIONAL(NEED_VISA, test "x$have_librevisa" != xno)
 326 if test "x$have_librevisa" != "xno"; then
 327         # Define HAVE_LIBREVISA in config.h if we found librevisa.
 328         AC_DEFINE_UNQUOTED(HAVE_LIBREVISA, [1],
 329                 [Specifies whether we have librevisa.])
 330         librevisa_ver=`$PKG_CONFIG --modversion librevisa`
 331         AC_DEFINE_UNQUOTED(HAVE_LIBREVISA_VER, ["$librevisa_ver"], [.])
 332 fi
 333
 334 # The GPIB SCPI backend is only compiled in if libgpib is found.
 335 PKG_CHECK_MODULES([libgpib], [libgpib],
 336         [have_libgpib="yes"; LIB_CFLAGS="$LIB_CFLAGS $libgpib_CFLAGS";
 337         LIBS="$LIBS $libgpib_LIBS";
 338         SR_PKGLIBS="$SR_PKGLIBS libgpib"],
 339         [have_libgpib="no"])
 340 AM_CONDITIONAL(NEED_GPIB, test "x$have_libgpib" != xno)
 341 if test "x$have_libgpib" != "xno"; then
 342         # Define HAVE_LIBGPIB in config.h if we found libgpib.
 343         AC_DEFINE_UNQUOTED(HAVE_LIBGPIB, [1],
 344                 [Specifies whether we have libgpib.])
 345         libgpib_ver=`$PKG_CONFIG --modversion libgpib`
 346         AC_DEFINE_UNQUOTED(HAVE_LIBGPIB_VER, ["$libgpib_ver"], [.])
 347 fi
 348
 349 # libusb-1.0 is only needed for some hardware drivers. Disable the respective
 350 # drivers if it is not found.
 351 if test "x$enable_libusb" != "xno"; then
 352         case "$host" in
 353         *freebsd*)
 354                 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
 355                 # This means libusb-1.0 is always available, no need to check for it,
 356                 # and no need to (potentially) disable any drivers if it's not found.
 357                 have_libusb1_0="yes"
 358                 ;;
 359         *)
 360                 PKG_CHECK_MODULES([libusb], [libusb-1.0 >= 1.0.16],
 361                         [have_libusb1_0="yes"; LIB_CFLAGS="$LIB_CFLAGS $libusb_CFLAGS";
 362                         LIBS="$LIBS $libusb_LIBS";
 363                         SR_PKGLIBS="$SR_PKGLIBS libusb-1.0"],
 364                         [have_libusb1_0="no"])
 365                 if test "x$enable_libusb$have_libusb1_0" = "xyesno"; then
 366                         AC_MSG_ERROR([libusb support requested, but it was not found.])
 367                 fi
 368                 ;;
 369         esac
 370 else
 371         have_libusb1_0="no"
 372 fi
 373 if test "x$have_libusb1_0" = "xno"; then
 374         HW_BRYMEN_BM86X="no"; HW_FX2LAFW="no";
 375         HW_HANTEK_DSO="no"; HW_IKALOGIC_SCANALOGIC2="no";
 376         HW_KECHENG_KC_330B="no"; HW_LASCAR_EL_USB="no";
 377         HW_SYSCLK_LWLA="no"; HW_TESTO="no"; HW_UNI_T_DMM="no";
 378         HW_UNI_T_UT32X="no"; HW_VICTOR_DMM="no";
 379         HW_ZEROPLUS_LOGIC_CUBE="no"; HW_SALEAE_LOGIC16="no";
 380 else
 381         # Define HAVE_LIBUSB_1_0 in config.h if we found libusb-1.0.
 382         AC_DEFINE_UNQUOTED(HAVE_LIBUSB_1_0, [1],
 383                 [Specifies whether we have libusb-1.0.])
 384 fi
 385
 386 # USB + FX2 firmware helper code is only compiled in if libusb-1.0 was found.
 387 AM_CONDITIONAL(NEED_USB, test "x$have_libusb1_0" != xno)
 388
 389 # libftdi is only needed for some hardware drivers. Disable them if not found.
 390 if test "x$enable_libftdi" != "xno"; then
 391         PKG_CHECK_MODULES([libftdi], [libftdi >= 0.16],
 392                 [have_libftdi="yes"; LIB_CFLAGS="$LIB_CFLAGS $libftdi_CFLAGS";
 393                 LIBS="$LIBS $libftdi_LIBS"; SR_PKGLIBS="$SR_PKGLIBS libftdi";
 394                 libftdi_ver=`$PKG_CONFIG --modversion libftdi`],
 395                 [PKG_CHECK_MODULES([libftdi1], [libftdi1 >= 1.0],
 396                         [LIB_CFLAGS="$LIB_CFLAGS $libftdi1_CFLAGS";
 397                         LIBS="$LIBS $libftdi1_LIBS";
 398                         SR_PKGLIBS="$SR_PKGLIBS libftdi1";
 399                         libftdi_ver=`$PKG_CONFIG --modversion libftdi1`],
 400                         [have_libftdi="no"])])
 401         if test "x$enable_libftdi$have_libftdi" = "xyesno"; then
 402                 AC_MSG_ERROR([libftdi support requested, but it was not found.])
 403         fi
 404 else
 405         have_libftdi="no"
 406 fi
 407 if test "x$have_libftdi" = "xno"; then
 408         HW_ASIX_SIGMA="no"; HW_CHRONOVU_LA="no"; HW_IKALOGIC_SCANAPLUS="no";
 409         HW_PIPISTRELLO_OLS="no";
 410 else
 411         # Define HAVE_LIBFTDI in config.h if we found libftdi.
 412         AC_DEFINE_UNQUOTED(HAVE_LIBFTDI, [1],
 413                 [Specifies whether we have libftdi.])
 414         AC_DEFINE_UNQUOTED(HAVE_LIBFTDI_VER, ["$libftdi_ver"], [.])
 415 fi
 416
 417 # glibmm-2.4 is needed for the C++ bindings.
 418 PKG_CHECK_MODULES([glibmm], [glibmm-2.4 >= 2.32.0],
 419         [CXXFLAGS="$CXXFLAGS $glibmm_CFLAGS";
 420         CXXLIBS="$CXXLIBS $glibmm_LIBS"],
 421         [BINDINGS_CXX="no"; cxx_msg="glibmm required"])
 422
 423 # C++ bindings want stoi and stod.
 424 if test "x$BINDINGS_CXX" = "xyes"; then
 425         AC_LANG_PUSH([C++])
 426         AC_MSG_CHECKING([for stoi and stod])
 427         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <string>],
 428                 [{ return std::stoi("1") + std::stod("1.0"); }])],
 429                 [AC_MSG_RESULT([yes]);
 430                 AC_DEFINE_UNQUOTED(HAVE_STOI_STOD, [1],
 431                 [Specifies whether we have the stoi and stod functions.])],
 432                 [AC_MSG_RESULT([no])])
 433         AC_LANG_POP([C++])
 434 fi
 435
 436 # PyGObject is needed for the Python bindings.
 437 PKG_CHECK_MODULES([pygobject], [pygobject-3.0 >= 3.0.0],
 438         [CXXFLAGS="$CXXFLAGS $pygobject_CFLAGS";
 439         CXXLIBS="$CXXLIBS $pygobject_LIBS";
 440         PKG_CHECK_MODULES([pygobject_3_7_91], [pygobject-3.0 >= 3.7.91],
 441                 [pyg_flags_signed=0], [pyg_flags_signed=1]);
 442         AC_DEFINE_UNQUOTED(PYGOBJECT_FLAGS_SIGNED, [$pyg_flags_signed],
 443                 [Whether last argument to pyg_flags_get_value() is signed.])],
 444         [BINDINGS_PYTHON="no"; python_msg="Python pygobject module required"])
 445
 446 # The Check unit testing framework is optional. Disable if not found.
 447 PKG_CHECK_MODULES([check], [check >= 0.9.4],
 448         [have_check="yes"], [have_check="no"])
 449 AM_CONDITIONAL(HAVE_CHECK, test x"$have_check" = "xyes")
 450
 451 # The BeagleLogic driver needs sys/mman.h and sys/ioctl.h. Don't try to
 452 # build it if these headers aren't available.
 453 AC_CHECK_HEADERS([sys/mman.h sys/ioctl.h], [], [HW_BEAGLELOGIC="no"])
 454
 455 # The BayLibre ACME driver needs sys/timerfd.h. Don't try to build it if
 456 # this header isn't available.
 457 AC_CHECK_HEADERS([sys/timerfd.h], [], [HW_BAYLIBRE_ACME="no"])
 458
 459 # The ACME driver can only be built for Linux.
 460 case "$host" in
 461         *linux*) ;;
 462         *) HW_BAYLIBRE_ACME="no" ;;
 463 esac
 464
 465 AC_SUBST(SR_PKGLIBS)
 466
 467 CFLAGS="$CFLAGS $LIB_CFLAGS"
 468 CXXFLAGS="$CXXFLAGS $LIB_CFLAGS"
 469
 470 # Find Java compiler and JNI includes for Java bindings.
 471 AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no])
 472 if test "x$HAVE_JAVAC" = "xyes" && test "x$BINDINGS_JAVA" = "xyes"; then
 473         AX_PROG_JAVAC
 474         if test "x$JNI_INCLUDE_DIRS" = "xauto"; then
 475                 if test "x$cross_compiling" = "xyes"; then
 476                         JNI_INCLUDE_DIRS=
 477                 else
 478                         AX_JNI_INCLUDE_DIR
 479                 fi
 480         fi
 481         for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS; do
 482                 CXXFLAGS="$CXXFLAGS -I$JNI_INCLUDE_DIR"
 483         done
 484         AC_LANG_PUSH([C++])
 485         AC_CHECK_HEADERS([jni.h], [], [BINDINGS_JAVA="no"; java_msg="Java JNI headers required"])
 486         AC_LANG_POP([C++])
 487 else
 488         BINDINGS_JAVA="no"; java_msg="Java compiler required"
 489 fi
 490
 491 # Python and Java bindings depend on C++ bindings.
 492 if test "x$BINDINGS_CXX" != "xyes"; then
 493         BINDINGS_PYTHON="no"; python_msg="C++ bindings required"
 494         BINDINGS_JAVA="no"; java_msg="C++ bindings required"
 495 fi
 496
 497 # Now set AM_CONDITIONALs and AC_DEFINEs for the enabled/disabled drivers.
 498
 499 AC_DEFUN([DRIVER2], [
 500         AM_CONDITIONAL($1, test "x$2" = "xyes")
 501         if test "x$2" = "xyes"; then AC_DEFINE($3, 1, [.]) fi
 502 ])
 503
 504 DRIVER2([HW_AGILENT_DMM], [$HW_AGILENT_DMM], [HAVE_HW_AGILENT_DMM])
 505 DRIVER2([HW_APPA_55II], [$HW_APPA_55II], [HAVE_HW_APPA_55II])
 506 DRIVER2([HW_ASIX_SIGMA], [$HW_ASIX_SIGMA], [HAVE_HW_ASIX_SIGMA])
 507 DRIVER2([HW_ATTEN_PPS3XXX], [$HW_ATTEN_PPS3XXX], [HAVE_HW_ATTEN_PPS3XXX])
 508 DRIVER2([HW_BAYLIBRE_ACME], [$HW_BAYLIBRE_ACME], [HAVE_HW_BAYLIBRE_ACME])
 509 DRIVER2([HW_BEAGLELOGIC], [$HW_BEAGLELOGIC], [HAVE_HW_BEAGLELOGIC])
 510 DRIVER2([HW_BRYMEN_BM86X], [$HW_BRYMEN_BM86X], [HAVE_HW_BRYMEN_BM86X])
 511 DRIVER2([HW_BRYMEN_DMM], [$HW_BRYMEN_DMM], [HAVE_HW_BRYMEN_DMM])
 512 DRIVER2([HW_CEM_DT_885X], [$HW_CEM_DT_885X], [HAVE_HW_CEM_DT_885X])
 513 DRIVER2([HW_CENTER_3XX], [$HW_CENTER_3XX], [HAVE_HW_CENTER_3XX])
 514 DRIVER2([HW_CHRONOVU_LA], [$HW_CHRONOVU_LA], [HAVE_HW_CHRONOVU_LA])
 515 DRIVER2([HW_COLEAD_SLM], [$HW_COLEAD_SLM], [HAVE_HW_COLEAD_SLM])
 516 DRIVER2([HW_CONRAD_DIGI_35_CPU], [$HW_CONRAD_DIGI_35_CPU], [HAVE_HW_CONRAD_DIGI_35_CPU])
 517 DRIVER2([HW_DEMO], [$HW_DEMO], [HAVE_HW_DEMO])
 518 DRIVER2([HW_DEREE_DE5000], [$HW_DEREE_DE5000], [HAVE_HW_DEREE_DE5000])
 519 DRIVER2([HW_FLUKE_DMM], [$HW_FLUKE_DMM], [HAVE_HW_FLUKE_DMM])
 520 DRIVER2([HW_FX2LAFW], [$HW_FX2LAFW], [HAVE_HW_FX2LAFW])
 521 DRIVER2([HW_GMC_MH_1X_2X], [$HW_GMC_MH_1X_2X], [HAVE_HW_GMC_MH_1X_2X])
 522 DRIVER2([HW_HAMEG_HMO], [$HW_HAMEG_HMO], [HAVE_HW_HAMEG_HMO])
 523 DRIVER2([HW_HANTEK_DSO], [$HW_HANTEK_DSO], [HAVE_HW_HANTEK_DSO])
 524 DRIVER2([HW_IKALOGIC_SCANALOGIC2], [$HW_IKALOGIC_SCANALOGIC2], [HAVE_HW_IKALOGIC_SCANALOGIC2])
 525 DRIVER2([HW_IKALOGIC_SCANAPLUS], [$HW_IKALOGIC_SCANAPLUS], [HAVE_HW_IKALOGIC_SCANAPLUS])
 526 DRIVER2([HW_KECHENG_KC_330B], [$HW_KECHENG_KC_330B], [HAVE_HW_KECHENG_KC_330B])
 527 DRIVER2([HW_LASCAR_EL_USB], [$HW_LASCAR_EL_USB], [HAVE_HW_LASCAR_EL_USB])
 528 DRIVER2([HW_MANSON_HCS_3XXX], [$HW_MANSON_HCS_3XXX], [HAVE_HW_MANSON_HCS_3XXX])
 529 DRIVER2([HW_MAYNUO_M97], [$HW_MAYNUO_M97], [HAVE_HW_MAYNUO_M97])
 530 DRIVER2([HW_MIC_985XX], [$HW_MIC_985XX], [HAVE_HW_MIC_985XX])
 531 DRIVER2([HW_MOTECH_LPS_30X], [$HW_MOTECH_LPS_30X], [HAVE_HW_MOTECH_LPS_30X])
 532 DRIVER2([HW_NORMA_DMM], [$HW_NORMA_DMM], [HAVE_HW_NORMA_DMM])
 533 DRIVER2([HW_OPENBENCH_LOGIC_SNIFFER], [$HW_OPENBENCH_LOGIC_SNIFFER], [HAVE_HW_OPENBENCH_LOGIC_SNIFFER])
 534 DRIVER2([HW_PIPISTRELLO_OLS], [$HW_PIPISTRELLO_OLS], [HAVE_HW_PIPISTRELLO_OLS])
 535 DRIVER2([HW_RIGOL_DS], [$HW_RIGOL_DS], [HAVE_HW_RIGOL_DS])
 536 DRIVER2([HW_SALEAE_LOGIC16], [$HW_SALEAE_LOGIC16], [HAVE_HW_SALEAE_LOGIC16])
 537 DRIVER2([HW_SCPI_PPS], [$HW_SCPI_PPS], [HAVE_HW_SCPI_PPS])
 538 DRIVER2([HW_SERIAL_DMM], [$HW_SERIAL_DMM], [HAVE_HW_SERIAL_DMM])
 539 DRIVER2([HW_SYSCLK_LWLA], [$HW_SYSCLK_LWLA], [HAVE_HW_SYSCLK_LWLA])
 540 DRIVER2([HW_TELEINFO], [$HW_TELEINFO], [HAVE_HW_TELEINFO])
 541 DRIVER2([HW_TESTO], [$HW_TESTO], [HAVE_HW_TESTO])
 542 DRIVER2([HW_TONDAJ_SL_814], [$HW_TONDAJ_SL_814], [HAVE_HW_TONDAJ_SL_814])
 543 DRIVER2([HW_UNI_T_DMM], [$HW_UNI_T_DMM], [HAVE_HW_UNI_T_DMM])
 544 DRIVER2([HW_UNI_T_UT32X], [$HW_UNI_T_UT32X], [HAVE_HW_UNI_T_UT32X])
 545 DRIVER2([HW_VICTOR_DMM], [$HW_VICTOR_DMM], [HAVE_HW_VICTOR_DMM])
 546 DRIVER2([HW_YOKOGAWA_DLM], [$HW_YOKOGAWA_DLM], [HAVE_HW_YOKOGAWA_DLM])
 547 DRIVER2([HW_ZEROPLUS_LOGIC_CUBE], [$HW_ZEROPLUS_LOGIC_CUBE], [HAVE_HW_ZEROPLUS_LOGIC_CUBE])
 548
 549 AM_CONDITIONAL(BINDINGS_CXX, test x$BINDINGS_CXX = xyes)
 550
 551 AM_CONDITIONAL(BINDINGS_PYTHON, test x$BINDINGS_PYTHON = xyes)
 552
 553 AM_CONDITIONAL(BINDINGS_JAVA, test x$BINDINGS_JAVA = xyes)
 554
 555 # Checks for header files.
 556 # These are already implicitly checked: inttypes.h stdint.h stdlib.h string.h
 557 # unistd.h memory.h strings.h dlfcn.h sys/types.h sys/stat.h.
 558
 559 # Checks for typedefs, structures, and compiler characteristics.
 560 AC_C_BIGENDIAN
 561
 562 AC_SUBST([FIRMWARE_DIR], ['$(datadir)/sigrok-firmware'])
 563 AC_SUBST(MAKEFLAGS, '--no-print-directory')
 564 AC_SUBST(AM_LIBTOOLFLAGS, '--silent')
 565
 566 AC_CONFIG_FILES([Makefile libsigrok.pc bindings/cxx/libsigrokcxx.pc])
 567
 568 AC_OUTPUT
 569
 570 echo
 571 echo "libsigrok configuration summary:"
 572 echo
 573 echo "  - Package version (major.minor.micro):    $SR_PACKAGE_VERSION"
 574 echo "  - Library version (current:revision:age): $SR_LIB_VERSION"
 575 echo "  - Prefix: $prefix"
 576 echo "  - Building on: $build"
 577 echo "  - Building for: $host"
 578 echo
 579 echo "Detected libraries:"
 580 echo
 581
 582 # Note: This only works for libs with pkg-config integration.
 583 for lib in "glib-2.0 >= 2.32.0" "libzip >= 0.10" "libserialport >= 0.1.1" \
 584         "librevisa >= 0.0.20130412" "libusb-1.0 >= 1.0.16" "libftdi >= 0.16" \
 585         "libftdi1 >= 1.0" "libgpib" "glibmm-2.4 >= 2.32.0" \
 586         "pygobject-3.0 >= 3.0.0" "check >= 0.9.4"
 587 do
 588         optional="OPTIONAL"
 589         if test "x$lib" = "xglib-2.0 >= 2.32.0"; then optional="REQUIRED"; fi
 590         if test "x$lib" = "xlibzip >= 0.10"; then optional="REQUIRED"; fi
 591         if `$PKG_CONFIG --exists $lib`; then
 592                 ver=`$PKG_CONFIG --modversion $lib`
 593                 answer="yes ($ver)"
 594         else
 595                 answer="no"
 596         fi
 597         echo "  - ($optional) $lib: $answer"
 598 done
 599
 600 eval echo -e "@Enabled hardware drivers:@@${driver_summary}" | tr @ \\n
 601
 602 # Prepare final bindings report messages.
 603 final_cxx=""
 604 final_python=""
 605 final_java=""
 606 if test "$enable_bindings" = "no"; then
 607         final_cxx=" (disabled)"
 608         final_python=" (disabled)"
 609         final_java=" (disabled)"
 610 else
 611         if test "$enable_cxx" = "no"; then
 612                 final_cxx=" (disabled)"
 613         elif test "$BINDINGS_CXX" = "no"; then
 614                 final_cxx=" ($cxx_msg)"
 615         fi
 616         if test "$enable_python" = "no"; then
 617                 final_python=" (disabled)"
 618         elif test "$BINDINGS_PYTHON" = "no"; then
 619                 final_python=" ($python_msg)"
 620         fi
 621         if test "$enable_java" = "no"; then
 622                 final_java=" (disabled)"
 623         elif test "$BINDINGS_JAVA" = "no"; then
 624                 final_java=" ($java_msg)"
 625         fi
 626 fi
 627
 628 echo "Enabled SCPI backends:"
 629 echo " - TCP............................. yes"
 630 if test "x$have_rpc" = "x0"; then
 631 echo " - RPC............................. no"
 632 else
 633 echo " - RPC............................. yes"
 634 fi
 635 echo " - serial.......................... $have_libserialport"
 636 echo " - VISA............................ $have_librevisa"
 637 echo " - GPIB............................ $have_libgpib"
 638 echo " - USBTMC.......................... $have_libusb1_0"
 639 echo
 640
 641 echo "Enabled language bindings:"
 642 echo " - C++............................. $BINDINGS_CXX$final_cxx"
 643 echo " - Python.......................... $BINDINGS_PYTHON$final_python"
 644 echo " - Java............................ $BINDINGS_JAVA$final_java"
 645 echo