2 ## This file is part of the libsigrok project.
4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
7 ## This program is free software: you can redistribute it and/or modify
8 ## it under the terms of the GNU General Public License as published by
9 ## the Free Software Foundation, either version 3 of the License, or
10 ## (at your option) any later version.
12 ## This program is distributed in the hope that it will be useful,
13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
15 ## GNU General Public License for more details.
17 ## You should have received a copy of the GNU General Public License
18 ## along with this program. If not, see <http://www.gnu.org/licenses/>.
21 # We require at least autoconf 2.63 (AC_INIT format changed there).
24 AC_INIT([libsigrok], [0.5.0],
25 [sigrok-devel@lists.sourceforge.net],
26 [libsigrok], [http://www.sigrok.org])
27 AC_CONFIG_MACRO_DIR([m4])
28 AC_CONFIG_AUX_DIR([autostuff])
29 AC_CONFIG_HEADERS([config.h include/libsigrok/version.h])
31 # We require at least automake 1.11 (needed for 'silent rules').
32 AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define nostdinc subdir-objects check-news color-tests])
33 AM_SILENT_RULES([yes])
34 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
38 # Checks for programs.
44 # Required for per-target flags or subdir-objects with C sources.
47 # Set the standard the C library headers should conform to.
48 AH_VERBATIM([_POSIX_C_SOURCE], [/* The targeted POSIX standard. */
49 #ifndef _POSIX_C_SOURCE
50 # define _POSIX_C_SOURCE 200112L
53 # Get compiler versions.
54 SR_PROG_VERSION([$CC], [sr_cc_version])
55 SR_PROG_VERSION([$CXX], [sr_cxx_version])
57 # Check for optional make features.
58 SR_PROG_MAKE_ORDER_ONLY
63 # Set up the libsigrok version defines.
64 SR_PKG_VERSION_SET([SR_PACKAGE_VERSION], [AC_PACKAGE_VERSION])
66 # Library version for libsigrok (NOT the same as the package version).
67 # Carefully read the libtool docs before updating these numbers!
68 # The algorithm for determining which number to change (and how) is nontrivial!
69 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
70 # Format: current:revision:age.
71 SR_LIB_VERSION_SET([SR_LIB_VERSION], [3:0:0])
73 AM_CONDITIONAL([WIN32], [test -z "${host_os##mingw*}" || test -z "${host_os##cygwin*}"])
75 #############################
76 ## Optional dependencies ##
77 #############################
81 # Initialize pkg-config.
82 # We require at least 0.22, as "Requires.private" behaviour changed there.
83 PKG_PROG_PKG_CONFIG([0.22])
85 # Keep track of all checked modules so we can list them at the end.
86 SR_PKG_CHECK_SUMMARY([sr_pkglibs_summary])
88 # Collect the pkg-config module names of all dependencies in SR_PKGLIBS.
89 # These are used to derive the compiler flags and for the "Requires.private"
90 # field in the generated libsigrok.pc file.
91 SR_VAR_OPT_PKG([SR_PKGLIBS], [sr_deps_avail])
98 SR_ARG_OPT_PKG([libserialport], [LIBSERIALPORT], [NEED_SERIAL],
99 [libserialport >= 0.1.1])
101 SR_ARG_OPT_PKG([libftdi], [LIBFTDI],,
102 [libftdi1 >= 1.0], [libftdi >= 0.16])
104 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
105 # This means libusb-1.0 is always available; no need to check for it.
106 # On Windows, require the latest version we can get our hands on,
107 # until the new generic event handling has seen an official release.
109 [freebsd*], [sr_libusb_req='libusb-1.0' sr_have_libusb=yes],
110 [mingw*], [sr_libusb_req='libusb-1.0 >= 1.0.20'],
111 [sr_libusb_req='libusb-1.0 >= 1.0.16'])
113 SR_ARG_OPT_PKG([libusb], [LIBUSB_1_0], [NEED_USB],
116 SR_ARG_OPT_PKG([librevisa], [LIBREVISA], [NEED_VISA],
117 [librevisa >= 0.0.20130412])
119 SR_ARG_OPT_PKG([libgpib], [LIBGPIB], [NEED_GPIB],
122 SR_ARG_OPT_CHECK([libieee1284], [LIBIEEE1284],, [
124 LIBS="-lieee1284 $LIBS"
125 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <ieee1284.h>]],
126 [[(void) ieee1284_open(0, 0, 0);]])],
127 [sr_have_libieee1284=yes], [sr_have_libieee1284=no])
130 AS_IF([test "x$sr_have_libieee1284" = xyes],
131 [SR_PREPEND([SR_EXTRA_LIBS], [-lieee1284])])
133 ######################
135 ######################
137 # The Check unit testing framework is optional. Disable if not found.
138 SR_PKG_CHECK([check], [SR_PKGLIBS_TESTS], [check >= 0.9.4])
139 AM_CONDITIONAL([HAVE_CHECK], [test "x$sr_have_check" = xyes])
141 # Enable the C99 standard if possible, and enforce the use
142 # of SR_API to explicitly mark all public API functions.
144 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [C99], [-std=c99 -c99 -AC99 -qlanglvl=extc99])
145 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [visibility], [-fvisibility=hidden])
147 SR_ARG_ENABLE_WARNINGS([SR_WFLAGS], [-Wall], [-Wall -Wextra -Wmissing-prototypes])
149 # Check host characteristics.
153 AC_CHECK_HEADERS([sys/mman.h], [SR_APPEND([sr_deps_avail], [sys_mman_h])])
154 AC_CHECK_HEADERS([sys/ioctl.h], [SR_APPEND([sr_deps_avail], [sys_ioctl_h])])
155 AC_CHECK_HEADERS([sys/timerfd.h], [SR_APPEND([sr_deps_avail], [sys_timerfd_h])])
157 # We need to link against the Winsock2 library for SCPI over TCP.
158 AS_CASE([$host_os], [mingw*], [SR_PREPEND([SR_EXTRA_LIBS], [-lws2_32])])
160 # libm (the standard math library) is always needed.
161 SR_SEARCH_LIBS([SR_EXTRA_LIBS], [pow], [m])
163 # RPC is only needed for VXI support.
164 AC_CACHE_CHECK([for RPC support], [sr_cv_have_rpc],
165 [AC_LINK_IFELSE([AC_LANG_PROGRAM(
166 [[#include <rpc/rpc.h>]m4_newline[CLIENT *rpc_test(void);]],
167 [[(void) clnt_create("", 0, 0, "");]])],
168 [sr_cv_have_rpc=yes], [sr_cv_have_rpc=no])])
169 AS_IF([test "x$sr_cv_have_rpc" = xyes],
170 [AC_DEFINE([HAVE_RPC], [1], [Specifies whether we have RPC support.])])
171 # VXI support is only compiled if RPC support was found.
172 AM_CONDITIONAL([NEED_RPC], [test "x$sr_cv_have_rpc" = xyes])
174 ########################
175 ## Hardware drivers ##
176 ########################
178 # Keep track of all drivers so we can list them at the end.
179 SR_VAR_SUMMARY([sr_driver_summary])
181 # Check whether the sr_deps_avail list contains all of the arguments.
182 # Unavailable dependencies are collected in sr_deps_missing.
183 sr_check_driver_deps() {
187 AS_CASE([" $sr_deps_avail "], [*" $sr_dep "*],,
188 [SR_APPEND([sr_deps_missing], [', '], [$sr_dep])])
190 test -z "$sr_deps_missing" || return 1
193 AC_ARG_ENABLE([all-drivers],
194 [AS_HELP_STRING([--enable-all-drivers],
195 [enable all drivers by default [default=yes]])],
196 [], [enable_all_drivers=yes])
198 ## _SR_DRIVER(Device name, driver-name, var-name, [dependencies...])
199 m4_define([_SR_DRIVER], [
201 [AS_HELP_STRING([--enable-$2], [enable $1 support])],
202 [$3=$enableval], [$3=$enable_all_drivers])
204 AS_IF([test "x[$]$3" = xyes], [sr_hw_info=yes[]m4_ifval([$4], [
205 sr_check_driver_deps $4 \
206 || $3=no sr_hw_info="no (missing: $sr_deps_missing)"
207 ])], [sr_hw_info='no (disabled)'])
208 sr_driver_summary_append "$2" "$sr_hw_info"
210 AM_CONDITIONAL([$3], [test "x[$]$3" = xyes])
211 AM_COND_IF([$3], [AC_DEFINE([HAVE_$3], [1], [Whether to support $1 device.])])
214 ## SR_DRIVER(Device name, driver-name, [dependencies...])
215 m4_define([SR_DRIVER],
216 [_SR_DRIVER([$1], [$2], m4_expand([AS_TR_CPP([HW_$2])]), [$3])])
218 SR_DRIVER([Agilent DMM], [agilent-dmm], [libserialport])
219 SR_DRIVER([Appa 55II], [appa-55ii], [libserialport])
220 SR_DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma], [libftdi])
221 SR_DRIVER([Atten PPS3xxx], [atten-pps3xxx], [libserialport])
222 SR_DRIVER([BayLibre ACME], [baylibre-acme], [sys_timerfd_h])
223 SR_DRIVER([BeagleLogic], [beaglelogic], [sys_mman_h sys_ioctl_h])
224 SR_DRIVER([Brymen BM86x], [brymen-bm86x], [libusb])
225 SR_DRIVER([Brymen DMM], [brymen-dmm], [libserialport])
226 SR_DRIVER([CEM DT-885x], [cem-dt-885x], [libserialport])
227 SR_DRIVER([Center 3xx], [center-3xx], [libserialport])
228 SR_DRIVER([ChronoVu LA], [chronovu-la], [libusb libftdi])
229 SR_DRIVER([Colead SLM], [colead-slm], [libserialport])
230 SR_DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu], [libserialport])
231 SR_DRIVER([DER EE DE-5000], [deree-de5000], [libserialport])
232 SR_DRIVER([demo], [demo])
233 SR_DRIVER([Fluke DMM], [fluke-dmm], [libserialport])
234 SR_DRIVER([fx2lafw], [fx2lafw], [libusb])
235 SR_DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x], [libserialport])
236 SR_DRIVER([GW Instek GDS-800], [gwinstek-gds-800], [libserialport])
237 SR_DRIVER([Hameg HMO], [hameg-hmo], [libserialport])
238 SR_DRIVER([Hantek DSO], [hantek-dso], [libusb])
239 SR_DRIVER([Hung-Chang DSO-2100], [hung-chang-dso-2100], [libieee1284])
240 SR_DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2], [libusb])
241 SR_DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus], [libftdi])
242 SR_DRIVER([Kecheng KC-330B], [kecheng-kc-330b], [libusb])
243 SR_DRIVER([KERN scale], [kern-scale], [libserialport])
244 SR_DRIVER([Korad KAxxxxP], [korad-kaxxxxp], [libserialport])
245 SR_DRIVER([Lascar EL-USB], [lascar-el-usb], [libusb])
246 SR_DRIVER([LeCroy LogicStudio], [lecroy-logicstudio], [libusb])
247 SR_DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx], [libserialport])
248 SR_DRIVER([maynuo-m97], [maynuo-m97])
249 SR_DRIVER([MIC 985xx], [mic-985xx], [libserialport])
250 SR_DRIVER([Motech LPS 30x], [motech-lps-30x], [libserialport])
251 SR_DRIVER([Norma DMM], [norma-dmm], [libserialport])
252 SR_DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer], [libserialport])
253 SR_DRIVER([Pipistrello-OLS], [pipistrello-ols], [libftdi])
254 SR_DRIVER([Rigol DS], [rigol-ds])
255 SR_DRIVER([Saleae Logic16], [saleae-logic16], [libusb])
256 SR_DRIVER([SCPI PPS], [scpi-pps])
257 SR_DRIVER([serial DMM], [serial-dmm], [libserialport])
258 SR_DRIVER([Sysclk LWLA], [sysclk-lwla], [libusb])
259 SR_DRIVER([Teleinfo], [teleinfo], [libserialport])
260 SR_DRIVER([Testo], [testo], [libusb])
261 SR_DRIVER([Tondaj SL-814], [tondaj-sl-814], [libserialport])
262 SR_DRIVER([UNI-T DMM], [uni-t-dmm], [libusb])
263 SR_DRIVER([UNI-T UT32x], [uni-t-ut32x], [libusb])
264 SR_DRIVER([Victor DMM], [victor-dmm], [libusb])
265 SR_DRIVER([Yokogawa DL/DLM], [yokogawa-dlm])
266 SR_DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube], [libusb])
268 ###############################
269 ## Language bindings setup ##
270 ###############################
273 SR_ARG_ENABLE_WARNINGS([SR_WXXFLAGS], [-Wall], [-Wall -Wextra])
275 AC_ARG_ENABLE([bindings],
276 [AS_HELP_STRING([--enable-bindings], [build language bindings [default=yes]])],
277 [], [enable_bindings=yes])
280 [AS_HELP_STRING([--enable-cxx], [build C++ bindings [default=yes]])],
281 [], [enable_cxx=$enable_bindings])
283 AC_ARG_ENABLE([python],
284 [AS_HELP_STRING([--enable-python], [build Python bindings [default=yes]])],
285 [], [enable_python=$enable_bindings])
287 AC_ARG_ENABLE([ruby],
288 [AS_HELP_STRING([--enable-ruby], [build Ruby bindings [default=yes]])],
289 [], [enable_ruby=$enable_bindings])
291 AC_ARG_ENABLE([java],
292 [AS_HELP_STRING([--enable-java], [build Java bindings [default=yes]])],
293 [], [enable_java=$enable_bindings])
301 # Check if the C++ compiler supports the C++11 standard.
302 AX_CXX_COMPILE_STDCXX_11([noext], [optional])
303 AS_IF([test "x$HAVE_CXX11" != x1],
304 [SR_APPEND([sr_cxx_missing], [', '], ['C++11'])])
306 # The C++ bindings need glibmm.
307 SR_PKG_CHECK([glibmm], [SR_PKGLIBS_CXX], [glibmm-2.4 >= 2.32.0])
308 AS_IF([test "x$sr_have_glibmm" != xyes],
309 [SR_APPEND([sr_cxx_missing], [', '], [glibmm])])
311 # The C++ bindings use Doxygen to parse libsigrok symbols.
312 AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes], [no])
313 AS_IF([test "x$HAVE_DOXYGEN" != xyes],
314 [SR_APPEND([sr_cxx_missing], [', '], [Doxygen])])
316 # Python is needed for the C++ bindings.
317 AM_PATH_PYTHON([2.7],
320 SR_APPEND([sr_cxx_missing], [', '], [Python])])
322 AS_IF([test -z "$sr_cxx_missing"],
323 [BINDINGS_CXX=$enable_cxx], [BINDINGS_CXX=no])
324 AM_CONDITIONAL([BINDINGS_CXX], [test "x$BINDINGS_CXX" = xyes])
326 # C++ bindings want stoi and stod.
327 AM_COND_IF([BINDINGS_CXX], [
328 AC_CACHE_CHECK([for stoi and stod], [sr_cv_have_stoi_stod],
329 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string>]],
330 [[(void) std::stoi("1"); (void) std::stod("1.0");]])],
331 [sr_cv_have_stoi_stod=yes], [sr_cv_have_stoi_stod=no])])
332 AS_IF([test "x$sr_cv_have_stoi_stod" = xyes],
333 [AC_DEFINE([HAVE_STOI_STOD], [1],
334 [Specifies whether we have the stoi and stod functions.])])
337 #######################
338 ## Python bindings ##
339 #######################
341 AS_IF([test "x$BINDINGS_CXX" = xyes],
342 [sr_python_missing=],
343 [sr_python_missing='C++ bindings'])
345 # Extract major and minor version number of the Python interpreter.
346 sr_pymajor=${PYTHON_VERSION%%.*}
347 sr_pyminor=${PYTHON_VERSION#*.}
349 # The Python bindings need Python development files. Check for either
350 # Python 3 or Python 2 headers depending on the interpreter version.
351 SR_PKG_CHECK([python_dev], [SR_PKGLIBS_PYTHON],
352 [python = $PYTHON_VERSION],
353 [python$sr_pymajor = $PYTHON_VERSION],
354 [python$sr_pymajor$sr_pyminor = $PYTHON_VERSION],
355 [python-$PYTHON_VERSION = $PYTHON_VERSION])
357 AS_IF([test "x$sr_have_python_dev" != xyes],
358 [SR_APPEND([sr_python_missing], [', '], [Headers])])
360 # PyGObject is needed for the Python bindings.
361 SR_PKG_CHECK([pygobject], [SR_PKGLIBS_PYTHON], [pygobject-3.0 >= 3.0.0])
362 AS_IF([test "x$sr_have_pygobject" != xyes],
363 [SR_APPEND([sr_python_missing], [', '], [PyGObject])])
365 PKG_CHECK_EXISTS([pygobject-3.0 < 3.7.91],
366 [AC_DEFINE([PYGOBJECT_FLAGS_SIGNED], [1],
367 [Whether last argument to pyg_flags_get_value() is signed.])])
369 # The Python bindings need the setuptools and numpy Python modules.
370 # We'll let it go through even if the AX macro wasn't found, as the
371 # Python modules may still be there.
372 m4_ifdef([AX_PYTHON_MODULE], [
373 AX_PYTHON_MODULE([setuptools])
374 AX_PYTHON_MODULE([numpy])
376 HAVE_PYMOD_SETUPTOOLS=yes
378 m4_warn([unsupported],
379 [Missing macro AX_PYTHON_MODULE: no check for setuptools and numpy])
381 AS_IF([test "x$HAVE_PYMOD_SETUPTOOLS" != xyes],
382 [SR_APPEND([sr_python_missing], [', '], [setuptools])])
383 AS_IF([test "x$HAVE_PYMOD_NUMPY" != xyes],
384 [SR_APPEND([sr_python_missing], [', '], [numpy])])
386 # The Python bindings use SWIG to generate code.
387 AC_CHECK_PROGS([SWIG], [swig swig3.0 swig2.0])
388 AS_IF([test "x$SWIG" != x],
389 AC_MSG_CHECKING([for $SWIG version])
390 [SWIG_VERSION=`$SWIG -version 2>&1 | sed -n 's/SWIG Version\s*//p'`]
391 AC_MSG_RESULT([$SWIG_VERSION]))
392 AS_IF([test "x$SWIG" = x],
393 [SR_APPEND([sr_python_missing], [', '], [SWIG])])
395 AS_IF([test -z "$sr_python_missing"],
396 [BINDINGS_PYTHON=$enable_python], [BINDINGS_PYTHON=no])
397 AM_CONDITIONAL([BINDINGS_PYTHON], [test "x$BINDINGS_PYTHON" = xyes])
399 #####################
401 #####################
403 AS_IF([test "x$BINDINGS_CXX" = xyes],
405 [sr_ruby_missing='C++ bindings'])
407 AC_PATH_PROGS(RUBY, ["${RUBY-ruby}"], [])
408 AS_IF([test "x$RUBY" != x],
409 AC_MSG_CHECKING([for Ruby version])
410 [RUBY_VERSION=`$RUBY -e 'puts RUBY_VERSION'`]
411 AC_MSG_RESULT([$RUBY_VERSION])
412 [RUBY_DLEXT=`$RUBY -rrbconfig -e 'puts RbConfig::CONFIG[["DLEXT"]]'`]
413 AC_SUBST(RUBY_DLEXT))
415 AS_IF([test "x$RUBY" = x],
416 [SR_APPEND([sr_ruby_missing], [', '], [Ruby])])
418 # Extract major and minor version number of the Ruby interpreter.
419 sr_rbmajor=${RUBY_VERSION%%.*}
420 sr_rbminor=${RUBY_VERSION#*.}
421 sr_rbminor=${sr_rbminor%%.*}
423 # The Ruby bindings need Ruby development files.
424 SR_PKG_CHECK([ruby_dev], [SR_PKGLIBS_RUBY],
426 [ruby-$sr_rbmajor.$sr_rbminor])
428 AS_IF([test "x$sr_have_ruby_dev" != xyes],
429 [SR_APPEND([sr_ruby_missing], [', '], [Headers])])
431 # The Ruby bindings use SWIG >= 3.0.8 to generate code.
432 AS_IF([test "x$SWIG" = x],
433 [SR_APPEND([sr_ruby_missing], [', '], [SWIG])],
434 [AS_VERSION_COMPARE($SWIG_VERSION, "3.0.8",
435 [SR_APPEND([sr_ruby_missing], [', '], ['SWIG >= 3.0.8'])])])
437 AS_IF([test -z "$sr_ruby_missing"],
438 [BINDINGS_RUBY=$enable_ruby], [BINDINGS_RUBY=no])
439 AM_CONDITIONAL([BINDINGS_RUBY], [test "x$BINDINGS_RUBY" = xyes])
445 AS_IF([test "x$BINDINGS_CXX" = xyes],
447 [sr_java_missing='C++ bindings'])
449 # The Java bindings use SWIG to generate code.
450 AS_IF([test "x$SWIG" = x],
451 [SR_APPEND([sr_java_missing], [', '], [SWIG])])
453 # Find Java compiler and JNI includes for Java bindings.
454 AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no])
455 AS_IF([test "x$HAVE_JAVAC" = xno],
456 [SR_APPEND([sr_java_missing], [', '], [JavaC])])
458 AC_ARG_WITH([jni-include-path],
459 [AS_HELP_STRING([[--with-jni-include-path=DIR-LIST (space-separated)]],
460 [specify JNI include directories [default=detect]])],
461 [JNI_INCLUDE_DIRS=" $withval"], [JNI_INCLUDE_DIRS=])
464 AS_IF([test "x$enable_java$HAVE_JAVAC" = xyesyes], [
466 AS_IF([test -z "$JNI_INCLUDE_DIRS" && test "x$cross_compiling" != xyes], [
467 ## Work around the totally broken logic in AX_JNI_INCLUDE_DIR:
468 ## If we can find jni.h without any special search path, skip
469 ## the execution of the broken macro to increase our chances of
471 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <jni.h>]], [])],,
472 [AX_JNI_INCLUDE_DIR])
475 for sr_dir in $JNI_INCLUDE_DIRS
477 SR_APPEND([JNI_CPPFLAGS], ["-I$sr_dir"])
479 AC_SUBST([JNI_CPPFLAGS])
481 sr_save_cppflags=$CPPFLAGS
482 SR_APPEND([CPPFLAGS], [$JNI_CPPFLAGS])
483 AC_CHECK_HEADER([jni.h],,
484 [SR_APPEND([sr_java_missing], [', '], ['JNI headers'])])
485 CPPFLAGS=$sr_save_cppflags
487 AS_IF([test -z "$sr_java_missing"],
488 [BINDINGS_JAVA=$enable_java], [BINDINGS_JAVA=no])
489 AM_CONDITIONAL([BINDINGS_JAVA], [test "x$BINDINGS_JAVA" = xyes])
491 ##############################
492 ## Finalize configuration ##
493 ##############################
495 # Add mandatory dependencies to module list.
496 SR_APPEND([SR_PKGLIBS], ['libzip >= 0.10'])
497 AC_SUBST([SR_PKGLIBS])
499 # Retrieve the compile and link flags for all modules combined.
500 # Also, bail out at this point if any module dependency is not met.
501 PKG_CHECK_MODULES([LIBSIGROK], [glib-2.0 >= 2.32.0 $SR_PKGLIBS])
502 PKG_CHECK_MODULES([TESTS], [$SR_PKGLIBS_TESTS glib-2.0 $SR_PKGLIBS])
504 # SR_PKGLIBS_CXX may be empty, so only invoke these checks when
505 # the C++ bindings are enabled.
506 AM_COND_IF([BINDINGS_CXX], [
507 PKG_CHECK_MODULES([LIBSIGROKCXX], [$SR_PKGLIBS_CXX])
508 PKG_CHECK_MODULES([PYSIGROK], [$SR_PKGLIBS_PYTHON $SR_PKGLIBS_CXX])
509 PKG_CHECK_MODULES([RBSIGROK], [$SR_PKGLIBS_RUBY $SR_PKGLIBS_CXX], [AC_SUBST(RBSIGROK_EXTDIR, "lib/$($PKG_CONFIG --variable=sitearch $SR_PKGLIBS_RUBY)/$($PKG_CONFIG --variable=RUBY_BASE_NAME $SR_PKGLIBS_RUBY)/vendor_ruby/$($PKG_CONFIG --variable=ruby_version $SR_PKGLIBS_RUBY)")])
512 # Check for specific libusb features, now that we know the CFLAGS.
514 sr_save_cflags=$CFLAGS
516 CFLAGS="$LIBSIGROK_CFLAGS $CFLAGS"
517 LIBS="$LIBSIGROK_LIBS $LIBS"
518 AC_CHECK_TYPES([libusb_os_handle],
519 [sr_have_libusb_os_handle=yes], [sr_have_libusb_os_handle=no],
520 [[#include <libusb.h>]])
521 AC_CHECK_FUNCS([zip_discard])
523 CFLAGS=$sr_save_cflags
525 AM_COND_IF([NEED_USB], [AS_CASE([$sr_have_libusb_os_handle:$host_os], [no:mingw*],
526 [AC_MSG_ERROR([Windows builds require the event-abstraction branch of libusb])])])
528 sr_glib_version=`$PKG_CONFIG --modversion glib-2.0 2>&AS_MESSAGE_LOG_FD`
529 sr_libzip_version=`$PKG_CONFIG --modversion libzip 2>&AS_MESSAGE_LOG_FD`
531 AC_DEFINE_UNQUOTED([CONF_LIBZIP_VERSION], ["$sr_libzip_version"],
532 [Build-time version of libzip.])
533 AC_DEFINE_UNQUOTED([CONF_HOST], ["$host"],
534 [The canonical host libsigrok will run on.])
536 AC_CONFIG_FILES([Makefile libsigrok.pc bindings/cxx/libsigrokcxx.pc])
540 # Prepare bindings report messages.
541 m4_define([SR_PREPARE_BINDING_REPORT], [
543 test -z "$sr_$1_missing" || sr_report_$1=" (missing: $sr_$1_missing)"
544 test "x$enable_$1" = xyes || sr_report_$1=' (disabled)'
546 m4_map_args([SR_PREPARE_BINDING_REPORT], [cxx], [python], [ruby], [java])
548 cat >&AS_MESSAGE_FD <<_EOF
550 libsigrok configuration summary:
551 - Package version................. $SR_PACKAGE_VERSION
552 - Library ABI version............. $SR_LIB_VERSION
553 - Prefix.......................... $prefix
554 - Building on..................... $build
555 - Building for.................... $host
557 Compile configuration:
558 - C compiler...................... $CC
559 - C compiler version.............. $sr_cc_version
560 - C compiler flags................ $CFLAGS
561 - Additional C compiler flags..... $SR_EXTRA_CFLAGS
562 - C compiler warnings............. $SR_WFLAGS
563 - C++ compiler.................... $CXX
564 - C++ compiler version............ $sr_cxx_version
565 - C++ compiler flags.............. $CXXFLAGS
566 - C++ compiler warnings........... $SR_WXXFLAGS
568 Detected libraries (required):
569 - glib-2.0 >= 2.32.0.............. $sr_glib_version
570 - libzip >= 0.10.................. $sr_libzip_version
572 Detected libraries (optional):
574 Enabled hardware drivers:
576 Enabled SCPI backends:
577 - TCP............................. yes
578 - RPC............................. $sr_cv_have_rpc
579 - serial.......................... $sr_have_libserialport
580 - VISA............................ $sr_have_librevisa
581 - GPIB............................ $sr_have_libgpib
582 - USBTMC.......................... $sr_have_libusb
584 Enabled language bindings:
585 - C++............................. $BINDINGS_CXX$sr_report_cxx
586 - Python.......................... $BINDINGS_PYTHON$sr_report_python
587 - Ruby............................ $BINDINGS_RUBY$sr_report_ruby
588 - Java............................ $BINDINGS_JAVA$sr_report_java