configure.ac

   1 ##
   2 ## This file is part of the libsigrok project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 3 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 AC_INIT([libsigrok], [0.4.0],
  25         [sigrok-devel@lists.sourceforge.net],
  26         [libsigrok], [http://www.sigrok.org])
  27 AC_CONFIG_MACRO_DIR([m4])
  28 AC_CONFIG_AUX_DIR([autostuff])
  29 AC_CONFIG_HEADERS([config.h include/libsigrok/version.h])
  30
  31 # We require at least automake 1.11 (needed for 'silent rules').
  32 AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define nostdinc subdir-objects check-news color-tests])
  33 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  34 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  35
  36 AH_TOP([#ifndef SR_CONFIG_H
  37 #define SR_CONFIG_H    /* To stop multiple inclusions. */])
  38 AH_BOTTOM([#endif /* SR_CONFIG_H */])
  39
  40 # Checks for programs.
  41 AC_PROG_CC
  42 AC_PROG_CPP
  43 AC_PROG_CXX
  44 AC_PROG_INSTALL
  45 AC_PROG_LN_S
  46
  47 # Required for per-target flags or subdir-objects with C sources.
  48 AM_PROG_CC_C_O
  49
  50 # Initialize libtool.
  51 LT_INIT
  52
  53 # Set up the libsigrok version defines.
  54 SR_PKG_VERSION_SET([SR_PACKAGE_VERSION], [AC_PACKAGE_VERSION])
  55
  56 # Library version for libsigrok (NOT the same as the package version).
  57 # Carefully read the libtool docs before updating these numbers!
  58 # The algorithm for determining which number to change (and how) is nontrivial!
  59 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  60 SR_LIB_VERSION_SET([SR_LIB_VERSION], [2:0:0])
  61
  62 #############################
  63 ##  Optional dependencies  ##
  64 #############################
  65
  66 # Initialize pkg-config.
  67 # We require at least 0.22, as "Requires.private" behaviour changed there.
  68 PKG_PROG_PKG_CONFIG([0.22])
  69
  70 # Keep track of all checked modules so we can list them at the end.
  71 SR_PKG_CHECK_SUMMARY([sr_pkglibs_summary])
  72
  73 # Collect the pkg-config module names of all dependencies in SR_PKGLIBS.
  74 # These are used to derive the compiler flags and for the "Requires.private"
  75 # field in the generated libsigrok.pc file.
  76 SR_VAR_OPT_PKG([SR_PKGLIBS], [sr_deps_avail])
  77 SR_PKGLIBS_CHECK=
  78 SR_PKGLIBS_CXX=
  79 SR_PKGLIBS_PYTHON=
  80
  81 SR_ARG_OPT_PKG([libserialport], [LIBSERIALPORT], [NEED_SERIAL],
  82         [libserialport >= 0.1.1])
  83
  84 SR_ARG_OPT_PKG([libftdi], [LIBFTDI],,
  85         [libftdi >= 0.16], [libftdi1 >= 1.0])
  86
  87 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
  88 # This means libusb-1.0 is always available; no need to check for it.
  89 AS_CASE([$host], [*freebsd*], [sr_have_libusb=yes])
  90
  91 SR_ARG_OPT_PKG([libusb], [LIBUSB_1_0], [NEED_USB],
  92         [libusb-1.0 >= 1.0.16])
  93
  94 SR_ARG_OPT_PKG([librevisa], [LIBREVISA], [NEED_VISA],
  95         [librevisa >= 0.0.20130412])
  96
  97 SR_ARG_OPT_PKG([libgpib], [LIBGPIB], [NEED_GPIB],
  98         [libgpib])
  99
 100 ######################
 101 ##  Feature checks  ##
 102 ######################
 103
 104 # The Check unit testing framework is optional. Disable if not found.
 105 SR_PKG_CHECK([check], [SR_PKGLIBS_CHECK], [check >= 0.9.4])
 106 AM_CONDITIONAL([HAVE_CHECK], [test "x$sr_have_check" = xyes])
 107
 108 AC_LANG([C])
 109
 110 # Enable the C11 standard if possible, and enforce the use
 111 # of SR_API to explicitly mark all public API functions.
 112 SR_EXTRA_CFLAGS=
 113 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [C11], [-std=gnu11 -std=c11])
 114 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [visibility], [-fvisibility=hidden])
 115
 116 SR_ARG_ENABLE_WARNINGS([SR_WFLAGS], [-Wall], [-Wall -Wextra -Wmissing-prototypes])
 117
 118 # Check host characteristics.
 119 AC_C_BIGENDIAN
 120
 121 AC_CHECK_HEADERS([sys/mman.h], [SR_APPEND([sr_deps_avail], [sys_mman_h])])
 122 AC_CHECK_HEADERS([sys/ioctl.h], [SR_APPEND([sr_deps_avail], [sys_ioctl_h])])
 123 AC_CHECK_HEADERS([sys/timerfd.h], [SR_APPEND([sr_deps_avail], [sys_timerfd_h])])
 124
 125 # RPC is only needed for VXI support.
 126 AC_CACHE_CHECK([for RPC support], [sr_cv_have_rpc],
 127         [AC_LINK_IFELSE([AC_LANG_PROGRAM(
 128                         [[#include <rpc/rpc.h>]m4_newline[CLIENT *rpc_test(void);]],
 129                         [[(void) clnt_create("", 0, 0, "");]])],
 130                 [sr_cv_have_rpc=yes], [sr_cv_have_rpc=no])])
 131 AS_IF([test "x$sr_cv_have_rpc" = xyes],
 132         [AC_DEFINE([HAVE_RPC], [1], [Specifies whether we have RPC support.])])
 133 # VXI support is only compiled if RPC support was found.
 134 AM_CONDITIONAL([NEED_RPC], [test "x$sr_cv_have_rpc" = xyes])
 135
 136 ########################
 137 ##  Hardware drivers  ##
 138 ########################
 139
 140 # Keep track of all drivers so we can list them at the end.
 141 SR_VAR_SUMMARY([sr_driver_summary])
 142
 143 # Check whether the sr_deps_avail list contains all of the arguments.
 144 # Unavailable dependencies are collected in sr_deps_missing.
 145 sr_check_driver_deps() {
 146         sr_deps_missing=
 147         for sr_dep
 148         do
 149                 AS_CASE([" $sr_deps_avail "], [*" $sr_dep "*],,
 150                         [SR_APPEND([sr_deps_missing], [', '], [$sr_dep])])
 151         done
 152 }
 153
 154 AC_ARG_ENABLE([all-drivers],
 155         [AS_HELP_STRING([--enable-all-drivers],
 156                         [enable all drivers by default [default=yes]])],
 157         [], [enable_all_drivers=yes])
 158
 159 ## _SR_DRIVER(Device name, driver-name, var-name, [dependencies...])
 160 m4_define([_SR_DRIVER], [
 161         AC_ARG_ENABLE([$2],
 162                 [AS_HELP_STRING([--enable-$2], [enable $1 support])],
 163                 [$3=$enableval], [$3=$enable_all_drivers])
 164
 165         AS_IF([test "x[$]$3" = xyes], [sr_hw_info=yes[]m4_ifval([$4], [
 166                 sr_check_driver_deps $4
 167                 AS_IF([test -n "$sr_deps_missing"],
 168                         [$3=no sr_hw_info="no (missing: $sr_deps_missing)"])
 169         ])], [sr_hw_info='no (disabled)'])
 170         sr_driver_summary_append "$2" "$sr_hw_info"
 171
 172         AM_CONDITIONAL([$3], [test "x[$]$3" = xyes])
 173         AM_COND_IF([$3], [AC_DEFINE([HAVE_$3], [1], [Whether to support $1 device.])])
 174 ])
 175
 176 ## SR_DRIVER(Device name, driver-name, [dependencies...])
 177 m4_define([SR_DRIVER],
 178         [_SR_DRIVER([$1], [$2], m4_expand([AS_TR_CPP([HW_$2])]), [$3])])
 179
 180 SR_DRIVER([Agilent DMM], [agilent-dmm], [libserialport])
 181 SR_DRIVER([Appa 55II], [appa-55ii], [libserialport])
 182 SR_DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma], [libftdi])
 183 SR_DRIVER([Atten PPS3xxx], [atten-pps3xxx], [libserialport])
 184 SR_DRIVER([BayLibre ACME], [baylibre-acme], [sys_timerfd_h])
 185 SR_DRIVER([BeagleLogic], [beaglelogic], [sys_mman_h sys_ioctl_h])
 186 SR_DRIVER([Brymen BM86x], [brymen-bm86x], [libusb])
 187 SR_DRIVER([Brymen DMM], [brymen-dmm], [libserialport])
 188 SR_DRIVER([CEM DT-885x], [cem-dt-885x], [libserialport])
 189 SR_DRIVER([Center 3xx], [center-3xx], [libserialport])
 190 SR_DRIVER([ChronoVu LA], [chronovu-la], [libftdi])
 191 SR_DRIVER([Colead SLM], [colead-slm], [libserialport])
 192 SR_DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu], [libserialport])
 193 SR_DRIVER([DER EE DE-5000], [deree-de5000], [libserialport])
 194 SR_DRIVER([demo], [demo])
 195 SR_DRIVER([Fluke DMM], [fluke-dmm], [libserialport])
 196 SR_DRIVER([fx2lafw], [fx2lafw], [libusb])
 197 SR_DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x], [libserialport])
 198 SR_DRIVER([Hameg HMO], [hameg-hmo], [libserialport])
 199 SR_DRIVER([Hantek DSO], [hantek-dso], [libusb])
 200 SR_DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2], [libusb])
 201 SR_DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus], [libftdi])
 202 SR_DRIVER([Kecheng KC-330B], [kecheng-kc-330b], [libusb])
 203 SR_DRIVER([Lascar EL-USB], [lascar-el-usb], [libusb])
 204 SR_DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx], [libserialport])
 205 SR_DRIVER([maynuo-m97], [maynuo-m97])
 206 SR_DRIVER([MIC 985xx], [mic-985xx], [libserialport])
 207 SR_DRIVER([Motech LPS 30x], [motech-lps-30x], [libserialport])
 208 SR_DRIVER([Norma DMM], [norma-dmm], [libserialport])
 209 SR_DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer], [libserialport])
 210 SR_DRIVER([Pipistrello-OLS], [pipistrello-ols], [libftdi])
 211 SR_DRIVER([Rigol DS], [rigol-ds])
 212 SR_DRIVER([Saleae Logic16], [saleae-logic16], [libusb])
 213 SR_DRIVER([SCPI PPS], [scpi-pps])
 214 SR_DRIVER([serial DMM], [serial-dmm], [libserialport])
 215 SR_DRIVER([Sysclk LWLA], [sysclk-lwla], [libusb])
 216 SR_DRIVER([Teleinfo], [teleinfo], [libserialport])
 217 SR_DRIVER([Testo], [testo], [libusb])
 218 SR_DRIVER([Tondaj SL-814], [tondaj-sl-814], [libserialport])
 219 SR_DRIVER([UNI-T DMM], [uni-t-dmm], [libusb])
 220 SR_DRIVER([UNI-T UT32x], [uni-t-ut32x], [libusb])
 221 SR_DRIVER([Victor DMM], [victor-dmm], [libusb])
 222 SR_DRIVER([Yokogawa DL/DLM], [yokogawa-dlm])
 223 SR_DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube], [libusb])
 224
 225 ###############################
 226 ##  Language bindings setup  ##
 227 ###############################
 228
 229 AC_LANG([C++])
 230 SR_ARG_ENABLE_WARNINGS([SR_WXXFLAGS], [-Wall], [-Wall -Wextra])
 231
 232 AC_ARG_ENABLE([bindings],
 233         [AS_HELP_STRING([--enable-bindings], [build language bindings [default=yes]])],
 234         [], [enable_bindings=yes])
 235
 236 AC_ARG_ENABLE([cxx],
 237         [AS_HELP_STRING([--enable-cxx], [build C++ bindings [default=yes]])],
 238         [], [enable_cxx=$enable_bindings])
 239
 240 AC_ARG_ENABLE([python],
 241         [AS_HELP_STRING([--enable-python], [build Python bindings [default=yes]])],
 242         [], [enable_python=$enable_bindings])
 243
 244 AC_ARG_ENABLE([java],
 245         [AS_HELP_STRING([--enable-java], [build Java bindings [default=yes]])],
 246         [], [enable_java=$enable_bindings])
 247
 248 ####################
 249 ##  C++ bindings  ##
 250 ####################
 251
 252 sr_cxx_missing=
 253
 254 # Check if the C++ compiler supports the C++11 standard.
 255 m4_ifdef([AX_CXX_COMPILE_STDCXX_11],
 256         [AX_CXX_COMPILE_STDCXX_11(, [optional])],
 257         [m4_warn([unsupported], [Missing macro AX_CXX_COMPILE_STDCXX_11: no C++11 check possible])])
 258 AS_IF([test "x$HAVE_CXX11" != x1],
 259         [SR_APPEND([sr_cxx_missing], [', '], ['C++11'])])
 260
 261 # The C++ bindings need glibmm.
 262 SR_PKG_CHECK([glibmm], [SR_PKGLIBS_CXX], [glibmm-2.4 >= 2.32.0])
 263 AS_IF([test "x$sr_have_glibmm" != xyes],
 264         [SR_APPEND([sr_cxx_missing], [', '], [glibmm])])
 265
 266 # The C++ bindings use Doxygen to parse libsigrok symbols.
 267 AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes], [no])
 268 AS_IF([test "x$HAVE_DOXYGEN" != xyes],
 269         [SR_APPEND([sr_cxx_missing], [', '], [Doxygen])])
 270
 271 # Python is needed for the C++ bindings.
 272 AM_PATH_PYTHON([2.7],
 273         [HAVE_PYTHON=yes],
 274         [HAVE_PYTHON=no
 275         SR_APPEND([sr_cxx_missing], [', '], [Python])])
 276
 277 AS_IF([test -z "$sr_cxx_missing"],
 278         [BINDINGS_CXX=$enable_cxx], [BINDINGS_CXX=no])
 279 AM_CONDITIONAL([BINDINGS_CXX], [test "x$BINDINGS_CXX" = xyes])
 280
 281 # C++ bindings want stoi and stod.
 282 AM_COND_IF([BINDINGS_CXX], [
 283         AC_CACHE_CHECK([for stoi and stod], [sr_cv_have_stoi_stod],
 284                 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string>]],
 285                                 [[(void) std::stoi("1"); (void) std::stod("1.0");]])],
 286                         [sr_cv_have_stoi_stod=yes], [sr_cv_have_stoi_stod=no])])
 287         AS_IF([test "x$sr_cv_have_stoi_stod" = xyes],
 288                 [AC_DEFINE([HAVE_STOI_STOD], [1],
 289                         [Specifies whether we have the stoi and stod functions.])])
 290 ])
 291
 292 #######################
 293 ##  Python bindings  ##
 294 #######################
 295
 296 AS_IF([test "x$BINDINGS_CXX" = xyes],
 297         [sr_python_missing=],
 298         [sr_python_missing='C++ bindings'])
 299
 300 # The Python bindings need Python development files.
 301 SR_PKG_CHECK([python_dev], [SR_PKGLIBS_PYTHON],
 302         [python >= 2.7], [python2 >= 2.7], [python27 >= 2.7])
 303 AS_IF([test "x$sr_have_python_dev" != xyes],
 304         [SR_APPEND([sr_python_missing], [', '], [Headers])])
 305
 306 # PyGObject is needed for the Python bindings.
 307 SR_PKG_CHECK([pygobject], [SR_PKGLIBS_PYTHON], [pygobject-3.0 >= 3.0.0])
 308 AS_IF([test "x$sr_have_pygobject" != xyes],
 309         [SR_APPEND([sr_python_missing], [', '], [PyGObject])])
 310
 311 PKG_CHECK_EXISTS([pygobject-3.0 < 3.7.91],
 312         [AC_DEFINE([PYGOBJECT_FLAGS_SIGNED], [1],
 313                 [Whether last argument to pyg_flags_get_value() is signed.])])
 314
 315 # The Python bindings need the setuptools Python module.
 316 # We'll let it go through even if the AX macro wasn't found,
 317 # as the Python module may still be there.
 318 HAVE_PYMOD_SETUPTOOLS=yes
 319 m4_ifdef([AX_PYTHON_MODULE],
 320         [AX_PYTHON_MODULE([setuptools])],
 321         [m4_warn([unsupported], [Missing macro AX_PYTHON_MODULE: no setuptools check])])
 322 AS_IF([test "x$HAVE_PYMOD_SETUPTOOLS" != xyes],
 323         [SR_APPEND([sr_python_missing], [', '], [setuptools])])
 324
 325 # The Python bindings use SWIG to generate code.
 326 AC_CHECK_PROGS([SWIG], [swig swig2.0 swig3.0])
 327 AS_IF([test "x$SWIG" = x],
 328         [SR_APPEND([sr_python_missing], [', '], [SWIG])])
 329
 330 AS_IF([test -z "$sr_python_missing"],
 331         [BINDINGS_PYTHON=$enable_python], [BINDINGS_PYTHON=no])
 332 AM_CONDITIONAL([BINDINGS_PYTHON], [test "x$BINDINGS_PYTHON" = xyes])
 333
 334 ####################
 335 ##  Java bindings ##
 336 ####################
 337
 338 AS_IF([test "x$BINDINGS_CXX" = xyes],
 339         [sr_java_missing=],
 340         [sr_java_missing='C++ bindings'])
 341
 342 # The Java bindings use SWIG to generate code.
 343 AS_IF([test "x$SWIG" = x],
 344         [SR_APPEND([sr_java_missing], [', '], [SWIG])])
 345
 346 # Find Java compiler and JNI includes for Java bindings.
 347 AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no])
 348 AS_IF([test "x$HAVE_JAVAC" = xno],
 349         [SR_APPEND([sr_java_missing], [', '], [JavaC])])
 350
 351 AC_ARG_WITH([jni-include-path],
 352         [AS_HELP_STRING([[--with-jni-include-path=DIR-LIST (space-separated)]],
 353                 [specify JNI include directories [default=detect]])],
 354         [JNI_INCLUDE_DIRS=" $withval"], [JNI_INCLUDE_DIRS=])
 355
 356 JNI_CPPFLAGS=
 357 AS_IF([test "x$enable_java$HAVE_JAVAC" = xyesyes], [
 358         AX_PROG_JAVAC
 359         AS_IF([test -z "$JNI_INCLUDE_DIRS" && test "x$cross_compiling" != xyes], [
 360                 ## Work around the totally broken logic in AX_JNI_INCLUDE_DIR:
 361                 ## If we can find jni.h without any special search path, skip
 362                 ## the execution of the broken macro to increase our chances of
 363                 ## success.
 364                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <jni.h>]], [])],,
 365                         [AX_JNI_INCLUDE_DIR])
 366         ])
 367 ])
 368 for sr_dir in $JNI_INCLUDE_DIRS
 369 do
 370         SR_APPEND([JNI_CPPFLAGS], ["-I$sr_dir"])
 371 done
 372 AC_SUBST([JNI_CPPFLAGS])
 373
 374 sr_save_cppflags=$CPPFLAGS
 375 SR_APPEND([CPPFLAGS], [$JNI_CPPFLAGS])
 376 AC_CHECK_HEADER([jni.h],,
 377         [SR_APPEND([sr_java_missing], [', '], ['JNI headers'])])
 378 CPPFLAGS=$sr_save_cppflags
 379
 380 AS_IF([test -z "$sr_java_missing"],
 381         [BINDINGS_JAVA=$enable_java], [BINDINGS_JAVA=no])
 382 AM_CONDITIONAL([BINDINGS_JAVA], [test "x$BINDINGS_JAVA" = xyes])
 383
 384 ##############################
 385 ##  Finalize configuration  ##
 386 ##############################
 387
 388 # Add mandatory dependencies to module list.
 389 SR_APPEND([SR_PKGLIBS], ['libzip >= 0.10'])
 390 AC_SUBST([SR_PKGLIBS])
 391
 392 # Retrieve the compile and link flags for all modules combined.
 393 # Also, bail out at this point if any module dependency is not met.
 394 PKG_CHECK_MODULES([LIBSIGROK], [glib-2.0 >= 2.32.0 $SR_PKGLIBS])
 395 PKG_CHECK_MODULES([CHECK], [$SR_PKGLIBS_CHECK glib-2.0 $SR_PKGLIBS])
 396
 397 # SR_PKGLIBS_CXX may be empty, so only invoke these checks when
 398 # the C++ bindings are enabled.
 399 AM_COND_IF([BINDINGS_CXX], [
 400         PKG_CHECK_MODULES([LIBSIGROKCXX], [$SR_PKGLIBS_CXX])
 401         PKG_CHECK_MODULES([PYSIGROK], [$SR_PKGLIBS_PYTHON $SR_PKGLIBS_CXX])
 402 ])
 403 sr_glib_version=`$PKG_CONFIG --modversion glib-2.0 2>&AS_MESSAGE_LOG_FD`
 404 sr_libzip_version=`$PKG_CONFIG --modversion libzip 2>&AS_MESSAGE_LOG_FD`
 405
 406 AC_DEFINE_UNQUOTED([CONF_LIBZIP_VERSION], ["$sr_libzip_version"],
 407         [Build-time version of libzip.])
 408 AC_DEFINE_UNQUOTED([CONF_HOST], ["$host"],
 409         [The canonical host libsigrok will run on.])
 410
 411 AC_LANG([C])
 412
 413 # libm (the standard math library) is always needed.
 414 AC_SEARCH_LIBS([pow], [m])
 415
 416 # We need to link against the Winsock2 library for SCPI over TCP.
 417 AS_CASE([$host], [*mingw*], [LIBS="$LIBS -lws2_32"])
 418
 419 AC_SUBST([FIRMWARE_DIR], ['$(datadir)/sigrok-firmware'])
 420 AC_SUBST([MAKEFLAGS], ['--no-print-directory'])
 421 AC_SUBST([AM_LIBTOOLFLAGS], ['--silent'])
 422
 423 AC_CONFIG_FILES([Makefile libsigrok.pc bindings/cxx/libsigrokcxx.pc])
 424
 425 AC_OUTPUT
 426
 427 # Prepare bindings report messages.
 428 m4_define([SR_PREPARE_BINDING_REPORT], [
 429         sr_report_$1=
 430         test -z "$sr_$1_missing" || sr_report_$1=" (missing: $sr_$1_missing)"
 431         test "x$enable_$1" = xyes || sr_report_$1=' (disabled)'
 432 ])
 433 m4_map_args([SR_PREPARE_BINDING_REPORT], [cxx], [python], [java])
 434
 435 cat >&AS_MESSAGE_FD <<_EOF
 436
 437 libsigrok configuration summary:
 438  - Package version................. $SR_PACKAGE_VERSION
 439  - Library ABI version............. $SR_LIB_VERSION
 440  - Prefix.......................... $prefix
 441  - Building on..................... $build
 442  - Building for.................... $host
 443  - Additional C compiler flags..... $SR_EXTRA_CFLAGS
 444  - C compiler warnings............. $SR_WFLAGS
 445  - C++ compiler warnings........... $SR_WXXFLAGS
 446
 447 Detected libraries (required):
 448  - glib-2.0 >= 2.32.0.............. $sr_glib_version
 449  - libzip >= 0.10.................. $sr_libzip_version
 450
 451 Detected libraries (optional):
 452 $sr_pkglibs_summary
 453 Enabled hardware drivers:
 454 $sr_driver_summary
 455 Enabled SCPI backends:
 456  - TCP............................. yes
 457  - RPC............................. $sr_cv_have_rpc
 458  - serial.......................... $sr_have_libserialport
 459  - VISA............................ $sr_have_librevisa
 460  - GPIB............................ $sr_have_libgpib
 461  - USBTMC.......................... $sr_have_libusb
 462
 463 Enabled language bindings:
 464  - C++............................. $BINDINGS_CXX$sr_report_cxx
 465  - Python.......................... $BINDINGS_PYTHON$sr_report_python
 466  - Java............................ $BINDINGS_JAVA$sr_report_java
 467
 468 _EOF