configure.ac

   1 ##
   2 ## This file is part of the libsigrok project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 3 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 AC_INIT([libsigrok], [0.4.0],
  25         [sigrok-devel@lists.sourceforge.net],
  26         [libsigrok], [http://www.sigrok.org])
  27 AC_CONFIG_MACRO_DIR([m4])
  28 AC_CONFIG_AUX_DIR([autostuff])
  29 AC_CONFIG_HEADERS([config.h include/libsigrok/version.h])
  30
  31 # We require at least automake 1.11 (needed for 'silent rules').
  32 AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define nostdinc subdir-objects check-news color-tests])
  33 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  34 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  35
  36 AH_TOP([#ifndef SR_CONFIG_H
  37 #define SR_CONFIG_H    /* To stop multiple inclusions. */])
  38 AH_BOTTOM([#endif /* SR_CONFIG_H */])
  39
  40 # Enable more compiler warnings via -Wall and -Wextra. Add -fvisibility=hidden
  41 # and enforce use of SR_API to explicitly mark all public API functions.
  42 CFLAGS="$CFLAGS -std=c11"
  43 CFLAGS="$CFLAGS -fvisibility=hidden"
  44 CFLAGS="$CFLAGS -D_POSIX_C_SOURCE=200112L"
  45
  46 # Checks for programs.
  47 AC_PROG_CC
  48 AC_PROG_CPP
  49 AC_PROG_CXX
  50 AC_PROG_INSTALL
  51 AC_PROG_LN_S
  52
  53 # Required for per-target flags or subdir-objects with C sources.
  54 AM_PROG_CC_C_O
  55
  56 # Initialize libtool.
  57 LT_INIT
  58
  59 # Set up the libsigrok version defines.
  60 SR_PKG_VERSION_SET([SR_PACKAGE_VERSION], [AC_PACKAGE_VERSION])
  61
  62 # Library version for libsigrok (NOT the same as the package version).
  63 # Carefully read the libtool docs before updating these numbers!
  64 # The algorithm for determining which number to change (and how) is nontrivial!
  65 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  66 SR_LIB_VERSION_SET([SR_LIB_VERSION], [2:0:0])
  67
  68 #############################
  69 ##  Optional dependencies  ##
  70 #############################
  71
  72 # Initialize pkg-config.
  73 # We require at least 0.22, as "Requires.private" behaviour changed there.
  74 PKG_PROG_PKG_CONFIG([0.22])
  75
  76 # This variable collects the pkg-config module names of all dependencies.
  77 # These are used to derive the compiler flags and for the "Requires.private"
  78 # field in the generated libsigrok.pc file.
  79 SR_PKGLIBS=
  80 SR_PKGLIBS_CHECK=
  81 SR_PKGLIBS_CXX=
  82 SR_PKGLIBS_PYTHON=
  83
  84 # Keep track of all checked modules so we can list them at the end.
  85 sr_pkglibs_summary=
  86 sr_nl='
  87 '
  88 ## SR_PKG_CHECK(tag, [collect-var], module...)
  89 m4_define([SR_PKG_CHECK], [
  90         sr_mod_leader=`printf '%.32s' "$3................................"`
  91         PKG_CHECK_EXISTS([$3], [
  92                 sr_have_$1=yes
  93                 m4_ifval([$2], [$2="[$]$2[$]{$2:+ }$3"])
  94                 sr_$1_version=`$PKG_CONFIG --modversion "$3" 2>&AS_MESSAGE_LOG_FD`
  95                 AS_VAR_APPEND([sr_pkglibs_summary], [" - $sr_mod_leader $sr_$1_version$sr_nl"])
  96         ], [
  97                 AS_VAR_APPEND([sr_pkglibs_summary], [" - $sr_mod_leader no$sr_nl"])
  98                 m4_ifval([$4],
  99                         [SR_PKG_CHECK([$1], [$2], m4_shift3($@))],
 100                         [sr_have_$1=no sr_$1_version=])
 101         ])
 102 ])
 103
 104 # List of detected features.
 105 sr_deps_avail=
 106
 107 ## SR_ARG_OPT_PKG(opt-name, [cpp-name], [cond-name], module...)
 108 m4_define([SR_ARG_OPT_PKG], [
 109         AC_ARG_WITH([$1], [AS_HELP_STRING([--without-$1],
 110                         [disable $1 support [default=detect]])])
 111         AS_IF([test "x$with_$1" = xno], [sr_have_$1=no],
 112                 [test "x$sr_have_$1" != xyes],
 113                         [SR_PKG_CHECK([$1], [SR_PKGLIBS], m4_shift3($@))])
 114         AS_IF([test "x$with_$1$sr_have_$1" = xyesno],
 115                 [AC_MSG_ERROR([$1 support requested, but it was not found.])])
 116         AS_IF([test "x$sr_have_$1" = xyes],
 117                 [sr_deps_avail="$sr_deps_avail $1"[]m4_ifval([$2], [
 118                 AC_DEFINE([HAVE_$2], [1], [Whether $1 is available.])
 119                 AC_DEFINE_UNQUOTED([CONF_$2_VERSION], ["$sr_$1_version"], [Build-time version of $1.])
 120         ])])
 121         m4_ifval([$3], [AM_CONDITIONAL([$3], [test "x$sr_have_$1" = xyes])])
 122 ])
 123
 124 SR_ARG_OPT_PKG([libserialport], [LIBSERIALPORT], [NEED_SERIAL],
 125         [libserialport >= 0.1.1])
 126
 127 SR_ARG_OPT_PKG([libftdi], [LIBFTDI],,
 128         [libftdi >= 0.16], [libftdi1 >= 1.0])
 129
 130 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
 131 # This means libusb-1.0 is always available; no need to check for it.
 132 AS_CASE([$host], [*freebsd*], [sr_have_libusb=yes])
 133
 134 SR_ARG_OPT_PKG([libusb], [LIBUSB_1_0], [NEED_USB],
 135         [libusb-1.0 >= 1.0.16])
 136
 137 SR_ARG_OPT_PKG([librevisa], [LIBREVISA], [NEED_VISA],
 138         [librevisa >= 0.0.20130412])
 139
 140 SR_ARG_OPT_PKG([libgpib], [LIBGPIB], [NEED_GPIB],
 141         [libgpib])
 142
 143 ######################
 144 ##  Feature checks  ##
 145 ######################
 146
 147 # The Check unit testing framework is optional. Disable if not found.
 148 SR_PKG_CHECK([check], [SR_PKGLIBS_CHECK], [check >= 0.9.4])
 149 AM_CONDITIONAL([HAVE_CHECK], [test "x$sr_have_check" = xyes])
 150
 151 AC_LANG([C])
 152 SR_ARG_ENABLE_WARNINGS([SR_WFLAGS], [-Wall], [-Wall -Wextra -Wmissing-prototypes])
 153
 154 # Check host characteristics.
 155 AC_C_BIGENDIAN
 156
 157 AC_CHECK_HEADERS([sys/mman.h], [sr_deps_avail="$sr_deps_avail sys_mman_h"])
 158 AC_CHECK_HEADERS([sys/ioctl.h], [sr_deps_avail="$sr_deps_avail sys_ioctl_h"])
 159 AC_CHECK_HEADERS([sys/timerfd.h], [sr_deps_avail="$sr_deps_avail sys_timerfd_h"])
 160
 161 # RPC is only needed for VXI support.
 162 AC_CACHE_CHECK([for RPC support], [sr_cv_have_rpc],
 163         [AC_LINK_IFELSE([AC_LANG_PROGRAM(
 164                         [[#include <rpc/rpc.h>]m4_newline[CLIENT *rpc_test(void);]],
 165                         [[(void) clnt_create("", 0, 0, "");]])],
 166                 [sr_cv_have_rpc=yes], [sr_cv_have_rpc=no])])
 167 AS_IF([test "x$sr_cv_have_rpc" = xyes],
 168         [AC_DEFINE([HAVE_RPC], [1], [Specifies whether we have RPC support.])])
 169 # VXI support is only compiled if RPC support was found.
 170 AM_CONDITIONAL([NEED_RPC], [test "x$sr_cv_have_rpc" = xyes])
 171
 172 ########################
 173 ##  Hardware drivers  ##
 174 ########################
 175
 176 # Keep track of all drivers so we can list them at the end.
 177 sr_driver_summary=
 178
 179 # Check whether the sr_deps_avail list contains all of the arguments.
 180 # Unavailable dependencies are collected in sr_deps_missing.
 181 sr_check_driver_deps() {
 182         sr_deps_missing=
 183         for sr_dep
 184         do
 185                 AS_CASE([" $sr_deps_avail "], [*" $sr_dep "*],,
 186                         [sr_deps_missing="$sr_deps_missing $sr_dep"])
 187         done
 188 }
 189
 190 AC_ARG_ENABLE([all-drivers],
 191         [AS_HELP_STRING([--enable-all-drivers],
 192                         [enable all drivers by default [default=yes]])],
 193         [], [enable_all_drivers=yes])
 194
 195 ## _SR_DRIVER(Device name, driver-name, var-name, [dependencies...])
 196 m4_define([_SR_DRIVER], [
 197         AC_ARG_ENABLE([$2],
 198                 [AS_HELP_STRING([--enable-$2], [enable $1 support])],
 199                 [$3=$enableval], [$3=$enable_all_drivers])
 200
 201         AS_IF([test "x[$]$3" = xyes], [sr_hw_info=yes[]m4_ifval([$4], [
 202                 sr_check_driver_deps $4
 203                 AS_IF([test -n "$sr_deps_missing"],
 204                         [$3=no sr_hw_info="no (missing:$sr_deps_missing)"])
 205         ])], [sr_hw_info='no (disabled)'])
 206         sr_hw_leader=`printf '%.32s' "$2................................"`
 207         AS_VAR_APPEND([sr_driver_summary], [" - $sr_hw_leader $sr_hw_info$sr_nl"])
 208
 209         AM_CONDITIONAL([$3], [test "x[$]$3" = xyes])
 210         AM_COND_IF([$3], [AC_DEFINE([HAVE_$3], [1], [Whether to support $1 device.])])
 211 ])
 212
 213 ## SR_DRIVER(Device name, driver-name, [dependencies...])
 214 m4_define([SR_DRIVER],
 215         [_SR_DRIVER([$1], [$2], m4_expand([AS_TR_CPP([HW_$2])]), [$3])])
 216
 217 SR_DRIVER([Agilent DMM], [agilent-dmm], [libserialport])
 218 SR_DRIVER([Appa 55II], [appa-55ii], [libserialport])
 219 SR_DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma], [libftdi])
 220 SR_DRIVER([Atten PPS3xxx], [atten-pps3xxx], [libserialport])
 221 SR_DRIVER([BayLibre ACME], [baylibre-acme], [sys_timerfd_h])
 222 SR_DRIVER([BeagleLogic], [beaglelogic], [sys_mman_h sys_ioctl_h])
 223 SR_DRIVER([Brymen BM86x], [brymen-bm86x], [libusb])
 224 SR_DRIVER([Brymen DMM], [brymen-dmm], [libserialport])
 225 SR_DRIVER([CEM DT-885x], [cem-dt-885x], [libserialport])
 226 SR_DRIVER([Center 3xx], [center-3xx], [libserialport])
 227 SR_DRIVER([ChronoVu LA], [chronovu-la], [libftdi])
 228 SR_DRIVER([Colead SLM], [colead-slm], [libserialport])
 229 SR_DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu], [libserialport])
 230 SR_DRIVER([DER EE DE-5000], [deree-de5000], [libserialport])
 231 SR_DRIVER([demo], [demo])
 232 SR_DRIVER([Fluke DMM], [fluke-dmm], [libserialport])
 233 SR_DRIVER([fx2lafw], [fx2lafw], [libusb])
 234 SR_DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x], [libserialport])
 235 SR_DRIVER([Hameg HMO], [hameg-hmo], [libserialport])
 236 SR_DRIVER([Hantek DSO], [hantek-dso], [libusb])
 237 SR_DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2], [libusb])
 238 SR_DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus], [libftdi])
 239 SR_DRIVER([Kecheng KC-330B], [kecheng-kc-330b], [libusb])
 240 SR_DRIVER([Lascar EL-USB], [lascar-el-usb], [libusb])
 241 SR_DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx], [libserialport])
 242 SR_DRIVER([maynuo-m97], [maynuo-m97])
 243 SR_DRIVER([MIC 985xx], [mic-985xx], [libserialport])
 244 SR_DRIVER([Motech LPS 30x], [motech-lps-30x], [libserialport])
 245 SR_DRIVER([Norma DMM], [norma-dmm], [libserialport])
 246 SR_DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer], [libserialport])
 247 SR_DRIVER([Pipistrello-OLS], [pipistrello-ols], [libftdi])
 248 SR_DRIVER([Rigol DS], [rigol-ds])
 249 SR_DRIVER([Saleae Logic16], [saleae-logic16], [libusb])
 250 SR_DRIVER([SCPI PPS], [scpi-pps])
 251 SR_DRIVER([serial DMM], [serial-dmm], [libserialport])
 252 SR_DRIVER([Sysclk LWLA], [sysclk-lwla], [libusb])
 253 SR_DRIVER([Teleinfo], [teleinfo], [libserialport])
 254 SR_DRIVER([Testo], [testo], [libusb])
 255 SR_DRIVER([Tondaj SL-814], [tondaj-sl-814], [libserialport])
 256 SR_DRIVER([UNI-T DMM], [uni-t-dmm], [libusb])
 257 SR_DRIVER([UNI-T UT32x], [uni-t-ut32x], [libusb])
 258 SR_DRIVER([Victor DMM], [victor-dmm], [libusb])
 259 SR_DRIVER([Yokogawa DL/DLM], [yokogawa-dlm])
 260 SR_DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube], [libusb])
 261
 262 ###############################
 263 ##  Language bindings setup  ##
 264 ###############################
 265
 266 AC_LANG([C++])
 267 SR_ARG_ENABLE_WARNINGS([SR_WXXFLAGS], [-Wall], [-Wall -Wextra])
 268
 269 AC_ARG_ENABLE([bindings],
 270         [AS_HELP_STRING([--enable-bindings], [build language bindings [default=yes]])],
 271         [], [enable_bindings=yes])
 272
 273 AC_ARG_ENABLE([cxx],
 274         [AS_HELP_STRING([--enable-cxx], [build C++ bindings [default=yes]])],
 275         [], [enable_cxx=$enable_bindings])
 276
 277 AC_ARG_ENABLE([python],
 278         [AS_HELP_STRING([--enable-python], [build Python bindings [default=yes]])],
 279         [], [enable_python=$enable_bindings])
 280
 281 AC_ARG_ENABLE([java],
 282         [AS_HELP_STRING([--enable-java], [build Java bindings [default=yes]])],
 283         [], [enable_java=$enable_bindings])
 284
 285 ####################
 286 ##  C++ bindings  ##
 287 ####################
 288
 289 sr_cxx_missing=
 290
 291 # Check if the C++ compiler supports the C++11 standard.
 292 m4_ifdef([AX_CXX_COMPILE_STDCXX_11],
 293         [AX_CXX_COMPILE_STDCXX_11(, [optional])],
 294         [m4_warn([unsupported], [Missing macro AX_CXX_COMPILE_STDCXX_11: no C++11 check possible])])
 295 test "x$HAVE_CXX11" = x1 || sr_cxx_missing="$sr_cxx_missing C++11"
 296
 297 # The C++ bindings need glibmm.
 298 SR_PKG_CHECK([glibmm], [SR_PKGLIBS_CXX], [glibmm-2.4 >= 2.32.0])
 299 test "x$sr_have_glibmm" = xyes || sr_cxx_missing="$sr_cxx_missing glibmm"
 300
 301 # The C++ bindings use Doxygen to parse libsigrok symbols.
 302 AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes], [no])
 303 test "x$HAVE_DOXYGEN" = xyes || sr_cxx_missing="$sr_cxx_missing Doxygen"
 304
 305 # Python is needed for the C++ bindings.
 306 AM_PATH_PYTHON([2.7],
 307         [HAVE_PYTHON=yes],
 308         [HAVE_PYTHON=no sr_cxx_missing="$sr_cxx_missing Python"])
 309
 310 AS_IF([test -z "$sr_cxx_missing"],
 311         [BINDINGS_CXX=$enable_cxx], [BINDINGS_CXX=no])
 312 AM_CONDITIONAL([BINDINGS_CXX], [test "x$BINDINGS_CXX" = xyes])
 313
 314 # C++ bindings want stoi and stod.
 315 AM_COND_IF([BINDINGS_CXX], [
 316         AC_CACHE_CHECK([for stoi and stod], [sr_cv_have_stoi_stod],
 317                 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string>]],
 318                                 [[(void) std::stoi("1"); (void) std::stod("1.0");]])],
 319                         [sr_cv_have_stoi_stod=yes], [sr_cv_have_stoi_stod=no])])
 320         AS_IF([test "x$sr_cv_have_stoi_stod" = xyes],
 321                 [AC_DEFINE([HAVE_STOI_STOD], [1],
 322                         [Specifies whether we have the stoi and stod functions.])])
 323 ])
 324
 325 #######################
 326 ##  Python bindings  ##
 327 #######################
 328
 329 sr_python_missing=
 330 test "x$BINDINGS_CXX" = xyes || sr_python_missing=" C++ bindings"
 331
 332 # The Python bindings need Python development files.
 333 SR_PKG_CHECK([python_dev], [SR_PKGLIBS_PYTHON],
 334         [python >= 2.7], [python2 >= 2.7], [python27 >= 2.7])
 335 test "x$sr_have_python_dev" = xyes \
 336         || sr_python_missing="$sr_python_missing Headers"
 337
 338 # PyGObject is needed for the Python bindings.
 339 SR_PKG_CHECK([pygobject], [SR_PKGLIBS_PYTHON], [pygobject-3.0 >= 3.0.0])
 340 test "x$sr_have_python_dev" = xyes \
 341         || sr_python_missing="$sr_python_missing PyGObject"
 342
 343 PKG_CHECK_EXISTS([pygobject-3.0 < 3.7.91],
 344         [AC_DEFINE([PYGOBJECT_FLAGS_SIGNED], [1],
 345                 [Whether last argument to pyg_flags_get_value() is signed.])])
 346
 347 # The Python bindings need the setuptools Python module.
 348 # We'll let it go through even if the AX macro wasn't found,
 349 # as the Python module may still be there.
 350 HAVE_PYMOD_SETUPTOOLS=yes
 351 m4_ifdef([AX_PYTHON_MODULE],
 352         [AX_PYTHON_MODULE([setuptools])],
 353         [m4_warn([unsupported], [Missing macro AX_PYTHON_MODULE: no setuptools check])])
 354 test "x$HAVE_PYMOD_SETUPTOOLS" = xyes \
 355         || sr_python_missing="$sr_python_missing Setuptools"
 356
 357 # The Python bindings use SWIG to generate code.
 358 AC_CHECK_PROGS([SWIG], [swig swig2.0 swig3.0], [no])
 359 test "x$SWIG" != xno || sr_python_missing="$sr_python_missing SWIG"
 360
 361 AS_IF([test -z "$sr_python_missing"],
 362         [BINDINGS_PYTHON=$enable_python], [BINDINGS_PYTHON=no])
 363 AM_CONDITIONAL([BINDINGS_PYTHON], [test "x$BINDINGS_PYTHON" = xyes])
 364
 365 ####################
 366 ##  Java bindings ##
 367 ####################
 368
 369 sr_java_missing=
 370 test "x$BINDINGS_CXX" = xyes || sr_java_missing=" C++ bindings"
 371
 372 # The Java bindings use SWIG to generate code.
 373 test "x$SWIG" != xno || sr_java_missing="$sr_java_missing SWIG"
 374
 375 # Find Java compiler and JNI includes for Java bindings.
 376 AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no])
 377 test "x$HAVE_JAVAC" = xyes || sr_java_missing="$sr_java_missing JavaC"
 378
 379 AC_ARG_WITH([jni-include-path],
 380         [AS_HELP_STRING([[--with-jni-include-path=DIR-LIST (space-separated)]],
 381                 [specify JNI include directories [default=detect]])],
 382         [JNI_INCLUDE_DIRS=" $withval"], [JNI_INCLUDE_DIRS=])
 383
 384 JNI_CPPFLAGS=
 385 AS_IF([test "x$enable_java$HAVE_JAVAC" = xyesyes], [
 386         AX_PROG_JAVAC
 387         AS_IF([test -z "$JNI_INCLUDE_DIRS" && test "x$cross_compiling" != xyes], [
 388                 ## Work around the totally broken logic in AX_JNI_INCLUDE_DIR:
 389                 ## If we can find jni.h without any special search path, skip
 390                 ## the execution of the broken macro to increase our chances of
 391                 ## success.
 392                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <jni.h>]], [])],,
 393                         [AX_JNI_INCLUDE_DIR])
 394         ])
 395 ])
 396 for sr_dir in $JNI_INCLUDE_DIRS
 397 do
 398         JNI_CPPFLAGS="$JNI_CPPFLAGS -I$sr_dir"
 399 done
 400 AC_SUBST([JNI_CPPFLAGS])
 401
 402 sr_save_cppflags=$CPPFLAGS
 403 CPPFLAGS=$CPPFLAGS$JNI_CPPFLAGS
 404 AC_CHECK_HEADER([jni.h],, [sr_java_missing="$sr_java_missing JNI headers"])
 405 CPPFLAGS=$sr_save_cppflags
 406
 407 AS_IF([test -z "$sr_java_missing"],
 408         [BINDINGS_JAVA=$enable_java], [BINDINGS_JAVA=no])
 409 AM_CONDITIONAL([BINDINGS_JAVA], [test "x$BINDINGS_JAVA" = xyes])
 410
 411 ##############################
 412 ##  Finalize configuration  ##
 413 ##############################
 414
 415 # Add mandatory dependencies to module list.
 416 SR_PKGLIBS="$SR_PKGLIBS${SR_PKGLIBS:+ }libzip >= 0.10"
 417 AC_SUBST([SR_PKGLIBS])
 418
 419 # Retrieve the compile and link flags for all modules combined.
 420 # Also, bail out at this point if any module dependency is not met.
 421 PKG_CHECK_MODULES([LIBSIGROK], [glib-2.0 >= 2.32.0 $SR_PKGLIBS])
 422 PKG_CHECK_MODULES([CHECK], [$SR_PKGLIBS_CHECK glib-2.0 $SR_PKGLIBS])
 423
 424 # SR_PKGLIBS_CXX may be empty, so only invoke these checks when
 425 # the C++ bindings are enabled.
 426 AM_COND_IF([BINDINGS_CXX], [
 427         PKG_CHECK_MODULES([LIBSIGROKCXX], [$SR_PKGLIBS_CXX])
 428         PKG_CHECK_MODULES([PYSIGROK], [$SR_PKGLIBS_PYTHON $SR_PKGLIBS_CXX])
 429 ])
 430 sr_glib_version=`$PKG_CONFIG --modversion glib-2.0 2>&AS_MESSAGE_LOG_FD`
 431 sr_libzip_version=`$PKG_CONFIG --modversion libzip 2>&AS_MESSAGE_LOG_FD`
 432
 433 AC_DEFINE_UNQUOTED([CONF_LIBZIP_VERSION], ["$sr_libzip_version"],
 434         [Build-time version of libzip.])
 435 AC_DEFINE_UNQUOTED([CONF_HOST], ["$host"],
 436         [The canonical host libsigrok will run on.])
 437
 438 AC_LANG([C])
 439
 440 # libm (the standard math library) is always needed.
 441 AC_SEARCH_LIBS([pow], [m])
 442
 443 # We need to link against the Winsock2 library for SCPI over TCP.
 444 AS_CASE([$host], [*mingw*], [LIBS="$LIBS -lws2_32"])
 445
 446 AC_SUBST([FIRMWARE_DIR], ['$(datadir)/sigrok-firmware'])
 447 AC_SUBST([MAKEFLAGS], ['--no-print-directory'])
 448 AC_SUBST([AM_LIBTOOLFLAGS], ['--silent'])
 449
 450 AC_CONFIG_FILES([Makefile libsigrok.pc bindings/cxx/libsigrokcxx.pc])
 451
 452 AC_OUTPUT
 453
 454 # Prepare bindings report messages.
 455 m4_define([SR_PREPARE_BINDING_REPORT], [
 456         sr_report_$1=
 457         test -z "$sr_$1_missing" || sr_report_$1=" (missing:$sr_$1_missing)"
 458         test "x$enable_$1" = xyes || sr_report_$1=' (disabled)'
 459 ])
 460 m4_map_args([SR_PREPARE_BINDING_REPORT], [cxx], [python], [java])
 461
 462 cat >&AS_MESSAGE_FD <<_EOF
 463
 464 libsigrok configuration summary:
 465  - Package version................. $SR_PACKAGE_VERSION
 466  - Library ABI version............. $SR_LIB_VERSION
 467  - Prefix.......................... $prefix
 468  - Building on..................... $build
 469  - Building for.................... $host
 470  - C compiler warnings............. $SR_WFLAGS
 471  - C++ compiler warnings........... $SR_WXXFLAGS
 472
 473 Detected libraries (required):
 474  - glib-2.0 >= 2.32.0.............. $sr_glib_version
 475  - libzip >= 0.10.................. $sr_libzip_version
 476
 477 Detected libraries (optional):
 478 $sr_pkglibs_summary
 479
 480 Enabled hardware drivers:
 481 $sr_driver_summary
 482
 483 Enabled SCPI backends:
 484  - TCP............................. yes
 485  - RPC............................. $sr_cv_have_rpc
 486  - serial.......................... $sr_have_libserialport
 487  - VISA............................ $sr_have_librevisa
 488  - GPIB............................ $sr_have_libgpib
 489  - USBTMC.......................... $sr_have_libusb
 490
 491 Enabled language bindings:
 492  - C++............................. $BINDINGS_CXX$sr_report_cxx
 493  - Python.......................... $BINDINGS_PYTHON$sr_report_python
 494  - Java............................ $BINDINGS_JAVA$sr_report_java
 495
 496 _EOF