contrib/sigrok-cli_cross.nsi.in

   1 ##
   2 ## This file is part of the sigrok-cli project.
   3 ##
   4 ## Copyright (C) 2011-2014 Uwe Hermann <uwe@hermann-uwe.de>
   5 ##
   6 ## This program is free software; you can redistribute it and/or modify
   7 ## it under the terms of the GNU General Public License as published by
   8 ## the Free Software Foundation; either version 2 of the License, or
   9 ## (at your option) any later version.
  10 ##
  11 ## This program is distributed in the hope that it will be useful,
  12 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ## GNU General Public License for more details.
  15 ##
  16 ## You should have received a copy of the GNU General Public License
  17 ## along with this program; if not, see <http://www.gnu.org/licenses/>.
  18 ##
  19
  20 #
  21 # This file is used to create the sigrok-cli Windows installer via NSIS.
  22 # It is meant for use in a cross-compile setup (not for native builds).
  23 # See the 'sigrok-cross-mingw' script in the sigrok-util repo for details.
  24 #
  25 # NSIS documentation:
  26 # http://nsis.sourceforge.net/Docs/
  27 # http://nsis.sourceforge.net/Docs/Modern%20UI%202/Readme.html
  28 #
  29
  30 # Include the "Modern UI" header, which gives us the usual Windows look-n-feel.
  31 !include "MUI2.nsh"
  32
  33
  34 # --- Global stuff ------------------------------------------------------------
  35
  36 # Installer/product name.
  37 Name "@PACKAGE_NAME@"
  38
  39 # Filename of the installer executable.
  40 OutFile "@PACKAGE_NAME@-@SC_PACKAGE_VERSION@-installer.exe"
  41
  42 # Where to install the application.
  43 InstallDir "$PROGRAMFILES\sigrok\@PACKAGE_NAME@"
  44
  45 # Request admin privileges for Windows Vista and Windows 7.
  46 # http://nsis.sourceforge.net/Docs/Chapter4.html
  47 RequestExecutionLevel admin
  48
  49 # Local helper definitions.
  50 !define REGSTR "Software\Microsoft\Windows\CurrentVersion\Uninstall\@PACKAGE_NAME@"
  51
  52
  53 # --- MUI interface configuration ---------------------------------------------
  54
  55 # Use the following icon for the installer EXE file.
  56 !define MUI_ICON "@top_srcdir@/contrib/sigrok-logo-notext.ico"
  57
  58 # Show a nice image at the top of each installer page.
  59 !define MUI_HEADERIMAGE
  60
  61 # Don't automatically go to the Finish page so the user can check the log.
  62 !define MUI_FINISHPAGE_NOAUTOCLOSE
  63
  64 # Upon "cancel", ask the user if he really wants to abort the installer.
  65 !define MUI_ABORTWARNING
  66
  67 # Don't force the user to accept the license, just show it.
  68 # Details: http://trac.videolan.org/vlc/ticket/3124
  69 !define MUI_LICENSEPAGE_BUTTON $(^NextBtn)
  70 !define MUI_LICENSEPAGE_TEXT_BOTTOM "Click Next to continue."
  71
  72 # Path where the cross-compiled sigrok tools and libraries are located.
  73 # Change this to where-ever you installed libsigrok.a and so on.
  74 !define CROSS "@prefix@"
  75
  76
  77 # --- MUI pages ---------------------------------------------------------------
  78
  79 # Show a nice "Welcome to the ... Setup Wizard" page.
  80 !insertmacro MUI_PAGE_WELCOME
  81
  82 # Show the license of the project.
  83 !insertmacro MUI_PAGE_LICENSE "@top_srcdir@/COPYING"
  84
  85 # Show a screen which allows the user to select which components to install.
  86 !insertmacro MUI_PAGE_COMPONENTS
  87
  88 # Allow the user to select a different install directory.
  89 !insertmacro MUI_PAGE_DIRECTORY
  90
  91 # Perform the actual installation, i.e. install the files.
  92 !insertmacro MUI_PAGE_INSTFILES
  93
  94 # Show a final "We're done, click Finish to close this wizard" message.
  95 !insertmacro MUI_PAGE_FINISH
  96
  97 # Pages used for the uninstaller.
  98 !insertmacro MUI_UNPAGE_WELCOME
  99 !insertmacro MUI_UNPAGE_CONFIRM
 100 !insertmacro MUI_UNPAGE_INSTFILES
 101 !insertmacro MUI_UNPAGE_FINISH
 102
 103
 104 # --- MUI language files ------------------------------------------------------
 105
 106 # Select an installer language (required!).
 107 !insertmacro MUI_LANGUAGE "English"
 108
 109
 110 # --- Default section ---------------------------------------------------------
 111
 112 Section "@PACKAGE_NAME@ (required)" Section1
 113         # This section is gray (can't be disabled) in the component list.
 114         SectionIn RO
 115
 116         # Install the file(s) specified below into the specified directory.
 117         SetOutPath "$INSTDIR"
 118
 119         # License file.
 120         File "@top_srcdir@/COPYING"
 121
 122         # sigrok-cli.exe.
 123         File "${CROSS}/bin/@PACKAGE_NAME@.exe"
 124
 125         # Zadig (used for installing WinUSB drivers).
 126         File "${CROSS}/zadig.exe"
 127         File "${CROSS}/zadig_xp.exe"
 128
 129         # Python
 130         File "${CROSS}/python34.dll"
 131         File "${CROSS}/python34.zip"
 132
 133         SetOutPath "$INSTDIR\share"
 134
 135         # Protocol decoders.
 136         File /r /x "__pycache__" /x "*.pyc" "${CROSS}/share/libsigrokdecode"
 137
 138         # Firmware files.
 139         File /r "${CROSS}/share/sigrok-firmware"
 140
 141         # Generate the uninstaller executable.
 142         WriteUninstaller "$INSTDIR\Uninstall.exe"
 143
 144         # Create a sub-directory in the start menu.
 145         CreateDirectory "$SMPROGRAMS\sigrok"
 146         CreateDirectory "$SMPROGRAMS\sigrok\@PACKAGE_NAME@"
 147
 148         # Create a shortcut for sigrok-cli (this merely opens a "DOS box").
 149         # Set the working directory (where the user will be placed into when
 150         # the DOS box starts) to the installation directory.
 151         SetOutPath "$INSTDIR"
 152         CreateShortCut "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\sigrok command-line tool.lnk" \
 153                 "$SYSDIR\cmd.exe" \
 154                 "/K echo For instructions run @PACKAGE_NAME@ --help." \
 155                 "$SYSDIR\cmd.exe" 0 \
 156                 SW_SHOWNORMAL "" "Run @PACKAGE_NAME@"
 157
 158         # Create a shortcut for the uninstaller.
 159         CreateShortCut "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\Uninstall @PACKAGE_NAME@.lnk" \
 160                 "$INSTDIR\Uninstall.exe" "" "$INSTDIR\Uninstall.exe" 0 \
 161                 SW_SHOWNORMAL "" "Uninstall @PACKAGE_NAME@"
 162
 163         # Create a shortcut for the Zadig executable.
 164         CreateShortCut "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\Zadig (@PACKAGE_NAME@).lnk" \
 165                 "$INSTDIR\zadig.exe" "" "$INSTDIR\zadig.exe" 0 \
 166                 SW_SHOWNORMAL "" "Zadig"
 167
 168         # Create a shortcut for the Zadig executable (for Win XP).
 169         CreateShortCut "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\Zadig (@PACKAGE_NAME@, Win XP).lnk" \
 170                 "$INSTDIR\zadig_xp.exe" "" "$INSTDIR\zadig_xp.exe" 0 \
 171                 SW_SHOWNORMAL "" "Zadig (Win XP)"
 172
 173         # Create registry keys for "Add/remove programs" in the control panel.
 174         WriteRegStr HKLM "${REGSTR}" "DisplayName" "@PACKAGE_STRING@"
 175         WriteRegStr HKLM "${REGSTR}" "UninstallString" \
 176                 "$\"$INSTDIR\Uninstall.exe$\""
 177         WriteRegStr HKLM "${REGSTR}" "InstallLocation" "$\"$INSTDIR$\""
 178         WriteRegStr HKLM "${REGSTR}" "DisplayIcon" \
 179                 "$\"$INSTDIR\sigrok-logo-notext.ico$\""
 180         WriteRegStr HKLM "${REGSTR}" "Publisher" "sigrok"
 181         WriteRegStr HKLM "${REGSTR}" "HelpLink" \
 182                 "http://sigrok.org/wiki/Sigrok-cli"
 183         WriteRegStr HKLM "${REGSTR}" "URLUpdateInfo" \
 184                 "http://sigrok.org/wiki/Downloads"
 185         WriteRegStr HKLM "${REGSTR}" "URLInfoAbout" "http://sigrok.org"
 186         WriteRegStr HKLM "${REGSTR}" "DisplayVersion" "@SC_PACKAGE_VERSION@"
 187         WriteRegStr HKLM "${REGSTR}" "Contact" \
 188                 "sigrok-devel@lists.sourceforge.org"
 189         WriteRegStr HKLM "${REGSTR}" "Comments" \
 190                 "This is the sigrok command-line application."
 191
 192         # Display "Remove" instead of "Modify/Remove" in the control panel.
 193         WriteRegDWORD HKLM "${REGSTR}" "NoModify" 1
 194         WriteRegDWORD HKLM "${REGSTR}" "NoRepair" 1
 195
 196         # TODO: Add sigrok-cli directory to the PATH env. variable.
 197 SectionEnd
 198
 199 Section /o "Example data" Section2
 200         # Example *.sr files.
 201         SetOutPath "$INSTDIR\examples"
 202
 203         File "${CROSS}/share/sigrok-dumps/arm_trace/stm32f105/trace_example.sr"
 204         File "${CROSS}/share/sigrok-dumps/am230x/am2301/am2301_1mhz.sr"
 205         File "${CROSS}/share/sigrok-dumps/avr_isp/atmega88/isp_atmega88_erase_chip.sr"
 206         File "${CROSS}/share/sigrok-dumps/can/microchip_mcp2515dm-bm/mcp2515dm-bm-125kbits_msg_222_5bytes.sr"
 207         File "${CROSS}/share/sigrok-dumps/dcf77/pollin_dcf1_module/dcf77_120s.sr"
 208         File "${CROSS}/share/sigrok-dumps/i2c/eeprom_24xx/microchip_24lc02b/hantek_6022be_powerup.sr"
 209         File "${CROSS}/share/sigrok-dumps/i2c/eeprom_24xx/microchip_24lc64/sainsmart_dds120_powerup_scl_sda_analog.sr"
 210         File "${CROSS}/share/sigrok-dumps/i2c/potentiometer/analog_devices_ad5258/ad5258_read_once_write_continuously_triangle.sr"
 211         File "${CROSS}/share/sigrok-dumps/mdio/lan8720a/lan8720a_read_write_read.sr"
 212         File "${CROSS}/share/sigrok-dumps/onewire/owfs/ds28ea00.sr"
 213         File "${CROSS}/share/sigrok-dumps/sdcard/sd_mode/rcar-h2/cmd23_cmd18.sr"
 214         File "${CROSS}/share/sigrok-dumps/spi/mx25l1605d/mx25l1605d_read.sr"
 215         File "${CROSS}/share/sigrok-dumps/uart/gps/mtk3339/mtk3339_8n1_9600.sr"
 216         File "${CROSS}/share/sigrok-dumps/usb/hid/mouse/olimex_stm32-h103_usb_hid/olimex_stm32-h103_usb_hid.sr"
 217         File "${CROSS}/share/sigrok-dumps/z80/kc85/kc85-20mhz.sr"
 218
 219         # Create a shortcut for the example data folder.
 220         CreateShortCut "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\Examples (@PACKAGE_NAME@).lnk" \
 221                 "$INSTDIR\examples" "" "$INSTDIR\examples" 0 \
 222                 SW_SHOWNORMAL "" ""
 223 SectionEnd
 224
 225
 226 # --- Uninstaller section -----------------------------------------------------
 227
 228 Section "Uninstall"
 229         # Always delete the uninstaller first (yes, this really works).
 230         Delete "$INSTDIR\Uninstall.exe"
 231
 232         # Delete the application, the application data, and related libs.
 233         Delete "$INSTDIR\COPYING"
 234         Delete "$INSTDIR\@PACKAGE_NAME@.exe"
 235         Delete "$INSTDIR\zadig.exe"
 236         Delete "$INSTDIR\zadig_xp.exe"
 237         Delete "$INSTDIR\python34.dll"
 238         Delete "$INSTDIR\python34.zip"
 239
 240         # Delete all decoders and everything else in libsigrokdecode/.
 241         # There could be *.pyc files or __pycache__ subdirs and so on.
 242         RMDir /r "$INSTDIR\share\libsigrokdecode"
 243
 244         # Delete the firmware files.
 245         RMDir /r "$INSTDIR\share\sigrok-firmware"
 246
 247         # Delete the example *.sr files.
 248         RMDir /r "$INSTDIR\examples\*"
 249
 250         # Delete the install directory and its sub-directories.
 251         RMDir "$INSTDIR\share"
 252         RMDir "$INSTDIR\examples"
 253         RMDir "$INSTDIR"
 254
 255         # Delete the links from the start menu.
 256         Delete "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\sigrok command-line tool.lnk"
 257         Delete "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\Uninstall @PACKAGE_NAME@.lnk"
 258         Delete "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\Zadig (@PACKAGE_NAME@).lnk"
 259         Delete "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\Zadig (@PACKAGE_NAME@, Win XP).lnk"
 260         Delete "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\Examples (@PACKAGE_NAME@).lnk"
 261
 262         # Delete the sub-directory in the start menu.
 263         RMDir "$SMPROGRAMS\sigrok\@PACKAGE_NAME@"
 264         RMDir "$SMPROGRAMS\sigrok"
 265
 266         # Delete the registry key(s).
 267         DeleteRegKey HKLM "${REGSTR}"
 268 SectionEnd
 269
 270
 271 # --- Component selection section descriptions --------------------------------
 272
 273 LangString DESC_Section1 ${LANG_ENGLISH} "This installs the sigrok command-line tool, some firmware files, the protocol decoders, and all required libraries."
 274 LangString DESC_Section2 ${LANG_ENGLISH} "This installs some example files that you can use to try out the features sigrok has to offer."
 275
 276 !insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
 277         !insertmacro MUI_DESCRIPTION_TEXT ${Section1} $(DESC_Section1)
 278         !insertmacro MUI_DESCRIPTION_TEXT ${Section2} $(DESC_Section2)
 279 !insertmacro MUI_FUNCTION_DESCRIPTION_END
 280