configure.ac

   1 ##
   2 ## This file is part of the libsigrok project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 3 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 # libsigrok package version number (NOT the same as shared lib version!).
  25 m4_define([sr_package_version_major], [0])
  26 m4_define([sr_package_version_minor], [3])
  27 m4_define([sr_package_version_micro], [0])
  28 m4_define([sr_package_version], [sr_package_version_major.sr_package_version_minor.sr_package_version_micro])
  29
  30 AC_INIT([libsigrok], [sr_package_version], [sigrok-devel@lists.sourceforge.net],
  31         [libsigrok], [http://www.sigrok.org])
  32 AC_CONFIG_HEADER([config.h])
  33 AC_CONFIG_MACRO_DIR([autostuff])
  34 AC_CONFIG_AUX_DIR([autostuff])
  35
  36 # We require at least automake 1.11 (needed for 'silent rules').
  37 AM_INIT_AUTOMAKE([1.11 -Wall -Werror subdir-objects check-news color-tests])
  38 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  39 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  40
  41 AH_TOP([#ifndef SR_CONFIG_H
  42 #define SR_CONFIG_H    /* To stop multiple inclusions. */])
  43 AH_BOTTOM([#endif /* SR_CONFIG_H */])
  44
  45 # Enable more compiler warnings via -Wall and -Wextra. Add -fvisibility=hidden
  46 # and enforce use of SR_API to explicitly mark all public API functions.
  47 COMMON_FLAGS="$CFLAGS -Wall -Wextra -fvisibility=hidden"
  48 CFLAGS="$COMMON_FLAGS -Wmissing-prototypes"
  49 CXXFLAGS="-std=c++11 $COMMON_FLAGS"
  50
  51 # Checks for programs.
  52 AC_PROG_CC
  53 AC_PROG_CPP
  54 AC_PROG_CXX
  55 AC_PROG_INSTALL
  56 AC_PROG_LN_S
  57
  58 # Required for per-target flags or subdir-objects with C sources.
  59 AM_PROG_CC_C_O
  60
  61 # Initialize libtool.
  62 LT_INIT
  63
  64 # Initialize pkg-config.
  65 # We require at least 0.22, as "Requires.private" behaviour changed there.
  66 PKG_PROG_PKG_CONFIG([0.22])
  67
  68 # Library version for libsigrok (NOT the same as the package version).
  69 # Carefully read the libtool docs before updating these numbers!
  70 # The algorithm for determining which number to change (and how) is nontrivial!
  71 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  72 SR_LIB_VERSION_CURRENT=2
  73 SR_LIB_VERSION_REVISION=0
  74 SR_LIB_VERSION_AGE=0
  75 SR_LIB_VERSION="$SR_LIB_VERSION_CURRENT:$SR_LIB_VERSION_REVISION:$SR_LIB_VERSION_AGE"
  76 SR_LIB_LDFLAGS="-version-info $SR_LIB_VERSION"
  77 AC_SUBST(SR_LIB_VERSION_CURRENT)
  78 AC_SUBST(SR_LIB_VERSION_REVISION)
  79 AC_SUBST(SR_LIB_VERSION_AGE)
  80 AC_SUBST(SR_LIB_VERSION)
  81 AC_SUBST(SR_LIB_LDFLAGS)
  82
  83 # Hardware support '--enable' options.
  84
  85 AC_ARG_ENABLE(all-drivers, AC_HELP_STRING([--enable-all-drivers],
  86         [enable all drivers by default [default=yes]]),
  87         [HW_ENABLED_DEFAULT="$enableval"],
  88         [HW_ENABLED_DEFAULT="yes"])
  89
  90 # Usage: DRIVER([Device name], [driver-name])
  91 # An optional third argument [no] disables that driver.
  92 m4_define([driverize], [m4_tolower(m4_bpatsubst([$1], [[^0-9a-zA-Z-]+], [-]))])
  93 m4_define([upperize], [m4_toupper(m4_bpatsubst([$1], [[^0-9a-zA-Z_]+], [_]))])
  94 AC_DEFUN([DRIVER], [
  95         if test -z "$3"; then
  96                 default=$HW_ENABLED_DEFAULT
  97         else
  98                 default="$3"
  99         fi
 100         AC_ARG_ENABLE($2, AC_HELP_STRING([--enable-$2], [enable $1 support]),
 101                 [m4_join([], [HW_], upperize([$2]))="$enableval"],
 102                 [m4_join([], [HW_], upperize([$2]))=$default])
 103         dots=$(expr substr ".............................." 1 $(expr 32 - length $2))
 104         driver_summary="${driver_summary}  - $2${dots} ${m4_join([], [HW_], upperize([$2]))}\n"
 105 ])
 106
 107 DRIVER([Agilent DMM], [agilent-dmm])
 108 DRIVER([Appa 55II], [appa-55ii])
 109 DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma])
 110 DRIVER([Atten PPS3xxx], [atten-pps3xxx])
 111 DRIVER([Brymen BM86x], [brymen-bm86x])
 112 DRIVER([Brymen DMM], [brymen-dmm])
 113 DRIVER([CEM DT-885x], [cem-dt-885x])
 114 DRIVER([Center 3xx], [center-3xx])
 115 DRIVER([ChronoVu LA], [chronovu-la])
 116 DRIVER([Colead SLM], [colead-slm])
 117 DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu])
 118 DRIVER([demo], [demo])
 119 DRIVER([Fluke DMM], [fluke-dmm])
 120 DRIVER([fx2lafw], [fx2lafw])
 121 DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x])
 122 DRIVER([Hameg HMO], [hameg-hmo])
 123 DRIVER([Hantek DSO], [hantek-dso])
 124 DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2])
 125 DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus])
 126 DRIVER([Kecheng KC-330B], [kecheng-kc-330b])
 127 DRIVER([Lascar EL-USB], [lascar-el-usb])
 128 DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx])
 129 DRIVER([MIC 985xx], [mic-985xx])
 130 DRIVER([Motech LPS 30x], [motech-lps-30x])
 131 DRIVER([Norma DMM], [norma-dmm])
 132 DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer])
 133 DRIVER([Rigol DS], [rigol-ds])
 134 DRIVER([Saleae Logic16], [saleae-logic16])
 135 DRIVER([serial DMM], [serial-dmm])
 136 DRIVER([Sysclk LWLA], [sysclk-lwla])
 137 DRIVER([Teleinfo], [teleinfo])
 138 DRIVER([Testo], [testo])
 139 DRIVER([Tondaj SL-814], [tondaj-sl-814])
 140 DRIVER([UNI-T DMM], [uni-t-dmm])
 141 DRIVER([UNI-T UT32x], [uni-t-ut32x])
 142 DRIVER([Victor DMM], [victor-dmm])
 143 DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube])
 144
 145 AC_ARG_ENABLE(libserialport,
 146         AC_HELP_STRING([--disable-libserialport],
 147         [disable libserialport support [default=detect]]))
 148
 149 AC_ARG_ENABLE(libftdi,
 150         AC_HELP_STRING([--disable-libftdi],
 151         [disable libftdi support [default=detect]]))
 152
 153 AC_ARG_ENABLE(libusb,
 154         AC_HELP_STRING([--disable-libusb],
 155         [disable libusb support [default=detect]]))
 156
 157 # Language binding '--enable' options
 158
 159 AC_ARG_ENABLE(c++,
 160         AC_HELP_STRING([--enable-cxx],
 161         [build C++ bindings [default=yes]]),
 162         [BINDINGS_CXX="$enableval"], [BINDINGS_CXX="yes"])
 163
 164 # Check if the C++ compiler supports the C++11 standard.
 165
 166 AX_CXX_COMPILE_STDCXX_11(,[optional])
 167
 168 if test "x$HAVE_CXX11" != "x1"; then
 169         BINDINGS_CXX="no"
 170 fi
 171
 172 # Checks for libraries.
 173
 174 case "$host" in
 175 *mingw*)
 176         # We need to link against the Winsock2 library for SCPI over TCP.
 177         LIBS="$LIBS -lws2_32";;
 178 esac
 179
 180 # This variable collects the pkg-config names of all detected libs.
 181 # It is then used to construct the "Requires.private:" field in the
 182 # libsigrok.pc file.
 183 SR_PKGLIBS=""
 184
 185 # libm (the standard math library) is always needed.
 186 AC_SEARCH_LIBS([pow], [m])
 187
 188 # RPC is only needed for VXI support.
 189 AC_MSG_CHECKING([for RPC support])
 190 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <rpc/rpc.h>],
 191                                 [CLIENT *rpc_test(void)],
 192                                 [{ return clnt_create("", 0, 0, ""); }])],
 193                [AC_MSG_RESULT([yes]); have_rpc=1],
 194                [AC_MSG_RESULT([no]);  have_rpc=0])
 195 # Define HAVE_RPC in config.h if we found RPC support.
 196 AC_DEFINE_UNQUOTED(HAVE_RPC, [$have_rpc], [Specifies whether we have RPC support.])
 197 # VXI support is only compiled if RPC support was found.
 198 AM_CONDITIONAL(NEED_RPC, test "x$have_rpc" != "x0")
 199
 200 # libglib-2.0 is always needed. Abort if it's not found.
 201 # Note: glib-2.0 is part of the libsigrok API (hard pkg-config requirement).
 202 # We require at least 2.32.0 due to e.g. g_variant_new_fixed_array().
 203 AM_PATH_GLIB_2_0([2.32.0],
 204         [LIB_CFLAGS="$LIB_CFLAGS $GLIB_CFLAGS"; LIBS="$LIBS $GLIB_LIBS"])
 205
 206 # libzip is always needed. Abort if it's not found.
 207 PKG_CHECK_MODULES([libzip], [libzip >= 0.10],
 208         [LIB_CFLAGS="$LIB_CFLAGS $libzip_CFLAGS"; LIBS="$LIBS $libzip_LIBS";
 209         SR_PKGLIBS="$SR_PKGLIBS libzip"])
 210
 211 # libserialport is only needed for some hardware drivers. Disable the
 212 # respective drivers if it is not found.
 213 if test "x$enable_libserialport" != "xno"; then
 214         PKG_CHECK_MODULES([libserialport], [libserialport >= 0.1.0],
 215                 [have_libserialport="yes"; LIB_CFLAGS="$LIB_CFLAGS $libserialport_CFLAGS";
 216                 LIBS="$LIBS $libserialport_LIBS";
 217                 SR_PKGLIBS="$SR_PKGLIBS libserialport"],
 218                 [have_libserialport="no"])
 219         if test "x$enable_libserialport$have_libserialport" = "xyesno"; then
 220                 AC_MSG_ERROR([libserialport support requested, but it was not found])
 221         fi
 222 else
 223         have_libserialport="no"
 224 fi
 225
 226 # Define HAVE_LIBSERIALPORT in config.h if we found libserialport.
 227 if test "x$have_libserialport" = "xno"; then
 228         HW_AGILENT_DMM="no"; HW_APPA_55II="no";
 229         HW_ATTEN_PPS3XXX="no"; HW_BRYMEN_DMM="no"; HW_CEM_DT_885X="no";
 230         HW_CENTER_3XX="no"; HW_COLEAD_SLM="no"; HW_CONRAD_DIGI_35_CPU="no";
 231         HW_FLUKE_DMM="no"; HW_GMC_MH_1X_2X="no"; HW_HAMEG_HMO="no";
 232         HW_MANSON_HCS_3XXX="no"; HW_MIC_985XX="no"; HW_MOTECH_LPS_30X="no";
 233         HW_NORMA_DMM="no"; HW_OPENBENCH_LOGIC_SNIFFER="no"; HW_SERIAL_DMM="no";
 234         HW_TELEINFO="no"; HW_TONDAJ_SL_814="no";
 235 else
 236         AC_DEFINE_UNQUOTED(HAVE_LIBSERIALPORT, [1],
 237                 [Specifies whether we have libserialport.])
 238 fi
 239
 240 # Serial port helper code is only compiled in if libserialport was found.
 241 AM_CONDITIONAL(NEED_SERIAL, test "x$have_libserialport" != xno)
 242
 243 PKG_CHECK_MODULES([librevisa], [librevisa >= 0.0.20130812],
 244         [have_librevisa="yes"; LIB_CFLAGS="$LIB_CFLAGS $librevisa_CFLAGS";
 245         LIBS="$LIBS $librevisa_LIBS";
 246         SR_PKGLIBS="$SR_PKGLIBS librevisa"],
 247         [have_librevisa="no"])
 248
 249 # VISA SCPI backend is only compiled in if librevisa was found.
 250 AM_CONDITIONAL(NEED_VISA, test "x$have_librevisa" != xno)
 251
 252 # Define HAVE_LIBREVISA in config.h if we found librevisa.
 253 if test "x$have_librevisa" != "xno"; then
 254         AC_DEFINE_UNQUOTED(HAVE_LIBREVISA, [1],
 255                 [Specifies whether we have librevisa.])
 256 fi
 257
 258 # libusb-1.0 is only needed for some hardware drivers. Disable the respective
 259 # drivers if it is not found.
 260 if test "x$enable_libusb" != "xno"; then
 261         case "$host" in
 262         *freebsd*)
 263                 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
 264                 # This means libusb-1.0 is always available, no need to check for it,
 265                 # and no need to (potentially) disable any drivers if it's not found.
 266                 have_libusb1_0="yes"
 267                 ;;
 268         *)
 269                 PKG_CHECK_MODULES([libusb], [libusb-1.0 >= 1.0.16],
 270                         [have_libusb1_0="yes"; LIB_CFLAGS="$LIB_CFLAGS $libusb_CFLAGS";
 271                         LIBS="$LIBS $libusb_LIBS";
 272                         SR_PKGLIBS="$SR_PKGLIBS libusb-1.0"],
 273                         [have_libusb1_0="no"])
 274                 if test "x$enable_libusb$have_libusb1_0" = "xyesno"; then
 275                         AC_MSG_ERROR([libusb support requested, but it was not found])
 276                 fi
 277                 ;;
 278         esac
 279 else
 280         have_libusb1_0="no"
 281 fi
 282
 283 # Define HAVE_LIBUSB_1_0 in config.h if we found libusb-1.0.
 284 if test "x$have_libusb1_0" = "xno"; then
 285         HW_BRYMEN_BM86X="no"; HW_FX2LAFW="no";
 286         HW_HANTEK_DSO="no"; HW_IKALOGIC_SCANALOGIC2="no";
 287         HW_KECHENG_KC_330B="no"; HW_LASCAR_EL_USB="no";
 288         HW_SYSCLK_LWLA="no"; HW_TESTO="no"; HW_UNI_T_DMM="no";
 289         HW_UNI_T_UT32X="no"; HW_VICTOR_DMM="no";
 290         HW_ZEROPLUS_LOGIC_CUBE="no"; HW_SALEAE_LOGIC16="no";
 291 else
 292         AC_DEFINE_UNQUOTED(HAVE_LIBUSB_1_0, [1],
 293                 [Specifies whether we have a libusb.h header.])
 294 fi
 295
 296 # USB + FX2 firmware helper code is only compiled in if libusb-1.0 was found.
 297 AM_CONDITIONAL(NEED_USB, test "x$have_libusb1_0" != xno)
 298
 299 # libftdi is only needed for some hardware drivers. Disable them if not found.
 300 if test "x$enable_libftdi" != "xno"; then
 301         PKG_CHECK_MODULES([libftdi], [libftdi >= 0.16],
 302                 [have_libftdi="yes"; LIB_CFLAGS="$LIB_CFLAGS $libftdi_CFLAGS";
 303                 LIBS="$LIBS $libftdi_LIBS";
 304                 SR_PKGLIBS="$SR_PKGLIBS libftdi"],
 305                 [PKG_CHECK_MODULES([libftdi1], [libftdi1 >= 1.0],
 306                         [LIB_CFLAGS="$LIB_CFLAGS $libftdi1_CFLAGS";
 307                         LIBS="$LIBS $libftdi1_LIBS";
 308                         SR_PKGLIBS="$SR_PKGLIBS libftdi1"],
 309                         [have_libftdi="no"])])
 310         if test "x$enable_libftdi$have_libftdi" = "xyesno"; then
 311                 AC_MSG_ERROR([libftdi support requested, but it was not found])
 312         fi
 313 else
 314         have_libftdi="no"
 315 fi
 316
 317 if test "x$have_libftdi" = "xno"; then
 318         HW_ASIX_SIGMA="no"; HW_CHRONOVU_LA="no"; HW_IKALOGIC_SCANAPLUS="no";
 319 fi
 320
 321 # glibmm-2.4 is needed for the C++ bindings.
 322 PKG_CHECK_MODULES([glibmm], [glibmm-2.4 >= 2.32.0],
 323         [CXXFLAGS="$CXXFLAGS $glibmm_CFLAGS";
 324         CXXLIBS="$CXXLIBS $glibmm_LIBS"], [BINDINGS_CXX="no"])
 325
 326 # The Check unit testing framework is optional. Disable if not found.
 327 PKG_CHECK_MODULES([check], [check >= 0.9.4],
 328         [have_check="yes"], [have_check="no"])
 329 AM_CONDITIONAL(HAVE_CHECK, test x"$have_check" = "xyes")
 330
 331 # The OLS driver uses serial port file descriptors directly, and therefore
 332 # will not currently work on Windows.
 333 case "$host" in
 334 *mingw*)
 335         HW_OPENBENCH_LOGIC_SNIFFER="no"
 336         ;;
 337 esac
 338
 339 AC_SUBST(SR_PKGLIBS)
 340
 341 CFLAGS="$CFLAGS -I./include/libsigrok $LIB_CFLAGS"
 342 CXXFLAGS="$CXXFLAGS -I./include -I./bindings/cxx/include $LIB_CFLAGS"
 343
 344 # Now set AM_CONDITIONALs and AC_DEFINEs for the enabled/disabled drivers.
 345
 346 AM_CONDITIONAL(HW_AGILENT_DMM, test x$HW_AGILENT_DMM = xyes)
 347 if test "x$HW_AGILENT_DMM" = "xyes"; then
 348         AC_DEFINE(HAVE_HW_AGILENT_DMM, 1, [Agilent DMM support])
 349 fi
 350
 351 AM_CONDITIONAL(HW_APPA_55II, test x$HW_APPA_55II = xyes)
 352 if test "x$HW_APPA_55II" = "xyes"; then
 353         AC_DEFINE(HAVE_HW_APPA_55II, 1, [APPA 55II support])
 354 fi
 355
 356 AM_CONDITIONAL(HW_ASIX_SIGMA, test x$HW_ASIX_SIGMA = xyes)
 357 if test "x$HW_ASIX_SIGMA" = "xyes"; then
 358         AC_DEFINE(HAVE_HW_ASIX_SIGMA, 1, [ASIX SIGMA/SIGMA2 support])
 359 fi
 360
 361 AM_CONDITIONAL(HW_ATTEN_PPS3XXX, test x$HW_ATTEN_PPS3XXX = xyes)
 362 if test "x$HW_ATTEN_PPS3XXX" = "xyes"; then
 363         AC_DEFINE(HAVE_HW_ATTEN_PPS3XXX, 1, [Atten PPS3xxx support])
 364 fi
 365
 366 AM_CONDITIONAL(HW_BRYMEN_BM86X, test x$HW_BRYMEN_BM86X = xyes)
 367 if test "x$HW_BRYMEN_BM86X" = "xyes"; then
 368         AC_DEFINE(HAVE_HW_BRYMEN_BM86X, 1, [Brymen BM86X support])
 369 fi
 370
 371 AM_CONDITIONAL(HW_BRYMEN_DMM, test x$HW_BRYMEN_DMM = xyes)
 372 if test "x$HW_BRYMEN_DMM" = "xyes"; then
 373         AC_DEFINE(HAVE_HW_BRYMEN_DMM, 1, [Brymen DMM support])
 374 fi
 375
 376 AM_CONDITIONAL(HW_CEM_DT_885X, test x$HW_CEM_DT_885X = xyes)
 377 if test "x$HW_CEM_DT_885X" = "xyes"; then
 378         AC_DEFINE(HAVE_HW_CEM_DT_885X, 1, [CEM DT-885x support])
 379 fi
 380
 381 AM_CONDITIONAL(HW_CENTER_3XX, test x$HW_CENTER_3XX = xyes)
 382 if test "x$HW_CENTER_3XX" = "xyes"; then
 383         AC_DEFINE(HAVE_HW_CENTER_3XX, 1, [Center 3xx support])
 384 fi
 385
 386 AM_CONDITIONAL(HW_CHRONOVU_LA, test x$HW_CHRONOVU_LA = xyes)
 387 if test "x$HW_CHRONOVU_LA" = "xyes"; then
 388         AC_DEFINE(HAVE_HW_CHRONOVU_LA, 1, [ChronoVu LA support])
 389 fi
 390
 391 AM_CONDITIONAL(HW_COLEAD_SLM, test x$HW_COLEAD_SLM = xyes)
 392 if test "x$HW_COLEAD_SLM" = "xyes"; then
 393         AC_DEFINE(HAVE_HW_COLEAD_SLM, 1, [Colead SLM support])
 394 fi
 395
 396 AM_CONDITIONAL(HW_CONRAD_DIGI_35_CPU, test x$HW_CONRAD_DIGI_35_CPU = xyes)
 397 if test "x$HW_CONRAD_DIGI_35_CPU" = "xyes"; then
 398         AC_DEFINE(HAVE_HW_CONRAD_DIGI_35_CPU, 1, [Conrad DIGI 35 CPU support])
 399 fi
 400
 401 AM_CONDITIONAL(HW_DEMO, test x$HW_DEMO = xyes)
 402 if test "x$HW_DEMO" = "xyes"; then
 403         AC_DEFINE(HAVE_HW_DEMO, 1, [Demo driver support])
 404 fi
 405
 406 AM_CONDITIONAL(HW_FLUKE_DMM, test x$HW_FLUKE_DMM = xyes)
 407 if test "x$HW_FLUKE_DMM" = "xyes"; then
 408         AC_DEFINE(HAVE_HW_FLUKE_DMM, 1, [Fluke DMM support])
 409 fi
 410
 411 AM_CONDITIONAL(HW_FX2LAFW, test x$HW_FX2LAFW = xyes)
 412 if test "x$HW_FX2LAFW" = "xyes"; then
 413         AC_DEFINE(HAVE_HW_FX2LAFW, 1, [fx2lafw support])
 414 fi
 415
 416 AM_CONDITIONAL(HW_GMC_MH_1X_2X, test x$HW_GMC_MH_1X_2X = xyes)
 417 if test "x$HW_GMC_MH_1X_2X" = "xyes"; then
 418         AC_DEFINE(HAVE_HW_GMC_MH_1X_2X, 1, [gmc-mh-1x-2x support])
 419 fi
 420
 421 AM_CONDITIONAL(HW_HANTEK_DSO, test x$HW_HANTEK_DSO = xyes)
 422 if test "x$HW_HANTEK_DSO" = "xyes"; then
 423         AC_DEFINE(HAVE_HW_HANTEK_DSO, 1, [Hantek DSO support])
 424 fi
 425
 426 AM_CONDITIONAL(HW_HAMEG_HMO, test x$HW_HAMEG_HMO = xyes)
 427 if test "x$HW_HAMEG_HMO" = "xyes"; then
 428         AC_DEFINE(HAVE_HW_HAMEG_HMO, 1, [Hameg HMO support])
 429 fi
 430
 431 AM_CONDITIONAL(HW_IKALOGIC_SCANALOGIC2, test x$HW_IKALOGIC_SCANALOGIC2 = xyes)
 432 if test "x$HW_IKALOGIC_SCANALOGIC2" = "xyes"; then
 433         AC_DEFINE(HAVE_HW_IKALOGIC_SCANALOGIC2, 1, [IKALOGIC Scanalogic-2 support])
 434 fi
 435
 436 AM_CONDITIONAL(HW_IKALOGIC_SCANAPLUS, test x$HW_IKALOGIC_SCANAPLUS = xyes)
 437 if test "x$HW_IKALOGIC_SCANAPLUS" = "xyes"; then
 438         AC_DEFINE(HAVE_HW_IKALOGIC_SCANAPLUS, 1, [IKALOGIC ScanaPLUS support])
 439 fi
 440
 441 AM_CONDITIONAL(HW_KECHENG_KC_330B, test x$HW_KECHENG_KC_330B = xyes)
 442 if test "x$HW_KECHENG_KC_330B" = "xyes"; then
 443         AC_DEFINE(HAVE_HW_KECHENG_KC_330B, 1, [Kecheng KC-330B support])
 444 fi
 445
 446 AM_CONDITIONAL(HW_LASCAR_EL_USB, test x$HW_LASCAR_EL_USB = xyes)
 447 if test "x$HW_LASCAR_EL_USB" = "xyes"; then
 448         AC_DEFINE(HAVE_HW_LASCAR_EL_USB, 1, [Lascar EL-USB support])
 449 fi
 450
 451 AM_CONDITIONAL(HW_MANSON_HCS_3XXX, test x$HW_MANSON_HCS_3XXX = xyes)
 452 if test "x$HW_MANSON_HCS_3XXX" = "xyes"; then
 453         AC_DEFINE(HAVE_HW_MANSON_HCS_3XXX, 1, [Manson HCS-3xxx support])
 454 fi
 455
 456 AM_CONDITIONAL(HW_MIC_985XX, test x$HW_MIC_985XX = xyes)
 457 if test "x$HW_MIC_985XX" = "xyes"; then
 458         AC_DEFINE(HAVE_HW_MIC_985XX, 1, [MIC 985xx support])
 459 fi
 460
 461 AM_CONDITIONAL(HW_MOTECH_LPS_30X, test x$HW_MOTECH_LPS_30X = xyes)
 462 if test "x$HW_MOTECH_LPS_30X" = "xyes"; then
 463         AC_DEFINE(HAVE_HW_MOTECH_LPS_30X, 1, [motech-lps-30x support])
 464 fi
 465
 466 AM_CONDITIONAL(HW_NORMA_DMM, test x$HW_NORMA_DMM = xyes)
 467 if test "x$HW_NORMA_DMM" = "xyes"; then
 468         AC_DEFINE(HAVE_HW_NORMA_DMM, 1, [Norma DMM support])
 469 fi
 470
 471 AM_CONDITIONAL(HW_OPENBENCH_LOGIC_SNIFFER, test x$HW_OPENBENCH_LOGIC_SNIFFER = xyes)
 472 if test "x$HW_OPENBENCH_LOGIC_SNIFFER" = "xyes"; then
 473         AC_DEFINE(HAVE_HW_OPENBENCH_LOGIC_SNIFFER, 1, [OpenBench Logic Sniffer (OLS) support])
 474 fi
 475
 476 AM_CONDITIONAL(HW_RIGOL_DS, test x$HW_RIGOL_DS = xyes)
 477 if test "x$HW_RIGOL_DS" = "xyes"; then
 478         AC_DEFINE(HAVE_HW_RIGOL_DS, 1, [Rigol DS support])
 479 fi
 480
 481 AM_CONDITIONAL(HW_SALEAE_LOGIC16, test x$HW_SALEAE_LOGIC16 = xyes)
 482 if test "x$HW_SALEAE_LOGIC16" = "xyes"; then
 483         AC_DEFINE(HAVE_HW_SALEAE_LOGIC16, 1, [Saleae Logic16 support])
 484 fi
 485
 486 AM_CONDITIONAL(HW_SERIAL_DMM, test x$HW_SERIAL_DMM = xyes)
 487 if test "x$HW_SERIAL_DMM" = "xyes"; then
 488         AC_DEFINE(HAVE_HW_SERIAL_DMM, 1, [Serial DMM support])
 489 fi
 490
 491 AM_CONDITIONAL(HW_SYSCLK_LWLA, test x$HW_SYSCLK_LWLA = xyes)
 492 if test "x$HW_SYSCLK_LWLA" = "xyes"; then
 493         AC_DEFINE(HAVE_HW_SYSCLK_LWLA, 1, [Sysclk LWLA support])
 494 fi
 495
 496 AM_CONDITIONAL(HW_TELEINFO, test x$HW_TELEINFO = xyes)
 497 if test "x$HW_TELEINFO" = "xyes"; then
 498         AC_DEFINE(HAVE_HW_TELEINFO, 1, [Teleinfo support])
 499 fi
 500
 501 AM_CONDITIONAL(HW_TESTO, test x$HW_TESTO = xyes)
 502 if test "x$HW_TESTO" = "xyes"; then
 503         AC_DEFINE(HAVE_HW_TESTO, 1, [Testo support])
 504 fi
 505
 506 AM_CONDITIONAL(HW_TONDAJ_SL_814, test x$HW_TONDAJ_SL_814 = xyes)
 507 if test "x$HW_TONDAJ_SL_814" = "xyes"; then
 508         AC_DEFINE(HAVE_HW_TONDAJ_SL_814, 1, [Tondaj SL-814 support])
 509 fi
 510
 511 AM_CONDITIONAL(HW_UNI_T_DMM, test x$HW_UNI_T_DMM = xyes)
 512 if test "x$HW_UNI_T_DMM" = "xyes"; then
 513         AC_DEFINE(HAVE_HW_UNI_T_DMM, 1, [UNI-T DMM support])
 514 fi
 515
 516 AM_CONDITIONAL(HW_UNI_T_UT32X, test x$HW_UNI_T_UT32X = xyes)
 517 if test "x$HW_UNI_T_UT32X" = "xyes"; then
 518         AC_DEFINE(HAVE_HW_UNI_T_UT32X, 1, [UNI-T UT32x support])
 519 fi
 520
 521 AM_CONDITIONAL(HW_VICTOR_DMM, test x$HW_VICTOR_DMM = xyes)
 522 if test "x$HW_VICTOR_DMM" = "xyes"; then
 523         AC_DEFINE(HAVE_HW_VICTOR_DMM, 1, [Victor DMM support])
 524 fi
 525
 526 AM_CONDITIONAL(HW_ZEROPLUS_LOGIC_CUBE, test x$HW_ZEROPLUS_LOGIC_CUBE = xyes)
 527 if test "x$HW_ZEROPLUS_LOGIC_CUBE" = "xyes"; then
 528         AC_DEFINE(HAVE_HW_ZEROPLUS_LOGIC_CUBE, 1, [ZEROPLUS Logic Cube support])
 529 fi
 530
 531 AM_CONDITIONAL(BINDINGS_CXX, test x$BINDINGS_CXX = xyes)
 532
 533 # Checks for header files.
 534 # These are already checked: inttypes.h stdint.h stdlib.h string.h unistd.h.
 535
 536 # Checks for typedefs, structures, and compiler characteristics.
 537 AC_C_BIGENDIAN
 538
 539 AC_SUBST(FIRMWARE_DIR, "$datadir/sigrok-firmware")
 540 AC_SUBST(MAKEFLAGS, '--no-print-directory')
 541 AC_SUBST(AM_LIBTOOLFLAGS, '--silent')
 542
 543 SR_PACKAGE_VERSION_MAJOR=sr_package_version_major
 544 SR_PACKAGE_VERSION_MINOR=sr_package_version_minor
 545 SR_PACKAGE_VERSION_MICRO=sr_package_version_micro
 546 SR_PACKAGE_VERSION=sr_package_version
 547
 548 AC_SUBST(SR_PACKAGE_VERSION_MAJOR)
 549 AC_SUBST(SR_PACKAGE_VERSION_MINOR)
 550 AC_SUBST(SR_PACKAGE_VERSION_MICRO)
 551 AC_SUBST(SR_PACKAGE_VERSION)
 552
 553 AC_CONFIG_FILES([Makefile include/libsigrok/version.h libsigrok.pc
 554         bindings/cxx/libsigrokxx.pc])
 555
 556 AC_OUTPUT
 557
 558 echo
 559 echo "libsigrok configuration summary:"
 560 echo
 561 echo "  - Package version (major.minor.micro):    $SR_PACKAGE_VERSION"
 562 echo "  - Library version (current:revision:age): $SR_LIB_VERSION"
 563 echo "  - Prefix: $prefix"
 564 echo "  - Building on: $build"
 565 echo "  - Building for: $host"
 566 echo
 567 echo "Detected libraries:"
 568 echo
 569
 570 # Note: This only works for libs with pkg-config integration.
 571 for lib in "glib-2.0 >= 2.32.0" "libzip >= 0.10" "libserialport >= 0.1.0" "librevisa >= 0.0.20130812" "libusb-1.0 >= 1.0.16" "libftdi >= 0.16" "libftdi1 >= 1.0" "check >= 0.9.4"; do
 572         optional="OPTIONAL"
 573         if test "x$lib" = "xglib-2.0 >= 2.32.0"; then optional="REQUIRED"; fi
 574         if test "x$lib" = "xlibzip >= 0.10"; then optional="REQUIRED"; fi
 575         if `$PKG_CONFIG --exists $lib`; then
 576                 ver=`$PKG_CONFIG --modversion $lib`
 577                 answer="yes ($ver)"
 578         else
 579                 answer="no"
 580         fi
 581         echo "  - ($optional) $lib: $answer"
 582 done
 583
 584 echo -e "\nEnabled hardware drivers:\n${driver_summary}"
 585
 586 echo -e "\nEnabled language bindings:\n"
 587 echo "  - C++............................. $BINDINGS_CXX"
 588 echo