configure.ac

   1 ##
   2 ## This file is part of the libsigrok project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 3 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 AC_INIT([libsigrok], [0.6.0],
  25         [sigrok-devel@lists.sourceforge.net],
  26         [libsigrok], [http://www.sigrok.org])
  27 AC_CONFIG_MACRO_DIR([m4])
  28 AC_CONFIG_AUX_DIR([autostuff])
  29 AC_CONFIG_HEADERS([config.h include/libsigrok/version.h])
  30
  31 # We require at least automake 1.11 (needed for 'silent rules').
  32 AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define nostdinc subdir-objects check-news color-tests])
  33 AM_SILENT_RULES([yes])
  34 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  35
  36 AC_CANONICAL_HOST
  37
  38 # Checks for programs.
  39 AC_PROG_CC
  40 AC_PROG_CXX
  41 AC_PROG_INSTALL
  42 AC_PROG_LN_S
  43
  44 # Required for per-target flags or subdir-objects with C sources.
  45 AM_PROG_CC_C_O
  46
  47 # Set the standard the C library headers should conform to.
  48 AH_VERBATIM([_POSIX_C_SOURCE], [/* The targeted POSIX standard. */
  49 #ifndef _POSIX_C_SOURCE
  50 # define _POSIX_C_SOURCE 200112L
  51 #endif])
  52
  53 # Get compiler versions.
  54 SR_PROG_VERSION([$CC], [sr_cc_version])
  55 SR_PROG_VERSION([$CXX], [sr_cxx_version])
  56
  57 # Check for optional make features.
  58 SR_PROG_MAKE_ORDER_ONLY
  59
  60 # Initialize libtool.
  61 LT_INIT
  62
  63 # Set up the libsigrok version defines.
  64 SR_PKG_VERSION_SET([SR_PACKAGE_VERSION], [AC_PACKAGE_VERSION])
  65
  66 # Library version for libsigrok (NOT the same as the package version).
  67 # Carefully read the libtool docs before updating these numbers!
  68 # The algorithm for determining which number to change (and how) is nontrivial!
  69 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  70 # Format: current:revision:age.
  71 SR_LIB_VERSION_SET([SR_LIB_VERSION], [4:0:0])
  72
  73 AM_CONDITIONAL([WIN32], [test -z "${host_os##mingw*}" || test -z "${host_os##cygwin*}"])
  74
  75 #############################
  76 ##  Optional dependencies  ##
  77 #############################
  78
  79 AC_LANG([C])
  80
  81 # Initialize pkg-config.
  82 # We require at least 0.22, as "Requires.private" behaviour changed there.
  83 PKG_PROG_PKG_CONFIG([0.22])
  84
  85 # Keep track of all checked modules so we can list them at the end.
  86 SR_PKG_CHECK_SUMMARY([sr_pkglibs_summary])
  87
  88 # Collect the pkg-config module names of all dependencies in SR_PKGLIBS.
  89 # These are used to derive the compiler flags and for the "Requires.private"
  90 # field in the generated libsigrok.pc file.
  91 SR_VAR_OPT_PKG([SR_PKGLIBS], [sr_deps_avail])
  92 SR_PKGLIBS_TESTS=
  93 SR_PKGLIBS_CXX=
  94 SR_PKGLIBS_PYTHON=
  95 SR_PKGLIBS_RUBY=
  96 SR_EXTRA_LIBS=
  97 SR_EXTRA_CXX_LIBS=
  98
  99 SR_ARG_OPT_PKG([zlib], [ZLIB], , [zlib])
 100 AM_CONDITIONAL([HAVE_ZLIB], [test "x$sr_have_zlib" = xyes])
 101 AM_COND_IF([HAVE_ZLIB], [
 102         SR_APPEND([sr_deps_avail], [crc32 zlib])
 103         SR_PREPEND([SR_EXTRA_LIBS], [-lz])
 104 ])
 105
 106 AM_CONDITIONAL([HAVE_INPUT_STF], [test "x$sr_have_zlib" = xyes])
 107 AM_COND_IF([HAVE_INPUT_STF], [
 108         AC_DEFINE([HAVE_INPUT_STF], [1], [Is the STF input module supported?])
 109 ])
 110
 111 SR_ARG_OPT_PKG([libserialport], [LIBSERIALPORT], ,
 112         [libserialport >= 0.1.1])
 113
 114 SR_ARG_OPT_PKG([libftdi], [LIBFTDI], , [libftdi1 >= 1.0])
 115
 116 # pkg-config file names: MinGW/MacOSX: hidapi; Linux: hidapi-hidraw/-libusb
 117 SR_ARG_OPT_PKG([libhidapi], [LIBHIDAPI], ,
 118         [hidapi >= 0.8.0], [hidapi-hidraw >= 0.8.0], [hidapi-libusb >= 0.8.0])
 119
 120 SR_ARG_OPT_PKG([libbluez], [LIBBLUEZ], , [bluez >= 4.0])
 121
 122 SR_ARG_OPT_PKG([libnettle], [LIBNETTLE], , [nettle])
 123
 124 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
 125 # This means libusb-1.0 is always available; no need to check for it.
 126 # On Windows, require the latest version we can get our hands on,
 127 # until the new generic event handling has seen an official release.
 128 AS_CASE([$host_os],
 129         [freebsd*], [sr_libusb_req='libusb-1.0' sr_have_libusb=yes],
 130         [mingw*], [sr_libusb_req='libusb-1.0 >= 1.0.20'],
 131         [sr_libusb_req='libusb-1.0 >= 1.0.16'])
 132
 133 SR_ARG_OPT_PKG([libusb], [LIBUSB_1_0], [NEED_USB],
 134         [$sr_libusb_req])
 135
 136 SR_ARG_OPT_PKG([librevisa], [LIBREVISA], [NEED_VISA],
 137         [librevisa >= 0.0.20130412])
 138
 139 SR_ARG_OPT_PKG([libgpib], [LIBGPIB], [NEED_GPIB],
 140         [libgpib])
 141
 142 SR_ARG_OPT_CHECK([libieee1284], [LIBIEEE1284],, [
 143         sr_save_LIBS=$LIBS
 144         LIBS="-lieee1284 $LIBS"
 145         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <ieee1284.h>]],
 146                                 [[(void) ieee1284_open(0, 0, 0);]])],
 147                 [sr_have_libieee1284=yes], [sr_have_libieee1284=no])
 148         LIBS=$sr_save_LIBS
 149 ])
 150 AS_IF([test "x$sr_have_libieee1284" = xyes],
 151         [SR_PREPEND([SR_EXTRA_LIBS], [-lieee1284])])
 152
 153 SR_ARG_OPT_PKG([libgio], [LIBGIO], , [gio-2.0 >= 2.24.0])
 154
 155 # See if any of the (potentially platform specific) libs are available
 156 # which provide some means of Bluetooth communication.
 157 AS_IF([test "x$sr_have_libbluez" = xyes],
 158         sr_have_bluetooth=yes, sr_have_bluetooth=no)
 159 AS_IF([test "x$sr_have_bluetooth" = xyes],
 160         [AC_DEFINE([HAVE_BLUETOOTH], [1], [Specifies whether Bluetooth communication is supported.])])
 161 AS_IF([test "x$sr_have_bluetooth" = xyes],
 162         [SR_APPEND([sr_deps_avail], [bluetooth_comm])])
 163
 164 AS_IF([test "x$sr_have_libserialport" = xyes -o "x$sr_have_libhidapi" = xyes -o "x$sr_have_bluetooth" = xyes],
 165         sr_have_serial_comm=yes, sr_have_serial_comm=no)
 166 AS_IF([test "x$sr_have_serial_comm" = xyes],
 167         [AC_DEFINE([HAVE_SERIAL_COMM], [1], [Specifies whether serial communication is supported.])])
 168 AS_IF([test "x$sr_have_serial_comm" = xyes],
 169         [SR_APPEND([sr_deps_avail], [serial_comm])])
 170 AM_CONDITIONAL([NEED_SERIAL], [test "x$sr_have_serial_comm" = xyes])
 171
 172 ######################
 173 ##  Feature checks  ##
 174 ######################
 175
 176 # The Check unit testing framework is optional. Disable if not found.
 177 SR_PKG_CHECK([check], [SR_PKGLIBS_TESTS], [check >= 0.9.4])
 178 AM_CONDITIONAL([HAVE_CHECK], [test "x$sr_have_check" = xyes])
 179
 180 # Enable the C99 standard if possible, and enforce the use
 181 # of SR_API to explicitly mark all public API functions.
 182 SR_EXTRA_CFLAGS=
 183 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [C99], [-std=c99 -c99 -AC99 -qlanglvl=extc99])
 184 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [visibility], [-fvisibility=hidden])
 185
 186 SR_ARG_ENABLE_WARNINGS([SR_WFLAGS], [-Wall], [-Wall -Wextra -Wmissing-prototypes])
 187
 188 # Check host characteristics.
 189 AC_SYS_LARGEFILE
 190 AC_C_BIGENDIAN
 191
 192 AC_CHECK_HEADERS([sys/mman.h], [SR_APPEND([sr_deps_avail], [sys_mman_h])])
 193 AC_CHECK_HEADERS([sys/ioctl.h], [SR_APPEND([sr_deps_avail], [sys_ioctl_h])])
 194 AC_CHECK_HEADERS([sys/timerfd.h], [SR_APPEND([sr_deps_avail], [sys_timerfd_h])])
 195
 196 # We need to link against the Winsock2 library for SCPI over TCP.
 197 AS_CASE([$host_os], [mingw*], [SR_PREPEND([SR_EXTRA_LIBS], [-lws2_32])])
 198
 199 # libm (the standard math library) is always needed.
 200 SR_SEARCH_LIBS([SR_EXTRA_LIBS], [pow], [m])
 201
 202 # RPC is only needed for VXI support.
 203 AC_CACHE_CHECK([for SunRPC support], [sr_cv_have_sunrpc],
 204         [AC_LINK_IFELSE([AC_LANG_PROGRAM(
 205                         [[#include <rpc/rpc.h>]m4_newline[CLIENT *rpc_test(void);]],
 206                         [[(void) clnt_create("", 0, 0, "");]])],
 207                 [RPC_CFLAGS=""; RPC_LIBS=""; sr_cv_have_sunrpc=yes],
 208                 [sr_cv_have_sunrpc=no])])
 209 PKG_CHECK_MODULES([TIRPC],
 210         [libtirpc],
 211         [RPC_CFLAGS=$TIRPC_CFLAGS; SR_PREPEND([SR_EXTRA_LIBS], [$TIRPC_LIBS]); sr_cv_have_tirpc=yes],
 212         [sr_cv_have_tirpc=no])
 213 AS_IF([test "x$sr_cv_have_sunrpc" = xyes -o "x$sr_cv_have_tirpc" = xyes],
 214         [sr_cv_have_rpc=yes], [sr_cv_have_rpc=no])
 215
 216 AC_SUBST(RPC_CFLAGS)
 217 AC_SUBST(RPC_LIBS)
 218
 219 AS_IF([test "x$sr_cv_have_rpc" = xyes],
 220         [AC_DEFINE([HAVE_RPC], [1], [Specifies whether we have RPC support (either by SunRPC or libtirpc).])])
 221
 222 # VXI support is only compiled if RPC support was found.
 223 AM_CONDITIONAL([NEED_RPC], [test "x$sr_cv_have_rpc" = xyes])
 224
 225 # Check for compiler support of 128 bit integers
 226 AC_CHECK_TYPES([__int128_t, __uint128_t], [], [], [])
 227
 228
 229 #######################
 230 ##  miniLZO related  ##
 231 #######################
 232 # These were taken from the README.LZO file in the miniLZO archive.
 233
 234 AC_CHECK_TYPE(ptrdiff_t,long)
 235 AC_TYPE_SIZE_T
 236 AC_CHECK_SIZEOF(short)
 237 AC_CHECK_SIZEOF(int)
 238 AC_CHECK_SIZEOF(long)
 239 AC_CHECK_SIZEOF(long long)
 240 AC_CHECK_SIZEOF(__int64)
 241 AC_CHECK_SIZEOF(void *)
 242 AC_CHECK_SIZEOF(size_t)
 243 AC_CHECK_SIZEOF(ptrdiff_t)
 244
 245 AC_C_CONST
 246
 247 AC_CHECK_FUNCS(memcmp memcpy memmove memset)
 248
 249 ########################
 250 ##  Hardware drivers  ##
 251 ########################
 252
 253 # Keep track of all drivers so we can list them at the end.
 254 SR_VAR_SUMMARY([sr_driver_summary])
 255
 256 # Check whether the sr_deps_avail list contains all of the arguments.
 257 # Unavailable dependencies are collected in sr_deps_missing.
 258 sr_check_driver_deps() {
 259         sr_deps_missing=
 260         for sr_dep
 261         do
 262                 AS_CASE([" $sr_deps_avail "], [*" $sr_dep "*],,
 263                         [SR_APPEND([sr_deps_missing], [', '], [$sr_dep])])
 264         done
 265         test -z "$sr_deps_missing" || return 1
 266 }
 267
 268 AC_ARG_ENABLE([all-drivers],
 269         [AS_HELP_STRING([--enable-all-drivers],
 270                         [enable all drivers by default [default=yes]])],
 271         [], [enable_all_drivers=yes])
 272
 273 ## _SR_DRIVER(Device name, driver-name, var-name, [dependencies...])
 274 m4_define([_SR_DRIVER], [
 275         AC_ARG_ENABLE([$2],
 276                 [AS_HELP_STRING([--enable-$2], [enable $1 support])],
 277                 [$3=$enableval], [$3=$enable_all_drivers])
 278
 279         AS_IF([test "x[$]$3" = xyes], [sr_hw_info=yes[]m4_ifval([$4], [
 280                 sr_check_driver_deps $4 \
 281                         || $3=no sr_hw_info="no (missing: $sr_deps_missing)"
 282         ])], [sr_hw_info='no (disabled)'])
 283         sr_driver_summary_append "$2" "$sr_hw_info"
 284
 285         AM_CONDITIONAL([$3], [test "x[$]$3" = xyes])
 286         AM_COND_IF([$3], [AC_DEFINE([HAVE_$3], [1], [Whether to support $1 device.]) AC_DEFINE([HAVE_DRIVERS], [1], [Whether at least one driver is enabled.])])
 287 ])
 288
 289 ## SR_DRIVER(Device name, driver-name, [dependencies...])
 290 m4_define([SR_DRIVER],
 291         [_SR_DRIVER([$1], [$2], m4_expand([AS_TR_CPP([HW_$2])]), [$3])])
 292
 293 SR_DRIVER([Agilent DMM], [agilent-dmm], [serial_comm])
 294 SR_DRIVER([Appa 55II], [appa-55ii], [serial_comm])
 295 SR_DRIVER([Arachnid Labs Re:load Pro], [arachnid-labs-re-load-pro], [serial_comm])
 296 SR_DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma], [libftdi])
 297 SR_DRIVER([ASIX OMEGA RTM CLI], [asix-omega-rtm-cli])
 298 SR_DRIVER([Atten PPS3xxx], [atten-pps3xxx], [serial_comm])
 299 SR_DRIVER([BayLibre ACME], [baylibre-acme], [sys_timerfd_h])
 300 SR_DRIVER([BeagleLogic], [beaglelogic], [sys_mman_h sys_ioctl_h])
 301 SR_DRIVER([CEM DT-885x], [cem-dt-885x], [serial_comm])
 302 SR_DRIVER([Center 3xx], [center-3xx], [serial_comm])
 303 SR_DRIVER([ChronoVu LA], [chronovu-la], [libusb libftdi])
 304 SR_DRIVER([Colead SLM], [colead-slm], [serial_comm])
 305 SR_DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu], [serial_comm])
 306 SR_DRIVER([dcttech usbrelay], [dcttech-usbrelay], [libhidapi])
 307 SR_DRIVER([demo], [demo])
 308 SR_DRIVER([DreamSourceLab DSLogic], [dreamsourcelab-dslogic], [libusb])
 309 SR_DRIVER([Fluke 45], [fluke-45])
 310 SR_DRIVER([Fluke DMM], [fluke-dmm], [serial_comm])
 311 SR_DRIVER([FTDI LA], [ftdi-la], [libusb libftdi])
 312 SR_DRIVER([fx2lafw], [fx2lafw], [libusb])
 313 SR_DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x], [serial_comm])
 314 SR_DRIVER([GW Instek GDS-800], [gwinstek-gds-800], [serial_comm])
 315 SR_DRIVER([GW Instek GPD], [gwinstek-gpd], [serial_comm])
 316 SR_DRIVER([Hameg HMO], [hameg-hmo])
 317 SR_DRIVER([Hantek 4032L], [hantek-4032l], [libusb])
 318 SR_DRIVER([Hantek 6xxx], [hantek-6xxx], [libusb])
 319 SR_DRIVER([Hantek DSO], [hantek-dso], [libusb])
 320 SR_DRIVER([HP 3457A], [hp-3457a])
 321 SR_DRIVER([HP 3478A], [hp-3478a], [libgpib])
 322 SR_DRIVER([hp-59306a], [hp-59306a])
 323 SR_DRIVER([Hung-Chang DSO-2100], [hung-chang-dso-2100], [libieee1284])
 324 SR_DRIVER([ICStation USBRelay], [icstation-usbrelay], [serial_comm])
 325 SR_DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2], [libusb])
 326 SR_DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus], [libftdi])
 327 SR_DRIVER([IPDBG LA], [ipdbg-la])
 328 SR_DRIVER([ITECH IT8500], [itech-it8500], [serial_comm])
 329 SR_DRIVER([Kecheng KC-330B], [kecheng-kc-330b], [libusb])
 330 SR_DRIVER([KERN scale], [kern-scale], [serial_comm])
 331 SR_DRIVER([Kingst LA2016], [kingst-la2016], [libusb])
 332 SR_DRIVER([Korad KAxxxxP], [korad-kaxxxxp], [serial_comm])
 333 SR_DRIVER([Lascar EL-USB], [lascar-el-usb], [libusb])
 334 SR_DRIVER([LeCroy LogicStudio], [lecroy-logicstudio], [libusb])
 335 SR_DRIVER([LeCroy X-Stream], [lecroy-xstream])
 336 SR_DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx], [serial_comm])
 337 SR_DRIVER([Mastech MS6514], [mastech-ms6514], [serial_comm])
 338 SR_DRIVER([maynuo-m97], [maynuo-m97])
 339 SR_DRIVER([MIC 985xx], [mic-985xx], [serial_comm])
 340 SR_DRIVER([Microchip PICkit2], [microchip-pickit2], [libusb])
 341 SR_DRIVER([Mooshimeter DMM], [mooshimeter-dmm], [bluetooth_comm libgio])
 342 SR_DRIVER([Motech LPS 30x], [motech-lps-30x], [serial_comm])
 343 SR_DRIVER([Norma DMM], [norma-dmm], [serial_comm])
 344 SR_DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer], [serial_comm])
 345 SR_DRIVER([PCE PCE-322A], [pce-322a], [serial_comm])
 346 SR_DRIVER([Pipistrello-OLS], [pipistrello-ols], [libftdi])
 347 SR_DRIVER([RDTech DPSxxxx/DPHxxxx], [rdtech-dps], [serial_comm])
 348 SR_DRIVER([RDTech UMXX], [rdtech-um], [serial_comm])
 349 SR_DRIVER([RDTech TCXX], [rdtech-tc], [serial_comm libnettle])
 350 SR_DRIVER([Rigol DS], [rigol-ds])
 351 SR_DRIVER([Rigol DG], [rigol-dg])
 352 SR_DRIVER([Rohde&Schwarz SME-0x], [rohde-schwarz-sme-0x], [serial_comm])
 353 SR_DRIVER([Saleae Logic16], [saleae-logic16], [libusb])
 354 SR_DRIVER([Saleae Logic Pro], [saleae-logic-pro], [libusb])
 355 SR_DRIVER([SCPI DMM], [scpi-dmm])
 356 SR_DRIVER([SCPI PPS], [scpi-pps])
 357 SR_DRIVER([serial DMM], [serial-dmm], [serial_comm])
 358 SR_DRIVER([serial LCR], [serial-lcr], [serial_comm])
 359 SR_DRIVER([Siglent SDS], [siglent-sds])
 360 SR_DRIVER([Sysclk LWLA], [sysclk-lwla], [libusb])
 361 SR_DRIVER([Sysclk SLA5032], [sysclk-sla5032], [libusb])
 362 SR_DRIVER([Teleinfo], [teleinfo], [serial_comm])
 363 SR_DRIVER([Testo], [testo], [libusb])
 364 SR_DRIVER([Tondaj SL-814], [tondaj-sl-814], [serial_comm])
 365 SR_DRIVER([UNI-T DMM], [uni-t-dmm], [libusb])
 366 SR_DRIVER([UNI-T UT181A], [uni-t-ut181a], [serial_comm])
 367 SR_DRIVER([UNI-T UT32x], [uni-t-ut32x], [serial_comm])
 368 SR_DRIVER([Yokogawa DL/DLM], [yokogawa-dlm])
 369 SR_DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube], [libusb])
 370 SR_DRIVER([ZKETECH EBD-USB], [zketech-ebd-usb], [serial_comm])
 371
 372 ###############################
 373 ##  Language bindings setup  ##
 374 ###############################
 375
 376 AC_LANG([C++])
 377 SR_ARG_ENABLE_WARNINGS([SR_WXXFLAGS], [-Wall], [-Wall -Wextra])
 378
 379 AC_ARG_ENABLE([bindings],
 380         [AS_HELP_STRING([--enable-bindings], [build language bindings [default=yes]])],
 381         [], [enable_bindings=yes])
 382
 383 AC_ARG_ENABLE([cxx],
 384         [AS_HELP_STRING([--enable-cxx], [build C++ bindings [default=yes]])],
 385         [], [enable_cxx=$enable_bindings])
 386
 387 AC_ARG_ENABLE([python],
 388         [AS_HELP_STRING([--enable-python], [build Python bindings [default=yes]])],
 389         [], [enable_python=$enable_bindings])
 390
 391 AC_ARG_ENABLE([ruby],
 392         [AS_HELP_STRING([--enable-ruby], [build Ruby bindings [default=yes]])],
 393         [], [enable_ruby=$enable_bindings])
 394
 395 AC_ARG_ENABLE([java],
 396         [AS_HELP_STRING([--enable-java], [build Java bindings [default=yes]])],
 397         [], [enable_java=$enable_bindings])
 398
 399 ####################
 400 ##  C++ bindings  ##
 401 ####################
 402
 403 sr_cxx_missing=
 404
 405 # Check if the C++ compiler supports at least the C++11 standard.
 406 # Get the highest of the available C++17/C++14/C++11 standards.
 407 # This transparently amends CXXFLAGS to pick the detected standard.
 408 HAVE_MODERN_CXX=
 409 AS_IF([test "x$HAVE_MODERN_CXX" = x],
 410         [AX_CXX_COMPILE_STDCXX([17], [noext], [optional])])
 411 AS_IF([test "x$HAVE_CXX17" = x1],
 412         [HAVE_MODERN_CXX=yes])
 413 AS_IF([test "x$HAVE_MODERN_CXX" = x],
 414         [AX_CXX_COMPILE_STDCXX([14], [noext], [optional])])
 415 AS_IF([test "x$HAVE_CXX14" = x1],
 416         [HAVE_MODERN_CXX=yes])
 417 AS_IF([test "x$HAVE_MODERN_CXX" = x],
 418         [AX_CXX_COMPILE_STDCXX([11], [noext], [optional])])
 419 AS_IF([test "x$HAVE_CXX11" = x1],
 420         [HAVE_MODERN_CXX=yes])
 421 AS_IF([test "x$HAVE_MODERN_CXX" = x],
 422         [SR_APPEND([sr_cxx_missing], [', '], ['C++11'])])
 423
 424 # The C++ bindings need glibmm.
 425 # Prefer glibmm-2.4 for backwards compatibility.
 426 # Accept glibmm-2.68 when glibmm-2.4 is not available.
 427 sr_have_glibmm=no
 428 AS_IF([test "x$sr_have_glibmm" != xyes],
 429         [SR_PKG_CHECK([glibmm24], [SR_PKGLIBS_CXX], [glibmm-2.4 >= 2.32.0])])
 430 AS_IF([test "x$sr_have_glibmm24" = xyes],
 431         [SR_APPEND([SR_GLIBMM_REQUIRES], ['glibmm-2.4 >= 2.32.0'])
 432         sr_have_glibmm=yes])
 433 AS_IF([test "x$sr_have_glibmm" != xyes],
 434         [SR_PKG_CHECK([glibmm268], [SR_PKGLIBS_CXX], [glibmm-2.68 >= 2.68.0])])
 435 AS_IF([test "x$sr_have_glibmm268" = xyes],
 436         [SR_APPEND([SR_GLIBMM_REQUIRES], ['glibmm-2.68 >= 2.68.0'])
 437         sr_have_glibmm=yes])
 438 AS_IF([test "x$sr_have_glibmm" = xyes],
 439         [AC_SUBST(SR_GLIBMM_REQUIRES)],
 440         [SR_APPEND([sr_cxx_missing], [', '], [glibmm])])
 441
 442 # The C++ bindings use Doxygen to parse libsigrok symbols.
 443 AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes], [no])
 444 AS_IF([test "x$HAVE_DOXYGEN" != xyes],
 445         [SR_APPEND([sr_cxx_missing], [', '], [Doxygen])])
 446
 447 # Link C++ code with gnustl_shared if it exists (Android)
 448 SR_SEARCH_LIBS([SR_EXTRA_CXX_LIBS], [__cxa_throw], [gnustl_shared])
 449
 450 # Python is needed for the C++ bindings.
 451 AM_PATH_PYTHON([2.7],
 452         [HAVE_PYTHON=yes],
 453         [HAVE_PYTHON=no
 454         SR_APPEND([sr_cxx_missing], [', '], [Python])])
 455
 456 AS_IF([test -z "$sr_cxx_missing"],
 457         [BINDINGS_CXX=$enable_cxx], [BINDINGS_CXX=no])
 458 AM_CONDITIONAL([BINDINGS_CXX], [test "x$BINDINGS_CXX" = xyes])
 459
 460 # C++ bindings want stoi and stod.
 461 AM_COND_IF([BINDINGS_CXX], [
 462         AC_CACHE_CHECK([for stoi and stod], [sr_cv_have_stoi_stod],
 463                 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string>]],
 464                                 [[(void) std::stoi("1"); (void) std::stod("1.0");]])],
 465                         [sr_cv_have_stoi_stod=yes], [sr_cv_have_stoi_stod=no])])
 466         AS_IF([test "x$sr_cv_have_stoi_stod" = xyes],
 467                 [AC_DEFINE([HAVE_STOI_STOD], [1],
 468                         [Specifies whether we have the stoi and stod functions.])])
 469         # In theory std::stoul() should have identical availability
 470         # as std::stoi() and std::stod() have. All of them are C++11.
 471         # But we play it safe here, and check support individually.
 472         AC_CACHE_CHECK([for stoul], [sr_cv_have_stoul],
 473                 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string>]],
 474                                 [[(void) std::stoul("1");]])],
 475                         [sr_cv_have_stoul=yes], [sr_cv_have_stoul=no])])
 476         AS_IF([test "x$sr_cv_have_stoul" = xyes],
 477                 [AC_DEFINE([HAVE_STOUL], [1],
 478                         [Specifies whether we have the std::stoul function.])])
 479 ])
 480
 481 #######################
 482 ##  Python bindings  ##
 483 #######################
 484
 485 AS_IF([test "x$BINDINGS_CXX" = xyes],
 486         [sr_python_missing=],
 487         [sr_python_missing='C++ bindings'])
 488
 489 # Extract major and minor version number of the Python interpreter.
 490 sr_pymajor=${PYTHON_VERSION%%.*}
 491 sr_pyminor=${PYTHON_VERSION#*.}
 492
 493 # The Python bindings need Python development files. Check for either
 494 # Python 3 or Python 2 headers depending on the interpreter version.
 495 SR_PKG_CHECK([python_dev], [SR_PKGLIBS_PYTHON],
 496         [python = $PYTHON_VERSION],
 497         [python$sr_pymajor = $PYTHON_VERSION],
 498         [python$sr_pymajor$sr_pyminor = $PYTHON_VERSION],
 499         [python-$PYTHON_VERSION = $PYTHON_VERSION])
 500
 501 AS_IF([test "x$sr_have_python_dev" != xyes],
 502         [SR_APPEND([sr_python_missing], [', '], [Headers])])
 503
 504 # PyGObject is needed for the Python bindings.
 505 SR_PKG_CHECK([pygobject], [SR_PKGLIBS_PYTHON], [pygobject-3.0 >= 3.0.0])
 506 AS_IF([test "x$sr_have_pygobject" != xyes],
 507         [SR_APPEND([sr_python_missing], [', '], [PyGObject])])
 508
 509 PKG_CHECK_EXISTS([pygobject-3.0 < 3.7.91],
 510         [AC_DEFINE([PYGOBJECT_FLAGS_SIGNED], [1],
 511                 [Whether last argument to pyg_flags_get_value() is signed.])])
 512
 513 # The Python bindings need the setuptools and numpy Python modules.
 514 # We'll let it go through even if the AX macro wasn't found, as the
 515 # Python modules may still be there.
 516 m4_ifdef([AX_PYTHON_MODULE], [
 517         AX_PYTHON_MODULE([setuptools])
 518         AX_PYTHON_MODULE([numpy])
 519 ], [
 520         HAVE_PYMOD_SETUPTOOLS=yes
 521         HAVE_PYMOD_NUMPY=yes
 522         m4_warn([unsupported],
 523                 [Missing macro AX_PYTHON_MODULE: no check for setuptools and numpy])
 524 ])
 525 AS_IF([test "x$HAVE_PYMOD_SETUPTOOLS" != xyes],
 526         [SR_APPEND([sr_python_missing], [', '], [setuptools])])
 527 AS_IF([test "x$HAVE_PYMOD_NUMPY" != xyes],
 528         [SR_APPEND([sr_python_missing], [', '], [numpy])])
 529
 530 # The Python bindings use SWIG to generate code.
 531 AC_CHECK_PROGS([SWIG], [swig swig4.0 swig3.0 swig2.0])
 532 AS_IF([test "x$SWIG" != x],
 533     AC_MSG_CHECKING([for $SWIG version])
 534     [SWIG_VERSION=`$SWIG -version 2>&1 | sed -n 's/SWIG Version //p'`]
 535     AC_MSG_RESULT([$SWIG_VERSION]))
 536 AS_IF([test "x$SWIG" = x],
 537         [SR_APPEND([sr_python_missing], [', '], [SWIG])])
 538
 539 AS_IF([test -z "$sr_python_missing"],
 540         [BINDINGS_PYTHON=$enable_python], [BINDINGS_PYTHON=no])
 541 AM_CONDITIONAL([BINDINGS_PYTHON], [test "x$BINDINGS_PYTHON" = xyes])
 542
 543 #####################
 544 ##  Ruby bindings  ##
 545 #####################
 546
 547 AS_IF([test "x$BINDINGS_CXX" = xyes],
 548         [sr_ruby_missing=],
 549         [sr_ruby_missing='C++ bindings'])
 550
 551 AC_PATH_PROGS(RUBY, ["${RUBY-ruby}"], [])
 552 AS_IF([test "x$RUBY" != x],
 553         AC_MSG_CHECKING([for Ruby version])
 554     [RUBY_VERSION=`$RUBY -e 'puts RUBY_VERSION'`]
 555     AC_MSG_RESULT([$RUBY_VERSION])
 556     [RUBY_DLEXT=`$RUBY -rrbconfig -e 'puts RbConfig::CONFIG[["DLEXT"]]'`]
 557     AC_SUBST(RUBY_DLEXT))
 558
 559 AS_IF([test "x$RUBY" = x],
 560         [SR_APPEND([sr_ruby_missing], [', '], [Ruby])])
 561
 562 # Extract major and minor version number of the Ruby interpreter.
 563 sr_rbmajor=${RUBY_VERSION%%.*}
 564 sr_rbminor=${RUBY_VERSION#*.}
 565 sr_rbminor=${sr_rbminor%%.*}
 566
 567 # The Ruby bindings need Ruby development files.
 568 SR_PKG_CHECK([ruby_dev], [SR_PKGLIBS_RUBY],
 569         [ruby >= 2.5.0],
 570         [ruby-$sr_rbmajor.$sr_rbminor >= 2.5.0])
 571
 572 AS_IF([test "x$sr_have_ruby_dev" != xyes],
 573         [SR_APPEND([sr_ruby_missing], [', '], [Headers])])
 574
 575 # The Ruby bindings use SWIG >= 3.0.8 to generate code.
 576 AS_IF([test "x$SWIG" = x],
 577         [SR_APPEND([sr_ruby_missing], [', '], [SWIG])],
 578         [AS_VERSION_COMPARE($SWIG_VERSION, "3.0.8",
 579                 [SR_APPEND([sr_ruby_missing], [', '], ['SWIG >= 3.0.8'])])])
 580
 581 AS_IF([test -z "$sr_ruby_missing"],
 582         [BINDINGS_RUBY=$enable_ruby], [BINDINGS_RUBY=no])
 583 AM_CONDITIONAL([BINDINGS_RUBY], [test "x$BINDINGS_RUBY" = xyes])
 584
 585 ####################
 586 ##  Java bindings ##
 587 ####################
 588
 589 AS_IF([test "x$BINDINGS_CXX" = xyes],
 590         [sr_java_missing=],
 591         [sr_java_missing='C++ bindings'])
 592
 593 # The Java bindings use SWIG to generate code.
 594 AS_IF([test "x$SWIG" = x],
 595         [SR_APPEND([sr_java_missing], [', '], [SWIG])])
 596
 597 # Find Java compiler and JNI includes for Java bindings.
 598 AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no])
 599 AS_IF([test "x$HAVE_JAVAC" = xno],
 600         [SR_APPEND([sr_java_missing], [', '], [JavaC])])
 601
 602 AC_ARG_WITH([jni-include-path],
 603         [AS_HELP_STRING([[--with-jni-include-path=DIR-LIST (space-separated)]],
 604                 [specify JNI include directories [default=detect]])],
 605         [JNI_INCLUDE_DIRS=" $withval"], [JNI_INCLUDE_DIRS=])
 606
 607 JNI_CPPFLAGS=
 608 AS_IF([test "x$enable_java$HAVE_JAVAC" = xyesyes], [
 609         AX_PROG_JAVAC
 610         AS_IF([test -z "$JNI_INCLUDE_DIRS" && test "x$cross_compiling" != xyes], [
 611                 ## Work around the totally broken logic in AX_JNI_INCLUDE_DIR:
 612                 ## If we can find jni.h without any special search path, skip
 613                 ## the execution of the broken macro to increase our chances of
 614                 ## success.
 615                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <jni.h>]], [])],,
 616                         [AX_JNI_INCLUDE_DIR])
 617         ])
 618 ])
 619 for sr_dir in $JNI_INCLUDE_DIRS
 620 do
 621         SR_APPEND([JNI_CPPFLAGS], ["-I$sr_dir"])
 622 done
 623 AC_SUBST([JNI_CPPFLAGS])
 624
 625 sr_save_cppflags=$CPPFLAGS
 626 SR_APPEND([CPPFLAGS], [$JNI_CPPFLAGS])
 627 AC_CHECK_HEADER([jni.h],,
 628         [SR_APPEND([sr_java_missing], [', '], ['JNI headers'])])
 629 CPPFLAGS=$sr_save_cppflags
 630
 631 AS_IF([test -z "$sr_java_missing"],
 632         [BINDINGS_JAVA=$enable_java], [BINDINGS_JAVA=no])
 633 AM_CONDITIONAL([BINDINGS_JAVA], [test "x$BINDINGS_JAVA" = xyes])
 634
 635 ##############################
 636 ##  Finalize configuration  ##
 637 ##############################
 638
 639 # Add mandatory dependencies to module list.
 640 SR_APPEND([SR_PKGLIBS], ['libzip >= 0.10'])
 641 AC_SUBST([SR_PKGLIBS])
 642
 643 # Retrieve the compile and link flags for all modules combined.
 644 # Also, bail out at this point if any module dependency is not met.
 645 PKG_CHECK_MODULES([LIBSIGROK], [glib-2.0 >= 2.32.0 $SR_PKGLIBS])
 646 PKG_CHECK_MODULES([TESTS], [$SR_PKGLIBS_TESTS glib-2.0 $SR_PKGLIBS])
 647
 648 # SR_PKGLIBS_CXX may be empty, so only invoke these checks when
 649 # the C++ bindings are enabled.
 650 AM_COND_IF([BINDINGS_CXX], [
 651         PKG_CHECK_MODULES([LIBSIGROKCXX], [$SR_PKGLIBS_CXX])
 652         PKG_CHECK_MODULES([PYSIGROK], [$SR_PKGLIBS_PYTHON $SR_PKGLIBS_CXX])
 653         PKG_CHECK_MODULES([RBSIGROK], [$SR_PKGLIBS_RUBY $SR_PKGLIBS_CXX], [AC_SUBST(RBSIGROK_EXTDIR, "lib/$($PKG_CONFIG --variable=sitearch $SR_PKGLIBS_RUBY)/$($PKG_CONFIG --variable=RUBY_BASE_NAME $SR_PKGLIBS_RUBY)/vendor_ruby/$($PKG_CONFIG --variable=ruby_version $SR_PKGLIBS_RUBY)")])
 654 ])
 655
 656 # Check for specific libusb features, now that we know the CFLAGS.
 657 # Also check for version dependent libftdi features.
 658 AC_LANG([C])
 659 sr_save_cflags=$CFLAGS
 660 sr_save_libs=$LIBS
 661 CFLAGS="$LIBSIGROK_CFLAGS $CFLAGS"
 662 LIBS="$LIBSIGROK_LIBS $LIBS"
 663 AC_CHECK_TYPES([libusb_os_handle],
 664         [sr_have_libusb_os_handle=yes], [sr_have_libusb_os_handle=no],
 665         [[#include <libusb.h>]])
 666 AC_CHECK_FUNCS([zip_discard])
 667 AC_CHECK_FUNCS([ftdi_tciflush ftdi_tcoflush ftdi_tcioflush])
 668 LIBS=$sr_save_libs
 669 CFLAGS=$sr_save_cflags
 670
 671 sr_glib_version=`$PKG_CONFIG --modversion glib-2.0 2>&AS_MESSAGE_LOG_FD`
 672 sr_libzip_version=`$PKG_CONFIG --modversion libzip 2>&AS_MESSAGE_LOG_FD`
 673 sr_zlib_version=`$PKG_CONFIG --modversion zlib 2>&AS_MESSAGE_LOG_FD`
 674
 675 AC_DEFINE_UNQUOTED([CONF_LIBZIP_VERSION], ["$sr_libzip_version"],
 676         [Build-time version of libzip.])
 677 AC_DEFINE_UNQUOTED([CONF_ZLIB_VERSION], ["$sr_zlib_version"],
 678         [Build-time version of zlib.])
 679 AC_DEFINE_UNQUOTED([CONF_HOST], ["$host"],
 680         [The canonical host libsigrok will run on.])
 681
 682 AC_CONFIG_FILES([Makefile libsigrok.pc bindings/cxx/libsigrokcxx.pc])
 683
 684 AC_OUTPUT
 685
 686 # Prepare bindings report messages.
 687 m4_define([SR_PREPARE_BINDING_REPORT], [
 688         sr_report_$1=
 689         test -z "$sr_$1_missing" || sr_report_$1=" (missing: $sr_$1_missing)"
 690         test "x$enable_$1" = xyes || sr_report_$1=' (disabled)'
 691 ])
 692 m4_map_args([SR_PREPARE_BINDING_REPORT], [cxx], [python], [ruby], [java])
 693
 694 cat >&AS_MESSAGE_FD <<_EOF
 695
 696 libsigrok configuration summary:
 697  - Package version................. $SR_PACKAGE_VERSION
 698  - Library ABI version............. $SR_LIB_VERSION
 699  - Prefix.......................... $prefix
 700  - Building on..................... $build
 701  - Building for.................... $host
 702  - Building shared / static........ $enable_shared / $enable_static
 703
 704 Compile configuration:
 705  - C compiler...................... $CC
 706  - C compiler version.............. $sr_cc_version
 707  - C compiler flags................ $CFLAGS
 708  - Additional C compiler flags..... $SR_EXTRA_CFLAGS
 709  - C compiler warnings............. $SR_WFLAGS
 710  - C++ compiler.................... $CXX
 711  - C++ compiler version............ $sr_cxx_version
 712  - C++ compiler flags.............. $CXXFLAGS
 713  - C++ compiler warnings........... $SR_WXXFLAGS
 714  - Linker flags.................... $LDFLAGS
 715
 716 Detected libraries (required):
 717  - glib-2.0 >= 2.32.0.............. $sr_glib_version
 718  - libzip >= 0.10.................. $sr_libzip_version
 719
 720 Detected libraries (optional):
 721 $sr_pkglibs_summary
 722 Enabled hardware drivers:
 723 $sr_driver_summary
 724 Enabled serial communication transports:
 725   - serial comm ................... $sr_have_serial_comm
 726   - libserialport ................. $sr_have_libserialport
 727   - hidapi ........................ $sr_have_libhidapi
 728   - bluetooth ..................... $sr_have_bluetooth
 729   - bluez ......................... $sr_have_libbluez
 730
 731 Enabled SCPI backends:
 732  - TCP............................. yes
 733  - SunRPC ......................... $sr_cv_have_sunrpc
 734  - TI-RPC ......................... $sr_cv_have_tirpc
 735  - RPC............................. $sr_cv_have_rpc
 736  - serial.......................... $sr_have_serial_comm
 737  - VISA............................ $sr_have_librevisa
 738  - GPIB............................ $sr_have_libgpib
 739  - USBTMC.......................... $sr_have_libusb
 740
 741 Enabled language bindings:
 742  - C++............................. $BINDINGS_CXX$sr_report_cxx
 743  - Python.......................... $BINDINGS_PYTHON$sr_report_python
 744  - Ruby............................ $BINDINGS_RUBY$sr_report_ruby
 745  - Java............................ $BINDINGS_JAVA$sr_report_java
 746
 747 _EOF
 748
 749 # Emit a warning if the C++ bindings are not being built.
 750 AM_COND_IF([BINDINGS_CXX], [], [
 751 cat >&AS_MESSAGE_FD <<_EOF
 752 ===============================================================================
 753 WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING
 754 ===============================================================================
 755 ===                                                                         ===
 756 ===         The libsigrok C++ bindings are not being built since you        ===
 757 ===             are missing one or more dependencies (see above)!           ===
 758 ===                                                                         ===
 759 ===      This means you won't be able to compile frontends that require     ===
 760 ===  the C++ bindings (such as PulseView)! You also won't be able to build  ===
 761 ===     other bindings and frontends using those (such as sigrok-meter)!    ===
 762 ===                                                                         ===
 763 ===============================================================================
 764 WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING
 765 ===============================================================================
 766
 767 _EOF
 768 ])