contrib/sigrok-cli_cross.nsi.in

   1 ##
   2 ## This file is part of the sigrok-cli project.
   3 ##
   4 ## Copyright (C) 2011-2014 Uwe Hermann <uwe@hermann-uwe.de>
   5 ##
   6 ## This program is free software; you can redistribute it and/or modify
   7 ## it under the terms of the GNU General Public License as published by
   8 ## the Free Software Foundation; either version 2 of the License, or
   9 ## (at your option) any later version.
  10 ##
  11 ## This program is distributed in the hope that it will be useful,
  12 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ## GNU General Public License for more details.
  15 ##
  16 ## You should have received a copy of the GNU General Public License
  17 ## along with this program; if not, write to the Free Software
  18 ## Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA  02110-1301 USA
  19 ##
  20
  21 #
  22 # This file is used to create the sigrok-cli Windows installer via NSIS.
  23 # It is meant for use in a cross-compile setup (not for native builds).
  24 # See the 'sigrok-cross-mingw' script in the sigrok-util repo for details.
  25 #
  26 # NSIS documentation:
  27 # http://nsis.sourceforge.net/Docs/
  28 # http://nsis.sourceforge.net/Docs/Modern%20UI%202/Readme.html
  29 #
  30
  31 # Include the "Modern UI" header, which gives us the usual Windows look-n-feel.
  32 !include "MUI2.nsh"
  33
  34
  35 # --- Global stuff ------------------------------------------------------------
  36
  37 # Installer/product name.
  38 Name "@PACKAGE_NAME@"
  39
  40 # Filename of the installer executable.
  41 OutFile "@PACKAGE_NAME@-@PACKAGE_VERSION@-installer.exe"
  42
  43 # Where to install the application.
  44 InstallDir "$PROGRAMFILES\sigrok\@PACKAGE_NAME@"
  45
  46 # Request admin privileges for Windows Vista and Windows 7.
  47 # http://nsis.sourceforge.net/Docs/Chapter4.html
  48 RequestExecutionLevel admin
  49
  50 # Local helper definitions.
  51 !define REGSTR "Software\Microsoft\Windows\CurrentVersion\Uninstall\@PACKAGE_NAME@"
  52
  53
  54 # --- MUI interface configuration ---------------------------------------------
  55
  56 # Use the following icon for the installer EXE file.
  57 !define MUI_ICON "sigrok-logo-notext.ico"
  58
  59 # Show a nice image at the top of each installer page.
  60 !define MUI_HEADERIMAGE
  61
  62 # Don't automatically go to the Finish page so the user can check the log.
  63 !define MUI_FINISHPAGE_NOAUTOCLOSE
  64
  65 # Upon "cancel", ask the user if he really wants to abort the installer.
  66 !define MUI_ABORTWARNING
  67
  68 # Don't force the user to accept the license, just show it.
  69 # Details: http://trac.videolan.org/vlc/ticket/3124
  70 !define MUI_LICENSEPAGE_BUTTON $(^NextBtn)
  71 !define MUI_LICENSEPAGE_TEXT_BOTTOM "Click Next to continue."
  72
  73 # File name of the Python installer MSI file.
  74 !define PY_INST "python-3.2.3.msi"
  75
  76 # Standard install path of the Python installer (do not change!).
  77 !define PY_BIN "c:\Python32"
  78
  79 # Path where the cross-compiled sigrok tools and libraries are located.
  80 # Change this to where-ever you installed libsigrok.a and so on.
  81 !define CROSS "$%HOME%/sr_mingw"
  82
  83 # Path where the cross-compiled MXE tools and libraries are located.
  84 # Change this to where-ever you installed MXE (and the files it built).
  85 !define MXE "$%HOME%/mxe-git/usr/i686-pc-mingw32"
  86
  87
  88 # --- MUI pages ---------------------------------------------------------------
  89
  90 # Show a nice "Welcome to the ... Setup Wizard" page.
  91 !insertmacro MUI_PAGE_WELCOME
  92
  93 # Show the license of the project.
  94 !insertmacro MUI_PAGE_LICENSE "../COPYING"
  95
  96 # Show a screen which allows the user to select which components to install.
  97 !insertmacro MUI_PAGE_COMPONENTS
  98
  99 # Allow the user to select a different install directory.
 100 !insertmacro MUI_PAGE_DIRECTORY
 101
 102 # Perform the actual installation, i.e. install the files.
 103 !insertmacro MUI_PAGE_INSTFILES
 104
 105 # Show a final "We're done, click Finish to close this wizard" message.
 106 !insertmacro MUI_PAGE_FINISH
 107
 108 # Pages used for the uninstaller.
 109 !insertmacro MUI_UNPAGE_WELCOME
 110 !insertmacro MUI_UNPAGE_CONFIRM
 111 !insertmacro MUI_UNPAGE_INSTFILES
 112 !insertmacro MUI_UNPAGE_FINISH
 113
 114
 115 # --- MUI language files ------------------------------------------------------
 116
 117 # Select an installer language (required!).
 118 !insertmacro MUI_LANGUAGE "English"
 119
 120
 121 # --- Default section ---------------------------------------------------------
 122
 123 Section "@PACKAGE_NAME@ (required)" Section1
 124
 125         # This section is gray (can't be disabled) in the component list.
 126         SectionIn RO
 127
 128         # Install the file(s) specified below into the specified directory.
 129         SetOutPath "$INSTDIR"
 130
 131         # License file.
 132         File "../COPYING"
 133
 134         # sigrok-cli.
 135         File "${CROSS}/bin/@PACKAGE_NAME@.exe"
 136
 137         # libusb0.dll (needed for libusb-0.1).
 138         File "${CROSS}/libusb0.dll"
 139
 140         # Install the file(s) specified below into the specified directory.
 141         SetOutPath "$INSTDIR\decoders"
 142
 143         # Protocol decoders.
 144         File /r /x "__pycache__" "${CROSS}/share/libsigrokdecode/decoders/*"
 145
 146         # Install the file(s) specified below into the specified directory.
 147         SetOutPath "$INSTDIR\firmware"
 148
 149         # Firmware files.
 150         File /r "${CROSS}/share/sigrok-firmware/*"
 151
 152         # Generate the uninstaller executable.
 153         WriteUninstaller "$INSTDIR\Uninstall.exe"
 154
 155         # Create a sub-directory in the start menu.
 156         CreateDirectory "$SMPROGRAMS\sigrok"
 157         CreateDirectory "$SMPROGRAMS\sigrok\@PACKAGE_NAME@"
 158
 159         # Create a shortcut for sigrok-cli (this merely opens a "DOS box").
 160         # Set the working directory (where the user will be placed into when
 161         # the DOS box starts) to the user's Desktop directory.
 162         SetOutPath "$DESKTOP"
 163         CreateShortCut "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\sigrok command-line tool.lnk" \
 164                 "$SYSDIR\cmd.exe" \
 165                 "/K echo For instructions run @PACKAGE_NAME@ --help." \
 166                 "$SYSDIR\cmd.exe" 0 \
 167                 SW_SHOWNORMAL "" "Run @PACKAGE_NAME@"
 168
 169         # Create a shortcut for the uninstaller.
 170         CreateShortCut "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\Uninstall.lnk" \
 171                 "$INSTDIR\Uninstall.exe" "" "$INSTDIR\Uninstall.exe" 0 \
 172                 SW_SHOWNORMAL "" "Uninstall @PACKAGE_NAME@"
 173
 174         # Create registry keys for "Add/remove programs" in the control panel.
 175         WriteRegStr HKLM "${REGSTR}" "DisplayName" "@PACKAGE_STRING@"
 176         WriteRegStr HKLM "${REGSTR}" "UninstallString" \
 177                 "$\"$INSTDIR\Uninstall.exe$\""
 178         WriteRegStr HKLM "${REGSTR}" "InstallLocation" "$\"$INSTDIR$\""
 179         WriteRegStr HKLM "${REGSTR}" "DisplayIcon" \
 180                 "$\"$INSTDIR\sigrok-logo-notext.ico$\""
 181         WriteRegStr HKLM "${REGSTR}" "Publisher" "sigrok"
 182         WriteRegStr HKLM "${REGSTR}" "HelpLink" \
 183                 "http://sigrok.org/wiki/Sigrok-cli"
 184         WriteRegStr HKLM "${REGSTR}" "URLUpdateInfo" \
 185                 "http://sigrok.org/wiki/Downloads"
 186         WriteRegStr HKLM "${REGSTR}" "URLInfoAbout" "http://sigrok.org"
 187         WriteRegStr HKLM "${REGSTR}" "DisplayVersion" "@PACKAGE_VERSION@"
 188         WriteRegStr HKLM "${REGSTR}" "Contact" \
 189                 "sigrok-devel@lists.sourceforge.org"
 190         WriteRegStr HKLM "${REGSTR}" "Comments" \
 191                 "This is the sigrok command-line application."
 192
 193         # Display "Remove" instead of "Modify/Remove" in the control panel.
 194         WriteRegDWORD HKLM "${REGSTR}" "NoModify" 1
 195         WriteRegDWORD HKLM "${REGSTR}" "NoRepair" 1
 196
 197         # TODO: Add sigrok-cli directory to the PATH env. variable.
 198
 199 SectionEnd
 200
 201
 202 # --- Python installer section ------------------------------------------------
 203
 204 Section "Python" Section2
 205
 206         # Copy the Python installer MSI file into the temporary directory.
 207         SetOutPath "$TEMP"
 208         File "${CROSS}/${PY_INST}"
 209
 210         # Run the Python installer MSI file from within our installer.
 211         ExecWait '"msiexec" /i "$TEMP\${PY_INST}" /QB- /passive ALLUSERS=1'
 212
 213         # Remove Python installer MSI file again.
 214         Delete "$TEMP\${PY_INST}"
 215
 216 SectionEnd
 217
 218
 219 # --- Uninstaller section -----------------------------------------------------
 220
 221 Section "Uninstall"
 222
 223         # Always delete the uninstaller first (yes, this really works).
 224         Delete "$INSTDIR\Uninstall.exe"
 225
 226         # Delete the application, the application data, and related libs.
 227         Delete "$INSTDIR\COPYING"
 228         Delete "$INSTDIR\@PACKAGE_NAME@.exe"
 229         Delete "$INSTDIR\libusb0.dll"
 230
 231         # Delete all decoders and everything else in decoders/.
 232         # There could be *.pyc files or __pycache__ subdirs and so on.
 233         RMDir /r "$INSTDIR\decoders\*"
 234
 235         # Delete the firmware files.
 236         RMDir /r "$INSTDIR\firmware\*"
 237
 238         # Delete the install directory and its sub-directories.
 239         RMDir "$INSTDIR\decoders"
 240         RMDir "$INSTDIR\firmware"
 241         RMDir "$INSTDIR"
 242
 243         # Delete the links from the start menu.
 244         Delete "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\sigrok command-line tool.lnk"
 245         Delete "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\Uninstall.lnk"
 246
 247         # Delete the sub-directory in the start menu.
 248         RMDir "$SMPROGRAMS\sigrok\@PACKAGE_NAME@"
 249         RMDir "$SMPROGRAMS\sigrok"
 250
 251         # Delete the registry key(s).
 252         DeleteRegKey HKLM "${REGSTR}"
 253
 254 SectionEnd
 255
 256
 257 # --- Component selection section descriptions --------------------------------
 258
 259 LangString DESC_Section1 ${LANG_ENGLISH} "This installs the sigrok command-line tool, some firmware files, the protocol decoders, and all required libraries."
 260 LangString DESC_Section2 ${LANG_ENGLISH} "This installs Python 3.2 in its default location of c:\Python32. If you already have Python 3.2 installed, you don't need to re-install it."
 261
 262 !insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
 263 !insertmacro MUI_DESCRIPTION_TEXT ${Section1} $(DESC_Section1)
 264 !insertmacro MUI_DESCRIPTION_TEXT ${Section2} $(DESC_Section2)
 265 !insertmacro MUI_FUNCTION_DESCRIPTION_END
 266