2 ## This file is part of the libsigrok project.
4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
7 ## This program is free software: you can redistribute it and/or modify
8 ## it under the terms of the GNU General Public License as published by
9 ## the Free Software Foundation, either version 3 of the License, or
10 ## (at your option) any later version.
12 ## This program is distributed in the hope that it will be useful,
13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
15 ## GNU General Public License for more details.
17 ## You should have received a copy of the GNU General Public License
18 ## along with this program. If not, see <http://www.gnu.org/licenses/>.
21 # We require at least autoconf 2.63 (AC_INIT format changed there).
24 AC_INIT([libsigrok], [0.5.0],
25 [sigrok-devel@lists.sourceforge.net],
26 [libsigrok], [http://www.sigrok.org])
27 AC_CONFIG_MACRO_DIR([m4])
28 AC_CONFIG_AUX_DIR([autostuff])
29 AC_CONFIG_HEADERS([config.h include/libsigrok/version.h])
31 # We require at least automake 1.11 (needed for 'silent rules').
32 AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define nostdinc subdir-objects check-news color-tests])
33 AM_SILENT_RULES([yes])
34 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
38 # Checks for programs.
44 # Required for per-target flags or subdir-objects with C sources.
47 # Set the standard the C library headers should conform to.
48 AH_VERBATIM([_POSIX_C_SOURCE], [/* The targeted POSIX standard. */
49 #ifndef _POSIX_C_SOURCE
50 # define _POSIX_C_SOURCE 200112L
53 # Get compiler versions.
54 SR_PROG_VERSION([$CC], [sr_cc_version])
55 SR_PROG_VERSION([$CXX], [sr_cxx_version])
57 # Check for optional make features.
58 SR_PROG_MAKE_ORDER_ONLY
63 # Set up the libsigrok version defines.
64 SR_PKG_VERSION_SET([SR_PACKAGE_VERSION], [AC_PACKAGE_VERSION])
66 # Library version for libsigrok (NOT the same as the package version).
67 # Carefully read the libtool docs before updating these numbers!
68 # The algorithm for determining which number to change (and how) is nontrivial!
69 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
70 # Format: current:revision:age.
71 SR_LIB_VERSION_SET([SR_LIB_VERSION], [3:0:0])
73 AM_CONDITIONAL([WIN32], [test -z "${host_os##mingw*}" || test -z "${host_os##cygwin*}"])
75 #############################
76 ## Optional dependencies ##
77 #############################
81 # Initialize pkg-config.
82 # We require at least 0.22, as "Requires.private" behaviour changed there.
83 PKG_PROG_PKG_CONFIG([0.22])
85 # Keep track of all checked modules so we can list them at the end.
86 SR_PKG_CHECK_SUMMARY([sr_pkglibs_summary])
88 # Collect the pkg-config module names of all dependencies in SR_PKGLIBS.
89 # These are used to derive the compiler flags and for the "Requires.private"
90 # field in the generated libsigrok.pc file.
91 SR_VAR_OPT_PKG([SR_PKGLIBS], [sr_deps_avail])
98 SR_ARG_OPT_PKG([libserialport], [LIBSERIALPORT], [NEED_SERIAL],
99 [libserialport >= 0.1.1])
101 SR_ARG_OPT_PKG([libftdi], [LIBFTDI],,
102 [libftdi1 >= 1.0], [libftdi >= 0.16])
104 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
105 # This means libusb-1.0 is always available; no need to check for it.
106 # On Windows, require the latest version we can get our hands on,
107 # until the new generic event handling has seen an official release.
109 [freebsd*], [sr_libusb_req='libusb-1.0' sr_have_libusb=yes],
110 [mingw*], [sr_libusb_req='libusb-1.0 >= 1.0.20'],
111 [sr_libusb_req='libusb-1.0 >= 1.0.16'])
113 SR_ARG_OPT_PKG([libusb], [LIBUSB_1_0], [NEED_USB],
116 SR_ARG_OPT_PKG([librevisa], [LIBREVISA], [NEED_VISA],
117 [librevisa >= 0.0.20130412])
119 SR_ARG_OPT_PKG([libgpib], [LIBGPIB], [NEED_GPIB],
122 SR_ARG_OPT_CHECK([libieee1284], [LIBIEEE1284],, [
124 LIBS="-lieee1284 $LIBS"
125 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <ieee1284.h>]],
126 [[(void) ieee1284_open(0, 0, 0);]])],
127 [sr_have_libieee1284=yes], [sr_have_libieee1284=no])
130 AS_IF([test "x$sr_have_libieee1284" = xyes],
131 [SR_PREPEND([SR_EXTRA_LIBS], [-lieee1284])])
133 ######################
135 ######################
137 # The Check unit testing framework is optional. Disable if not found.
138 SR_PKG_CHECK([check], [SR_PKGLIBS_TESTS], [check >= 0.9.4])
139 AM_CONDITIONAL([HAVE_CHECK], [test "x$sr_have_check" = xyes])
141 # Enable the C99 standard if possible, and enforce the use
142 # of SR_API to explicitly mark all public API functions.
144 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [C99], [-std=c99 -c99 -AC99 -qlanglvl=extc99])
145 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [visibility], [-fvisibility=hidden])
147 SR_ARG_ENABLE_WARNINGS([SR_WFLAGS], [-Wall], [-Wall -Wextra -Wmissing-prototypes])
149 # Check host characteristics.
153 AC_CHECK_HEADERS([sys/mman.h], [SR_APPEND([sr_deps_avail], [sys_mman_h])])
154 AC_CHECK_HEADERS([sys/ioctl.h], [SR_APPEND([sr_deps_avail], [sys_ioctl_h])])
155 AC_CHECK_HEADERS([sys/timerfd.h], [SR_APPEND([sr_deps_avail], [sys_timerfd_h])])
157 # We need to link against the Winsock2 library for SCPI over TCP.
158 AS_CASE([$host_os], [mingw*], [SR_PREPEND([SR_EXTRA_LIBS], [-lws2_32])])
160 # libm (the standard math library) is always needed.
161 SR_SEARCH_LIBS([SR_EXTRA_LIBS], [pow], [m])
163 # RPC is only needed for VXI support.
164 AC_CACHE_CHECK([for RPC support], [sr_cv_have_rpc],
165 [AC_LINK_IFELSE([AC_LANG_PROGRAM(
166 [[#include <rpc/rpc.h>]m4_newline[CLIENT *rpc_test(void);]],
167 [[(void) clnt_create("", 0, 0, "");]])],
168 [sr_cv_have_rpc=yes], [sr_cv_have_rpc=no])])
169 AS_IF([test "x$sr_cv_have_rpc" = xyes],
170 [AC_DEFINE([HAVE_RPC], [1], [Specifies whether we have RPC support.])])
171 # VXI support is only compiled if RPC support was found.
172 AM_CONDITIONAL([NEED_RPC], [test "x$sr_cv_have_rpc" = xyes])
174 # Check for compiler support of 128 bit integers
175 AC_CHECK_TYPES([__int128_t, __uint128_t], [], [], [])
177 ########################
178 ## Hardware drivers ##
179 ########################
181 # Keep track of all drivers so we can list them at the end.
182 SR_VAR_SUMMARY([sr_driver_summary])
184 # Check whether the sr_deps_avail list contains all of the arguments.
185 # Unavailable dependencies are collected in sr_deps_missing.
186 sr_check_driver_deps() {
190 AS_CASE([" $sr_deps_avail "], [*" $sr_dep "*],,
191 [SR_APPEND([sr_deps_missing], [', '], [$sr_dep])])
193 test -z "$sr_deps_missing" || return 1
196 AC_ARG_ENABLE([all-drivers],
197 [AS_HELP_STRING([--enable-all-drivers],
198 [enable all drivers by default [default=yes]])],
199 [], [enable_all_drivers=yes])
201 ## _SR_DRIVER(Device name, driver-name, var-name, [dependencies...])
202 m4_define([_SR_DRIVER], [
204 [AS_HELP_STRING([--enable-$2], [enable $1 support])],
205 [$3=$enableval], [$3=$enable_all_drivers])
207 AS_IF([test "x[$]$3" = xyes], [sr_hw_info=yes[]m4_ifval([$4], [
208 sr_check_driver_deps $4 \
209 || $3=no sr_hw_info="no (missing: $sr_deps_missing)"
210 ])], [sr_hw_info='no (disabled)'])
211 sr_driver_summary_append "$2" "$sr_hw_info"
213 AM_CONDITIONAL([$3], [test "x[$]$3" = xyes])
214 AM_COND_IF([$3], [AC_DEFINE([HAVE_$3], [1], [Whether to support $1 device.]) AC_DEFINE([HAVE_DRIVERS], [1], [Whether at least one driver is enabled.])])
217 ## SR_DRIVER(Device name, driver-name, [dependencies...])
218 m4_define([SR_DRIVER],
219 [_SR_DRIVER([$1], [$2], m4_expand([AS_TR_CPP([HW_$2])]), [$3])])
221 SR_DRIVER([Agilent DMM], [agilent-dmm], [libserialport])
222 SR_DRIVER([Appa 55II], [appa-55ii], [libserialport])
223 SR_DRIVER([Arachnid Labs Re:load Pro], [arachnid-labs-re-load-pro], [libserialport])
224 SR_DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma], [libftdi])
225 SR_DRIVER([Atten PPS3xxx], [atten-pps3xxx], [libserialport])
226 SR_DRIVER([BayLibre ACME], [baylibre-acme], [sys_timerfd_h])
227 SR_DRIVER([BeagleLogic], [beaglelogic], [sys_mman_h sys_ioctl_h])
228 SR_DRIVER([Brymen BM86x], [brymen-bm86x], [libusb])
229 SR_DRIVER([Brymen DMM], [brymen-dmm], [libserialport])
230 SR_DRIVER([CEM DT-885x], [cem-dt-885x], [libserialport])
231 SR_DRIVER([Center 3xx], [center-3xx], [libserialport])
232 SR_DRIVER([ChronoVu LA], [chronovu-la], [libusb libftdi])
233 SR_DRIVER([Colead SLM], [colead-slm], [libserialport])
234 SR_DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu], [libserialport])
235 SR_DRIVER([DER EE DE-5000], [deree-de5000], [libserialport])
236 SR_DRIVER([demo], [demo])
237 SR_DRIVER([Fluke DMM], [fluke-dmm], [libserialport])
238 SR_DRIVER([FTDI LA], [ftdi-la], [libusb libftdi])
239 SR_DRIVER([fx2lafw], [fx2lafw], [libusb])
240 SR_DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x], [libserialport])
241 SR_DRIVER([GW Instek GDS-800], [gwinstek-gds-800], [libserialport])
242 SR_DRIVER([Hameg HMO], [hameg-hmo], [libserialport])
243 SR_DRIVER([Hantek 6xxx], [hantek-6xxx], [libusb])
244 SR_DRIVER([Hantek DSO], [hantek-dso], [libusb])
245 SR_DRIVER([HP 3457A], [hp-3457a])
246 SR_DRIVER([Hung-Chang DSO-2100], [hung-chang-dso-2100], [libieee1284])
247 SR_DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2], [libusb])
248 SR_DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus], [libftdi])
249 SR_DRIVER([Kecheng KC-330B], [kecheng-kc-330b], [libusb])
250 SR_DRIVER([KERN scale], [kern-scale], [libserialport])
251 SR_DRIVER([Korad KAxxxxP], [korad-kaxxxxp], [libserialport])
252 SR_DRIVER([Lascar EL-USB], [lascar-el-usb], [libusb])
253 SR_DRIVER([LeCroy LogicStudio], [lecroy-logicstudio], [libusb])
254 SR_DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx], [libserialport])
255 SR_DRIVER([maynuo-m97], [maynuo-m97])
256 SR_DRIVER([MIC 985xx], [mic-985xx], [libserialport])
257 SR_DRIVER([Motech LPS 30x], [motech-lps-30x], [libserialport])
258 SR_DRIVER([Norma DMM], [norma-dmm], [libserialport])
259 SR_DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer], [libserialport])
260 SR_DRIVER([PCE PCE-322A], [pce-322a], [libserialport])
261 SR_DRIVER([Pipistrello-OLS], [pipistrello-ols], [libftdi])
262 SR_DRIVER([Rigol DS], [rigol-ds])
263 SR_DRIVER([Saleae Logic16], [saleae-logic16], [libusb])
264 SR_DRIVER([SCPI PPS], [scpi-pps])
265 SR_DRIVER([serial DMM], [serial-dmm], [libserialport])
266 SR_DRIVER([Sysclk LWLA], [sysclk-lwla], [libusb])
267 SR_DRIVER([Teleinfo], [teleinfo], [libserialport])
268 SR_DRIVER([Testo], [testo], [libusb])
269 SR_DRIVER([Tondaj SL-814], [tondaj-sl-814], [libserialport])
270 SR_DRIVER([UNI-T DMM], [uni-t-dmm], [libusb])
271 SR_DRIVER([UNI-T UT32x], [uni-t-ut32x], [libusb])
272 SR_DRIVER([Victor DMM], [victor-dmm], [libusb])
273 SR_DRIVER([Yokogawa DL/DLM], [yokogawa-dlm])
274 SR_DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube], [libusb])
276 ###############################
277 ## Language bindings setup ##
278 ###############################
281 SR_ARG_ENABLE_WARNINGS([SR_WXXFLAGS], [-Wall], [-Wall -Wextra])
283 AC_ARG_ENABLE([bindings],
284 [AS_HELP_STRING([--enable-bindings], [build language bindings [default=yes]])],
285 [], [enable_bindings=yes])
288 [AS_HELP_STRING([--enable-cxx], [build C++ bindings [default=yes]])],
289 [], [enable_cxx=$enable_bindings])
291 AC_ARG_ENABLE([python],
292 [AS_HELP_STRING([--enable-python], [build Python bindings [default=yes]])],
293 [], [enable_python=$enable_bindings])
295 AC_ARG_ENABLE([ruby],
296 [AS_HELP_STRING([--enable-ruby], [build Ruby bindings [default=yes]])],
297 [], [enable_ruby=$enable_bindings])
299 AC_ARG_ENABLE([java],
300 [AS_HELP_STRING([--enable-java], [build Java bindings [default=yes]])],
301 [], [enable_java=$enable_bindings])
309 # Check if the C++ compiler supports the C++11 standard.
310 AX_CXX_COMPILE_STDCXX([11], [noext], [optional])
311 AS_IF([test "x$HAVE_CXX11" != x1],
312 [SR_APPEND([sr_cxx_missing], [', '], ['C++11'])])
314 # The C++ bindings need glibmm.
315 SR_PKG_CHECK([glibmm], [SR_PKGLIBS_CXX], [glibmm-2.4 >= 2.32.0])
316 AS_IF([test "x$sr_have_glibmm" != xyes],
317 [SR_APPEND([sr_cxx_missing], [', '], [glibmm])])
319 # The C++ bindings use Doxygen to parse libsigrok symbols.
320 AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes], [no])
321 AS_IF([test "x$HAVE_DOXYGEN" != xyes],
322 [SR_APPEND([sr_cxx_missing], [', '], [Doxygen])])
324 # Python is needed for the C++ bindings.
325 AM_PATH_PYTHON([2.7],
328 SR_APPEND([sr_cxx_missing], [', '], [Python])])
330 AS_IF([test -z "$sr_cxx_missing"],
331 [BINDINGS_CXX=$enable_cxx], [BINDINGS_CXX=no])
332 AM_CONDITIONAL([BINDINGS_CXX], [test "x$BINDINGS_CXX" = xyes])
334 # C++ bindings want stoi and stod.
335 AM_COND_IF([BINDINGS_CXX], [
336 AC_CACHE_CHECK([for stoi and stod], [sr_cv_have_stoi_stod],
337 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string>]],
338 [[(void) std::stoi("1"); (void) std::stod("1.0");]])],
339 [sr_cv_have_stoi_stod=yes], [sr_cv_have_stoi_stod=no])])
340 AS_IF([test "x$sr_cv_have_stoi_stod" = xyes],
341 [AC_DEFINE([HAVE_STOI_STOD], [1],
342 [Specifies whether we have the stoi and stod functions.])])
345 #######################
346 ## Python bindings ##
347 #######################
349 AS_IF([test "x$BINDINGS_CXX" = xyes],
350 [sr_python_missing=],
351 [sr_python_missing='C++ bindings'])
353 # Extract major and minor version number of the Python interpreter.
354 sr_pymajor=${PYTHON_VERSION%%.*}
355 sr_pyminor=${PYTHON_VERSION#*.}
357 # The Python bindings need Python development files. Check for either
358 # Python 3 or Python 2 headers depending on the interpreter version.
359 SR_PKG_CHECK([python_dev], [SR_PKGLIBS_PYTHON],
360 [python = $PYTHON_VERSION],
361 [python$sr_pymajor = $PYTHON_VERSION],
362 [python$sr_pymajor$sr_pyminor = $PYTHON_VERSION],
363 [python-$PYTHON_VERSION = $PYTHON_VERSION])
365 AS_IF([test "x$sr_have_python_dev" != xyes],
366 [SR_APPEND([sr_python_missing], [', '], [Headers])])
368 # PyGObject is needed for the Python bindings.
369 SR_PKG_CHECK([pygobject], [SR_PKGLIBS_PYTHON], [pygobject-3.0 >= 3.0.0])
370 AS_IF([test "x$sr_have_pygobject" != xyes],
371 [SR_APPEND([sr_python_missing], [', '], [PyGObject])])
373 PKG_CHECK_EXISTS([pygobject-3.0 < 3.7.91],
374 [AC_DEFINE([PYGOBJECT_FLAGS_SIGNED], [1],
375 [Whether last argument to pyg_flags_get_value() is signed.])])
377 # The Python bindings need the setuptools and numpy Python modules.
378 # We'll let it go through even if the AX macro wasn't found, as the
379 # Python modules may still be there.
380 m4_ifdef([AX_PYTHON_MODULE], [
381 AX_PYTHON_MODULE([setuptools])
382 AX_PYTHON_MODULE([numpy])
384 HAVE_PYMOD_SETUPTOOLS=yes
386 m4_warn([unsupported],
387 [Missing macro AX_PYTHON_MODULE: no check for setuptools and numpy])
389 AS_IF([test "x$HAVE_PYMOD_SETUPTOOLS" != xyes],
390 [SR_APPEND([sr_python_missing], [', '], [setuptools])])
391 AS_IF([test "x$HAVE_PYMOD_NUMPY" != xyes],
392 [SR_APPEND([sr_python_missing], [', '], [numpy])])
394 # The Python bindings use SWIG to generate code.
395 AC_CHECK_PROGS([SWIG], [swig swig3.0 swig2.0])
396 AS_IF([test "x$SWIG" != x],
397 AC_MSG_CHECKING([for $SWIG version])
398 [SWIG_VERSION=`$SWIG -version 2>&1 | sed -n 's/SWIG Version //p'`]
399 AC_MSG_RESULT([$SWIG_VERSION]))
400 AS_IF([test "x$SWIG" = x],
401 [SR_APPEND([sr_python_missing], [', '], [SWIG])])
403 AS_IF([test -z "$sr_python_missing"],
404 [BINDINGS_PYTHON=$enable_python], [BINDINGS_PYTHON=no])
405 AM_CONDITIONAL([BINDINGS_PYTHON], [test "x$BINDINGS_PYTHON" = xyes])
407 #####################
409 #####################
411 AS_IF([test "x$BINDINGS_CXX" = xyes],
413 [sr_ruby_missing='C++ bindings'])
415 AC_PATH_PROGS(RUBY, ["${RUBY-ruby}"], [])
416 AS_IF([test "x$RUBY" != x],
417 AC_MSG_CHECKING([for Ruby version])
418 [RUBY_VERSION=`$RUBY -e 'puts RUBY_VERSION'`]
419 AC_MSG_RESULT([$RUBY_VERSION])
420 [RUBY_DLEXT=`$RUBY -rrbconfig -e 'puts RbConfig::CONFIG[["DLEXT"]]'`]
421 AC_SUBST(RUBY_DLEXT))
423 AS_IF([test "x$RUBY" = x],
424 [SR_APPEND([sr_ruby_missing], [', '], [Ruby])])
426 # Extract major and minor version number of the Ruby interpreter.
427 sr_rbmajor=${RUBY_VERSION%%.*}
428 sr_rbminor=${RUBY_VERSION#*.}
429 sr_rbminor=${sr_rbminor%%.*}
431 # The Ruby bindings need Ruby development files.
432 SR_PKG_CHECK([ruby_dev], [SR_PKGLIBS_RUBY],
434 [ruby-$sr_rbmajor.$sr_rbminor])
436 AS_IF([test "x$sr_have_ruby_dev" != xyes],
437 [SR_APPEND([sr_ruby_missing], [', '], [Headers])])
439 # The Ruby bindings use SWIG >= 3.0.8 to generate code.
440 AS_IF([test "x$SWIG" = x],
441 [SR_APPEND([sr_ruby_missing], [', '], [SWIG])],
442 [AS_VERSION_COMPARE($SWIG_VERSION, "3.0.8",
443 [SR_APPEND([sr_ruby_missing], [', '], ['SWIG >= 3.0.8'])])])
445 AS_IF([test -z "$sr_ruby_missing"],
446 [BINDINGS_RUBY=$enable_ruby], [BINDINGS_RUBY=no])
447 AM_CONDITIONAL([BINDINGS_RUBY], [test "x$BINDINGS_RUBY" = xyes])
453 AS_IF([test "x$BINDINGS_CXX" = xyes],
455 [sr_java_missing='C++ bindings'])
457 # The Java bindings use SWIG to generate code.
458 AS_IF([test "x$SWIG" = x],
459 [SR_APPEND([sr_java_missing], [', '], [SWIG])])
461 # Find Java compiler and JNI includes for Java bindings.
462 AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no])
463 AS_IF([test "x$HAVE_JAVAC" = xno],
464 [SR_APPEND([sr_java_missing], [', '], [JavaC])])
466 AC_ARG_WITH([jni-include-path],
467 [AS_HELP_STRING([[--with-jni-include-path=DIR-LIST (space-separated)]],
468 [specify JNI include directories [default=detect]])],
469 [JNI_INCLUDE_DIRS=" $withval"], [JNI_INCLUDE_DIRS=])
472 AS_IF([test "x$enable_java$HAVE_JAVAC" = xyesyes], [
474 AS_IF([test -z "$JNI_INCLUDE_DIRS" && test "x$cross_compiling" != xyes], [
475 ## Work around the totally broken logic in AX_JNI_INCLUDE_DIR:
476 ## If we can find jni.h without any special search path, skip
477 ## the execution of the broken macro to increase our chances of
479 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <jni.h>]], [])],,
480 [AX_JNI_INCLUDE_DIR])
483 for sr_dir in $JNI_INCLUDE_DIRS
485 SR_APPEND([JNI_CPPFLAGS], ["-I$sr_dir"])
487 AC_SUBST([JNI_CPPFLAGS])
489 sr_save_cppflags=$CPPFLAGS
490 SR_APPEND([CPPFLAGS], [$JNI_CPPFLAGS])
491 AC_CHECK_HEADER([jni.h],,
492 [SR_APPEND([sr_java_missing], [', '], ['JNI headers'])])
493 CPPFLAGS=$sr_save_cppflags
495 AS_IF([test -z "$sr_java_missing"],
496 [BINDINGS_JAVA=$enable_java], [BINDINGS_JAVA=no])
497 AM_CONDITIONAL([BINDINGS_JAVA], [test "x$BINDINGS_JAVA" = xyes])
499 ##############################
500 ## Finalize configuration ##
501 ##############################
503 # Add mandatory dependencies to module list.
504 SR_APPEND([SR_PKGLIBS], ['libzip >= 0.10'])
505 AC_SUBST([SR_PKGLIBS])
507 # Retrieve the compile and link flags for all modules combined.
508 # Also, bail out at this point if any module dependency is not met.
509 PKG_CHECK_MODULES([LIBSIGROK], [glib-2.0 >= 2.32.0 $SR_PKGLIBS])
510 PKG_CHECK_MODULES([TESTS], [$SR_PKGLIBS_TESTS glib-2.0 $SR_PKGLIBS])
512 # SR_PKGLIBS_CXX may be empty, so only invoke these checks when
513 # the C++ bindings are enabled.
514 AM_COND_IF([BINDINGS_CXX], [
515 PKG_CHECK_MODULES([LIBSIGROKCXX], [$SR_PKGLIBS_CXX])
516 PKG_CHECK_MODULES([PYSIGROK], [$SR_PKGLIBS_PYTHON $SR_PKGLIBS_CXX])
517 PKG_CHECK_MODULES([RBSIGROK], [$SR_PKGLIBS_RUBY $SR_PKGLIBS_CXX], [AC_SUBST(RBSIGROK_EXTDIR, "lib/$($PKG_CONFIG --variable=sitearch $SR_PKGLIBS_RUBY)/$($PKG_CONFIG --variable=RUBY_BASE_NAME $SR_PKGLIBS_RUBY)/vendor_ruby/$($PKG_CONFIG --variable=ruby_version $SR_PKGLIBS_RUBY)")])
520 # Check for specific libusb features, now that we know the CFLAGS.
522 sr_save_cflags=$CFLAGS
524 CFLAGS="$LIBSIGROK_CFLAGS $CFLAGS"
525 LIBS="$LIBSIGROK_LIBS $LIBS"
526 AC_CHECK_TYPES([libusb_os_handle],
527 [sr_have_libusb_os_handle=yes], [sr_have_libusb_os_handle=no],
528 [[#include <libusb.h>]])
529 AC_CHECK_FUNCS([zip_discard])
531 CFLAGS=$sr_save_cflags
533 AM_COND_IF([NEED_USB], [AS_CASE([$sr_have_libusb_os_handle:$host_os], [no:mingw*],
534 [AC_MSG_ERROR([Windows builds require the event-abstraction branch of libusb])])])
536 sr_glib_version=`$PKG_CONFIG --modversion glib-2.0 2>&AS_MESSAGE_LOG_FD`
537 sr_libzip_version=`$PKG_CONFIG --modversion libzip 2>&AS_MESSAGE_LOG_FD`
539 AC_DEFINE_UNQUOTED([CONF_LIBZIP_VERSION], ["$sr_libzip_version"],
540 [Build-time version of libzip.])
541 AC_DEFINE_UNQUOTED([CONF_HOST], ["$host"],
542 [The canonical host libsigrok will run on.])
544 AC_CONFIG_FILES([Makefile libsigrok.pc bindings/cxx/libsigrokcxx.pc])
548 # Prepare bindings report messages.
549 m4_define([SR_PREPARE_BINDING_REPORT], [
551 test -z "$sr_$1_missing" || sr_report_$1=" (missing: $sr_$1_missing)"
552 test "x$enable_$1" = xyes || sr_report_$1=' (disabled)'
554 m4_map_args([SR_PREPARE_BINDING_REPORT], [cxx], [python], [ruby], [java])
556 cat >&AS_MESSAGE_FD <<_EOF
558 libsigrok configuration summary:
559 - Package version................. $SR_PACKAGE_VERSION
560 - Library ABI version............. $SR_LIB_VERSION
561 - Prefix.......................... $prefix
562 - Building on..................... $build
563 - Building for.................... $host
565 Compile configuration:
566 - C compiler...................... $CC
567 - C compiler version.............. $sr_cc_version
568 - C compiler flags................ $CFLAGS
569 - Additional C compiler flags..... $SR_EXTRA_CFLAGS
570 - C compiler warnings............. $SR_WFLAGS
571 - C++ compiler.................... $CXX
572 - C++ compiler version............ $sr_cxx_version
573 - C++ compiler flags.............. $CXXFLAGS
574 - C++ compiler warnings........... $SR_WXXFLAGS
576 Detected libraries (required):
577 - glib-2.0 >= 2.32.0.............. $sr_glib_version
578 - libzip >= 0.10.................. $sr_libzip_version
580 Detected libraries (optional):
582 Enabled hardware drivers:
584 Enabled SCPI backends:
585 - TCP............................. yes
586 - RPC............................. $sr_cv_have_rpc
587 - serial.......................... $sr_have_libserialport
588 - VISA............................ $sr_have_librevisa
589 - GPIB............................ $sr_have_libgpib
590 - USBTMC.......................... $sr_have_libusb
592 Enabled language bindings:
593 - C++............................. $BINDINGS_CXX$sr_report_cxx
594 - Python.......................... $BINDINGS_PYTHON$sr_report_python
595 - Ruby............................ $BINDINGS_RUBY$sr_report_ruby
596 - Java............................ $BINDINGS_JAVA$sr_report_java