2 ## This file is part of the libsigrok project.
4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
7 ## This program is free software: you can redistribute it and/or modify
8 ## it under the terms of the GNU General Public License as published by
9 ## the Free Software Foundation, either version 3 of the License, or
10 ## (at your option) any later version.
12 ## This program is distributed in the hope that it will be useful,
13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
15 ## GNU General Public License for more details.
17 ## You should have received a copy of the GNU General Public License
18 ## along with this program. If not, see <http://www.gnu.org/licenses/>.
21 # We require at least autoconf 2.63 (AC_INIT format changed there).
24 AC_INIT([libsigrok], [0.4.0],
25 [sigrok-devel@lists.sourceforge.net],
26 [libsigrok], [http://www.sigrok.org])
27 AC_CONFIG_MACRO_DIR([m4])
28 AC_CONFIG_AUX_DIR([autostuff])
29 AC_CONFIG_HEADERS([config.h include/libsigrok/version.h])
31 # We require at least automake 1.11 (needed for 'silent rules').
32 AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define nostdinc subdir-objects check-news color-tests])
33 AM_SILENT_RULES([yes])
34 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
36 AH_TOP([#ifndef SR_CONFIG_H
37 #define SR_CONFIG_H /* To stop multiple inclusions. */])
38 AH_BOTTOM([#endif /* SR_CONFIG_H */])
40 # Checks for programs.
46 # Required for per-target flags or subdir-objects with C sources.
52 # Set up the libsigrok version defines.
53 SR_PKG_VERSION_SET([SR_PACKAGE_VERSION], [AC_PACKAGE_VERSION])
55 # Library version for libsigrok (NOT the same as the package version).
56 # Carefully read the libtool docs before updating these numbers!
57 # The algorithm for determining which number to change (and how) is nontrivial!
58 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
59 SR_LIB_VERSION_SET([SR_LIB_VERSION], [2:0:0])
61 #############################
62 ## Optional dependencies ##
63 #############################
65 # Initialize pkg-config.
66 # We require at least 0.22, as "Requires.private" behaviour changed there.
67 PKG_PROG_PKG_CONFIG([0.22])
69 # Keep track of all checked modules so we can list them at the end.
70 SR_PKG_CHECK_SUMMARY([sr_pkglibs_summary])
72 # Collect the pkg-config module names of all dependencies in SR_PKGLIBS.
73 # These are used to derive the compiler flags and for the "Requires.private"
74 # field in the generated libsigrok.pc file.
75 SR_VAR_OPT_PKG([SR_PKGLIBS], [sr_deps_avail])
80 SR_ARG_OPT_PKG([libserialport], [LIBSERIALPORT], [NEED_SERIAL],
81 [libserialport >= 0.1.1])
83 SR_ARG_OPT_PKG([libftdi], [LIBFTDI],,
84 [libftdi1 >= 1.0], [libftdi >= 0.16])
86 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
87 # This means libusb-1.0 is always available; no need to check for it.
88 AS_CASE([$host], [*freebsd*], [sr_have_libusb=yes])
90 SR_ARG_OPT_PKG([libusb], [LIBUSB_1_0], [NEED_USB],
91 [libusb-1.0 >= 1.0.16])
93 SR_ARG_OPT_PKG([librevisa], [LIBREVISA], [NEED_VISA],
94 [librevisa >= 0.0.20130412])
96 SR_ARG_OPT_PKG([libgpib], [LIBGPIB], [NEED_GPIB],
99 ######################
101 ######################
103 # The Check unit testing framework is optional. Disable if not found.
104 SR_PKG_CHECK([check], [SR_PKGLIBS_TESTS], [check >= 0.9.4])
105 AM_CONDITIONAL([HAVE_CHECK], [test "x$sr_have_check" = xyes])
109 # Enable the C99 standard if possible, and enforce the use
110 # of SR_API to explicitly mark all public API functions.
112 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [C99], [-std=c99 -c99 -AC99 -qlanglvl=extc99])
113 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [visibility], [-fvisibility=hidden])
115 SR_ARG_ENABLE_WARNINGS([SR_WFLAGS], [-Wall], [-Wall -Wextra -Wmissing-prototypes])
117 # Check host characteristics.
121 AC_CHECK_HEADERS([sys/mman.h], [SR_APPEND([sr_deps_avail], [sys_mman_h])])
122 AC_CHECK_HEADERS([sys/ioctl.h], [SR_APPEND([sr_deps_avail], [sys_ioctl_h])])
123 AC_CHECK_HEADERS([sys/timerfd.h], [SR_APPEND([sr_deps_avail], [sys_timerfd_h])])
125 # We need to link against the Winsock2 library for SCPI over TCP.
126 AS_CASE([$host], [*-mingw*], [SR_EXTRA_LIBS='-lws2_32'], [SR_EXTRA_LIBS=])
128 # libm (the standard math library) is always needed.
129 SR_SEARCH_LIBS([SR_EXTRA_LIBS], [pow], [m])
131 AC_ARG_WITH([libieee1284], [AS_HELP_STRING([--without-libieee1284],
132 [disable libieee1284 support [default=detect]])])
133 sr_have_libieee1284=no
134 AS_IF([test "x$with_libieee1284" != xno], [
135 AC_CHECK_HEADER([ieee1284.h], [
136 SR_SEARCH_LIBS([SR_EXTRA_LIBS], [ieee1284_open], [ieee1284], [
137 sr_have_libieee1284=yes
138 SR_APPEND([sr_deps_avail], [libieee1284])
139 sr_pkg_check_summary_append "libieee1284" yes
142 AS_IF([test "$sr_have_libieee1284" = no], [
143 AS_IF([test "x$with_libieee1284" = xyes], [
144 AC_MSG_ERROR([libieee1284 support requested, but it was not found.])
146 sr_pkg_check_summary_append "libieee1284" no
150 # RPC is only needed for VXI support.
151 AC_CACHE_CHECK([for RPC support], [sr_cv_have_rpc],
152 [AC_LINK_IFELSE([AC_LANG_PROGRAM(
153 [[#include <rpc/rpc.h>]m4_newline[CLIENT *rpc_test(void);]],
154 [[(void) clnt_create("", 0, 0, "");]])],
155 [sr_cv_have_rpc=yes], [sr_cv_have_rpc=no])])
156 AS_IF([test "x$sr_cv_have_rpc" = xyes],
157 [AC_DEFINE([HAVE_RPC], [1], [Specifies whether we have RPC support.])])
158 # VXI support is only compiled if RPC support was found.
159 AM_CONDITIONAL([NEED_RPC], [test "x$sr_cv_have_rpc" = xyes])
161 ########################
162 ## Hardware drivers ##
163 ########################
165 # Keep track of all drivers so we can list them at the end.
166 SR_VAR_SUMMARY([sr_driver_summary])
168 # Check whether the sr_deps_avail list contains all of the arguments.
169 # Unavailable dependencies are collected in sr_deps_missing.
170 sr_check_driver_deps() {
174 AS_CASE([" $sr_deps_avail "], [*" $sr_dep "*],,
175 [SR_APPEND([sr_deps_missing], [', '], [$sr_dep])])
177 test -z "$sr_deps_missing" || return 1
180 AC_ARG_ENABLE([all-drivers],
181 [AS_HELP_STRING([--enable-all-drivers],
182 [enable all drivers by default [default=yes]])],
183 [], [enable_all_drivers=yes])
185 ## _SR_DRIVER(Device name, driver-name, var-name, [dependencies...])
186 m4_define([_SR_DRIVER], [
188 [AS_HELP_STRING([--enable-$2], [enable $1 support])],
189 [$3=$enableval], [$3=$enable_all_drivers])
191 AS_IF([test "x[$]$3" = xyes], [sr_hw_info=yes[]m4_ifval([$4], [
192 sr_check_driver_deps $4 \
193 || $3=no sr_hw_info="no (missing: $sr_deps_missing)"
194 ])], [sr_hw_info='no (disabled)'])
195 sr_driver_summary_append "$2" "$sr_hw_info"
197 AM_CONDITIONAL([$3], [test "x[$]$3" = xyes])
198 AM_COND_IF([$3], [AC_DEFINE([HAVE_$3], [1], [Whether to support $1 device.])])
201 ## SR_DRIVER(Device name, driver-name, [dependencies...])
202 m4_define([SR_DRIVER],
203 [_SR_DRIVER([$1], [$2], m4_expand([AS_TR_CPP([HW_$2])]), [$3])])
205 SR_DRIVER([Agilent DMM], [agilent-dmm], [libserialport])
206 SR_DRIVER([Appa 55II], [appa-55ii], [libserialport])
207 SR_DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma], [libftdi])
208 SR_DRIVER([Atten PPS3xxx], [atten-pps3xxx], [libserialport])
209 SR_DRIVER([BayLibre ACME], [baylibre-acme], [sys_timerfd_h])
210 SR_DRIVER([BeagleLogic], [beaglelogic], [sys_mman_h sys_ioctl_h])
211 SR_DRIVER([Brymen BM86x], [brymen-bm86x], [libusb])
212 SR_DRIVER([Brymen DMM], [brymen-dmm], [libserialport])
213 SR_DRIVER([CEM DT-885x], [cem-dt-885x], [libserialport])
214 SR_DRIVER([Center 3xx], [center-3xx], [libserialport])
215 SR_DRIVER([ChronoVu LA], [chronovu-la], [libftdi])
216 SR_DRIVER([Colead SLM], [colead-slm], [libserialport])
217 SR_DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu], [libserialport])
218 SR_DRIVER([DER EE DE-5000], [deree-de5000], [libserialport])
219 SR_DRIVER([demo], [demo])
220 SR_DRIVER([Fluke DMM], [fluke-dmm], [libserialport])
221 SR_DRIVER([fx2lafw], [fx2lafw], [libusb])
222 SR_DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x], [libserialport])
223 SR_DRIVER([Hameg HMO], [hameg-hmo], [libserialport])
224 SR_DRIVER([Hantek DSO], [hantek-dso], [libusb])
225 SR_DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2], [libusb])
226 SR_DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus], [libftdi])
227 SR_DRIVER([Kecheng KC-330B], [kecheng-kc-330b], [libusb])
228 SR_DRIVER([KERN scale], [kern-scale], [libserialport])
229 SR_DRIVER([Lascar EL-USB], [lascar-el-usb], [libusb])
230 SR_DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx], [libserialport])
231 SR_DRIVER([maynuo-m97], [maynuo-m97])
232 SR_DRIVER([MIC 985xx], [mic-985xx], [libserialport])
233 SR_DRIVER([Motech LPS 30x], [motech-lps-30x], [libserialport])
234 SR_DRIVER([Norma DMM], [norma-dmm], [libserialport])
235 SR_DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer], [libserialport])
236 SR_DRIVER([Pipistrello-OLS], [pipistrello-ols], [libftdi])
237 SR_DRIVER([Rigol DS], [rigol-ds])
238 SR_DRIVER([Saleae Logic16], [saleae-logic16], [libusb])
239 SR_DRIVER([SCPI PPS], [scpi-pps])
240 SR_DRIVER([serial DMM], [serial-dmm], [libserialport])
241 SR_DRIVER([Sysclk LWLA], [sysclk-lwla], [libusb])
242 SR_DRIVER([Teleinfo], [teleinfo], [libserialport])
243 SR_DRIVER([Testo], [testo], [libusb])
244 SR_DRIVER([Tondaj SL-814], [tondaj-sl-814], [libserialport])
245 SR_DRIVER([UNI-T DMM], [uni-t-dmm], [libusb])
246 SR_DRIVER([UNI-T UT32x], [uni-t-ut32x], [libusb])
247 SR_DRIVER([Victor DMM], [victor-dmm], [libusb])
248 SR_DRIVER([Yokogawa DL/DLM], [yokogawa-dlm])
249 SR_DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube], [libusb])
251 ###############################
252 ## Language bindings setup ##
253 ###############################
256 SR_ARG_ENABLE_WARNINGS([SR_WXXFLAGS], [-Wall], [-Wall -Wextra])
258 AC_ARG_ENABLE([bindings],
259 [AS_HELP_STRING([--enable-bindings], [build language bindings [default=yes]])],
260 [], [enable_bindings=yes])
263 [AS_HELP_STRING([--enable-cxx], [build C++ bindings [default=yes]])],
264 [], [enable_cxx=$enable_bindings])
266 AC_ARG_ENABLE([python],
267 [AS_HELP_STRING([--enable-python], [build Python bindings [default=yes]])],
268 [], [enable_python=$enable_bindings])
270 AC_ARG_ENABLE([java],
271 [AS_HELP_STRING([--enable-java], [build Java bindings [default=yes]])],
272 [], [enable_java=$enable_bindings])
280 # Check if the C++ compiler supports the C++11 standard.
281 AX_CXX_COMPILE_STDCXX_11([noext], [optional])
282 AS_IF([test "x$HAVE_CXX11" != x1],
283 [SR_APPEND([sr_cxx_missing], [', '], ['C++11'])])
285 # The C++ bindings need glibmm.
286 SR_PKG_CHECK([glibmm], [SR_PKGLIBS_CXX], [glibmm-2.4 >= 2.32.0])
287 AS_IF([test "x$sr_have_glibmm" != xyes],
288 [SR_APPEND([sr_cxx_missing], [', '], [glibmm])])
290 # The C++ bindings use Doxygen to parse libsigrok symbols.
291 AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes], [no])
292 AS_IF([test "x$HAVE_DOXYGEN" != xyes],
293 [SR_APPEND([sr_cxx_missing], [', '], [Doxygen])])
295 # Python is needed for the C++ bindings.
296 AM_PATH_PYTHON([2.7],
299 SR_APPEND([sr_cxx_missing], [', '], [Python])])
301 AS_IF([test -z "$sr_cxx_missing"],
302 [BINDINGS_CXX=$enable_cxx], [BINDINGS_CXX=no])
303 AM_CONDITIONAL([BINDINGS_CXX], [test "x$BINDINGS_CXX" = xyes])
305 # C++ bindings want stoi and stod.
306 AM_COND_IF([BINDINGS_CXX], [
307 AC_CACHE_CHECK([for stoi and stod], [sr_cv_have_stoi_stod],
308 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string>]],
309 [[(void) std::stoi("1"); (void) std::stod("1.0");]])],
310 [sr_cv_have_stoi_stod=yes], [sr_cv_have_stoi_stod=no])])
311 AS_IF([test "x$sr_cv_have_stoi_stod" = xyes],
312 [AC_DEFINE([HAVE_STOI_STOD], [1],
313 [Specifies whether we have the stoi and stod functions.])])
316 #######################
317 ## Python bindings ##
318 #######################
320 AS_IF([test "x$BINDINGS_CXX" = xyes],
321 [sr_python_missing=],
322 [sr_python_missing='C++ bindings'])
324 # The Python bindings need Python development files.
325 SR_PKG_CHECK([python_dev], [SR_PKGLIBS_PYTHON],
326 [python >= 2.7], [python2 >= 2.7], [python27 >= 2.7])
327 AS_IF([test "x$sr_have_python_dev" != xyes],
328 [SR_APPEND([sr_python_missing], [', '], [Headers])])
330 # PyGObject is needed for the Python bindings.
331 SR_PKG_CHECK([pygobject], [SR_PKGLIBS_PYTHON], [pygobject-3.0 >= 3.0.0])
332 AS_IF([test "x$sr_have_pygobject" != xyes],
333 [SR_APPEND([sr_python_missing], [', '], [PyGObject])])
335 PKG_CHECK_EXISTS([pygobject-3.0 < 3.7.91],
336 [AC_DEFINE([PYGOBJECT_FLAGS_SIGNED], [1],
337 [Whether last argument to pyg_flags_get_value() is signed.])])
339 # The Python bindings need the setuptools Python module.
340 # We'll let it go through even if the AX macro wasn't found,
341 # as the Python module may still be there.
342 HAVE_PYMOD_SETUPTOOLS=yes
343 m4_ifdef([AX_PYTHON_MODULE],
344 [AX_PYTHON_MODULE([setuptools])],
345 [m4_warn([unsupported], [Missing macro AX_PYTHON_MODULE: no setuptools check])])
346 AS_IF([test "x$HAVE_PYMOD_SETUPTOOLS" != xyes],
347 [SR_APPEND([sr_python_missing], [', '], [setuptools])])
349 # The Python bindings use SWIG to generate code.
350 AC_CHECK_PROGS([SWIG], [swig swig3.0 swig2.0])
351 AS_IF([test "x$SWIG" = x],
352 [SR_APPEND([sr_python_missing], [', '], [SWIG])])
354 AS_IF([test -z "$sr_python_missing"],
355 [BINDINGS_PYTHON=$enable_python], [BINDINGS_PYTHON=no])
356 AM_CONDITIONAL([BINDINGS_PYTHON], [test "x$BINDINGS_PYTHON" = xyes])
362 AS_IF([test "x$BINDINGS_CXX" = xyes],
364 [sr_java_missing='C++ bindings'])
366 # The Java bindings use SWIG to generate code.
367 AS_IF([test "x$SWIG" = x],
368 [SR_APPEND([sr_java_missing], [', '], [SWIG])])
370 # Find Java compiler and JNI includes for Java bindings.
371 AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no])
372 AS_IF([test "x$HAVE_JAVAC" = xno],
373 [SR_APPEND([sr_java_missing], [', '], [JavaC])])
375 AC_ARG_WITH([jni-include-path],
376 [AS_HELP_STRING([[--with-jni-include-path=DIR-LIST (space-separated)]],
377 [specify JNI include directories [default=detect]])],
378 [JNI_INCLUDE_DIRS=" $withval"], [JNI_INCLUDE_DIRS=])
381 AS_IF([test "x$enable_java$HAVE_JAVAC" = xyesyes], [
383 AS_IF([test -z "$JNI_INCLUDE_DIRS" && test "x$cross_compiling" != xyes], [
384 ## Work around the totally broken logic in AX_JNI_INCLUDE_DIR:
385 ## If we can find jni.h without any special search path, skip
386 ## the execution of the broken macro to increase our chances of
388 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <jni.h>]], [])],,
389 [AX_JNI_INCLUDE_DIR])
392 for sr_dir in $JNI_INCLUDE_DIRS
394 SR_APPEND([JNI_CPPFLAGS], ["-I$sr_dir"])
396 AC_SUBST([JNI_CPPFLAGS])
398 sr_save_cppflags=$CPPFLAGS
399 SR_APPEND([CPPFLAGS], [$JNI_CPPFLAGS])
400 AC_CHECK_HEADER([jni.h],,
401 [SR_APPEND([sr_java_missing], [', '], ['JNI headers'])])
402 CPPFLAGS=$sr_save_cppflags
404 AS_IF([test -z "$sr_java_missing"],
405 [BINDINGS_JAVA=$enable_java], [BINDINGS_JAVA=no])
406 AM_CONDITIONAL([BINDINGS_JAVA], [test "x$BINDINGS_JAVA" = xyes])
408 ##############################
409 ## Finalize configuration ##
410 ##############################
412 # Add mandatory dependencies to module list.
413 SR_APPEND([SR_PKGLIBS], ['libzip >= 0.10'])
414 AC_SUBST([SR_PKGLIBS])
416 # Retrieve the compile and link flags for all modules combined.
417 # Also, bail out at this point if any module dependency is not met.
418 PKG_CHECK_MODULES([LIBSIGROK], [glib-2.0 >= 2.32.0 $SR_PKGLIBS])
419 PKG_CHECK_MODULES([TESTS], [$SR_PKGLIBS_TESTS glib-2.0 $SR_PKGLIBS])
421 # SR_PKGLIBS_CXX may be empty, so only invoke these checks when
422 # the C++ bindings are enabled.
423 AM_COND_IF([BINDINGS_CXX], [
424 PKG_CHECK_MODULES([LIBSIGROKCXX], [$SR_PKGLIBS_CXX])
425 PKG_CHECK_MODULES([PYSIGROK], [$SR_PKGLIBS_PYTHON $SR_PKGLIBS_CXX])
427 sr_glib_version=`$PKG_CONFIG --modversion glib-2.0 2>&AS_MESSAGE_LOG_FD`
428 sr_libzip_version=`$PKG_CONFIG --modversion libzip 2>&AS_MESSAGE_LOG_FD`
430 AC_DEFINE_UNQUOTED([CONF_LIBZIP_VERSION], ["$sr_libzip_version"],
431 [Build-time version of libzip.])
432 AC_DEFINE_UNQUOTED([CONF_HOST], ["$host"],
433 [The canonical host libsigrok will run on.])
435 AC_CONFIG_FILES([Makefile libsigrok.pc bindings/cxx/libsigrokcxx.pc])
439 # Prepare bindings report messages.
440 m4_define([SR_PREPARE_BINDING_REPORT], [
442 test -z "$sr_$1_missing" || sr_report_$1=" (missing: $sr_$1_missing)"
443 test "x$enable_$1" = xyes || sr_report_$1=' (disabled)'
445 m4_map_args([SR_PREPARE_BINDING_REPORT], [cxx], [python], [java])
447 cat >&AS_MESSAGE_FD <<_EOF
449 libsigrok configuration summary:
450 - Package version................. $SR_PACKAGE_VERSION
451 - Library ABI version............. $SR_LIB_VERSION
452 - Prefix.......................... $prefix
453 - Building on..................... $build
454 - Building for.................... $host
455 - Additional C compiler flags..... $SR_EXTRA_CFLAGS
456 - C compiler warnings............. $SR_WFLAGS
457 - C++ compiler warnings........... $SR_WXXFLAGS
459 Detected libraries (required):
460 - glib-2.0 >= 2.32.0.............. $sr_glib_version
461 - libzip >= 0.10.................. $sr_libzip_version
463 Detected libraries (optional):
465 Enabled hardware drivers:
467 Enabled SCPI backends:
468 - TCP............................. yes
469 - RPC............................. $sr_cv_have_rpc
470 - serial.......................... $sr_have_libserialport
471 - VISA............................ $sr_have_librevisa
472 - GPIB............................ $sr_have_libgpib
473 - USBTMC.......................... $sr_have_libusb
475 Enabled language bindings:
476 - C++............................. $BINDINGS_CXX$sr_report_cxx
477 - Python.......................... $BINDINGS_PYTHON$sr_report_python
478 - Java............................ $BINDINGS_JAVA$sr_report_java