]>
Commit | Line | Data |
---|---|---|
1 | ## | |
2 | ## This file is part of the libsigrok project. | |
3 | ## | |
4 | ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com> | |
5 | ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com> | |
6 | ## | |
7 | ## This program is free software: you can redistribute it and/or modify | |
8 | ## it under the terms of the GNU General Public License as published by | |
9 | ## the Free Software Foundation, either version 3 of the License, or | |
10 | ## (at your option) any later version. | |
11 | ## | |
12 | ## This program is distributed in the hope that it will be useful, | |
13 | ## but WITHOUT ANY WARRANTY; without even the implied warranty of | |
14 | ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the | |
15 | ## GNU General Public License for more details. | |
16 | ## | |
17 | ## You should have received a copy of the GNU General Public License | |
18 | ## along with this program. If not, see <http://www.gnu.org/licenses/>. | |
19 | ## | |
20 | ||
21 | # We require at least autoconf 2.63 (AC_INIT format changed there). | |
22 | AC_PREREQ([2.63]) | |
23 | ||
24 | AC_INIT([libsigrok], [0.4.0], | |
25 | [sigrok-devel@lists.sourceforge.net], | |
26 | [libsigrok], [http://www.sigrok.org]) | |
27 | AC_CONFIG_MACRO_DIR([m4]) | |
28 | AC_CONFIG_AUX_DIR([autostuff]) | |
29 | AC_CONFIG_HEADERS([config.h include/libsigrok/version.h]) | |
30 | ||
31 | # We require at least automake 1.11 (needed for 'silent rules'). | |
32 | AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define nostdinc subdir-objects check-news color-tests]) | |
33 | m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])]) | |
34 | m4_ifdef([AM_PROG_AR], [AM_PROG_AR]) | |
35 | ||
36 | AH_TOP([#ifndef SR_CONFIG_H | |
37 | #define SR_CONFIG_H /* To stop multiple inclusions. */]) | |
38 | AH_BOTTOM([#endif /* SR_CONFIG_H */]) | |
39 | ||
40 | # Enable more compiler warnings via -Wall and -Wextra. Add -fvisibility=hidden | |
41 | # and enforce use of SR_API to explicitly mark all public API functions. | |
42 | CFLAGS="$CFLAGS -std=c11" | |
43 | CFLAGS="$CFLAGS -fvisibility=hidden" | |
44 | CFLAGS="$CFLAGS -D_POSIX_C_SOURCE=200112L" | |
45 | ||
46 | # Checks for programs. | |
47 | AC_PROG_CC | |
48 | AC_PROG_CPP | |
49 | AC_PROG_CXX | |
50 | AC_PROG_INSTALL | |
51 | AC_PROG_LN_S | |
52 | ||
53 | # Required for per-target flags or subdir-objects with C sources. | |
54 | AM_PROG_CC_C_O | |
55 | ||
56 | # Initialize libtool. | |
57 | LT_INIT | |
58 | ||
59 | # Set up the libsigrok version defines. | |
60 | SR_PKG_VERSION_SET([SR_PACKAGE_VERSION], [AC_PACKAGE_VERSION]) | |
61 | ||
62 | # Library version for libsigrok (NOT the same as the package version). | |
63 | # Carefully read the libtool docs before updating these numbers! | |
64 | # The algorithm for determining which number to change (and how) is nontrivial! | |
65 | # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info | |
66 | SR_LIB_VERSION_SET([SR_LIB_VERSION], [2:0:0]) | |
67 | ||
68 | ############################# | |
69 | ## Optional dependencies ## | |
70 | ############################# | |
71 | ||
72 | # Initialize pkg-config. | |
73 | # We require at least 0.22, as "Requires.private" behaviour changed there. | |
74 | PKG_PROG_PKG_CONFIG([0.22]) | |
75 | ||
76 | # Keep track of all checked modules so we can list them at the end. | |
77 | SR_PKG_CHECK_SUMMARY([sr_pkglibs_summary]) | |
78 | ||
79 | # Collect the pkg-config module names of all dependencies in SR_PKGLIBS. | |
80 | # These are used to derive the compiler flags and for the "Requires.private" | |
81 | # field in the generated libsigrok.pc file. | |
82 | SR_VAR_OPT_PKG([SR_PKGLIBS], [sr_deps_avail]) | |
83 | SR_PKGLIBS_CHECK= | |
84 | SR_PKGLIBS_CXX= | |
85 | SR_PKGLIBS_PYTHON= | |
86 | ||
87 | SR_ARG_OPT_PKG([libserialport], [LIBSERIALPORT], [NEED_SERIAL], | |
88 | [libserialport >= 0.1.1]) | |
89 | ||
90 | SR_ARG_OPT_PKG([libftdi], [LIBFTDI],, | |
91 | [libftdi >= 0.16], [libftdi1 >= 1.0]) | |
92 | ||
93 | # FreeBSD comes with an "integrated" libusb-1.0-style USB API. | |
94 | # This means libusb-1.0 is always available; no need to check for it. | |
95 | AS_CASE([$host], [*freebsd*], [sr_have_libusb=yes]) | |
96 | ||
97 | SR_ARG_OPT_PKG([libusb], [LIBUSB_1_0], [NEED_USB], | |
98 | [libusb-1.0 >= 1.0.16]) | |
99 | ||
100 | SR_ARG_OPT_PKG([librevisa], [LIBREVISA], [NEED_VISA], | |
101 | [librevisa >= 0.0.20130412]) | |
102 | ||
103 | SR_ARG_OPT_PKG([libgpib], [LIBGPIB], [NEED_GPIB], | |
104 | [libgpib]) | |
105 | ||
106 | ###################### | |
107 | ## Feature checks ## | |
108 | ###################### | |
109 | ||
110 | # The Check unit testing framework is optional. Disable if not found. | |
111 | SR_PKG_CHECK([check], [SR_PKGLIBS_CHECK], [check >= 0.9.4]) | |
112 | AM_CONDITIONAL([HAVE_CHECK], [test "x$sr_have_check" = xyes]) | |
113 | ||
114 | AC_LANG([C]) | |
115 | SR_ARG_ENABLE_WARNINGS([SR_WFLAGS], [-Wall], [-Wall -Wextra -Wmissing-prototypes]) | |
116 | ||
117 | # Check host characteristics. | |
118 | AC_C_BIGENDIAN | |
119 | ||
120 | AC_CHECK_HEADERS([sys/mman.h], [SR_APPEND([sr_deps_avail], [sys_mman_h])]) | |
121 | AC_CHECK_HEADERS([sys/ioctl.h], [SR_APPEND([sr_deps_avail], [sys_ioctl_h])]) | |
122 | AC_CHECK_HEADERS([sys/timerfd.h], [SR_APPEND([sr_deps_avail], [sys_timerfd_h])]) | |
123 | ||
124 | # RPC is only needed for VXI support. | |
125 | AC_CACHE_CHECK([for RPC support], [sr_cv_have_rpc], | |
126 | [AC_LINK_IFELSE([AC_LANG_PROGRAM( | |
127 | [[#include <rpc/rpc.h>]m4_newline[CLIENT *rpc_test(void);]], | |
128 | [[(void) clnt_create("", 0, 0, "");]])], | |
129 | [sr_cv_have_rpc=yes], [sr_cv_have_rpc=no])]) | |
130 | AS_IF([test "x$sr_cv_have_rpc" = xyes], | |
131 | [AC_DEFINE([HAVE_RPC], [1], [Specifies whether we have RPC support.])]) | |
132 | # VXI support is only compiled if RPC support was found. | |
133 | AM_CONDITIONAL([NEED_RPC], [test "x$sr_cv_have_rpc" = xyes]) | |
134 | ||
135 | ######################## | |
136 | ## Hardware drivers ## | |
137 | ######################## | |
138 | ||
139 | # Keep track of all drivers so we can list them at the end. | |
140 | SR_VAR_SUMMARY([sr_driver_summary]) | |
141 | ||
142 | # Check whether the sr_deps_avail list contains all of the arguments. | |
143 | # Unavailable dependencies are collected in sr_deps_missing. | |
144 | sr_check_driver_deps() { | |
145 | sr_deps_missing= | |
146 | for sr_dep | |
147 | do | |
148 | AS_CASE([" $sr_deps_avail "], [*" $sr_dep "*],, | |
149 | [sr_deps_missing="$sr_deps_missing $sr_dep"]) | |
150 | done | |
151 | } | |
152 | ||
153 | AC_ARG_ENABLE([all-drivers], | |
154 | [AS_HELP_STRING([--enable-all-drivers], | |
155 | [enable all drivers by default [default=yes]])], | |
156 | [], [enable_all_drivers=yes]) | |
157 | ||
158 | ## _SR_DRIVER(Device name, driver-name, var-name, [dependencies...]) | |
159 | m4_define([_SR_DRIVER], [ | |
160 | AC_ARG_ENABLE([$2], | |
161 | [AS_HELP_STRING([--enable-$2], [enable $1 support])], | |
162 | [$3=$enableval], [$3=$enable_all_drivers]) | |
163 | ||
164 | AS_IF([test "x[$]$3" = xyes], [sr_hw_info=yes[]m4_ifval([$4], [ | |
165 | sr_check_driver_deps $4 | |
166 | AS_IF([test -n "$sr_deps_missing"], | |
167 | [$3=no sr_hw_info="no (missing:$sr_deps_missing)"]) | |
168 | ])], [sr_hw_info='no (disabled)']) | |
169 | sr_driver_summary_append "$2" "$sr_hw_info" | |
170 | ||
171 | AM_CONDITIONAL([$3], [test "x[$]$3" = xyes]) | |
172 | AM_COND_IF([$3], [AC_DEFINE([HAVE_$3], [1], [Whether to support $1 device.])]) | |
173 | ]) | |
174 | ||
175 | ## SR_DRIVER(Device name, driver-name, [dependencies...]) | |
176 | m4_define([SR_DRIVER], | |
177 | [_SR_DRIVER([$1], [$2], m4_expand([AS_TR_CPP([HW_$2])]), [$3])]) | |
178 | ||
179 | SR_DRIVER([Agilent DMM], [agilent-dmm], [libserialport]) | |
180 | SR_DRIVER([Appa 55II], [appa-55ii], [libserialport]) | |
181 | SR_DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma], [libftdi]) | |
182 | SR_DRIVER([Atten PPS3xxx], [atten-pps3xxx], [libserialport]) | |
183 | SR_DRIVER([BayLibre ACME], [baylibre-acme], [sys_timerfd_h]) | |
184 | SR_DRIVER([BeagleLogic], [beaglelogic], [sys_mman_h sys_ioctl_h]) | |
185 | SR_DRIVER([Brymen BM86x], [brymen-bm86x], [libusb]) | |
186 | SR_DRIVER([Brymen DMM], [brymen-dmm], [libserialport]) | |
187 | SR_DRIVER([CEM DT-885x], [cem-dt-885x], [libserialport]) | |
188 | SR_DRIVER([Center 3xx], [center-3xx], [libserialport]) | |
189 | SR_DRIVER([ChronoVu LA], [chronovu-la], [libftdi]) | |
190 | SR_DRIVER([Colead SLM], [colead-slm], [libserialport]) | |
191 | SR_DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu], [libserialport]) | |
192 | SR_DRIVER([DER EE DE-5000], [deree-de5000], [libserialport]) | |
193 | SR_DRIVER([demo], [demo]) | |
194 | SR_DRIVER([Fluke DMM], [fluke-dmm], [libserialport]) | |
195 | SR_DRIVER([fx2lafw], [fx2lafw], [libusb]) | |
196 | SR_DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x], [libserialport]) | |
197 | SR_DRIVER([Hameg HMO], [hameg-hmo], [libserialport]) | |
198 | SR_DRIVER([Hantek DSO], [hantek-dso], [libusb]) | |
199 | SR_DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2], [libusb]) | |
200 | SR_DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus], [libftdi]) | |
201 | SR_DRIVER([Kecheng KC-330B], [kecheng-kc-330b], [libusb]) | |
202 | SR_DRIVER([Lascar EL-USB], [lascar-el-usb], [libusb]) | |
203 | SR_DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx], [libserialport]) | |
204 | SR_DRIVER([maynuo-m97], [maynuo-m97]) | |
205 | SR_DRIVER([MIC 985xx], [mic-985xx], [libserialport]) | |
206 | SR_DRIVER([Motech LPS 30x], [motech-lps-30x], [libserialport]) | |
207 | SR_DRIVER([Norma DMM], [norma-dmm], [libserialport]) | |
208 | SR_DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer], [libserialport]) | |
209 | SR_DRIVER([Pipistrello-OLS], [pipistrello-ols], [libftdi]) | |
210 | SR_DRIVER([Rigol DS], [rigol-ds]) | |
211 | SR_DRIVER([Saleae Logic16], [saleae-logic16], [libusb]) | |
212 | SR_DRIVER([SCPI PPS], [scpi-pps]) | |
213 | SR_DRIVER([serial DMM], [serial-dmm], [libserialport]) | |
214 | SR_DRIVER([Sysclk LWLA], [sysclk-lwla], [libusb]) | |
215 | SR_DRIVER([Teleinfo], [teleinfo], [libserialport]) | |
216 | SR_DRIVER([Testo], [testo], [libusb]) | |
217 | SR_DRIVER([Tondaj SL-814], [tondaj-sl-814], [libserialport]) | |
218 | SR_DRIVER([UNI-T DMM], [uni-t-dmm], [libusb]) | |
219 | SR_DRIVER([UNI-T UT32x], [uni-t-ut32x], [libusb]) | |
220 | SR_DRIVER([Victor DMM], [victor-dmm], [libusb]) | |
221 | SR_DRIVER([Yokogawa DL/DLM], [yokogawa-dlm]) | |
222 | SR_DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube], [libusb]) | |
223 | ||
224 | ############################### | |
225 | ## Language bindings setup ## | |
226 | ############################### | |
227 | ||
228 | AC_LANG([C++]) | |
229 | SR_ARG_ENABLE_WARNINGS([SR_WXXFLAGS], [-Wall], [-Wall -Wextra]) | |
230 | ||
231 | AC_ARG_ENABLE([bindings], | |
232 | [AS_HELP_STRING([--enable-bindings], [build language bindings [default=yes]])], | |
233 | [], [enable_bindings=yes]) | |
234 | ||
235 | AC_ARG_ENABLE([cxx], | |
236 | [AS_HELP_STRING([--enable-cxx], [build C++ bindings [default=yes]])], | |
237 | [], [enable_cxx=$enable_bindings]) | |
238 | ||
239 | AC_ARG_ENABLE([python], | |
240 | [AS_HELP_STRING([--enable-python], [build Python bindings [default=yes]])], | |
241 | [], [enable_python=$enable_bindings]) | |
242 | ||
243 | AC_ARG_ENABLE([java], | |
244 | [AS_HELP_STRING([--enable-java], [build Java bindings [default=yes]])], | |
245 | [], [enable_java=$enable_bindings]) | |
246 | ||
247 | #################### | |
248 | ## C++ bindings ## | |
249 | #################### | |
250 | ||
251 | sr_cxx_missing= | |
252 | ||
253 | # Check if the C++ compiler supports the C++11 standard. | |
254 | m4_ifdef([AX_CXX_COMPILE_STDCXX_11], | |
255 | [AX_CXX_COMPILE_STDCXX_11(, [optional])], | |
256 | [m4_warn([unsupported], [Missing macro AX_CXX_COMPILE_STDCXX_11: no C++11 check possible])]) | |
257 | test "x$HAVE_CXX11" = x1 || sr_cxx_missing="$sr_cxx_missing C++11" | |
258 | ||
259 | # The C++ bindings need glibmm. | |
260 | SR_PKG_CHECK([glibmm], [SR_PKGLIBS_CXX], [glibmm-2.4 >= 2.32.0]) | |
261 | test "x$sr_have_glibmm" = xyes || sr_cxx_missing="$sr_cxx_missing glibmm" | |
262 | ||
263 | # The C++ bindings use Doxygen to parse libsigrok symbols. | |
264 | AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes], [no]) | |
265 | test "x$HAVE_DOXYGEN" = xyes || sr_cxx_missing="$sr_cxx_missing Doxygen" | |
266 | ||
267 | # Python is needed for the C++ bindings. | |
268 | AM_PATH_PYTHON([2.7], | |
269 | [HAVE_PYTHON=yes], | |
270 | [HAVE_PYTHON=no sr_cxx_missing="$sr_cxx_missing Python"]) | |
271 | ||
272 | AS_IF([test -z "$sr_cxx_missing"], | |
273 | [BINDINGS_CXX=$enable_cxx], [BINDINGS_CXX=no]) | |
274 | AM_CONDITIONAL([BINDINGS_CXX], [test "x$BINDINGS_CXX" = xyes]) | |
275 | ||
276 | # C++ bindings want stoi and stod. | |
277 | AM_COND_IF([BINDINGS_CXX], [ | |
278 | AC_CACHE_CHECK([for stoi and stod], [sr_cv_have_stoi_stod], | |
279 | [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string>]], | |
280 | [[(void) std::stoi("1"); (void) std::stod("1.0");]])], | |
281 | [sr_cv_have_stoi_stod=yes], [sr_cv_have_stoi_stod=no])]) | |
282 | AS_IF([test "x$sr_cv_have_stoi_stod" = xyes], | |
283 | [AC_DEFINE([HAVE_STOI_STOD], [1], | |
284 | [Specifies whether we have the stoi and stod functions.])]) | |
285 | ]) | |
286 | ||
287 | ####################### | |
288 | ## Python bindings ## | |
289 | ####################### | |
290 | ||
291 | sr_python_missing= | |
292 | test "x$BINDINGS_CXX" = xyes || sr_python_missing=" C++ bindings" | |
293 | ||
294 | # The Python bindings need Python development files. | |
295 | SR_PKG_CHECK([python_dev], [SR_PKGLIBS_PYTHON], | |
296 | [python >= 2.7], [python2 >= 2.7], [python27 >= 2.7]) | |
297 | test "x$sr_have_python_dev" = xyes \ | |
298 | || sr_python_missing="$sr_python_missing Headers" | |
299 | ||
300 | # PyGObject is needed for the Python bindings. | |
301 | SR_PKG_CHECK([pygobject], [SR_PKGLIBS_PYTHON], [pygobject-3.0 >= 3.0.0]) | |
302 | test "x$sr_have_python_dev" = xyes \ | |
303 | || sr_python_missing="$sr_python_missing PyGObject" | |
304 | ||
305 | PKG_CHECK_EXISTS([pygobject-3.0 < 3.7.91], | |
306 | [AC_DEFINE([PYGOBJECT_FLAGS_SIGNED], [1], | |
307 | [Whether last argument to pyg_flags_get_value() is signed.])]) | |
308 | ||
309 | # The Python bindings need the setuptools Python module. | |
310 | # We'll let it go through even if the AX macro wasn't found, | |
311 | # as the Python module may still be there. | |
312 | HAVE_PYMOD_SETUPTOOLS=yes | |
313 | m4_ifdef([AX_PYTHON_MODULE], | |
314 | [AX_PYTHON_MODULE([setuptools])], | |
315 | [m4_warn([unsupported], [Missing macro AX_PYTHON_MODULE: no setuptools check])]) | |
316 | test "x$HAVE_PYMOD_SETUPTOOLS" = xyes \ | |
317 | || sr_python_missing="$sr_python_missing Setuptools" | |
318 | ||
319 | # The Python bindings use SWIG to generate code. | |
320 | AC_CHECK_PROGS([SWIG], [swig swig2.0 swig3.0], [no]) | |
321 | test "x$SWIG" != xno || sr_python_missing="$sr_python_missing SWIG" | |
322 | ||
323 | AS_IF([test -z "$sr_python_missing"], | |
324 | [BINDINGS_PYTHON=$enable_python], [BINDINGS_PYTHON=no]) | |
325 | AM_CONDITIONAL([BINDINGS_PYTHON], [test "x$BINDINGS_PYTHON" = xyes]) | |
326 | ||
327 | #################### | |
328 | ## Java bindings ## | |
329 | #################### | |
330 | ||
331 | sr_java_missing= | |
332 | test "x$BINDINGS_CXX" = xyes || sr_java_missing=" C++ bindings" | |
333 | ||
334 | # The Java bindings use SWIG to generate code. | |
335 | test "x$SWIG" != xno || sr_java_missing="$sr_java_missing SWIG" | |
336 | ||
337 | # Find Java compiler and JNI includes for Java bindings. | |
338 | AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no]) | |
339 | test "x$HAVE_JAVAC" = xyes || sr_java_missing="$sr_java_missing JavaC" | |
340 | ||
341 | AC_ARG_WITH([jni-include-path], | |
342 | [AS_HELP_STRING([[--with-jni-include-path=DIR-LIST (space-separated)]], | |
343 | [specify JNI include directories [default=detect]])], | |
344 | [JNI_INCLUDE_DIRS=" $withval"], [JNI_INCLUDE_DIRS=]) | |
345 | ||
346 | JNI_CPPFLAGS= | |
347 | AS_IF([test "x$enable_java$HAVE_JAVAC" = xyesyes], [ | |
348 | AX_PROG_JAVAC | |
349 | AS_IF([test -z "$JNI_INCLUDE_DIRS" && test "x$cross_compiling" != xyes], [ | |
350 | ## Work around the totally broken logic in AX_JNI_INCLUDE_DIR: | |
351 | ## If we can find jni.h without any special search path, skip | |
352 | ## the execution of the broken macro to increase our chances of | |
353 | ## success. | |
354 | AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <jni.h>]], [])],, | |
355 | [AX_JNI_INCLUDE_DIR]) | |
356 | ]) | |
357 | ]) | |
358 | for sr_dir in $JNI_INCLUDE_DIRS | |
359 | do | |
360 | JNI_CPPFLAGS="$JNI_CPPFLAGS -I$sr_dir" | |
361 | done | |
362 | AC_SUBST([JNI_CPPFLAGS]) | |
363 | ||
364 | sr_save_cppflags=$CPPFLAGS | |
365 | CPPFLAGS=$CPPFLAGS$JNI_CPPFLAGS | |
366 | AC_CHECK_HEADER([jni.h],, [sr_java_missing="$sr_java_missing JNI headers"]) | |
367 | CPPFLAGS=$sr_save_cppflags | |
368 | ||
369 | AS_IF([test -z "$sr_java_missing"], | |
370 | [BINDINGS_JAVA=$enable_java], [BINDINGS_JAVA=no]) | |
371 | AM_CONDITIONAL([BINDINGS_JAVA], [test "x$BINDINGS_JAVA" = xyes]) | |
372 | ||
373 | ############################## | |
374 | ## Finalize configuration ## | |
375 | ############################## | |
376 | ||
377 | # Add mandatory dependencies to module list. | |
378 | SR_PKGLIBS="$SR_PKGLIBS${SR_PKGLIBS:+ }libzip >= 0.10" | |
379 | AC_SUBST([SR_PKGLIBS]) | |
380 | ||
381 | # Retrieve the compile and link flags for all modules combined. | |
382 | # Also, bail out at this point if any module dependency is not met. | |
383 | PKG_CHECK_MODULES([LIBSIGROK], [glib-2.0 >= 2.32.0 $SR_PKGLIBS]) | |
384 | PKG_CHECK_MODULES([CHECK], [$SR_PKGLIBS_CHECK glib-2.0 $SR_PKGLIBS]) | |
385 | ||
386 | # SR_PKGLIBS_CXX may be empty, so only invoke these checks when | |
387 | # the C++ bindings are enabled. | |
388 | AM_COND_IF([BINDINGS_CXX], [ | |
389 | PKG_CHECK_MODULES([LIBSIGROKCXX], [$SR_PKGLIBS_CXX]) | |
390 | PKG_CHECK_MODULES([PYSIGROK], [$SR_PKGLIBS_PYTHON $SR_PKGLIBS_CXX]) | |
391 | ]) | |
392 | sr_glib_version=`$PKG_CONFIG --modversion glib-2.0 2>&AS_MESSAGE_LOG_FD` | |
393 | sr_libzip_version=`$PKG_CONFIG --modversion libzip 2>&AS_MESSAGE_LOG_FD` | |
394 | ||
395 | AC_DEFINE_UNQUOTED([CONF_LIBZIP_VERSION], ["$sr_libzip_version"], | |
396 | [Build-time version of libzip.]) | |
397 | AC_DEFINE_UNQUOTED([CONF_HOST], ["$host"], | |
398 | [The canonical host libsigrok will run on.]) | |
399 | ||
400 | AC_LANG([C]) | |
401 | ||
402 | # libm (the standard math library) is always needed. | |
403 | AC_SEARCH_LIBS([pow], [m]) | |
404 | ||
405 | # We need to link against the Winsock2 library for SCPI over TCP. | |
406 | AS_CASE([$host], [*mingw*], [LIBS="$LIBS -lws2_32"]) | |
407 | ||
408 | AC_SUBST([FIRMWARE_DIR], ['$(datadir)/sigrok-firmware']) | |
409 | AC_SUBST([MAKEFLAGS], ['--no-print-directory']) | |
410 | AC_SUBST([AM_LIBTOOLFLAGS], ['--silent']) | |
411 | ||
412 | AC_CONFIG_FILES([Makefile libsigrok.pc bindings/cxx/libsigrokcxx.pc]) | |
413 | ||
414 | AC_OUTPUT | |
415 | ||
416 | # Prepare bindings report messages. | |
417 | m4_define([SR_PREPARE_BINDING_REPORT], [ | |
418 | sr_report_$1= | |
419 | test -z "$sr_$1_missing" || sr_report_$1=" (missing:$sr_$1_missing)" | |
420 | test "x$enable_$1" = xyes || sr_report_$1=' (disabled)' | |
421 | ]) | |
422 | m4_map_args([SR_PREPARE_BINDING_REPORT], [cxx], [python], [java]) | |
423 | ||
424 | cat >&AS_MESSAGE_FD <<_EOF | |
425 | ||
426 | libsigrok configuration summary: | |
427 | - Package version................. $SR_PACKAGE_VERSION | |
428 | - Library ABI version............. $SR_LIB_VERSION | |
429 | - Prefix.......................... $prefix | |
430 | - Building on..................... $build | |
431 | - Building for.................... $host | |
432 | - C compiler warnings............. $SR_WFLAGS | |
433 | - C++ compiler warnings........... $SR_WXXFLAGS | |
434 | ||
435 | Detected libraries (required): | |
436 | - glib-2.0 >= 2.32.0.............. $sr_glib_version | |
437 | - libzip >= 0.10.................. $sr_libzip_version | |
438 | ||
439 | Detected libraries (optional): | |
440 | $sr_pkglibs_summary | |
441 | Enabled hardware drivers: | |
442 | $sr_driver_summary | |
443 | Enabled SCPI backends: | |
444 | - TCP............................. yes | |
445 | - RPC............................. $sr_cv_have_rpc | |
446 | - serial.......................... $sr_have_libserialport | |
447 | - VISA............................ $sr_have_librevisa | |
448 | - GPIB............................ $sr_have_libgpib | |
449 | - USBTMC.......................... $sr_have_libusb | |
450 | ||
451 | Enabled language bindings: | |
452 | - C++............................. $BINDINGS_CXX$sr_report_cxx | |
453 | - Python.......................... $BINDINGS_PYTHON$sr_report_python | |
454 | - Java............................ $BINDINGS_JAVA$sr_report_java | |
455 | ||
456 | _EOF |