]>
Commit | Line | Data |
---|---|---|
a7171293 UH |
1 | ## |
2 | ## This file is part of the PulseView project. | |
3 | ## | |
f4097c59 | 4 | ## Copyright (C) 2013-2014 Uwe Hermann <uwe@hermann-uwe.de> |
a7171293 UH |
5 | ## |
6 | ## This program is free software; you can redistribute it and/or modify | |
7 | ## it under the terms of the GNU General Public License as published by | |
8 | ## the Free Software Foundation; either version 2 of the License, or | |
9 | ## (at your option) any later version. | |
10 | ## | |
11 | ## This program is distributed in the hope that it will be useful, | |
12 | ## but WITHOUT ANY WARRANTY; without even the implied warranty of | |
13 | ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the | |
14 | ## GNU General Public License for more details. | |
15 | ## | |
16 | ## You should have received a copy of the GNU General Public License | |
efdec55a | 17 | ## along with this program; if not, see <http://www.gnu.org/licenses/>. |
a7171293 UH |
18 | ## |
19 | ||
20 | # | |
21 | # This file is used to create the PulseView Windows installer via NSIS. | |
22 | # It is meant for use in a cross-compile setup (not for native builds). | |
23 | # See the 'sigrok-cross-mingw' script in the sigrok-util repo for details. | |
24 | # | |
25 | # NSIS documentation: | |
26 | # http://nsis.sourceforge.net/Docs/ | |
27 | # http://nsis.sourceforge.net/Docs/Modern%20UI%202/Readme.html | |
28 | # | |
29 | ||
30 | # Include the "Modern UI" header, which gives us the usual Windows look-n-feel. | |
31 | !include "MUI2.nsh" | |
32 | ||
63ebd7fe SA |
33 | # Include the file association header so that we can register file extensions. |
34 | !include "FileAssociation.nsh" | |
35 | ||
a7171293 UH |
36 | |
37 | # --- Global stuff ------------------------------------------------------------ | |
38 | ||
39 | # Installer/product name. | |
40 | Name "PulseView" | |
41 | ||
42 | # Filename of the installer executable. | |
f9cb49cc | 43 | OutFile "pulseview-@PV_VERSION_STRING@-installer.exe" |
a7171293 UH |
44 | |
45 | # Where to install the application. | |
46 | InstallDir "$PROGRAMFILES\sigrok\PulseView" | |
47 | ||
48 | # Request admin privileges for Windows Vista and Windows 7. | |
49 | # http://nsis.sourceforge.net/Docs/Chapter4.html | |
50 | RequestExecutionLevel admin | |
51 | ||
52 | # Local helper definitions. | |
53 | !define REGSTR "Software\Microsoft\Windows\CurrentVersion\Uninstall\PulseView" | |
54 | ||
55 | ||
56 | # --- MUI interface configuration --------------------------------------------- | |
57 | ||
58 | # Use the following icon for the installer EXE file. | |
fce541c3 | 59 | !define MUI_ICON "@PROJECT_SOURCE_DIR@/icons/pulseview.ico" |
a7171293 UH |
60 | |
61 | # Show a nice image at the top of each installer page. | |
62 | !define MUI_HEADERIMAGE | |
63 | ||
64 | # Don't automatically go to the Finish page so the user can check the log. | |
65 | !define MUI_FINISHPAGE_NOAUTOCLOSE | |
66 | ||
67 | # Upon "cancel", ask the user if he really wants to abort the installer. | |
68 | !define MUI_ABORTWARNING | |
69 | ||
70 | # Don't force the user to accept the license, just show it. | |
71 | # Details: http://trac.videolan.org/vlc/ticket/3124 | |
72 | !define MUI_LICENSEPAGE_BUTTON $(^NextBtn) | |
73 | !define MUI_LICENSEPAGE_TEXT_BOTTOM "Click Next to continue." | |
74 | ||
a7171293 UH |
75 | # Path where the cross-compiled sigrok tools and libraries are located. |
76 | # Change this to where-ever you installed libsigrok.a and so on. | |
f9cb49cc | 77 | !define CROSS "@CMAKE_INSTALL_PREFIX@" |
a7171293 | 78 | |
bf627f70 SA |
79 | # Defines for WinAPI SHChangeNotify call. |
80 | !define SHCNE_ASSOCCHANGED 0x8000000 | |
81 | !define SHCNF_IDLIST 0 | |
82 | ||
a7171293 | 83 | |
a53b8efe | 84 | # --- Functions/Macros -------------------------------------------------------- |
63ebd7fe SA |
85 | |
86 | Function register_sr_files | |
bf627f70 SA |
87 | ${registerExtension} "$INSTDIR\pulseview.exe" ".sr" "sigrok session file" |
88 | ||
89 | # Force Windows to update the icon cache so that the icon for .sr files shows up. | |
90 | System::Call 'Shell32::SHChangeNotify(i ${SHCNE_ASSOCCHANGED}, i ${SHCNF_IDLIST}, i 0, i 0)' | |
63ebd7fe SA |
91 | FunctionEnd |
92 | ||
a53b8efe SA |
93 | # Inspired by http://nsis.sourceforge.net/Create_Internet_Shorcuts_during_installation |
94 | !Macro "CreateURL" "URLFile" "URLSite" "URLDesc" | |
95 | WriteINIStr "$INSTDIR\${URLFile}.URL" "InternetShortcut" "URL" "${URLSite}" | |
96 | CreateShortCut "$SMPROGRAMS\sigrok\PulseView\${URLFile}.lnk" "$INSTDIR\${URLFile}.url" "" \ | |
97 | "$INSTDIR\pulseview.exe" 0 "SW_SHOWNORMAL" "" "${URLDesc}" | |
98 | !MacroEnd | |
63ebd7fe | 99 | |
a7171293 UH |
100 | # --- MUI pages --------------------------------------------------------------- |
101 | ||
102 | # Show a nice "Welcome to the ... Setup Wizard" page. | |
103 | !insertmacro MUI_PAGE_WELCOME | |
104 | ||
105 | # Show the license of the project. | |
f9cb49cc | 106 | !insertmacro MUI_PAGE_LICENSE "@PROJECT_SOURCE_DIR@/COPYING" |
a7171293 UH |
107 | |
108 | # Show a screen which allows the user to select which components to install. | |
109 | !insertmacro MUI_PAGE_COMPONENTS | |
110 | ||
111 | # Allow the user to select a different install directory. | |
112 | !insertmacro MUI_PAGE_DIRECTORY | |
113 | ||
114 | # Perform the actual installation, i.e. install the files. | |
115 | !insertmacro MUI_PAGE_INSTFILES | |
116 | ||
63ebd7fe SA |
117 | # Insert the "Show Readme" button in the finish dialog. We repurpose it for |
118 | # registering the .sr file extension. This way, we don't need to add in-depth | |
119 | # modifications to the finish page. | |
120 | !define MUI_FINISHPAGE_SHOWREADME "" | |
121 | !define MUI_FINISHPAGE_SHOWREADME_CHECKED | |
122 | !define MUI_FINISHPAGE_SHOWREADME_TEXT "Register .sr files with PulseView" | |
123 | !define MUI_FINISHPAGE_SHOWREADME_FUNCTION register_sr_files | |
124 | ||
a7171293 UH |
125 | # Show a final "We're done, click Finish to close this wizard" message. |
126 | !insertmacro MUI_PAGE_FINISH | |
127 | ||
128 | # Pages used for the uninstaller. | |
129 | !insertmacro MUI_UNPAGE_WELCOME | |
130 | !insertmacro MUI_UNPAGE_CONFIRM | |
131 | !insertmacro MUI_UNPAGE_INSTFILES | |
132 | !insertmacro MUI_UNPAGE_FINISH | |
133 | ||
134 | ||
135 | # --- MUI language files ------------------------------------------------------ | |
136 | ||
137 | # Select an installer language (required!). | |
138 | !insertmacro MUI_LANGUAGE "English" | |
139 | ||
140 | ||
141 | # --- Default section --------------------------------------------------------- | |
142 | ||
143 | Section "PulseView (required)" Section1 | |
a7171293 UH |
144 | # This section is gray (can't be disabled) in the component list. |
145 | SectionIn RO | |
146 | ||
147 | # Install the file(s) specified below into the specified directory. | |
148 | SetOutPath "$INSTDIR" | |
149 | ||
f4097c59 | 150 | # License file. |
f9cb49cc | 151 | File "@PROJECT_SOURCE_DIR@/COPYING" |
a7171293 | 152 | |
f4097c59 | 153 | # PulseView (statically linked, includes all libs). |
a7171293 UH |
154 | File "${CROSS}/bin/pulseview.exe" |
155 | ||
d64796ed | 156 | # Zadig (used for installing WinUSB drivers). |
48898353 UH |
157 | File "${CROSS}/zadig.exe" |
158 | File "${CROSS}/zadig_xp.exe" | |
159 | ||
1f763c17 | 160 | # Python |
0ebddfac UH |
161 | File "${CROSS}/python34.dll" |
162 | File "${CROSS}/python34.zip" | |
1f763c17 | 163 | |
a7e53a4a DE |
164 | SetOutPath "$INSTDIR\share" |
165 | ||
f4097c59 | 166 | # Protocol decoders. |
a7e53a4a | 167 | File /r /x "__pycache__" /x "*.pyc" "${CROSS}/share/libsigrokdecode" |
a7171293 | 168 | |
d8823c8c | 169 | # Firmware files. |
a7e53a4a | 170 | File /r "${CROSS}/share/sigrok-firmware" |
d8823c8c | 171 | |
a7171293 UH |
172 | # Generate the uninstaller executable. |
173 | WriteUninstaller "$INSTDIR\Uninstall.exe" | |
174 | ||
175 | # Create a sub-directory in the start menu. | |
176 | CreateDirectory "$SMPROGRAMS\sigrok" | |
177 | CreateDirectory "$SMPROGRAMS\sigrok\PulseView" | |
178 | ||
179 | # Create a shortcut for the PulseView application. | |
77243b3e | 180 | SetOutPath "$INSTDIR" |
a7171293 UH |
181 | CreateShortCut "$SMPROGRAMS\sigrok\PulseView\PulseView.lnk" \ |
182 | "$INSTDIR\pulseview.exe" "" "$INSTDIR\pulseview.exe" \ | |
183 | 0 SW_SHOWNORMAL \ | |
184 | "" "Open-source, portable sigrok GUI" | |
185 | ||
a3110cab SA |
186 | # Create a shortcut for the PulseView application running in debug mode. |
187 | CreateShortCut "$SMPROGRAMS\sigrok\PulseView\PulseView (Debug).lnk" \ | |
188 | "$INSTDIR\pulseview.exe" "-l 5" "$INSTDIR\pulseview.exe" \ | |
189 | 0 SW_SHOWNORMAL \ | |
190 | "" "Open-source, portable sigrok GUI (debug log level)" | |
191 | ||
a7171293 | 192 | # Create a shortcut for the uninstaller. |
b8f93b68 | 193 | CreateShortCut "$SMPROGRAMS\sigrok\PulseView\Uninstall PulseView.lnk" \ |
a7171293 UH |
194 | "$INSTDIR\Uninstall.exe" "" "$INSTDIR\Uninstall.exe" 0 \ |
195 | SW_SHOWNORMAL "" "Uninstall PulseView" | |
196 | ||
0518e9c9 | 197 | # Create a shortcut for the Zadig executable. |
b8f93b68 | 198 | CreateShortCut "$SMPROGRAMS\sigrok\PulseView\Zadig (PulseView).lnk" \ |
0518e9c9 | 199 | "$INSTDIR\zadig.exe" "" "$INSTDIR\zadig.exe" 0 \ |
b8f93b68 | 200 | SW_SHOWNORMAL "" "Zadig (PulseView)" |
0518e9c9 UH |
201 | |
202 | # Create a shortcut for the Zadig executable (for Win XP). | |
b8f93b68 | 203 | CreateShortCut "$SMPROGRAMS\sigrok\PulseView\Zadig (PulseView, Win XP).lnk" \ |
0518e9c9 | 204 | "$INSTDIR\zadig_xp.exe" "" "$INSTDIR\zadig_xp.exe" 0 \ |
b8f93b68 | 205 | SW_SHOWNORMAL "" "Zadig (PulseView, Win XP)" |
0518e9c9 | 206 | |
a53b8efe SA |
207 | # Create shortcuts to the HTML and PDF manuals, respectively. |
208 | !InsertMacro "CreateURL" "PulseView HTML manual" "https://sigrok.org/doc/pulseview/@PV_MANUAL_VERSION@/manual.html" "PulseView HTML manual" | |
209 | !InsertMacro "CreateURL" "PulseView PDF manual" "https://sigrok.org/doc/pulseview/@PV_MANUAL_VERSION@/manual.pdf" "PulseView PDF manual" | |
210 | ||
a7171293 UH |
211 | # Create registry keys for "Add/remove programs" in the control panel. |
212 | WriteRegStr HKLM "${REGSTR}" "DisplayName" "PulseView" | |
213 | WriteRegStr HKLM "${REGSTR}" "UninstallString" \ | |
214 | "$\"$INSTDIR\Uninstall.exe$\"" | |
215 | WriteRegStr HKLM "${REGSTR}" "InstallLocation" "$\"$INSTDIR$\"" | |
216 | WriteRegStr HKLM "${REGSTR}" "DisplayIcon" \ | |
fce541c3 | 217 | "$\"$INSTDIR\pulseview.ico$\"" |
a7171293 UH |
218 | WriteRegStr HKLM "${REGSTR}" "Publisher" "sigrok" |
219 | WriteRegStr HKLM "${REGSTR}" "HelpLink" \ | |
220 | "http://sigrok.org/wiki/PulseView" | |
221 | WriteRegStr HKLM "${REGSTR}" "URLUpdateInfo" \ | |
222 | "http://sigrok.org/wiki/Downloads" | |
223 | WriteRegStr HKLM "${REGSTR}" "URLInfoAbout" "http://sigrok.org" | |
f9cb49cc | 224 | WriteRegStr HKLM "${REGSTR}" "DisplayVersion" "@PV_VERSION_STRING@" |
a7171293 UH |
225 | WriteRegStr HKLM "${REGSTR}" "Contact" \ |
226 | "sigrok-devel@lists.sourceforge.org" | |
227 | WriteRegStr HKLM "${REGSTR}" "Comments" \ | |
228 | "This is a Qt based sigrok GUI." | |
229 | ||
230 | # Display "Remove" instead of "Modify/Remove" in the control panel. | |
231 | WriteRegDWORD HKLM "${REGSTR}" "NoModify" 1 | |
232 | WriteRegDWORD HKLM "${REGSTR}" "NoRepair" 1 | |
a7171293 UH |
233 | SectionEnd |
234 | ||
4bbd53c9 SA |
235 | Section /o "Example data" Section2 |
236 | # Example *.sr files. | |
237 | SetOutPath "$INSTDIR\examples" | |
238 | ||
239 | File "${CROSS}/share/sigrok-dumps/arm_trace/stm32f105/trace_example.sr" | |
240 | File "${CROSS}/share/sigrok-dumps/am230x/am2301/am2301_1mhz.sr" | |
241 | File "${CROSS}/share/sigrok-dumps/avr_isp/atmega88/isp_atmega88_erase_chip.sr" | |
242 | File "${CROSS}/share/sigrok-dumps/can/microchip_mcp2515dm-bm/mcp2515dm-bm-125kbits_msg_222_5bytes.sr" | |
243 | File "${CROSS}/share/sigrok-dumps/dcf77/pollin_dcf1_module/dcf77_120s.sr" | |
244 | File "${CROSS}/share/sigrok-dumps/i2c/eeprom_24xx/microchip_24lc02b/hantek_6022be_powerup.sr" | |
245 | File "${CROSS}/share/sigrok-dumps/i2c/eeprom_24xx/microchip_24lc64/sainsmart_dds120_powerup_scl_sda_analog.sr" | |
246 | File "${CROSS}/share/sigrok-dumps/i2c/potentiometer/analog_devices_ad5258/ad5258_read_once_write_continuously_triangle.sr" | |
247 | File "${CROSS}/share/sigrok-dumps/mdio/lan8720a/lan8720a_read_write_read.sr" | |
248 | File "${CROSS}/share/sigrok-dumps/onewire/owfs/ds28ea00.sr" | |
249 | File "${CROSS}/share/sigrok-dumps/sdcard/sd_mode/rcar-h2/cmd23_cmd18.sr" | |
250 | File "${CROSS}/share/sigrok-dumps/spi/mx25l1605d/mx25l1605d_read.sr" | |
251 | File "${CROSS}/share/sigrok-dumps/uart/gps/mtk3339/mtk3339_8n1_9600.sr" | |
252 | File "${CROSS}/share/sigrok-dumps/usb/hid/mouse/olimex_stm32-h103_usb_hid/olimex_stm32-h103_usb_hid.sr" | |
253 | File "${CROSS}/share/sigrok-dumps/z80/kc85/kc85-20mhz.sr" | |
254 | ||
255 | # Create a shortcut for the example data folder. | |
0e206885 | 256 | CreateShortCut "$SMPROGRAMS\sigrok\PulseView\Examples (PulseView).lnk" \ |
4bbd53c9 SA |
257 | "$INSTDIR\examples" "" "$INSTDIR\examples" 0 \ |
258 | SW_SHOWNORMAL "" "" | |
259 | SectionEnd | |
260 | ||
a7171293 | 261 | |
a7171293 UH |
262 | # --- Uninstaller section ----------------------------------------------------- |
263 | ||
264 | Section "Uninstall" | |
a7171293 UH |
265 | # Always delete the uninstaller first (yes, this really works). |
266 | Delete "$INSTDIR\Uninstall.exe" | |
267 | ||
268 | # Delete the application, the application data, and related libs. | |
269 | Delete "$INSTDIR\COPYING" | |
270 | Delete "$INSTDIR\pulseview.exe" | |
48898353 UH |
271 | Delete "$INSTDIR\zadig.exe" |
272 | Delete "$INSTDIR\zadig_xp.exe" | |
0ebddfac UH |
273 | Delete "$INSTDIR\python34.dll" |
274 | Delete "$INSTDIR\python34.zip" | |
a7171293 | 275 | |
a7e53a4a | 276 | # Delete all decoders and everything else in libsigrokdecode/. |
a7171293 | 277 | # There could be *.pyc files or __pycache__ subdirs and so on. |
a7e53a4a | 278 | RMDir /r "$INSTDIR\share\libsigrokdecode" |
a7171293 | 279 | |
d8823c8c | 280 | # Delete the firmware files. |
a7e53a4a | 281 | RMDir /r "$INSTDIR\share\sigrok-firmware" |
d8823c8c | 282 | |
95052d70 UH |
283 | # Delete the example *.sr files. |
284 | RMDir /r "$INSTDIR\examples\*" | |
285 | ||
a53b8efe SA |
286 | # Delete the URL files for the manual. |
287 | Delete "$INSTDIR\PulseView HTML manual.url" | |
288 | Delete "$INSTDIR\PulseView PDF manual.url" | |
289 | ||
a7171293 | 290 | # Delete the install directory and its sub-directories. |
a7e53a4a | 291 | RMDir "$INSTDIR\share" |
95052d70 | 292 | RMDir "$INSTDIR\examples" |
a7171293 UH |
293 | RMDir "$INSTDIR" |
294 | ||
295 | # Delete the links from the start menu. | |
296 | Delete "$SMPROGRAMS\sigrok\PulseView\PulseView.lnk" | |
a53b8efe | 297 | Delete "$SMPROGRAMS\sigrok\PulseView\PulseView (Debug).lnk" |
b8f93b68 UH |
298 | Delete "$SMPROGRAMS\sigrok\PulseView\Uninstall PulseView.lnk" |
299 | Delete "$SMPROGRAMS\sigrok\PulseView\Zadig (PulseView).lnk" | |
300 | Delete "$SMPROGRAMS\sigrok\PulseView\Zadig (PulseView, Win XP).lnk" | |
0e206885 | 301 | Delete "$SMPROGRAMS\sigrok\PulseView\Examples (PulseView).lnk" |
a7171293 | 302 | |
a53b8efe SA |
303 | # Delete the links to the manual. |
304 | Delete "$SMPROGRAMS\sigrok\PulseView\PulseView HTML manual.lnk" | |
305 | Delete "$SMPROGRAMS\sigrok\PulseView\PulseView PDF manual.lnk" | |
306 | ||
a7171293 UH |
307 | # Delete the sub-directory in the start menu. |
308 | RMDir "$SMPROGRAMS\sigrok\PulseView" | |
309 | RMDir "$SMPROGRAMS\sigrok" | |
310 | ||
311 | # Delete the registry key(s). | |
312 | DeleteRegKey HKLM "${REGSTR}" | |
313 | ||
63ebd7fe SA |
314 | # Unregister any previously registered file extension(s). |
315 | ${unregisterExtension} ".sr" "sigrok session file" | |
316 | ||
ebe0a196 SA |
317 | # Force Windows to update the icon cache so that the icon for .sr files is reset. |
318 | System::Call 'Shell32::SHChangeNotify(i ${SHCNE_ASSOCCHANGED}, i ${SHCNF_IDLIST}, i 0, i 0)' | |
a7171293 UH |
319 | SectionEnd |
320 | ||
321 | ||
322 | # --- Component selection section descriptions -------------------------------- | |
323 | ||
4bbd53c9 SA |
324 | LangString DESC_Section1 ${LANG_ENGLISH} "This installs the PulseView sigrok GUI, some firmware files, the protocol decoders, and all required libraries." |
325 | LangString DESC_Section2 ${LANG_ENGLISH} "This installs some example files that you can use to try out the features sigrok has to offer." | |
a7171293 UH |
326 | |
327 | !insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN | |
4bbd53c9 SA |
328 | !insertmacro MUI_DESCRIPTION_TEXT ${Section1} $(DESC_Section1) |
329 | !insertmacro MUI_DESCRIPTION_TEXT ${Section2} $(DESC_Section2) | |
a7171293 UH |
330 | !insertmacro MUI_FUNCTION_DESCRIPTION_END |
331 |