[libsigrok.git] / configure.ac

##
## This file is part of the sigrok project.
##
## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
##
## This program is free software: you can redistribute it and/or modify
## it under the terms of the GNU General Public License as published by
## the Free Software Foundation, either version 3 of the License, or
## (at your option) any later version.
##
## This program is distributed in the hope that it will be useful,
## but WITHOUT ANY WARRANTY; without even the implied warranty of
## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
## GNU General Public License for more details.
##
## You should have received a copy of the GNU General Public License
## along with this program.  If not, see <http://www.gnu.org/licenses/>.
##

# We require at least autoconf 2.63 (AC_INIT format changed there).
AC_PREREQ([2.63])

# libsigrok package version number (NOT the same as shared lib version!).
m4_define([sr_package_version_major], [0])
m4_define([sr_package_version_minor], [1])
m4_define([sr_package_version_micro], [0])
m4_define([sr_package_version], [sr_package_version_major.sr_package_version_minor.sr_package_version_micro])

AC_INIT([libsigrok], [sr_package_version], [sigrok-devel@lists.sourceforge.net],
	[libsigrok], [http://www.sigrok.org])
AC_CONFIG_HEADER([config.h])
AC_CONFIG_MACRO_DIR([autostuff])
AC_CONFIG_AUX_DIR([autostuff])

# We require at least automake 1.11 (needed for 'silent rules').
AM_INIT_AUTOMAKE([1.11 -Wall -Werror foreign std-options])
m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])

