6e8df6c2e33cf2783b5dd1c267aaaaaadfd490b9
[sigrok-cli.git] / contrib / sigrok-cli_cross.nsi.in
1 ##
2 ## This file is part of the sigrok-cli project.
3 ##
4 ## Copyright (C) 2011-2014 Uwe Hermann <uwe@hermann-uwe.de>
5 ##
6 ## This program is free software; you can redistribute it and/or modify
7 ## it under the terms of the GNU General Public License as published by
8 ## the Free Software Foundation; either version 2 of the License, or
9 ## (at your option) any later version.
10 ##
11 ## This program is distributed in the hope that it will be useful,
12 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
13 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14 ## GNU General Public License for more details.
15 ##
16 ## You should have received a copy of the GNU General Public License
17 ## along with this program; if not, see <http://www.gnu.org/licenses/>.
18 ##
19
20 #
21 # This file is used to create the sigrok-cli Windows installer via NSIS.
22 # It is meant for use in a cross-compile setup (not for native builds).
23 # See the 'sigrok-cross-mingw' script in the sigrok-util repo for details.
24 #
25 # NSIS documentation:
26 # http://nsis.sourceforge.net/Docs/
27 # http://nsis.sourceforge.net/Docs/Modern%20UI%202/Readme.html
28 #
29
30 # Include the "Modern UI" header, which gives us the usual Windows look-n-feel.
31 !include "MUI2.nsh"
32
33
34 # --- Global stuff ------------------------------------------------------------
35
36 # Installer/product name.
37 Name "@PACKAGE_NAME@"
38
39 # Filename of the installer executable.
40 OutFile "@PACKAGE_NAME@-@SC_PACKAGE_VERSION@-installer.exe"
41
42 # Where to install the application.
43 InstallDir "$PROGRAMFILES\sigrok\@PACKAGE_NAME@"
44
45 # Request admin privileges for Windows Vista and Windows 7.
46 # http://nsis.sourceforge.net/Docs/Chapter4.html
47 RequestExecutionLevel admin
48
49 # Local helper definitions.
50 !define REGSTR "Software\Microsoft\Windows\CurrentVersion\Uninstall\@PACKAGE_NAME@"
51
52
53 # --- MUI interface configuration ---------------------------------------------
54
55 # Use the following icon for the installer EXE file.
56 !define MUI_ICON "@top_srcdir@/contrib/sigrok-logo-notext.ico"
57
58 # Show a nice image at the top of each installer page.
59 !define MUI_HEADERIMAGE
60
61 # Don't automatically go to the Finish page so the user can check the log.
62 !define MUI_FINISHPAGE_NOAUTOCLOSE
63
64 # Upon "cancel", ask the user if he really wants to abort the installer.
65 !define MUI_ABORTWARNING
66
67 # Don't force the user to accept the license, just show it.
68 # Details: http://trac.videolan.org/vlc/ticket/3124
69 !define MUI_LICENSEPAGE_BUTTON $(^NextBtn)
70 !define MUI_LICENSEPAGE_TEXT_BOTTOM "Click Next to continue."
71
72 # Path where the cross-compiled sigrok tools and libraries are located.
73 # Change this to where-ever you installed libsigrok.a and so on.
74 !define CROSS "@prefix@"
75
76
77 # --- MUI pages ---------------------------------------------------------------
78
79 # Show a nice "Welcome to the ... Setup Wizard" page.
80 !insertmacro MUI_PAGE_WELCOME
81
82 # Show the license of the project.
83 !insertmacro MUI_PAGE_LICENSE "@top_srcdir@/COPYING"
84
85 # Show a screen which allows the user to select which components to install.
86 !insertmacro MUI_PAGE_COMPONENTS
87
88 # Allow the user to select a different install directory.
89 !insertmacro MUI_PAGE_DIRECTORY
90
91 # Perform the actual installation, i.e. install the files.
92 !insertmacro MUI_PAGE_INSTFILES
93
94 # Show a final "We're done, click Finish to close this wizard" message.
95 !insertmacro MUI_PAGE_FINISH
96
97 # Pages used for the uninstaller.
98 !insertmacro MUI_UNPAGE_WELCOME
99 !insertmacro MUI_UNPAGE_CONFIRM
100 !insertmacro MUI_UNPAGE_INSTFILES
101 !insertmacro MUI_UNPAGE_FINISH
102
103
104 # --- MUI language files ------------------------------------------------------
105
106 # Select an installer language (required!).
107 !insertmacro MUI_LANGUAGE "English"
108
109
110 # --- Default section ---------------------------------------------------------
111
112 Section "@PACKAGE_NAME@ (required)" Section1
113
114         # This section is gray (can't be disabled) in the component list.
115         SectionIn RO
116
117         # Install the file(s) specified below into the specified directory.
118         SetOutPath "$INSTDIR"
119
120         # License file.
121         File "@top_srcdir@/COPYING"
122
123         # sigrok-cli.exe.
124         File "${CROSS}/bin/@PACKAGE_NAME@.exe"
125
126         # Zadig (used for installing WinUSB drivers).
127         File "${CROSS}/zadig.exe"
128         File "${CROSS}/zadig_xp.exe"
129
130         # Python
131         File "${CROSS}/python34.dll"
132         File "${CROSS}/python34.zip"
133
134         SetOutPath "$INSTDIR\share"
135
136         # Protocol decoders.
137         File /r /x "__pycache__" /x "*.pyc" "${CROSS}/share/libsigrokdecode"
138
139         # Firmware files.
140         File /r "${CROSS}/share/sigrok-firmware"
141
142         # Example *.sr files.
143         SetOutPath "$INSTDIR\examples"
144         File /r "${CROSS}/share/sigrok-dumps/*"
145
146         # Generate the uninstaller executable.
147         WriteUninstaller "$INSTDIR\Uninstall.exe"
148
149         # Create a sub-directory in the start menu.
150         CreateDirectory "$SMPROGRAMS\sigrok"
151         CreateDirectory "$SMPROGRAMS\sigrok\@PACKAGE_NAME@"
152
153         # Create a shortcut for sigrok-cli (this merely opens a "DOS box").
154         # Set the working directory (where the user will be placed into when
155         # the DOS box starts) to the installation directory.
156         SetOutPath "$INSTDIR"
157         CreateShortCut "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\sigrok command-line tool.lnk" \
158                 "$SYSDIR\cmd.exe" \
159                 "/K echo For instructions run @PACKAGE_NAME@ --help." \
160                 "$SYSDIR\cmd.exe" 0 \
161                 SW_SHOWNORMAL "" "Run @PACKAGE_NAME@"
162
163         # Create a shortcut for the uninstaller.
164         CreateShortCut "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\Uninstall.lnk" \
165                 "$INSTDIR\Uninstall.exe" "" "$INSTDIR\Uninstall.exe" 0 \
166                 SW_SHOWNORMAL "" "Uninstall @PACKAGE_NAME@"
167
168         # Create a shortcut for the Zadig executable.
169         CreateShortCut "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\Zadig.lnk" \
170                 "$INSTDIR\zadig.exe" "" "$INSTDIR\zadig.exe" 0 \
171                 SW_SHOWNORMAL "" "Zadig"
172
173         # Create a shortcut for the Zadig executable (for Win XP).
174         CreateShortCut "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\Zadig (Win XP).lnk" \
175                 "$INSTDIR\zadig_xp.exe" "" "$INSTDIR\zadig_xp.exe" 0 \
176                 SW_SHOWNORMAL "" "Zadig (Win XP)"
177
178         # Create registry keys for "Add/remove programs" in the control panel.
179         WriteRegStr HKLM "${REGSTR}" "DisplayName" "@PACKAGE_STRING@"
180         WriteRegStr HKLM "${REGSTR}" "UninstallString" \
181                 "$\"$INSTDIR\Uninstall.exe$\""
182         WriteRegStr HKLM "${REGSTR}" "InstallLocation" "$\"$INSTDIR$\""
183         WriteRegStr HKLM "${REGSTR}" "DisplayIcon" \
184                 "$\"$INSTDIR\sigrok-logo-notext.ico$\""
185         WriteRegStr HKLM "${REGSTR}" "Publisher" "sigrok"
186         WriteRegStr HKLM "${REGSTR}" "HelpLink" \
187                 "http://sigrok.org/wiki/Sigrok-cli"
188         WriteRegStr HKLM "${REGSTR}" "URLUpdateInfo" \
189                 "http://sigrok.org/wiki/Downloads"
190         WriteRegStr HKLM "${REGSTR}" "URLInfoAbout" "http://sigrok.org"
191         WriteRegStr HKLM "${REGSTR}" "DisplayVersion" "@SC_PACKAGE_VERSION@"
192         WriteRegStr HKLM "${REGSTR}" "Contact" \
193                 "sigrok-devel@lists.sourceforge.org"
194         WriteRegStr HKLM "${REGSTR}" "Comments" \
195                 "This is the sigrok command-line application."
196
197         # Display "Remove" instead of "Modify/Remove" in the control panel.
198         WriteRegDWORD HKLM "${REGSTR}" "NoModify" 1
199         WriteRegDWORD HKLM "${REGSTR}" "NoRepair" 1
200
201         # TODO: Add sigrok-cli directory to the PATH env. variable.
202
203 SectionEnd
204
205
206 # --- Uninstaller section -----------------------------------------------------
207
208 Section "Uninstall"
209
210         # Always delete the uninstaller first (yes, this really works).
211         Delete "$INSTDIR\Uninstall.exe"
212
213         # Delete the application, the application data, and related libs.
214         Delete "$INSTDIR\COPYING"
215         Delete "$INSTDIR\@PACKAGE_NAME@.exe"
216         Delete "$INSTDIR\zadig.exe"
217         Delete "$INSTDIR\zadig_xp.exe"
218         Delete "$INSTDIR\python34.dll"
219         Delete "$INSTDIR\python34.zip"
220
221         # Delete all decoders and everything else in libsigrokdecode/.
222         # There could be *.pyc files or __pycache__ subdirs and so on.
223         RMDir /r "$INSTDIR\share\libsigrokdecode"
224
225         # Delete the firmware files.
226         RMDir /r "$INSTDIR\share\sigrok-firmware"
227
228         # Delete the example *.sr files.
229         RMDir /r "$INSTDIR\examples\*"
230
231         # Delete the install directory and its sub-directories.
232         RMDir "$INSTDIR\share"
233         RMDir "$INSTDIR\examples"
234         RMDir "$INSTDIR"
235
236         # Delete the links from the start menu.
237         Delete "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\sigrok command-line tool.lnk"
238         Delete "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\Uninstall.lnk"
239         Delete "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\Zadig.lnk"
240         Delete "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\Zadig (Win XP).lnk"
241
242         # Delete the sub-directory in the start menu.
243         RMDir "$SMPROGRAMS\sigrok\@PACKAGE_NAME@"
244         RMDir "$SMPROGRAMS\sigrok"
245
246         # Delete the registry key(s).
247         DeleteRegKey HKLM "${REGSTR}"
248
249 SectionEnd
250
251
252 # --- Component selection section descriptions --------------------------------
253
254 LangString DESC_Section1 ${LANG_ENGLISH} "This installs the sigrok command-line tool, some firmware files, the protocol decoders, some example files, and all required libraries."
255
256 !insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
257 !insertmacro MUI_DESCRIPTION_TEXT ${Section1} $(DESC_Section1)
258 !insertmacro MUI_FUNCTION_DESCRIPTION_END
259