configure.ac

   1 ##
   2 ## This file is part of the sigrok-test project.
   3 ##
   4 ## Copyright (C) 2010 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2014 Uwe Hermann <uwe@hermann-uwe.de>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 3 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 AC_INIT([sigrok-test], [0.1.0], [sigrok-devel@lists.sourceforge.net],
  25         [sigrok-test], [http://www.sigrok.org])
  26 AC_CONFIG_MACRO_DIR([m4])
  27 AC_CONFIG_AUX_DIR([autostuff])
  28 AC_CONFIG_HEADERS([config.h])
  29
  30 # We require at least automake 1.11 (needed for 'silent rules').
  31 AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define subdir-objects check-news])
  32 AM_SILENT_RULES([yes])
  33
  34 AC_CANONICAL_HOST
  35
  36 # Checks for programs.
  37 AC_PROG_CC
  38
  39 # Required for per-target flags or subdir-objects with C sources.
  40 AM_PROG_CC_C_O
  41
  42 # Get compiler versions.
  43 SR_PROG_VERSION([$CC], [st_cc_version])
  44
  45 ############################
  46 ##  Package dependencies  ##
  47 ############################
  48
  49 # Initialize pkg-config.
  50 # We require at least 0.22, as "Requires.private" behaviour changed there.
  51 PKG_PROG_PKG_CONFIG([0.22])
  52
  53 # Keep track of all checked modules so we can list them at the end.
  54 ST_PKGLIBS=
  55 SR_PKG_CHECK_SUMMARY([st_pkglibs_summary])
  56
  57 # Python 3 is always needed.
  58 # Starting with Python 3.8 we need to check for "python-3.8-embed"
  59 # first, since usually only that variant will add "-lpython3.8".
  60 # https://docs.python.org/3/whatsnew/3.8.html#debug-build-uses-the-same-abi-as-release-build
  61 SR_PKG_CHECK([python3], [ST_PKGLIBS],
  62         [python-3.8-embed], [python-3.8 >= 3.8], [python-3.7 >= 3.7], [python-3.6 >= 3.6], [python-3.5 >= 3.5], [python-3.4 >= 3.4], [python-3.3 >= 3.3], [python-3.2 >= 3.2], [python3 >= 3.2])
  63 AS_IF([test "x$sr_have_python3" = xno],
  64         [AC_MSG_ERROR([Cannot find Python 3 development headers.])])
  65
  66 ######################
  67 ##  Feature checks  ##
  68 ######################
  69
  70 AC_LANG([C])
  71
  72 # Enable the C99 standard if possible.
  73 ST_EXTRA_CFLAGS=
  74 SR_CHECK_COMPILE_FLAGS([ST_EXTRA_CFLAGS], [C99],
  75         [-std=c99 -c99 -AC99 -qlanglvl=extc99])
  76
  77 SR_ARG_ENABLE_WARNINGS([ST_WFLAGS],
  78         [-Wall], [-Wall -Wextra -Wmissing-prototypes])
  79
  80 # Check host characteristics.
  81 AC_SYS_LARGEFILE
  82
  83 # Checks for header files.
  84 AC_CHECK_HEADER([sys/resource.h],,
  85         [AC_MSG_ERROR([Missing required header sys/resource.h])])
  86
  87 ##############################
  88 ##  Finalize configuration  ##
  89 ##############################
  90
  91 # Retrieve the compile and link flags for all modules combined.
  92 # Also, bail out at this point if any module dependency is not met.
  93 # Check availability of library version dependent features.
  94 PKG_CHECK_MODULES([SIGROK_TEST],
  95         [glib-2.0 >= 2.24.0 libsigrok >= 0.5.0 libsigrokdecode >= 0.5.0 $ST_PKGLIBS])
  96 AC_LANG([C])
  97 st_save_cflags=$CFLAGS
  98 st_save_libs=$LIBS
  99 CFLAGS="$SIGROK_TEST_CFLAGS $CFLAGS"
 100 LIBS="$SIGROK_TEST_LIBS $LIBS"
 101 AC_CHECK_FUNCS([srd_session_send_eof])
 102 CFLAGS=$st_save_cflags
 103 LIBS=$st_save_libs
 104
 105 # Allow the user to override the location of the protocol decoders.
 106 AC_ARG_WITH([decodersdir],
 107         [AS_HELP_STRING([--with-decodersdir=DIR],
 108                         [specify location of protcol decoders [default=auto]])],
 109         [st_decodersdir=$withval], [st_decodersdir=auto])
 110
 111 AS_IF([test "x$st_decodersdir" = xauto], [
 112         st_decodersdir=`$PKG_CONFIG --variable=decodersdir libsigrokdecode 2>&AS_MESSAGE_LOG_FD`
 113         AS_IF([test "[$]?" != 0 || test -z "$st_decodersdir"],
 114                 [st_decodersdir='$(datadir)/libsigrokdecode/decoders'])
 115 ])
 116 AC_SUBST([DECODERS_DIR], [$st_decodersdir])
 117
 118 st_glib_version=`$PKG_CONFIG --modversion glib-2.0 2>&AS_MESSAGE_LOG_FD`
 119 st_libsigrok_version=`$PKG_CONFIG --modversion libsigrok 2>&AS_MESSAGE_LOG_FD`
 120 st_libsigrokdecode_version=`$PKG_CONFIG --modversion libsigrokdecode 2>&AS_MESSAGE_LOG_FD`
 121
 122 AC_CONFIG_FILES([Makefile])
 123 AC_OUTPUT
 124
 125 cat >&AS_MESSAGE_FD <<_EOF
 126
 127 sigrok-test configuration summary:
 128  - Package version................. $PACKAGE_VERSION
 129  - Prefix.......................... $prefix
 130  - Decoders directory.............. $st_decodersdir
 131  - Building on..................... $build
 132  - Building for.................... $host
 133
 134 Compile configuration:
 135  - C compiler...................... $CC
 136  - C compiler version.............. $st_cc_version
 137  - C compiler flags................ $CFLAGS
 138  - Additional C compiler flags..... $ST_EXTRA_CFLAGS
 139  - C compiler warnings............. $ST_WFLAGS
 140  - Linker flags.................... $LDFLAGS
 141
 142 Detected libraries (required):
 143  - glib-2.0 >= 2.24.0.............. $st_glib_version
 144  - libsigrok >= 0.5.0.............. $st_libsigrok_version
 145  - libsigrokdecode >= 0.5.0........ $st_libsigrokdecode_version
 146 $st_pkglibs_summary
 147 _EOF