]>
Commit | Line | Data |
---|---|---|
826938d8 | 1 | ## |
50985c20 | 2 | ## This file is part of the libsigrok project. |
826938d8 | 3 | ## |
c73d2ea4 | 4 | ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com> |
d375b3c3 | 5 | ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com> |
826938d8 UH |
6 | ## |
7 | ## This program is free software: you can redistribute it and/or modify | |
8 | ## it under the terms of the GNU General Public License as published by | |
9 | ## the Free Software Foundation, either version 3 of the License, or | |
10 | ## (at your option) any later version. | |
11 | ## | |
12 | ## This program is distributed in the hope that it will be useful, | |
13 | ## but WITHOUT ANY WARRANTY; without even the implied warranty of | |
14 | ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the | |
15 | ## GNU General Public License for more details. | |
16 | ## | |
17 | ## You should have received a copy of the GNU General Public License | |
18 | ## along with this program. If not, see <http://www.gnu.org/licenses/>. | |
19 | ## | |
20 | ||
ef7228ba UH |
21 | # We require at least autoconf 2.63 (AC_INIT format changed there). |
22 | AC_PREREQ([2.63]) | |
826938d8 | 23 | |
33b20ce8 | 24 | AC_INIT([libsigrok], [0.6.0], |
7f289d14 | 25 | [sigrok-devel@lists.sourceforge.net], |
db8ae7b9 | 26 | [libsigrok], [http://www.sigrok.org]) |
ea1d5351 | 27 | AC_CONFIG_MACRO_DIR([m4]) |
d8521c93 | 28 | AC_CONFIG_AUX_DIR([autostuff]) |
24138539 | 29 | AC_CONFIG_HEADERS([config.h include/libsigrok/version.h]) |
826938d8 | 30 | |
ef7228ba | 31 | # We require at least automake 1.11 (needed for 'silent rules'). |
9ac018d0 | 32 | AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define nostdinc subdir-objects check-news color-tests]) |
bbb3996c | 33 | AM_SILENT_RULES([yes]) |
432e5e95 | 34 | m4_ifdef([AM_PROG_AR], [AM_PROG_AR]) |
826938d8 | 35 | |
bcc3694f DE |
36 | AC_CANONICAL_HOST |
37 | ||
826938d8 | 38 | # Checks for programs. |
826938d8 | 39 | AC_PROG_CC |
c23c8659 | 40 | AC_PROG_CXX |
826938d8 UH |
41 | AC_PROG_INSTALL |
42 | AC_PROG_LN_S | |
43 | ||
bb203cde UH |
44 | # Required for per-target flags or subdir-objects with C sources. |
45 | AM_PROG_CC_C_O | |
46 | ||
56c8705e DE |
47 | # Set the standard the C library headers should conform to. |
48 | AH_VERBATIM([_POSIX_C_SOURCE], [/* The targeted POSIX standard. */ | |
49 | #ifndef _POSIX_C_SOURCE | |
50 | # define _POSIX_C_SOURCE 200112L | |
51 | #endif]) | |
52 | ||
4512ccd3 DE |
53 | # Get compiler versions. |
54 | SR_PROG_VERSION([$CC], [sr_cc_version]) | |
55 | SR_PROG_VERSION([$CXX], [sr_cxx_version]) | |
56 | ||
3841c4c5 | 57 | # Check for optional make features. |
5b9e9bba DE |
58 | SR_PROG_MAKE_ORDER_ONLY |
59 | ||
826938d8 UH |
60 | # Initialize libtool. |
61 | LT_INIT | |
62 | ||
24138539 DE |
63 | # Set up the libsigrok version defines. |
64 | SR_PKG_VERSION_SET([SR_PACKAGE_VERSION], [AC_PACKAGE_VERSION]) | |
b2478a23 | 65 | |
3af71f0d | 66 | # Library version for libsigrok (NOT the same as the package version). |
826938d8 UH |
67 | # Carefully read the libtool docs before updating these numbers! |
68 | # The algorithm for determining which number to change (and how) is nontrivial! | |
69 | # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info | |
89c82260 | 70 | # Format: current:revision:age. |
9b355aa1 | 71 | SR_LIB_VERSION_SET([SR_LIB_VERSION], [4:0:0]) |
826938d8 | 72 | |
655b116c DE |
73 | AM_CONDITIONAL([WIN32], [test -z "${host_os##mingw*}" || test -z "${host_os##cygwin*}"]) |
74 | ||
1f61c22f DE |
75 | ############################# |
76 | ## Optional dependencies ## | |
77 | ############################# | |
de44e114 | 78 | |
8c2024e0 DE |
79 | AC_LANG([C]) |
80 | ||
1f61c22f DE |
81 | # Initialize pkg-config. |
82 | # We require at least 0.22, as "Requires.private" behaviour changed there. | |
83 | PKG_PROG_PKG_CONFIG([0.22]) | |
bcacb863 | 84 | |
1bb196e4 DE |
85 | # Keep track of all checked modules so we can list them at the end. |
86 | SR_PKG_CHECK_SUMMARY([sr_pkglibs_summary]) | |
87 | ||
88 | # Collect the pkg-config module names of all dependencies in SR_PKGLIBS. | |
1f61c22f DE |
89 | # These are used to derive the compiler flags and for the "Requires.private" |
90 | # field in the generated libsigrok.pc file. | |
1bb196e4 | 91 | SR_VAR_OPT_PKG([SR_PKGLIBS], [sr_deps_avail]) |
65489c1a | 92 | SR_PKGLIBS_TESTS= |
1f61c22f DE |
93 | SR_PKGLIBS_CXX= |
94 | SR_PKGLIBS_PYTHON= | |
27d44cf6 | 95 | SR_PKGLIBS_RUBY= |
8c2024e0 | 96 | SR_EXTRA_LIBS= |
9d8f363d | 97 | SR_EXTRA_CXX_LIBS= |
1f61c22f | 98 | |
1df81f4b | 99 | SR_ARG_OPT_PKG([libserialport], [LIBSERIALPORT], , |
1f61c22f | 100 | [libserialport >= 0.1.1]) |
1f61c22f | 101 | |
689749b7 | 102 | SR_ARG_OPT_PKG([libftdi], [LIBFTDI], , [libftdi1 >= 1.0]) |
1f61c22f | 103 | |
aa29b255 | 104 | # pkg-config file names: MinGW/MacOSX: hidapi; Linux: hidapi-hidraw/-libusb |
4417074c GS |
105 | SR_ARG_OPT_PKG([libhidapi], [LIBHIDAPI], , |
106 | [hidapi >= 0.8.0], [hidapi-hidraw >= 0.8.0], [hidapi-libusb >= 0.8.0]) | |
107 | ||
aa29b255 | 108 | SR_ARG_OPT_PKG([libbluez], [LIBBLUEZ], , [bluez >= 4.0]) |
f085705f | 109 | |
cae33a58 AS |
110 | SR_ARG_OPT_PKG([libnettle], [LIBNETTLE], , [nettle]) |
111 | ||
1f61c22f DE |
112 | # FreeBSD comes with an "integrated" libusb-1.0-style USB API. |
113 | # This means libusb-1.0 is always available; no need to check for it. | |
c1adbb1e DE |
114 | # On Windows, require the latest version we can get our hands on, |
115 | # until the new generic event handling has seen an official release. | |
116 | AS_CASE([$host_os], | |
117 | [freebsd*], [sr_libusb_req='libusb-1.0' sr_have_libusb=yes], | |
118 | [mingw*], [sr_libusb_req='libusb-1.0 >= 1.0.20'], | |
119 | [sr_libusb_req='libusb-1.0 >= 1.0.16']) | |
1f61c22f | 120 | |
2cbde151 | 121 | SR_ARG_OPT_PKG([libusb], [LIBUSB_1_0], [NEED_USB], |
c1adbb1e | 122 | [$sr_libusb_req]) |
c23c8659 | 123 | |
2cbde151 | 124 | SR_ARG_OPT_PKG([librevisa], [LIBREVISA], [NEED_VISA], |
1f61c22f | 125 | [librevisa >= 0.0.20130412]) |
d92de05a | 126 | |
2cbde151 | 127 | SR_ARG_OPT_PKG([libgpib], [LIBGPIB], [NEED_GPIB], |
1f61c22f DE |
128 | [libgpib]) |
129 | ||
8c2024e0 DE |
130 | SR_ARG_OPT_CHECK([libieee1284], [LIBIEEE1284],, [ |
131 | sr_save_LIBS=$LIBS | |
132 | LIBS="-lieee1284 $LIBS" | |
133 | AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <ieee1284.h>]], | |
134 | [[(void) ieee1284_open(0, 0, 0);]])], | |
135 | [sr_have_libieee1284=yes], [sr_have_libieee1284=no]) | |
39cf2004 | 136 | LIBS=$sr_save_LIBS |
8c2024e0 DE |
137 | ]) |
138 | AS_IF([test "x$sr_have_libieee1284" = xyes], | |
139 | [SR_PREPEND([SR_EXTRA_LIBS], [-lieee1284])]) | |
140 | ||
ebcd1aba DH |
141 | SR_ARG_OPT_PKG([libgio], [LIBGIO], , [gio-2.0 >= 2.24.0]) |
142 | ||
f085705f GS |
143 | # See if any of the (potentially platform specific) libs are available |
144 | # which provide some means of Bluetooth communication. | |
145 | AS_IF([test "x$sr_have_libbluez" = xyes], | |
146 | sr_have_bluetooth=yes, sr_have_bluetooth=no) | |
147 | AS_IF([test "x$sr_have_bluetooth" = xyes], | |
148 | [AC_DEFINE([HAVE_BLUETOOTH], [1], [Specifies whether Bluetooth communication is supported.])]) | |
ebcd1aba DH |
149 | AS_IF([test "x$sr_have_bluetooth" = xyes], |
150 | [SR_APPEND([sr_deps_avail], [bluetooth_comm])]) | |
f085705f GS |
151 | |
152 | AS_IF([test "x$sr_have_libserialport" = xyes -o "x$sr_have_libhidapi" = xyes -o "x$sr_have_bluetooth" = xyes], | |
1df81f4b GS |
153 | sr_have_serial_comm=yes, sr_have_serial_comm=no) |
154 | AS_IF([test "x$sr_have_serial_comm" = xyes], | |
155 | [AC_DEFINE([HAVE_SERIAL_COMM], [1], [Specifies whether serial communication is supported.])]) | |
156 | AS_IF([test "x$sr_have_serial_comm" = xyes], | |
157 | [SR_APPEND([sr_deps_avail], [serial_comm])]) | |
158 | AM_CONDITIONAL([NEED_SERIAL], [test "x$sr_have_serial_comm" = xyes]) | |
159 | ||
1f61c22f DE |
160 | ###################### |
161 | ## Feature checks ## | |
162 | ###################### | |
f7740954 | 163 | |
aba69262 | 164 | # The Check unit testing framework is optional. Disable if not found. |
65489c1a | 165 | SR_PKG_CHECK([check], [SR_PKGLIBS_TESTS], [check >= 0.9.4]) |
1f61c22f DE |
166 | AM_CONDITIONAL([HAVE_CHECK], [test "x$sr_have_check" = xyes]) |
167 | ||
e662d9e8 | 168 | # Enable the C99 standard if possible, and enforce the use |
b84a7331 DE |
169 | # of SR_API to explicitly mark all public API functions. |
170 | SR_EXTRA_CFLAGS= | |
e662d9e8 | 171 | SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [C99], [-std=c99 -c99 -AC99 -qlanglvl=extc99]) |
b84a7331 DE |
172 | SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [visibility], [-fvisibility=hidden]) |
173 | ||
4cf2f34f | 174 | SR_ARG_ENABLE_WARNINGS([SR_WFLAGS], [-Wall], [-Wall -Wextra -Wmissing-prototypes]) |
1f61c22f DE |
175 | |
176 | # Check host characteristics. | |
bbb3996c | 177 | AC_SYS_LARGEFILE |
1f61c22f | 178 | AC_C_BIGENDIAN |
79bb0e97 | 179 | |
1bb196e4 DE |
180 | AC_CHECK_HEADERS([sys/mman.h], [SR_APPEND([sr_deps_avail], [sys_mman_h])]) |
181 | AC_CHECK_HEADERS([sys/ioctl.h], [SR_APPEND([sr_deps_avail], [sys_ioctl_h])]) | |
182 | AC_CHECK_HEADERS([sys/timerfd.h], [SR_APPEND([sr_deps_avail], [sys_timerfd_h])]) | |
1f61c22f | 183 | |
bc8ff24d | 184 | # We need to link against the Winsock2 library for SCPI over TCP. |
8c2024e0 | 185 | AS_CASE([$host_os], [mingw*], [SR_PREPEND([SR_EXTRA_LIBS], [-lws2_32])]) |
bc8ff24d DE |
186 | |
187 | # libm (the standard math library) is always needed. | |
188 | SR_SEARCH_LIBS([SR_EXTRA_LIBS], [pow], [m]) | |
189 | ||
1f61c22f | 190 | # RPC is only needed for VXI support. |
a3fe36d0 | 191 | AC_CACHE_CHECK([for SunRPC support], [sr_cv_have_sunrpc], |
1f61c22f DE |
192 | [AC_LINK_IFELSE([AC_LANG_PROGRAM( |
193 | [[#include <rpc/rpc.h>]m4_newline[CLIENT *rpc_test(void);]], | |
194 | [[(void) clnt_create("", 0, 0, "");]])], | |
a3fe36d0 SA |
195 | [RPC_CFLAGS=""; RPC_LIBS=""; sr_cv_have_sunrpc=yes], |
196 | [sr_cv_have_sunrpc=no])]) | |
197 | PKG_CHECK_MODULES([TIRPC], | |
198 | [libtirpc], | |
199 | [RPC_CFLAGS=$TIRPC_CFLAGS; SR_PREPEND([SR_EXTRA_LIBS], [$TIRPC_LIBS]); sr_cv_have_tirpc=yes], | |
200 | [sr_cv_have_tirpc=no]) | |
201 | AS_IF([test "x$sr_cv_have_sunrpc" = xyes -o "x$sr_cv_have_tirpc" = xyes], | |
202 | [sr_cv_have_rpc=yes], [sr_cv_have_rpc=no]) | |
203 | ||
204 | AC_SUBST(RPC_CFLAGS) | |
205 | AC_SUBST(RPC_LIBS) | |
206 | ||
1f61c22f | 207 | AS_IF([test "x$sr_cv_have_rpc" = xyes], |
a3fe36d0 SA |
208 | [AC_DEFINE([HAVE_RPC], [1], [Specifies whether we have RPC support (either by SunRPC or libtirpc).])]) |
209 | ||
1f61c22f DE |
210 | # VXI support is only compiled if RPC support was found. |
211 | AM_CONDITIONAL([NEED_RPC], [test "x$sr_cv_have_rpc" = xyes]) | |
212 | ||
e9869966 SB |
213 | # Check for compiler support of 128 bit integers |
214 | AC_CHECK_TYPES([__int128_t, __uint128_t], [], [], []) | |
215 | ||
d37c7109 DE |
216 | ######################## |
217 | ## Hardware drivers ## | |
218 | ######################## | |
219 | ||
220 | # Keep track of all drivers so we can list them at the end. | |
1bb196e4 | 221 | SR_VAR_SUMMARY([sr_driver_summary]) |
d37c7109 DE |
222 | |
223 | # Check whether the sr_deps_avail list contains all of the arguments. | |
224 | # Unavailable dependencies are collected in sr_deps_missing. | |
225 | sr_check_driver_deps() { | |
226 | sr_deps_missing= | |
227 | for sr_dep | |
228 | do | |
229 | AS_CASE([" $sr_deps_avail "], [*" $sr_dep "*],, | |
26b67f11 | 230 | [SR_APPEND([sr_deps_missing], [', '], [$sr_dep])]) |
d37c7109 | 231 | done |
4ed3d9b6 | 232 | test -z "$sr_deps_missing" || return 1 |
d37c7109 DE |
233 | } |
234 | ||
235 | AC_ARG_ENABLE([all-drivers], | |
236 | [AS_HELP_STRING([--enable-all-drivers], | |
237 | [enable all drivers by default [default=yes]])], | |
238 | [], [enable_all_drivers=yes]) | |
239 | ||
240 | ## _SR_DRIVER(Device name, driver-name, var-name, [dependencies...]) | |
241 | m4_define([_SR_DRIVER], [ | |
b8b727e4 | 242 | AC_ARG_ENABLE([$2], |
d37c7109 DE |
243 | [AS_HELP_STRING([--enable-$2], [enable $1 support])], |
244 | [$3=$enableval], [$3=$enable_all_drivers]) | |
245 | ||
246 | AS_IF([test "x[$]$3" = xyes], [sr_hw_info=yes[]m4_ifval([$4], [ | |
4ed3d9b6 DE |
247 | sr_check_driver_deps $4 \ |
248 | || $3=no sr_hw_info="no (missing: $sr_deps_missing)" | |
d37c7109 | 249 | ])], [sr_hw_info='no (disabled)']) |
1bb196e4 | 250 | sr_driver_summary_append "$2" "$sr_hw_info" |
d37c7109 DE |
251 | |
252 | AM_CONDITIONAL([$3], [test "x[$]$3" = xyes]) | |
bf85ea21 | 253 | AM_COND_IF([$3], [AC_DEFINE([HAVE_$3], [1], [Whether to support $1 device.]) AC_DEFINE([HAVE_DRIVERS], [1], [Whether at least one driver is enabled.])]) |
d37c7109 DE |
254 | ]) |
255 | ||
256 | ## SR_DRIVER(Device name, driver-name, [dependencies...]) | |
257 | m4_define([SR_DRIVER], | |
258 | [_SR_DRIVER([$1], [$2], m4_expand([AS_TR_CPP([HW_$2])]), [$3])]) | |
259 | ||
bb15350e GS |
260 | SR_DRIVER([Agilent DMM], [agilent-dmm], [serial_comm]) |
261 | SR_DRIVER([Appa 55II], [appa-55ii], [serial_comm]) | |
262 | SR_DRIVER([Arachnid Labs Re:load Pro], [arachnid-labs-re-load-pro], [serial_comm]) | |
d37c7109 | 263 | SR_DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma], [libftdi]) |
bb15350e | 264 | SR_DRIVER([Atten PPS3xxx], [atten-pps3xxx], [serial_comm]) |
d37c7109 DE |
265 | SR_DRIVER([BayLibre ACME], [baylibre-acme], [sys_timerfd_h]) |
266 | SR_DRIVER([BeagleLogic], [beaglelogic], [sys_mman_h sys_ioctl_h]) | |
bb15350e GS |
267 | SR_DRIVER([CEM DT-885x], [cem-dt-885x], [serial_comm]) |
268 | SR_DRIVER([Center 3xx], [center-3xx], [serial_comm]) | |
382bea82 | 269 | SR_DRIVER([ChronoVu LA], [chronovu-la], [libusb libftdi]) |
bb15350e GS |
270 | SR_DRIVER([Colead SLM], [colead-slm], [serial_comm]) |
271 | SR_DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu], [serial_comm]) | |
d37c7109 | 272 | SR_DRIVER([demo], [demo]) |
44b46d70 | 273 | SR_DRIVER([DreamSourceLab DSLogic], [dreamsourcelab-dslogic], [libusb]) |
e756c595 | 274 | SR_DRIVER([Fluke 45], [fluke-45]) |
bb15350e | 275 | SR_DRIVER([Fluke DMM], [fluke-dmm], [serial_comm]) |
f2273382 | 276 | SR_DRIVER([FTDI LA], [ftdi-la], [libusb libftdi]) |
d37c7109 | 277 | SR_DRIVER([fx2lafw], [fx2lafw], [libusb]) |
bb15350e GS |
278 | SR_DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x], [serial_comm]) |
279 | SR_DRIVER([GW Instek GDS-800], [gwinstek-gds-800], [serial_comm]) | |
280 | SR_DRIVER([GW Instek GPD], [gwinstek-gpd], [serial_comm]) | |
281 | SR_DRIVER([Hameg HMO], [hameg-hmo], [serial_comm]) | |
5089a143 | 282 | SR_DRIVER([Hantek 4032L], [hantek-4032l], [libusb]) |
f2a66a8e | 283 | SR_DRIVER([Hantek 6xxx], [hantek-6xxx], [libusb]) |
d37c7109 | 284 | SR_DRIVER([Hantek DSO], [hantek-dso], [libusb]) |
00b2a092 | 285 | SR_DRIVER([HP 3457A], [hp-3457a]) |
d2c1730a | 286 | SR_DRIVER([HP 3478A], [hp-3478a], [libgpib]) |
96e05afa | 287 | SR_DRIVER([Hung-Chang DSO-2100], [hung-chang-dso-2100], [libieee1284]) |
d37c7109 DE |
288 | SR_DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2], [libusb]) |
289 | SR_DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus], [libftdi]) | |
8a9788e2 | 290 | SR_DRIVER([IPDBG LA], [ipdbg-la]) |
f21b6983 | 291 | SR_DRIVER([ITECH IT8500], [itech-it8500], [serial_comm]) |
d37c7109 | 292 | SR_DRIVER([Kecheng KC-330B], [kecheng-kc-330b], [libusb]) |
bb15350e | 293 | SR_DRIVER([KERN scale], [kern-scale], [serial_comm]) |
f2cd2deb | 294 | SR_DRIVER([Kingst LA2016], [kingst-la2016], [libusb]) |
bb15350e | 295 | SR_DRIVER([Korad KAxxxxP], [korad-kaxxxxp], [serial_comm]) |
d37c7109 | 296 | SR_DRIVER([Lascar EL-USB], [lascar-el-usb], [libusb]) |
c7b17bcb | 297 | SR_DRIVER([LeCroy LogicStudio], [lecroy-logicstudio], [libusb]) |
bb08570f | 298 | SR_DRIVER([LeCroy X-Stream], [lecroy-xstream]) |
bb15350e | 299 | SR_DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx], [serial_comm]) |
9b1101d6 | 300 | SR_DRIVER([Mastech MS6514], [mastech-ms6514], [serial_comm]) |
d37c7109 | 301 | SR_DRIVER([maynuo-m97], [maynuo-m97]) |
bb15350e | 302 | SR_DRIVER([MIC 985xx], [mic-985xx], [serial_comm]) |
a5c0259c | 303 | SR_DRIVER([Microchip PICkit2], [microchip-pickit2], [libusb]) |
ebcd1aba | 304 | SR_DRIVER([Mooshimeter DMM], [mooshimeter-dmm], [bluetooth_comm libgio]) |
bb15350e GS |
305 | SR_DRIVER([Motech LPS 30x], [motech-lps-30x], [serial_comm]) |
306 | SR_DRIVER([Norma DMM], [norma-dmm], [serial_comm]) | |
307 | SR_DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer], [serial_comm]) | |
308 | SR_DRIVER([PCE PCE-322A], [pce-322a], [serial_comm]) | |
d37c7109 | 309 | SR_DRIVER([Pipistrello-OLS], [pipistrello-ols], [libftdi]) |
bb15350e | 310 | SR_DRIVER([RDTech DPSxxxx/DPHxxxx], [rdtech-dps], [serial_comm]) |
8b607a24 | 311 | SR_DRIVER([RDTech UMXX], [rdtech-um], [serial_comm]) |
cae33a58 | 312 | SR_DRIVER([RDTech TCXX], [rdtech-tc], [serial_comm libnettle]) |
d37c7109 | 313 | SR_DRIVER([Rigol DS], [rigol-ds]) |
068db0fb | 314 | SR_DRIVER([Rigol DG], [rigol-dg]) |
bb15350e | 315 | SR_DRIVER([Rohde&Schwarz SME-0x], [rohde-schwarz-sme-0x], [serial_comm]) |
d37c7109 | 316 | SR_DRIVER([Saleae Logic16], [saleae-logic16], [libusb]) |
b6189f7c | 317 | SR_DRIVER([Saleae Logic Pro], [saleae-logic-pro], [libusb]) |
7a396ff5 | 318 | SR_DRIVER([SCPI DMM], [scpi-dmm]) |
d37c7109 | 319 | SR_DRIVER([SCPI PPS], [scpi-pps]) |
bb15350e GS |
320 | SR_DRIVER([serial DMM], [serial-dmm], [serial_comm]) |
321 | SR_DRIVER([serial LCR], [serial-lcr], [serial_comm]) | |
89f5fab9 | 322 | SR_DRIVER([Siglent SDS], [siglent-sds]) |
d37c7109 | 323 | SR_DRIVER([Sysclk LWLA], [sysclk-lwla], [libusb]) |
8da8c826 | 324 | SR_DRIVER([Sysclk SLA5032], [sysclk-sla5032], [libusb]) |
bb15350e | 325 | SR_DRIVER([Teleinfo], [teleinfo], [serial_comm]) |
d37c7109 | 326 | SR_DRIVER([Testo], [testo], [libusb]) |
bb15350e | 327 | SR_DRIVER([Tondaj SL-814], [tondaj-sl-814], [serial_comm]) |
d37c7109 | 328 | SR_DRIVER([UNI-T DMM], [uni-t-dmm], [libusb]) |
ebc51109 | 329 | SR_DRIVER([UNI-T UT181A], [uni-t-ut181a], [serial_comm]) |
164c5ae5 | 330 | SR_DRIVER([UNI-T UT32x], [uni-t-ut32x], [serial_comm]) |
d37c7109 DE |
331 | SR_DRIVER([Yokogawa DL/DLM], [yokogawa-dlm]) |
332 | SR_DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube], [libusb]) | |
bb15350e | 333 | SR_DRIVER([ZKETECH EBD-USB], [zketech-ebd-usb], [serial_comm]) |
1f61c22f DE |
334 | |
335 | ############################### | |
336 | ## Language bindings setup ## | |
337 | ############################### | |
338 | ||
d37c7109 | 339 | AC_LANG([C++]) |
4cf2f34f | 340 | SR_ARG_ENABLE_WARNINGS([SR_WXXFLAGS], [-Wall], [-Wall -Wextra]) |
d37c7109 | 341 | |
1f61c22f DE |
342 | AC_ARG_ENABLE([bindings], |
343 | [AS_HELP_STRING([--enable-bindings], [build language bindings [default=yes]])], | |
344 | [], [enable_bindings=yes]) | |
176c7219 | 345 | |
1f61c22f DE |
346 | AC_ARG_ENABLE([cxx], |
347 | [AS_HELP_STRING([--enable-cxx], [build C++ bindings [default=yes]])], | |
348 | [], [enable_cxx=$enable_bindings]) | |
a0b277ba | 349 | |
1f61c22f DE |
350 | AC_ARG_ENABLE([python], |
351 | [AS_HELP_STRING([--enable-python], [build Python bindings [default=yes]])], | |
352 | [], [enable_python=$enable_bindings]) | |
826938d8 | 353 | |
27d44cf6 | 354 | AC_ARG_ENABLE([ruby], |
856433b2 UH |
355 | [AS_HELP_STRING([--enable-ruby], [build Ruby bindings [default=yes]])], |
356 | [], [enable_ruby=$enable_bindings]) | |
27d44cf6 | 357 | |
1f61c22f DE |
358 | AC_ARG_ENABLE([java], |
359 | [AS_HELP_STRING([--enable-java], [build Java bindings [default=yes]])], | |
360 | [], [enable_java=$enable_bindings]) | |
361 | ||
362 | #################### | |
363 | ## C++ bindings ## | |
364 | #################### | |
365 | ||
366 | sr_cxx_missing= | |
367 | ||
368 | # Check if the C++ compiler supports the C++11 standard. | |
b571f84c | 369 | AX_CXX_COMPILE_STDCXX([11], [noext], [optional]) |
26b67f11 DE |
370 | AS_IF([test "x$HAVE_CXX11" != x1], |
371 | [SR_APPEND([sr_cxx_missing], [', '], ['C++11'])]) | |
1f61c22f DE |
372 | |
373 | # The C++ bindings need glibmm. | |
374 | SR_PKG_CHECK([glibmm], [SR_PKGLIBS_CXX], [glibmm-2.4 >= 2.32.0]) | |
26b67f11 DE |
375 | AS_IF([test "x$sr_have_glibmm" != xyes], |
376 | [SR_APPEND([sr_cxx_missing], [', '], [glibmm])]) | |
1f61c22f DE |
377 | |
378 | # The C++ bindings use Doxygen to parse libsigrok symbols. | |
379 | AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes], [no]) | |
26b67f11 DE |
380 | AS_IF([test "x$HAVE_DOXYGEN" != xyes], |
381 | [SR_APPEND([sr_cxx_missing], [', '], [Doxygen])]) | |
1f61c22f | 382 | |
9d8f363d MC |
383 | # Link C++ code with gnustl_shared if it exists (Android) |
384 | SR_SEARCH_LIBS([SR_EXTRA_CXX_LIBS], [__cxa_throw], [gnustl_shared]) | |
385 | ||
1f61c22f DE |
386 | # Python is needed for the C++ bindings. |
387 | AM_PATH_PYTHON([2.7], | |
388 | [HAVE_PYTHON=yes], | |
26b67f11 DE |
389 | [HAVE_PYTHON=no |
390 | SR_APPEND([sr_cxx_missing], [', '], [Python])]) | |
1f61c22f DE |
391 | |
392 | AS_IF([test -z "$sr_cxx_missing"], | |
393 | [BINDINGS_CXX=$enable_cxx], [BINDINGS_CXX=no]) | |
394 | AM_CONDITIONAL([BINDINGS_CXX], [test "x$BINDINGS_CXX" = xyes]) | |
395 | ||
396 | # C++ bindings want stoi and stod. | |
397 | AM_COND_IF([BINDINGS_CXX], [ | |
398 | AC_CACHE_CHECK([for stoi and stod], [sr_cv_have_stoi_stod], | |
399 | [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string>]], | |
400 | [[(void) std::stoi("1"); (void) std::stod("1.0");]])], | |
401 | [sr_cv_have_stoi_stod=yes], [sr_cv_have_stoi_stod=no])]) | |
402 | AS_IF([test "x$sr_cv_have_stoi_stod" = xyes], | |
403 | [AC_DEFINE([HAVE_STOI_STOD], [1], | |
404 | [Specifies whether we have the stoi and stod functions.])]) | |
405 | ]) | |
406 | ||
407 | ####################### | |
408 | ## Python bindings ## | |
409 | ####################### | |
410 | ||
26b67f11 DE |
411 | AS_IF([test "x$BINDINGS_CXX" = xyes], |
412 | [sr_python_missing=], | |
413 | [sr_python_missing='C++ bindings']) | |
1f61c22f | 414 | |
3d869132 DE |
415 | # Extract major and minor version number of the Python interpreter. |
416 | sr_pymajor=${PYTHON_VERSION%%.*} | |
417 | sr_pyminor=${PYTHON_VERSION#*.} | |
418 | ||
419 | # The Python bindings need Python development files. Check for either | |
420 | # Python 3 or Python 2 headers depending on the interpreter version. | |
1f61c22f | 421 | SR_PKG_CHECK([python_dev], [SR_PKGLIBS_PYTHON], |
3d869132 DE |
422 | [python = $PYTHON_VERSION], |
423 | [python$sr_pymajor = $PYTHON_VERSION], | |
424 | [python$sr_pymajor$sr_pyminor = $PYTHON_VERSION], | |
425 | [python-$PYTHON_VERSION = $PYTHON_VERSION]) | |
426 | ||
26b67f11 DE |
427 | AS_IF([test "x$sr_have_python_dev" != xyes], |
428 | [SR_APPEND([sr_python_missing], [', '], [Headers])]) | |
1f61c22f DE |
429 | |
430 | # PyGObject is needed for the Python bindings. | |
431 | SR_PKG_CHECK([pygobject], [SR_PKGLIBS_PYTHON], [pygobject-3.0 >= 3.0.0]) | |
26b67f11 DE |
432 | AS_IF([test "x$sr_have_pygobject" != xyes], |
433 | [SR_APPEND([sr_python_missing], [', '], [PyGObject])]) | |
1f61c22f DE |
434 | |
435 | PKG_CHECK_EXISTS([pygobject-3.0 < 3.7.91], | |
436 | [AC_DEFINE([PYGOBJECT_FLAGS_SIGNED], [1], | |
437 | [Whether last argument to pyg_flags_get_value() is signed.])]) | |
438 | ||
eb2373f1 DE |
439 | # The Python bindings need the setuptools and numpy Python modules. |
440 | # We'll let it go through even if the AX macro wasn't found, as the | |
441 | # Python modules may still be there. | |
442 | m4_ifdef([AX_PYTHON_MODULE], [ | |
443 | AX_PYTHON_MODULE([setuptools]) | |
444 | AX_PYTHON_MODULE([numpy]) | |
445 | ], [ | |
446 | HAVE_PYMOD_SETUPTOOLS=yes | |
447 | HAVE_PYMOD_NUMPY=yes | |
448 | m4_warn([unsupported], | |
449 | [Missing macro AX_PYTHON_MODULE: no check for setuptools and numpy]) | |
450 | ]) | |
26b67f11 DE |
451 | AS_IF([test "x$HAVE_PYMOD_SETUPTOOLS" != xyes], |
452 | [SR_APPEND([sr_python_missing], [', '], [setuptools])]) | |
eb2373f1 DE |
453 | AS_IF([test "x$HAVE_PYMOD_NUMPY" != xyes], |
454 | [SR_APPEND([sr_python_missing], [', '], [numpy])]) | |
1f61c22f DE |
455 | |
456 | # The Python bindings use SWIG to generate code. | |
c9901879 | 457 | AC_CHECK_PROGS([SWIG], [swig swig4.0 swig3.0 swig2.0]) |
e469259a AJ |
458 | AS_IF([test "x$SWIG" != x], |
459 | AC_MSG_CHECKING([for $SWIG version]) | |
27272a70 | 460 | [SWIG_VERSION=`$SWIG -version 2>&1 | sed -n 's/SWIG Version //p'`] |
e469259a | 461 | AC_MSG_RESULT([$SWIG_VERSION])) |
26b67f11 DE |
462 | AS_IF([test "x$SWIG" = x], |
463 | [SR_APPEND([sr_python_missing], [', '], [SWIG])]) | |
1f61c22f DE |
464 | |
465 | AS_IF([test -z "$sr_python_missing"], | |
466 | [BINDINGS_PYTHON=$enable_python], [BINDINGS_PYTHON=no]) | |
467 | AM_CONDITIONAL([BINDINGS_PYTHON], [test "x$BINDINGS_PYTHON" = xyes]) | |
468 | ||
27d44cf6 AJ |
469 | ##################### |
470 | ## Ruby bindings ## | |
471 | ##################### | |
472 | ||
473 | AS_IF([test "x$BINDINGS_CXX" = xyes], | |
474 | [sr_ruby_missing=], | |
475 | [sr_ruby_missing='C++ bindings']) | |
476 | ||
e9227902 AJ |
477 | AC_PATH_PROGS(RUBY, ["${RUBY-ruby}"], []) |
478 | AS_IF([test "x$RUBY" != x], | |
479 | AC_MSG_CHECKING([for Ruby version]) | |
480 | [RUBY_VERSION=`$RUBY -e 'puts RUBY_VERSION'`] | |
481 | AC_MSG_RESULT([$RUBY_VERSION]) | |
482 | [RUBY_DLEXT=`$RUBY -rrbconfig -e 'puts RbConfig::CONFIG[["DLEXT"]]'`] | |
483 | AC_SUBST(RUBY_DLEXT)) | |
27d44cf6 AJ |
484 | |
485 | AS_IF([test "x$RUBY" = x], | |
e9227902 | 486 | [SR_APPEND([sr_ruby_missing], [', '], [Ruby])]) |
27d44cf6 AJ |
487 | |
488 | # Extract major and minor version number of the Ruby interpreter. | |
489 | sr_rbmajor=${RUBY_VERSION%%.*} | |
490 | sr_rbminor=${RUBY_VERSION#*.} | |
491 | sr_rbminor=${sr_rbminor%%.*} | |
492 | ||
493 | # The Ruby bindings need Ruby development files. | |
494 | SR_PKG_CHECK([ruby_dev], [SR_PKGLIBS_RUBY], | |
339d12df UH |
495 | [ruby >= 2.5.0], |
496 | [ruby-$sr_rbmajor.$sr_rbminor >= 2.5.0]) | |
27d44cf6 AJ |
497 | |
498 | AS_IF([test "x$sr_have_ruby_dev" != xyes], | |
499 | [SR_APPEND([sr_ruby_missing], [', '], [Headers])]) | |
500 | ||
e469259a | 501 | # The Ruby bindings use SWIG >= 3.0.8 to generate code. |
27d44cf6 | 502 | AS_IF([test "x$SWIG" = x], |
e469259a AJ |
503 | [SR_APPEND([sr_ruby_missing], [', '], [SWIG])], |
504 | [AS_VERSION_COMPARE($SWIG_VERSION, "3.0.8", | |
505 | [SR_APPEND([sr_ruby_missing], [', '], ['SWIG >= 3.0.8'])])]) | |
27d44cf6 AJ |
506 | |
507 | AS_IF([test -z "$sr_ruby_missing"], | |
508 | [BINDINGS_RUBY=$enable_ruby], [BINDINGS_RUBY=no]) | |
509 | AM_CONDITIONAL([BINDINGS_RUBY], [test "x$BINDINGS_RUBY" = xyes]) | |
27d44cf6 | 510 | |
1f61c22f DE |
511 | #################### |
512 | ## Java bindings ## | |
513 | #################### | |
514 | ||
26b67f11 DE |
515 | AS_IF([test "x$BINDINGS_CXX" = xyes], |
516 | [sr_java_missing=], | |
517 | [sr_java_missing='C++ bindings']) | |
1f61c22f DE |
518 | |
519 | # The Java bindings use SWIG to generate code. | |
26b67f11 DE |
520 | AS_IF([test "x$SWIG" = x], |
521 | [SR_APPEND([sr_java_missing], [', '], [SWIG])]) | |
4f10853e | 522 | |
9fcf4d0b | 523 | # Find Java compiler and JNI includes for Java bindings. |
9fcf4d0b | 524 | AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no]) |
26b67f11 DE |
525 | AS_IF([test "x$HAVE_JAVAC" = xno], |
526 | [SR_APPEND([sr_java_missing], [', '], [JavaC])]) | |
1f61c22f DE |
527 | |
528 | AC_ARG_WITH([jni-include-path], | |
529 | [AS_HELP_STRING([[--with-jni-include-path=DIR-LIST (space-separated)]], | |
530 | [specify JNI include directories [default=detect]])], | |
531 | [JNI_INCLUDE_DIRS=" $withval"], [JNI_INCLUDE_DIRS=]) | |
532 | ||
533 | JNI_CPPFLAGS= | |
534 | AS_IF([test "x$enable_java$HAVE_JAVAC" = xyesyes], [ | |
9fcf4d0b | 535 | AX_PROG_JAVAC |
1f61c22f DE |
536 | AS_IF([test -z "$JNI_INCLUDE_DIRS" && test "x$cross_compiling" != xyes], [ |
537 | ## Work around the totally broken logic in AX_JNI_INCLUDE_DIR: | |
538 | ## If we can find jni.h without any special search path, skip | |
539 | ## the execution of the broken macro to increase our chances of | |
540 | ## success. | |
541 | AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <jni.h>]], [])],, | |
542 | [AX_JNI_INCLUDE_DIR]) | |
543 | ]) | |
544 | ]) | |
545 | for sr_dir in $JNI_INCLUDE_DIRS | |
546 | do | |
26b67f11 | 547 | SR_APPEND([JNI_CPPFLAGS], ["-I$sr_dir"]) |
1f61c22f DE |
548 | done |
549 | AC_SUBST([JNI_CPPFLAGS]) | |
550 | ||
551 | sr_save_cppflags=$CPPFLAGS | |
26b67f11 DE |
552 | SR_APPEND([CPPFLAGS], [$JNI_CPPFLAGS]) |
553 | AC_CHECK_HEADER([jni.h],, | |
554 | [SR_APPEND([sr_java_missing], [', '], ['JNI headers'])]) | |
1f61c22f DE |
555 | CPPFLAGS=$sr_save_cppflags |
556 | ||
557 | AS_IF([test -z "$sr_java_missing"], | |
558 | [BINDINGS_JAVA=$enable_java], [BINDINGS_JAVA=no]) | |
559 | AM_CONDITIONAL([BINDINGS_JAVA], [test "x$BINDINGS_JAVA" = xyes]) | |
560 | ||
561 | ############################## | |
562 | ## Finalize configuration ## | |
563 | ############################## | |
564 | ||
565 | # Add mandatory dependencies to module list. | |
a6dc3dac | 566 | SR_APPEND([SR_PKGLIBS], ['libzip >= 0.10']) |
1f61c22f DE |
567 | AC_SUBST([SR_PKGLIBS]) |
568 | ||
569 | # Retrieve the compile and link flags for all modules combined. | |
570 | # Also, bail out at this point if any module dependency is not met. | |
571 | PKG_CHECK_MODULES([LIBSIGROK], [glib-2.0 >= 2.32.0 $SR_PKGLIBS]) | |
65489c1a | 572 | PKG_CHECK_MODULES([TESTS], [$SR_PKGLIBS_TESTS glib-2.0 $SR_PKGLIBS]) |
1f61c22f | 573 | |
da0763d0 DE |
574 | # SR_PKGLIBS_CXX may be empty, so only invoke these checks when |
575 | # the C++ bindings are enabled. | |
576 | AM_COND_IF([BINDINGS_CXX], [ | |
577 | PKG_CHECK_MODULES([LIBSIGROKCXX], [$SR_PKGLIBS_CXX]) | |
578 | PKG_CHECK_MODULES([PYSIGROK], [$SR_PKGLIBS_PYTHON $SR_PKGLIBS_CXX]) | |
27d44cf6 | 579 | PKG_CHECK_MODULES([RBSIGROK], [$SR_PKGLIBS_RUBY $SR_PKGLIBS_CXX], [AC_SUBST(RBSIGROK_EXTDIR, "lib/$($PKG_CONFIG --variable=sitearch $SR_PKGLIBS_RUBY)/$($PKG_CONFIG --variable=RUBY_BASE_NAME $SR_PKGLIBS_RUBY)/vendor_ruby/$($PKG_CONFIG --variable=ruby_version $SR_PKGLIBS_RUBY)")]) |
da0763d0 | 580 | ]) |
c1adbb1e DE |
581 | |
582 | # Check for specific libusb features, now that we know the CFLAGS. | |
583 | AC_LANG([C]) | |
584 | sr_save_cflags=$CFLAGS | |
a6dc3dac | 585 | sr_save_libs=$LIBS |
c1adbb1e | 586 | CFLAGS="$LIBSIGROK_CFLAGS $CFLAGS" |
a6dc3dac | 587 | LIBS="$LIBSIGROK_LIBS $LIBS" |
c1adbb1e DE |
588 | AC_CHECK_TYPES([libusb_os_handle], |
589 | [sr_have_libusb_os_handle=yes], [sr_have_libusb_os_handle=no], | |
590 | [[#include <libusb.h>]]) | |
a6dc3dac DE |
591 | AC_CHECK_FUNCS([zip_discard]) |
592 | LIBS=$sr_save_libs | |
c1adbb1e | 593 | CFLAGS=$sr_save_cflags |
a6dc3dac | 594 | |
c1adbb1e DE |
595 | AM_COND_IF([NEED_USB], [AS_CASE([$sr_have_libusb_os_handle:$host_os], [no:mingw*], |
596 | [AC_MSG_ERROR([Windows builds require the event-abstraction branch of libusb])])]) | |
597 | ||
1f61c22f DE |
598 | sr_glib_version=`$PKG_CONFIG --modversion glib-2.0 2>&AS_MESSAGE_LOG_FD` |
599 | sr_libzip_version=`$PKG_CONFIG --modversion libzip 2>&AS_MESSAGE_LOG_FD` | |
600 | ||
2cbde151 DE |
601 | AC_DEFINE_UNQUOTED([CONF_LIBZIP_VERSION], ["$sr_libzip_version"], |
602 | [Build-time version of libzip.]) | |
603 | AC_DEFINE_UNQUOTED([CONF_HOST], ["$host"], | |
604 | [The canonical host libsigrok will run on.]) | |
1f61c22f | 605 | |
b2478a23 | 606 | AC_CONFIG_FILES([Makefile libsigrok.pc bindings/cxx/libsigrokcxx.pc]) |
826938d8 UH |
607 | |
608 | AC_OUTPUT | |
609 | ||
1f61c22f | 610 | # Prepare bindings report messages. |
d37c7109 DE |
611 | m4_define([SR_PREPARE_BINDING_REPORT], [ |
612 | sr_report_$1= | |
26b67f11 | 613 | test -z "$sr_$1_missing" || sr_report_$1=" (missing: $sr_$1_missing)" |
d37c7109 | 614 | test "x$enable_$1" = xyes || sr_report_$1=' (disabled)' |
1f61c22f | 615 | ]) |
27d44cf6 | 616 | m4_map_args([SR_PREPARE_BINDING_REPORT], [cxx], [python], [ruby], [java]) |
45aed072 | 617 | |
1f61c22f DE |
618 | cat >&AS_MESSAGE_FD <<_EOF |
619 | ||
620 | libsigrok configuration summary: | |
621 | - Package version................. $SR_PACKAGE_VERSION | |
622 | - Library ABI version............. $SR_LIB_VERSION | |
623 | - Prefix.......................... $prefix | |
624 | - Building on..................... $build | |
625 | - Building for.................... $host | |
54d8d22a | 626 | - Building shared / static........ $enable_shared / $enable_static |
4512ccd3 DE |
627 | |
628 | Compile configuration: | |
6aa7fcf1 | 629 | - C compiler...................... $CC |
4512ccd3 | 630 | - C compiler version.............. $sr_cc_version |
6aa7fcf1 | 631 | - C compiler flags................ $CFLAGS |
b84a7331 | 632 | - Additional C compiler flags..... $SR_EXTRA_CFLAGS |
4cf2f34f | 633 | - C compiler warnings............. $SR_WFLAGS |
6aa7fcf1 | 634 | - C++ compiler.................... $CXX |
4512ccd3 | 635 | - C++ compiler version............ $sr_cxx_version |
6aa7fcf1 | 636 | - C++ compiler flags.............. $CXXFLAGS |
4cf2f34f | 637 | - C++ compiler warnings........... $SR_WXXFLAGS |
f5066b2b | 638 | - Linker flags.................... $LDFLAGS |
1f61c22f DE |
639 | |
640 | Detected libraries (required): | |
965d6889 | 641 | - glib-2.0 >= 2.32.0.............. $sr_glib_version |
a6dc3dac | 642 | - libzip >= 0.10.................. $sr_libzip_version |
1f61c22f DE |
643 | |
644 | Detected libraries (optional): | |
645 | $sr_pkglibs_summary | |
c5f179a9 | 646 | Enabled hardware drivers: |
d37c7109 | 647 | $sr_driver_summary |
1df81f4b GS |
648 | Enabled serial communication transports: |
649 | - serial comm ................... $sr_have_serial_comm | |
650 | - libserialport ................. $sr_have_libserialport | |
4417074c | 651 | - hidapi ........................ $sr_have_libhidapi |
f085705f GS |
652 | - bluetooth ..................... $sr_have_bluetooth |
653 | - bluez ......................... $sr_have_libbluez | |
1df81f4b | 654 | |
1f61c22f DE |
655 | Enabled SCPI backends: |
656 | - TCP............................. yes | |
a3fe36d0 SA |
657 | - SunRPC ......................... $sr_cv_have_sunrpc |
658 | - TI-RPC ......................... $sr_cv_have_tirpc | |
1f61c22f | 659 | - RPC............................. $sr_cv_have_rpc |
1df81f4b | 660 | - serial.......................... $sr_have_serial_comm |
1f61c22f DE |
661 | - VISA............................ $sr_have_librevisa |
662 | - GPIB............................ $sr_have_libgpib | |
663 | - USBTMC.......................... $sr_have_libusb | |
664 | ||
665 | Enabled language bindings: | |
666 | - C++............................. $BINDINGS_CXX$sr_report_cxx | |
667 | - Python.......................... $BINDINGS_PYTHON$sr_report_python | |
27d44cf6 | 668 | - Ruby............................ $BINDINGS_RUBY$sr_report_ruby |
1f61c22f | 669 | - Java............................ $BINDINGS_JAVA$sr_report_java |
826938d8 | 670 | |
1f61c22f | 671 | _EOF |
9bf09301 UH |
672 | |
673 | # Emit a warning if the C++ bindings are not being built. | |
674 | AM_COND_IF([BINDINGS_CXX], [], [ | |
675 | cat >&AS_MESSAGE_FD <<_EOF | |
676 | =============================================================================== | |
677 | WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING | |
678 | =============================================================================== | |
679 | === === | |
680 | === The libsigrok C++ bindings are not being built since you === | |
681 | === are missing one or more dependencies (see above)! === | |
682 | === === | |
683 | === This means you won't be able to compile frontends that require === | |
684 | === the C++ bindings (such as PulseView)! You also won't be able to build === | |
685 | === other bindings and frontends using those (such as sigrok-meter)! === | |
686 | === === | |
687 | =============================================================================== | |
688 | WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING | |
689 | =============================================================================== | |
690 | ||
691 | _EOF | |
692 | ]) |