configure.ac

   1 ##
   2 ## This file is part of the libserialport project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2013 Martin Ling <martin-libserialport@earth.li>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU Lesser General Public License as
   9 ## published by the Free Software Foundation, either version 3 of the
  10 ## License, or (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU Lesser General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 # libserialport package version number (NOT the same as shared lib version!).
  25 m4_define([sp_package_version_major], [0])
  26 m4_define([sp_package_version_minor], [2])
  27 m4_define([sp_package_version_micro], [0])
  28 m4_define([sp_package_version], [sp_package_version_major.sp_package_version_minor.sp_package_version_micro])
  29
  30 AC_INIT([libserialport], [sp_package_version], [martin-libserialport@earth.li],
  31         [libserialport], [http://sigrok.org/wiki/Libserialport])
  32 AC_CONFIG_MACRO_DIR([autostuff])
  33 AC_CONFIG_AUX_DIR([autostuff])
  34
  35 AC_CANONICAL_TARGET
  36
  37 # We require at least automake 1.11 (needed for 'silent rules').
  38 AM_INIT_AUTOMAKE([1.11 -Wall -Werror check-news])
  39 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  40 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  41
  42 # Enable more compiler warnings.
  43 CFLAGS="$CFLAGS -std=c99 -Wall -Wextra -pedantic"
  44
  45 # Checks for programs.
  46 AC_PROG_CC
  47 AC_PROG_CPP
  48 AC_PROG_INSTALL
  49 AC_PROG_LN_S
  50
  51 # Initialize libtool.
  52 LT_INIT
  53
  54 # Initialize pkg-config.
  55 # We require at least 0.22, as "Requires.private" behaviour changed there.
  56 PKG_PROG_PKG_CONFIG([0.22])
  57
  58 # Library version for libserialport (NOT the same as the package version).
  59 # Carefully read the libtool docs before updating these numbers!
  60 # The algorithm for determining which number to change (and how) is nontrivial!
  61 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  62 SP_LIB_VERSION_CURRENT=0
  63 SP_LIB_VERSION_REVISION=0
  64 SP_LIB_VERSION_AGE=0
  65 SP_LIB_VERSION="$SP_LIB_VERSION_CURRENT:$SP_LIB_VERSION_REVISION:$SP_LIB_VERSION_AGE"
  66 SP_LIB_LDFLAGS="-version-info $SP_LIB_VERSION"
  67 AC_SUBST(SP_LIB_VERSION_CURRENT)
  68 AC_SUBST(SP_LIB_VERSION_REVISION)
  69 AC_SUBST(SP_LIB_VERSION_AGE)
  70 AC_SUBST(SP_LIB_VERSION)
  71 AC_SUBST(SP_LIB_LDFLAGS)
  72
  73 # Checks for libraries.
  74
  75 # This variable collects the pkg-config names of all detected libs.
  76 # It is then used to construct the "Requires.private:" field in the
  77 # libserialport.pc file.
  78 SP_PKGLIBS=""
  79 SP_LIBS=""
  80
  81 case $target_os in
  82 *linux*)
  83         AM_CONDITIONAL([LINUX], true)
  84         AM_CONDITIONAL([WIN32], false)
  85         AM_CONDITIONAL([MACOSX], false)
  86         ;;
  87 *darwin*)
  88         AM_CONDITIONAL([LINUX], false)
  89         AM_CONDITIONAL([WIN32], false)
  90         AM_CONDITIONAL([MACOSX], true)
  91         LDFLAGS="$LDFLAGS -Wl,-framework -Wl,IOKit -Wl,-framework -Wl,CoreFoundation"
  92         AC_CHECK_HEADER(IOKit/IOKitLib.h, [], [AC_MSG_ERROR([IOKit/IOKitLib.h not found])])
  93         ;;
  94 mingw* | cygwin*)
  95         AM_CONDITIONAL([LINUX], false)
  96         AM_CONDITIONAL([WIN32], true)
  97         AM_CONDITIONAL([MACOSX], false)
  98         SP_LIBS="-lsetupapi -luuid"
  99         ;;
 100 *)
 101         AM_CONDITIONAL([LINUX], false)
 102         AM_CONDITIONAL([WIN32], false)
 103         AM_CONDITIONAL([MACOSX], false)
 104         AC_DEFINE(NO_ENUMERATION)
 105         AC_DEFINE(NO_PORT_METADATA)
 106 esac
 107
 108 AC_SUBST(SP_PKGLIBS)
 109 AC_SUBST(SP_LIBS)
 110
 111 # Define size_t if not defined as standard.
 112 AC_TYPE_SIZE_T
 113
 114 # Check for specific termios structures.
 115 AC_CHECK_TYPE([struct termios2], [AC_DEFINE(HAVE_TERMIOS2, 1)], [], [[#include <linux/termios.h>]])
 116 AC_CHECK_TYPE([struct termiox], [AC_DEFINE(HAVE_TERMIOX, 1)], [], [[#include <linux/termios.h>]])
 117 AC_CHECK_MEMBERS([struct termios.c_ispeed, struct termios.c_ospeed],
 118         [AC_DEFINE(HAVE_TERMIOS_SPEED, 1)], [], [[#include <linux/termios.h>]])
 119 AC_CHECK_MEMBERS([struct termios2.c_ispeed, struct termios2.c_ospeed],
 120         [AC_DEFINE(HAVE_TERMIOS2_SPEED, 1)], [], [[#include <linux/termios.h>]])
 121
 122 # Check for readlinkat.
 123 AC_CHECK_FUNC([readlinkat], [AC_DEFINE(HAVE_READLINKAT, 1)], [])
 124
 125 # Check for serial_struct.
 126 AC_CHECK_TYPE([struct serial_struct], [AC_DEFINE(HAVE_SERIAL_STRUCT, 1)],
 127         [], [[#include <linux/serial.h>]])
 128
 129 saved="$CFLAGS"; CFLAGS="$CFLAGS -Werror"
 130 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 131                 __attribute__((visibility("hidden"))) void foo(void) { }
 132         ]])],
 133         [AC_DEFINE(SP_API , __attribute__((visibility("default"))))]
 134         [AC_DEFINE(SP_PRIV, __attribute__((visibility("hidden"))))],
 135 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 136                 __declspec(dllexport) void foo(void) { }
 137         ]])],
 138         [AC_DEFINE(SP_API , __declspec(dllexport))]
 139         [AC_DEFINE(SP_PRIV,)],
 140         [AC_DEFINE(SP_API,)]
 141         [AC_DEFINE(SP_PRIV,)]))
 142 CFLAGS="$saved"
 143
 144 AC_SUBST(MAKEFLAGS, '--no-print-directory')
 145 AC_SUBST(AM_LIBTOOLFLAGS, '--silent')
 146
 147 SP_PACKAGE_VERSION_MAJOR=sp_package_version_major
 148 SP_PACKAGE_VERSION_MINOR=sp_package_version_minor
 149 SP_PACKAGE_VERSION_MICRO=sp_package_version_micro
 150 SP_PACKAGE_VERSION=sp_package_version
 151
 152 AC_SUBST(SP_PACKAGE_VERSION_MAJOR)
 153 AC_SUBST(SP_PACKAGE_VERSION_MINOR)
 154 AC_SUBST(SP_PACKAGE_VERSION_MICRO)
 155 AC_SUBST(SP_PACKAGE_VERSION)
 156
 157 AC_CONFIG_FILES([Makefile libserialport.h libserialport.pc])
 158
 159 AC_OUTPUT
 160
 161 echo
 162 echo "libserialport configuration summary:"
 163 echo
 164 echo "  - Package version (major.minor.micro):    $SP_PACKAGE_VERSION"
 165 echo "  - Library version (current:revision:age): $SP_LIB_VERSION"
 166 echo "  - Prefix: $prefix"
 167 echo "  - Building on: $build"
 168 echo "  - Building for: $host"
 169 echo