AH_TOP([#ifndef SR_CONFIG_H
#define SR_CONFIG_H    /* To stop multiple inclusions. */])
AH_BOTTOM([#endif /* SR_CONFIG_H */])

# Enable more compiler warnings via -Wall and -Wextra. Add -fvisibility=hidden
# and enforce use of SR_API to explicitly mark all public API functions.
CFLAGS="-g -Wall -Wextra -fvisibility=hidden"

# Checks for programs.
AC_PROG_CXX
AC_PROG_CC
AC_PROG_CPP
AC_PROG_INSTALL
AC_PROG_LN_S

# Initialize libtool.
LT_INIT

# Initialize pkg-config.
# We require at least 0.22, as "Requires.private" behaviour changed there.
PKG_PROG_PKG_CONFIG([0.22])

# Library version for libsigrok (NOT the same as the package version).
# Carefully read the libtool docs before updating these numbers!
# The algorithm for determining which number to change (and how) is nontrivial!
# http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
SR_LIB_VERSION_CURRENT=0
SR_LIB_VERSION_REVISION=0
SR_LIB_VERSION_AGE=0
SR_LIB_VERSION="$SR_LIB_VERSION_CURRENT:$SR_LIB_VERSION_REVISION:$SR_LIB_VERSION_AGE"
SR_LIB_LDFLAGS="-version-info $SR_LIB_VERSION"
AC_SUBST(SR_LIB_VERSION_CURRENT)
AC_SUBST(SR_LIB_VERSION_REVISION)
AC_SUBST(SR_LIB_VERSION_AGE)
AC_SUBST(SR_LIB_VERSION)
AC_SUBST(SR_LIB_LDFLAGS)

# Logic analyzer hardware support '--enable' options.

# Disabled by default, unfinished.
AC_ARG_ENABLE(alsa, AC_HELP_STRING([--enable-alsa],
	      [enable ALSA driver support [default=no]]),
	      [LA_ALSA="$enableval"],
	      [LA_ALSA=no])
AM_CONDITIONAL(LA_ALSA, test x$LA_ALSA = xyes)
if test "x$LA_ALSA" = "xyes"; then
	AC_DEFINE(HAVE_LA_ALSA, 1, [ALSA driver support])
fi

AC_ARG_ENABLE(asix-sigma, AC_HELP_STRING([--enable-asix-sigma],
	      [enable ASIX SIGMA/SIGMA2 support [default=yes]]),
	      [LA_ASIX_SIGMA="$enableval"],
	      [LA_ASIX_SIGMA=yes])
AM_CONDITIONAL(LA_ASIX_SIGMA, test x$LA_ASIX_SIGMA = xyes)
if test "x$LA_ASIX_SIGMA" = "xyes"; then
	AC_DEFINE(HAVE_LA_ASIX_SIGMA, 1, [ASIX SIGMA/SIGMA2 support])
fi

AC_ARG_ENABLE(chronovu-la8, AC_HELP_STRING([--enable-chronovu-la8],
	      [enable ChronoVu LA8 support [default=yes]]),
	      [LA_CHRONOVU_LA8="$enableval"],
	      [LA_CHRONOVU_LA8=yes])
AM_CONDITIONAL(LA_CHRONOVU_LA8, test x$LA_CHRONOVU_LA8 = xyes)
if test "x$LA_CHRONOVU_LA8" = "xyes"; then
	AC_DEFINE(HAVE_LA_CHRONOVU_LA8, 1, [ChronoVu LA8 support])
fi

# Disabled per default for now, will be enabled when it's tested some more.
AC_ARG_ENABLE(fx2lafw, AC_HELP_STRING([--enable-fx2lafw],
	      [enable fx2lafw support (for FX2 LAs). [default=no]]),
	      [LA_FX2LAFW="$enableval"],
	      [LA_FX2LAFW=yes])
AM_CONDITIONAL(LA_FX2LAFW, test x$LA_FX2LAFW = xyes)
if test "x$LA_FX2LAFW" = "xyes"; then
	AC_DEFINE(HAVE_LA_FX2LAFW, 1, [fx2lafw support])
fi

AC_ARG_ENABLE(demo, AC_HELP_STRING([--enable-demo],
	      [enable demo driver support [default=yes]]),
	      [LA_DEMO="$enableval"],
	      [LA_DEMO=yes])
AM_CONDITIONAL(LA_DEMO, test x$LA_DEMO = xyes)
if test "x$LA_DEMO" = "xyes"; then
	AC_DEFINE(HAVE_LA_DEMO, 1, [Demo driver support])
fi

# Disabled by default, unfinished.
AC_ARG_ENABLE(link-mso19, AC_HELP_STRING([--enable-link-mso19],
	      [enable Link Instruments MSO-19 support [default=no]]),
	      [LA_LINK_MSO19="$enableval"],
	      [LA_LINK_MSO19=no])
AM_CONDITIONAL(LA_LINK_MSO19, test x$LA_LINK_MSO19 = xyes)
if test "x$LA_LINK_MSO19" = "xyes"; then
	AC_DEFINE(HAVE_LA_LINK_MSO19, 1, [Link Instruments MSO-19 support])
fi

AC_ARG_ENABLE(ols, AC_HELP_STRING([--enable-ols],
	      [enable OpenBench Logic Sniffer (OLS) support [default=yes]]),
	      [LA_OLS="$enableval"],
	      [LA_OLS=yes])
AM_CONDITIONAL(LA_OLS, test x$LA_OLS = xyes)
if test "x$LA_OLS" = "xyes"; then
	AC_DEFINE(HAVE_LA_OLS, 1, [OpenBench Logic Sniffer (OLS) support])
fi

AC_ARG_ENABLE(zeroplus-logic-cube,
	      AC_HELP_STRING([--enable-zeroplus-logic-cube],
	      [enable Zeroplus Logic Cube support [default=yes]]),
	      [LA_ZEROPLUS_LOGIC_CUBE="$enableval"],
	      [LA_ZEROPLUS_LOGIC_CUBE=yes])
AM_CONDITIONAL(LA_ZEROPLUS_LOGIC_CUBE, test x$LA_ZEROPLUS_LOGIC_CUBE = xyes)
if test "x$LA_ZEROPLUS_LOGIC_CUBE" = "xyes"; then
	AC_DEFINE(HAVE_LA_ZEROPLUS_LOGIC_CUBE, 1, [Zeroplus Logic Cube support])
fi

# Checks for libraries.

# This variable collects the pkg-config names of all detected libs.
# It is then used to construct the "Requires.private:" field in the
# libsigrok.pc file.
SR_PKGLIBS=""

# libglib-2.0 is always needed.
# Note: glib-2.0 is part of the libsigrok API (hard pkg-config requirement).
AM_PATH_GLIB_2_0([2.22.0],
	[CFLAGS="$CFLAGS $GLIB_CFLAGS"; LIBS="$LIBS $GLIB_LIBS"])

# libgthread-2.0 is always needed (e.g. for the demo hardware driver).
PKG_CHECK_MODULES([gthread], [gthread-2.0 >= 2.22.0],
	[CFLAGS="$CFLAGS $gthread_CFLAGS"; LIBS="$LIBS $gthread_LIBS";
	SR_PKGLIBS="$SR_PKGLIBS gthread-2.0"])

# libusb is only needed for some hardware drivers.
if test "x$LA_ASIX_SIGMA" != xno \
   -o "x$LA_CHRONOVU_LA8" != xno \
   -o "x$LA_ZEROPLUS_LOGIC_CUBE" != xno \
   -o "x$LA_FX2LAFW" != xno; then
	case "$build" in
	*freebsd*)
		# FreeBSD comes with an "integrated" libusb-1.0-style USB API.
		AC_DEFINE_UNQUOTED(HAVE_LIBUSB_1_0, [1],
			[Specifies whether we have a libusb.h header.])
		;;
	*)
		PKG_CHECK_MODULES([libusb], [libusb-1.0 >= 1.0.5],
			[CFLAGS="$CFLAGS $libusb_CFLAGS";
			LIBS="$LIBS $libusb_LIBS";
			SR_PKGLIBS="$SR_PKGLIBS libusb-1.0"])
		AC_CHECK_LIB(usb-1.0, libusb_init)
		;;
	esac
fi

# libzip is always needed.
PKG_CHECK_MODULES([libzip], [libzip >= 0.8],
	[CFLAGS="$CFLAGS $libzip_CFLAGS"; LIBS="$LIBS $libzip_LIBS";
	SR_PKGLIBS="$SR_PKGLIBS libzip"])

# libftdi is only needed for some hardware drivers.
if test "x$LA_ASIX_SIGMA" != xno \
     -o "x$LA_CHRONOVU_LA8" != xno; then
	PKG_CHECK_MODULES([libftdi], [libftdi >= 0.16],
		[CFLAGS="$CFLAGS $libftdi_CFLAGS";
		LIBS="$LIBS $libftdi_LIBS";
		SR_PKGLIBS="$SR_PKGLIBS libftdi"])
fi

# libudev is only needed for some hardware drivers.
if test "x$LA_LINK_MSO19" != xno; then
	PKG_CHECK_MODULES([libudev], [libudev >= 151],
		[CFLAGS="$CFLAGS $libudev_CFLAGS"; LIBS="$LIBS $libudev_LIBS";
		SR_PKGLIBS="$SR_PKGLIBS libudev"])
fi

# ALSA is only needed for some hardware drivers.
if test "x$LA_ALSA" != xno; then
	PKG_CHECK_MODULES([alsa], [alsa >= 1.0],
		[CFLAGS="$CFLAGS $alsa_CFLAGS"; LIBS="$LIBS $alsa_LIBS";
		SR_PKGLIBS="$SR_PKGLIBS alsa"])
fi

AC_SUBST(SR_PKGLIBS)

# Checks for header files.
# These are already checked: inttypes.h stdint.h stdlib.h string.h unistd.h.
AC_CHECK_HEADERS([fcntl.h sys/time.h termios.h])

# Checks for typedefs, structures, and compiler characteristics.
AC_C_INLINE
AC_TYPE_INT8_T
AC_TYPE_INT16_T
AC_TYPE_INT32_T
AC_TYPE_INT64_T
AC_TYPE_UINT8_T
AC_TYPE_UINT16_T
AC_TYPE_UINT32_T
AC_TYPE_UINT64_T
AC_TYPE_SIZE_T

# Checks for library functions.
AC_CHECK_FUNCS([gettimeofday memset strchr strcspn strdup strerror strncasecmp strstr strtol strtoul strtoull])

AC_SUBST(FIRMWARE_DIR, "$datadir/libsigrok/firmware")
AC_SUBST(MAKEFLAGS, '--no-print-directory')
AC_SUBST(AM_LIBTOOLFLAGS, '--silent')

SR_PACKAGE_VERSION_MAJOR=sr_package_version_major
SR_PACKAGE_VERSION_MINOR=sr_package_version_minor
SR_PACKAGE_VERSION_MICRO=sr_package_version_micro
SR_PACKAGE_VERSION=sr_package_version

AC_SUBST(SR_PACKAGE_VERSION_MAJOR)
AC_SUBST(SR_PACKAGE_VERSION_MINOR)
AC_SUBST(SR_PACKAGE_VERSION_MICRO)
AC_SUBST(SR_PACKAGE_VERSION)

AC_CONFIG_FILES([Makefile
		 sigrok.h
		 firmware/Makefile
		 hardware/Makefile
		 hardware/alsa/Makefile
		 hardware/asix-sigma/Makefile
		 hardware/chronovu-la8/Makefile
		 hardware/common/Makefile
		 hardware/demo/Makefile
		 hardware/fx2lafw/Makefile
		 hardware/link-mso19/Makefile
		 hardware/openbench-logic-sniffer/Makefile
		 hardware/zeroplus-logic-cube/Makefile
		 input/Makefile
		 output/Makefile
		 output/text/Makefile
		 libsigrok.pc
		 contrib/Makefile
		])

AC_OUTPUT

echo
echo "libsigrok configuration summary:"
echo
echo "  - Package version (major.minor.micro):    $SR_PACKAGE_VERSION"
echo "  - Library version (current:revision:age): $SR_LIB_VERSION"
echo "  - Prefix: $prefix"
echo
echo "Detected libraries:"
echo

# Note: This only works for libs with pkg-config integration.
for lib in "glib-2.0" "gthread-2.0" "libusb-1.0" "libzip" "libftdi" "libudev" "alsa"; do
	if `$PKG_CONFIG --exists $lib`; then
		ver=`$PKG_CONFIG --modversion $lib`
		answer="yes ($ver)"
	else
		answer="no"
	fi
	echo "  - $lib: $answer"
done

echo
echo "Enabled hardware drivers:"
echo
echo "  - ASIX SIGMA/SIGMA2............... $LA_ASIX_SIGMA"
echo "  - ChronoVu LA8.................... $LA_CHRONOVU_LA8"
echo "  - Demo driver..................... $LA_DEMO"
echo "  - fx2lafw (for FX2 LAs)........... $LA_FX2LAFW"
echo "  - Link MSO-19..................... $LA_LINK_MSO19"
echo "  - Openbench Logic Sniffer......... $LA_OLS"
echo "  - Zeroplus Logic Cube............. $LA_ZEROPLUS_LOGIC_CUBE"
echo
Commit	Line	Data
826938d8 UH	1	##
	2	## This file is part of the sigrok project.
	3	##
c73d2ea4	4	## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
826938d8 UH	5	##
	6	## This program is free software: you can redistribute it and/or modify
	7	## it under the terms of the GNU General Public License as published by
	8	## the Free Software Foundation, either version 3 of the License, or
	9	## (at your option) any later version.
	10	##
	11	## This program is distributed in the hope that it will be useful,
	12	## but WITHOUT ANY WARRANTY; without even the implied warranty of
	13	## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	14	## GNU General Public License for more details.
	15	##
	16	## You should have received a copy of the GNU General Public License
	17	## along with this program. If not, see <http://www.gnu.org/licenses/>.
	18	##
	19
ef7228ba UH	20	# We require at least autoconf 2.63 (AC_INIT format changed there).
ef7228ba UH	21	AC_PREREQ([2.63])
826938d8	22
3af71f0d	23	# libsigrok package version number (NOT the same as shared lib version!).
6dddd902 UH	24	m4_define([sr_package_version_major], [0])
	25	m4_define([sr_package_version_minor], [1])
	26	m4_define([sr_package_version_micro], [0])
	27	m4_define([sr_package_version], [sr_package_version_major.sr_package_version_minor.sr_package_version_micro])
826938d8	28
6dddd902	29	AC_INIT([libsigrok], [sr_package_version], [sigrok-devel@lists.sourceforge.net],
db8ae7b9	30	[libsigrok], [http://www.sigrok.org])
826938d8	31	AC_CONFIG_HEADER([config.h])
d8521c93 UH	32	AC_CONFIG_MACRO_DIR([autostuff])
d8521c93 UH	33	AC_CONFIG_AUX_DIR([autostuff])
826938d8	34
ef7228ba UH	35	# We require at least automake 1.11 (needed for 'silent rules').
ef7228ba UH	36	AM_INIT_AUTOMAKE([1.11 -Wall -Werror foreign std-options])
826938d8 UH	37	m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
826938d8 UH	38
6dddd902 UH	39	AH_TOP([#ifndef SR_CONFIG_H
	40	#define SR_CONFIG_H /* To stop multiple inclusions. */])
	41	AH_BOTTOM([#endif /* SR_CONFIG_H */])
826938d8	42
1a081ca6 UH	43	# Enable more compiler warnings via -Wall and -Wextra. Add -fvisibility=hidden
	44	# and enforce use of SR_API to explicitly mark all public API functions.
	45	CFLAGS="-g -Wall -Wextra -fvisibility=hidden"
826938d8 UH	46
	47	# Checks for programs.
	48	AC_PROG_CXX
	49	AC_PROG_CC
	50	AC_PROG_CPP
	51	AC_PROG_INSTALL
	52	AC_PROG_LN_S
	53
	54	# Initialize libtool.
	55	LT_INIT
	56
	57	# Initialize pkg-config.
	58	# We require at least 0.22, as "Requires.private" behaviour changed there.
	59	PKG_PROG_PKG_CONFIG([0.22])
	60
3af71f0d	61	# Library version for libsigrok (NOT the same as the package version).
826938d8 UH	62	# Carefully read the libtool docs before updating these numbers!
	63	# The algorithm for determining which number to change (and how) is nontrivial!
	64	# http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
6dddd902 UH	65	SR_LIB_VERSION_CURRENT=0
	66	SR_LIB_VERSION_REVISION=0
	67	SR_LIB_VERSION_AGE=0
	68	SR_LIB_VERSION="$SR_LIB_VERSION_CURRENT:$SR_LIB_VERSION_REVISION:$SR_LIB_VERSION_AGE"
	69	SR_LIB_LDFLAGS="-version-info $SR_LIB_VERSION"
	70	AC_SUBST(SR_LIB_VERSION_CURRENT)
	71	AC_SUBST(SR_LIB_VERSION_REVISION)
	72	AC_SUBST(SR_LIB_VERSION_AGE)
	73	AC_SUBST(SR_LIB_VERSION)
	74	AC_SUBST(SR_LIB_LDFLAGS)
826938d8	75
826938d8 UH	76	# Logic analyzer hardware support '--enable' options.
	77
	78	# Disabled by default, unfinished.
	79	AC_ARG_ENABLE(alsa, AC_HELP_STRING([--enable-alsa],
	80	[enable ALSA driver support [default=no]]),
	81	[LA_ALSA="$enableval"],
	82	[LA_ALSA=no])
	83	AM_CONDITIONAL(LA_ALSA, test x$LA_ALSA = xyes)
	84	if test "x$LA_ALSA" = "xyes"; then
	85	AC_DEFINE(HAVE_LA_ALSA, 1, [ALSA driver support])
	86	fi
	87
	88	AC_ARG_ENABLE(asix-sigma, AC_HELP_STRING([--enable-asix-sigma],
6352d030	89	[enable ASIX SIGMA/SIGMA2 support [default=yes]]),
826938d8 UH	90	[LA_ASIX_SIGMA="$enableval"],
	91	[LA_ASIX_SIGMA=yes])
	92	AM_CONDITIONAL(LA_ASIX_SIGMA, test x$LA_ASIX_SIGMA = xyes)
	93	if test "x$LA_ASIX_SIGMA" = "xyes"; then
6352d030	94	AC_DEFINE(HAVE_LA_ASIX_SIGMA, 1, [ASIX SIGMA/SIGMA2 support])
826938d8 UH	95	fi
	96
	97	AC_ARG_ENABLE(chronovu-la8, AC_HELP_STRING([--enable-chronovu-la8],
	98	[enable ChronoVu LA8 support [default=yes]]),
	99	[LA_CHRONOVU_LA8="$enableval"],
	100	[LA_CHRONOVU_LA8=yes])
	101	AM_CONDITIONAL(LA_CHRONOVU_LA8, test x$LA_CHRONOVU_LA8 = xyes)
	102	if test "x$LA_CHRONOVU_LA8" = "xyes"; then
	103	AC_DEFINE(HAVE_LA_CHRONOVU_LA8, 1, [ChronoVu LA8 support])
	104	fi
	105
2e26e0aa	106	# Disabled per default for now, will be enabled when it's tested some more.
f302a082	107	AC_ARG_ENABLE(fx2lafw, AC_HELP_STRING([--enable-fx2lafw],
2e26e0aa	108	[enable fx2lafw support (for FX2 LAs). [default=no]]),
f302a082	109	[LA_FX2LAFW="$enableval"],
d56ee265	110	[LA_FX2LAFW=yes])
f302a082 JH	111	AM_CONDITIONAL(LA_FX2LAFW, test x$LA_FX2LAFW = xyes)
	112	if test "x$LA_FX2LAFW" = "xyes"; then
	113	AC_DEFINE(HAVE_LA_FX2LAFW, 1, [fx2lafw support])
	114	fi
	115
826938d8 UH	116	AC_ARG_ENABLE(demo, AC_HELP_STRING([--enable-demo],
	117	[enable demo driver support [default=yes]]),
	118	[LA_DEMO="$enableval"],
	119	[LA_DEMO=yes])
	120	AM_CONDITIONAL(LA_DEMO, test x$LA_DEMO = xyes)
	121	if test "x$LA_DEMO" = "xyes"; then
	122	AC_DEFINE(HAVE_LA_DEMO, 1, [Demo driver support])
	123	fi
	124
	125	# Disabled by default, unfinished.
	126	AC_ARG_ENABLE(link-mso19, AC_HELP_STRING([--enable-link-mso19],
	127	[enable Link Instruments MSO-19 support [default=no]]),
	128	[LA_LINK_MSO19="$enableval"],
	129	[LA_LINK_MSO19=no])
	130	AM_CONDITIONAL(LA_LINK_MSO19, test x$LA_LINK_MSO19 = xyes)
	131	if test "x$LA_LINK_MSO19" = "xyes"; then
	132	AC_DEFINE(HAVE_LA_LINK_MSO19, 1, [Link Instruments MSO-19 support])
	133	fi
	134
	135	AC_ARG_ENABLE(ols, AC_HELP_STRING([--enable-ols],
	136	[enable OpenBench Logic Sniffer (OLS) support [default=yes]]),
	137	[LA_OLS="$enableval"],
	138	[LA_OLS=yes])
	139	AM_CONDITIONAL(LA_OLS, test x$LA_OLS = xyes)
	140	if test "x$LA_OLS" = "xyes"; then
	141	AC_DEFINE(HAVE_LA_OLS, 1, [OpenBench Logic Sniffer (OLS) support])
	142	fi
	143
826938d8 UH	144	AC_ARG_ENABLE(zeroplus-logic-cube,
	145	AC_HELP_STRING([--enable-zeroplus-logic-cube],
	146	[enable Zeroplus Logic Cube support [default=yes]]),
	147	[LA_ZEROPLUS_LOGIC_CUBE="$enableval"],
	148	[LA_ZEROPLUS_LOGIC_CUBE=yes])
	149	AM_CONDITIONAL(LA_ZEROPLUS_LOGIC_CUBE, test x$LA_ZEROPLUS_LOGIC_CUBE = xyes)
	150	if test "x$LA_ZEROPLUS_LOGIC_CUBE" = "xyes"; then
	151	AC_DEFINE(HAVE_LA_ZEROPLUS_LOGIC_CUBE, 1, [Zeroplus Logic Cube support])
	152	fi
	153
	154	# Checks for libraries.
	155
	156	# This variable collects the pkg-config names of all detected libs.
	157	# It is then used to construct the "Requires.private:" field in the
	158	# libsigrok.pc file.
6dddd902	159	SR_PKGLIBS=""
826938d8 UH	160
	161	# libglib-2.0 is always needed.
	162	# Note: glib-2.0 is part of the libsigrok API (hard pkg-config requirement).
	163	AM_PATH_GLIB_2_0([2.22.0],
	164	[CFLAGS="$CFLAGS $GLIB_CFLAGS"; LIBS="$LIBS $GLIB_LIBS"])
	165
	166	# libgthread-2.0 is always needed (e.g. for the demo hardware driver).
	167	PKG_CHECK_MODULES([gthread], [gthread-2.0 >= 2.22.0],
	168	[CFLAGS="$CFLAGS $gthread_CFLAGS"; LIBS="$LIBS $gthread_LIBS";
6dddd902	169	SR_PKGLIBS="$SR_PKGLIBS gthread-2.0"])
826938d8 UH	170
826938d8 UH	171	# libusb is only needed for some hardware drivers.
824b1a8f	172	if test "x$LA_ASIX_SIGMA" != xno \
826938d8	173	-o "x$LA_CHRONOVU_LA8" != xno \
f302a082 JH	174	-o "x$LA_ZEROPLUS_LOGIC_CUBE" != xno \
f302a082 JH	175	-o "x$LA_FX2LAFW" != xno; then
826938d8 UH	176	case "$build" in
	177	freebsd)
	178	# FreeBSD comes with an "integrated" libusb-1.0-style USB API.
	179	AC_DEFINE_UNQUOTED(HAVE_LIBUSB_1_0, [1],
	180	[Specifies whether we have a libusb.h header.])
	181	;;
	182	*)
	183	PKG_CHECK_MODULES([libusb], [libusb-1.0 >= 1.0.5],
	184	[CFLAGS="$CFLAGS $libusb_CFLAGS";
	185	LIBS="$LIBS $libusb_LIBS";
6dddd902	186	SR_PKGLIBS="$SR_PKGLIBS libusb-1.0"])
826938d8 UH	187	AC_CHECK_LIB(usb-1.0, libusb_init)
	188	;;
	189	esac
	190	fi
	191
	192	# libzip is always needed.
	193	PKG_CHECK_MODULES([libzip], [libzip >= 0.8],
	194	[CFLAGS="$CFLAGS $libzip_CFLAGS"; LIBS="$LIBS $libzip_LIBS";
6dddd902	195	SR_PKGLIBS="$SR_PKGLIBS libzip"])
826938d8	196
826938d8 UH	197	# libftdi is only needed for some hardware drivers.
	198	if test "x$LA_ASIX_SIGMA" != xno \
	199	-o "x$LA_CHRONOVU_LA8" != xno; then
	200	PKG_CHECK_MODULES([libftdi], [libftdi >= 0.16],
	201	[CFLAGS="$CFLAGS $libftdi_CFLAGS";
	202	LIBS="$LIBS $libftdi_LIBS";
6dddd902	203	SR_PKGLIBS="$SR_PKGLIBS libftdi"])
826938d8 UH	204	fi
	205
	206	# libudev is only needed for some hardware drivers.
	207	if test "x$LA_LINK_MSO19" != xno; then
	208	PKG_CHECK_MODULES([libudev], [libudev >= 151],
	209	[CFLAGS="$CFLAGS $libudev_CFLAGS"; LIBS="$LIBS $libudev_LIBS";
6dddd902	210	SR_PKGLIBS="$SR_PKGLIBS libudev"])
826938d8 UH	211	fi
	212
	213	# ALSA is only needed for some hardware drivers.
	214	if test "x$LA_ALSA" != xno; then
	215	PKG_CHECK_MODULES([alsa], [alsa >= 1.0],
	216	[CFLAGS="$CFLAGS $alsa_CFLAGS"; LIBS="$LIBS $alsa_LIBS";
6dddd902	217	SR_PKGLIBS="$SR_PKGLIBS alsa"])
826938d8 UH	218	fi
826938d8 UH	219
6dddd902	220	AC_SUBST(SR_PKGLIBS)
826938d8 UH	221
	222	# Checks for header files.
	223	# These are already checked: inttypes.h stdint.h stdlib.h string.h unistd.h.
	224	AC_CHECK_HEADERS([fcntl.h sys/time.h termios.h])
	225
	226	# Checks for typedefs, structures, and compiler characteristics.
	227	AC_C_INLINE
	228	AC_TYPE_INT8_T
	229	AC_TYPE_INT16_T
	230	AC_TYPE_INT32_T
	231	AC_TYPE_INT64_T
	232	AC_TYPE_UINT8_T
	233	AC_TYPE_UINT16_T
	234	AC_TYPE_UINT32_T
	235	AC_TYPE_UINT64_T
	236	AC_TYPE_SIZE_T
	237
	238	# Checks for library functions.
	239	AC_CHECK_FUNCS([gettimeofday memset strchr strcspn strdup strerror strncasecmp strstr strtol strtoul strtoull])
	240
8e190238	241	AC_SUBST(FIRMWARE_DIR, "$datadir/libsigrok/firmware")
826938d8 UH	242	AC_SUBST(MAKEFLAGS, '--no-print-directory')
	243	AC_SUBST(AM_LIBTOOLFLAGS, '--silent')
	244
6dddd902 UH	245	SR_PACKAGE_VERSION_MAJOR=sr_package_version_major
	246	SR_PACKAGE_VERSION_MINOR=sr_package_version_minor
	247	SR_PACKAGE_VERSION_MICRO=sr_package_version_micro
	248	SR_PACKAGE_VERSION=sr_package_version
3af71f0d	249
6dddd902 UH	250	AC_SUBST(SR_PACKAGE_VERSION_MAJOR)
	251	AC_SUBST(SR_PACKAGE_VERSION_MINOR)
	252	AC_SUBST(SR_PACKAGE_VERSION_MICRO)
	253	AC_SUBST(SR_PACKAGE_VERSION)
3af71f0d	254
826938d8	255	AC_CONFIG_FILES([Makefile
4937b235	256	sigrok.h
db8ae7b9 UH	257	firmware/Makefile
	258	hardware/Makefile
	259	hardware/alsa/Makefile
	260	hardware/asix-sigma/Makefile
	261	hardware/chronovu-la8/Makefile
	262	hardware/common/Makefile
	263	hardware/demo/Makefile
f302a082	264	hardware/fx2lafw/Makefile
db8ae7b9 UH	265	hardware/link-mso19/Makefile
db8ae7b9 UH	266	hardware/openbench-logic-sniffer/Makefile
db8ae7b9 UH	267	hardware/zeroplus-logic-cube/Makefile
	268	input/Makefile
	269	output/Makefile
	270	output/text/Makefile
	271	libsigrok.pc
826938d8	272	contrib/Makefile
826938d8 UH	273	])
	274
	275	AC_OUTPUT
	276
	277	echo
45aed072	278	echo "libsigrok configuration summary:"
826938d8	279	echo
6dddd902 UH	280	echo " - Package version (major.minor.micro): $SR_PACKAGE_VERSION"
6dddd902 UH	281	echo " - Library version (current:revision:age): $SR_LIB_VERSION"
45aed072 UH	282	echo " - Prefix: $prefix"
	283	echo
	284	echo "Detected libraries:"
	285	echo
	286
	287	# Note: This only works for libs with pkg-config integration.
e210c6c0	288	for lib in "glib-2.0" "gthread-2.0" "libusb-1.0" "libzip" "libftdi" "libudev" "alsa"; do
45aed072 UH	289	if `$PKG_CONFIG --exists $lib`; then
	290	ver=`$PKG_CONFIG --modversion $lib`
	291	answer="yes ($ver)"
	292	else
	293	answer="no"
	294	fi
	295	echo " - $lib: $answer"
	296	done
	297
	298	echo
	299	echo "Enabled hardware drivers:"
	300	echo
6352d030	301	echo " - ASIX SIGMA/SIGMA2............... $LA_ASIX_SIGMA"
45aed072 UH	302	echo " - ChronoVu LA8.................... $LA_CHRONOVU_LA8"
45aed072 UH	303	echo " - Demo driver..................... $LA_DEMO"
b5750520	304	echo " - fx2lafw (for FX2 LAs)........... $LA_FX2LAFW"
45aed072 UH	305	echo " - Link MSO-19..................... $LA_LINK_MSO19"
45aed072 UH	306	echo " - Openbench Logic Sniffer......... $LA_OLS"
45aed072	307	echo " - Zeroplus Logic Cube............. $LA_ZEROPLUS_LOGIC_CUBE"
826938d8 UH	308	echo
826938d8 UH	309