configure.ac

   1 ##
   2 ## This file is part of the libserialport project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2013 Martin Ling <martin-libserialport@earth.li>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU Lesser General Public License as
   9 ## published by the Free Software Foundation, either version 3 of the
  10 ## License, or (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU Lesser General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 # libserialport package version number (NOT the same as shared lib version!).
  25 m4_define([sp_package_version_major], [0])
  26 m4_define([sp_package_version_minor], [1])
  27 m4_define([sp_package_version_micro], [1])
  28 m4_define([sp_package_version], [sp_package_version_major.sp_package_version_minor.sp_package_version_micro])
  29
  30 AC_INIT([libserialport], [sp_package_version], [martin-libserialport@earth.li],
  31         [libserialport], [http://sigrok.org/wiki/Libserialport])
  32 AC_CONFIG_HEADERS([config.h])
  33 AC_CONFIG_MACRO_DIR([autostuff])
  34 AC_CONFIG_AUX_DIR([autostuff])
  35
  36 AH_TOP([#ifndef SP_CONFIG_H
  37 #define SP_CONFIG_H])
  38 AH_BOTTOM([#endif])
  39
  40 # We require at least automake 1.11 (needed for 'silent rules').
  41 AM_INIT_AUTOMAKE([1.11 -Wall -Werror check-news])
  42 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  43 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  44
  45 # Enable more compiler warnings.
  46 CFLAGS="$CFLAGS -std=c99 -Wall -Wextra -pedantic -Wmissing-prototypes -Wshadow"
  47
  48 # Checks for programs.
  49 AC_PROG_CC
  50 AC_PROG_CPP
  51 AC_PROG_INSTALL
  52 AC_PROG_LN_S
  53
  54 # Initialize libtool.
  55 LT_INIT
  56
  57 # Initialize pkg-config.
  58 # We require at least 0.22, as "Requires.private" behaviour changed there.
  59 PKG_PROG_PKG_CONFIG([0.22])
  60
  61 # Library version for libserialport (NOT the same as the package version).
  62 # Carefully read the libtool docs before updating these numbers!
  63 # The algorithm for determining which number to change (and how) is nontrivial!
  64 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  65 SP_LIB_VERSION_CURRENT=0
  66 SP_LIB_VERSION_REVISION=0
  67 SP_LIB_VERSION_AGE=0
  68 SP_LIB_VERSION="$SP_LIB_VERSION_CURRENT:$SP_LIB_VERSION_REVISION:$SP_LIB_VERSION_AGE"
  69 SP_LIB_LDFLAGS="-version-info $SP_LIB_VERSION"
  70 AC_SUBST(SP_LIB_VERSION_CURRENT)
  71 AC_SUBST(SP_LIB_VERSION_REVISION)
  72 AC_SUBST(SP_LIB_VERSION_AGE)
  73 AC_SUBST(SP_LIB_VERSION)
  74 AC_SUBST(SP_LIB_LDFLAGS)
  75
  76 # Checks for libraries.
  77
  78 # This variable collects the pkg-config names of all detected libs.
  79 # It is then used to construct the "Requires.private:" field in the
  80 # libserialport.pc file.
  81 SP_PKGLIBS=""
  82 SP_LIBS=""
  83
  84 case $host_os in
  85 *linux*)
  86         AM_CONDITIONAL([LINUX], true)
  87         AM_CONDITIONAL([WIN32], false)
  88         AM_CONDITIONAL([MACOSX], false)
  89         AM_CONDITIONAL([FREEBSD], false)
  90         ;;
  91 *darwin*)
  92         AM_CONDITIONAL([LINUX], false)
  93         AM_CONDITIONAL([WIN32], false)
  94         AM_CONDITIONAL([MACOSX], true)
  95         AM_CONDITIONAL([FREEBSD], false)
  96         LDFLAGS="$LDFLAGS -Wl,-framework -Wl,IOKit -Wl,-framework -Wl,CoreFoundation"
  97         AC_CHECK_HEADER(IOKit/IOKitLib.h, [], [AC_MSG_ERROR([IOKit/IOKitLib.h not found])])
  98         ;;
  99 mingw* | cygwin*)
 100         AM_CONDITIONAL([LINUX], false)
 101         AM_CONDITIONAL([WIN32], true)
 102         AM_CONDITIONAL([MACOSX], false)
 103         AM_CONDITIONAL([FREEBSD], false)
 104         SP_LIBS="-lsetupapi"
 105         ;;
 106 *freebsd*)
 107         AM_CONDITIONAL([LINUX], false)
 108         AM_CONDITIONAL([WIN32], false)
 109         AM_CONDITIONAL([MACOSX], false)
 110         AM_CONDITIONAL([FREEBSD], true)
 111         ;;
 112 *)
 113         AM_CONDITIONAL([LINUX], false)
 114         AM_CONDITIONAL([WIN32], false)
 115         AM_CONDITIONAL([MACOSX], false)
 116         AM_CONDITIONAL([FREEBSD], false)
 117         AC_DEFINE(NO_ENUMERATION,,[Enumeration is unsupported])
 118         AC_DEFINE(NO_PORT_METADATA,,[Port metadata is unavailable])
 119 esac
 120
 121 AC_SUBST(SP_PKGLIBS)
 122 AC_SUBST(SP_LIBS)
 123
 124 # Define size_t if not defined as standard.
 125 AC_TYPE_SIZE_T
 126
 127 # Check for specific termios structures.
 128 AC_CHECK_TYPE([struct termios2],
 129         [AC_DEFINE(HAVE_TERMIOS2, 1,
 130                 [struct termios2 is available.])],
 131         [], [[#include <linux/termios.h>]])
 132 AC_CHECK_TYPE([struct termiox],
 133         [AC_DEFINE(HAVE_TERMIOX, 1,
 134                 [struct termiox is available.])],
 135         [], [[#include <linux/termios.h>]])
 136 AC_CHECK_MEMBERS([struct termios.c_ispeed, struct termios.c_ospeed],
 137         [AC_DEFINE(HAVE_TERMIOS_SPEED, 1,
 138                 [struct termios has c_ispeed/c_ospeed.])],
 139         [], [[#include <linux/termios.h>]])
 140 AC_CHECK_MEMBERS([struct termios2.c_ispeed, struct termios2.c_ospeed],
 141         [AC_DEFINE(HAVE_TERMIOS2_SPEED, 1,
 142                 [struct termios2 has c_ispeed/c_ospeed.])],
 143         [], [[#include <linux/termios.h>]])
 144
 145 # Check for the BOTHER definition, needed for setting arbitrary baud rates.
 146 # We can't just #ifdef BOTHER in the code, because of the separation between
 147 # code using libc headers and code using kernel termios.h headers.
 148 AC_MSG_CHECKING(for BOTHER)
 149 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 150 #include <linux/termios.h>
 151 ]],
 152 [[
 153 #ifndef BOTHER
 154 #error BOTHER is not defined
 155 #endif
 156 ]])],
 157 [AC_DEFINE(HAVE_BOTHER, 1, [BOTHER macro is available])
 158 AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no])])
 159
 160 # Check for serial_struct.
 161 AC_CHECK_TYPE([struct serial_struct],
 162         [AC_DEFINE(HAVE_SERIAL_STRUCT, 1,
 163                 [struct serial is available.])],
 164         [], [[#include <linux/serial.h>]])
 165
 166 saved="$CFLAGS"; CFLAGS="$CFLAGS -Werror"
 167 AC_DEFINE(SP_API,,[Macro preceding public API functions])
 168 AC_DEFINE(SP_PRIV,,[Macro preceding private functions])
 169 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 170                 __attribute__((visibility("hidden"))) void foo(void) { }
 171         ]])],
 172         [AC_DEFINE(SP_API, __attribute__((visibility("default"))))]
 173         [AC_DEFINE(SP_PRIV, __attribute__((visibility("hidden"))))],
 174 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 175                 __declspec(dllexport) void foo(void) { }
 176         ]])],
 177         [AC_DEFINE(SP_API, __declspec(dllexport))]
 178         [AC_DEFINE(SP_PRIV,)],
 179         [AC_DEFINE(SP_API,)]
 180         [AC_DEFINE(SP_PRIV,)]))
 181 CFLAGS="$saved"
 182
 183 AC_SUBST(MAKEFLAGS, '--no-print-directory')
 184 AC_SUBST(AM_LIBTOOLFLAGS, '--silent')
 185
 186 SP_PACKAGE_VERSION_MAJOR=sp_package_version_major
 187 SP_PACKAGE_VERSION_MINOR=sp_package_version_minor
 188 SP_PACKAGE_VERSION_MICRO=sp_package_version_micro
 189 SP_PACKAGE_VERSION=sp_package_version
 190
 191 AC_SUBST(SP_PACKAGE_VERSION_MAJOR)
 192 AC_SUBST(SP_PACKAGE_VERSION_MINOR)
 193 AC_SUBST(SP_PACKAGE_VERSION_MICRO)
 194 AC_SUBST(SP_PACKAGE_VERSION)
 195
 196 AC_CONFIG_FILES([Makefile libserialport.h libserialport.pc])
 197
 198 AC_OUTPUT
 199
 200 echo
 201 echo "libserialport configuration summary:"
 202 echo
 203 echo "  - Package version (major.minor.micro):    $SP_PACKAGE_VERSION"
 204 echo "  - Library version (current:revision:age): $SP_LIB_VERSION"
 205 echo "  - Prefix: $prefix"
 206 echo "  - Building on: $build"
 207 echo "  - Building for: $host"
 208 echo