contrib/sigrok-cli.nsi.in

   1 ##
   2 ## This file is part of the sigrok project.
   3 ##
   4 ## Copyright (C) 2011-2012 Uwe Hermann <uwe@hermann-uwe.de>
   5 ##
   6 ## This program is free software; you can redistribute it and/or modify
   7 ## it under the terms of the GNU General Public License as published by
   8 ## the Free Software Foundation; either version 2 of the License, or
   9 ## (at your option) any later version.
  10 ##
  11 ## This program is distributed in the hope that it will be useful,
  12 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ## GNU General Public License for more details.
  15 ##
  16 ## You should have received a copy of the GNU General Public License
  17 ## along with this program; if not, write to the Free Software
  18 ## Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA  02110-1301 USA
  19 ##
  20
  21 #
  22 # This file is used to create the sigrok-cli Windows installer via NSIS.
  23 #
  24 # NSIS documentation:
  25 # http://nsis.sourceforge.net/Docs/
  26 # http://nsis.sourceforge.net/Docs/Modern%20UI%202/Readme.html
  27 #
  28
  29 # Include the "Modern UI" header, which gives us the usual Windows look-n-feel.
  30 !include "MUI2.nsh"
  31
  32
  33 # --- Global stuff ------------------------------------------------------------
  34
  35 # Installer/product name.
  36 Name "@PACKAGE_NAME@"
  37
  38 # Filename of the installer executable.
  39 OutFile "@PACKAGE_NAME@-installer-@PACKAGE_VERSION@.exe"
  40
  41 # Where to install the application.
  42 InstallDir "$PROGRAMFILES\sigrok\@PACKAGE_NAME@"
  43
  44 # Request application privileges for Windows Vista.
  45 RequestExecutionLevel user
  46
  47
  48 # --- MUI interface configuration ---------------------------------------------
  49
  50 # Use the following icon for the installer EXE file.
  51 !define MUI_ICON "sigrok-logo-notext.ico"
  52
  53 # Show a nice image at the top of each installer page.
  54 !define MUI_HEADERIMAGE
  55
  56 # Don't automatically go to the Finish page so the user can check the log.
  57 !define MUI_FINISHPAGE_NOAUTOCLOSE
  58
  59 # Upon "cancel", ask the user if he really wants to abort the installer.
  60 !define MUI_ABORTWARNING
  61
  62 # Don't force the user to accept the license, just show it.
  63 # Details: http://trac.videolan.org/vlc/ticket/3124
  64 !define MUI_LICENSEPAGE_BUTTON $(^NextBtn)
  65 !define MUI_LICENSEPAGE_TEXT_BOTTOM "Click Next to continue."
  66
  67 # File name of the Python installer MSI file.
  68 !define PY_INST "python-3.2.2.msi"
  69
  70 # Standard install path of the Python installer (do not change!).
  71 !define PY_BIN "c:\Python32"
  72
  73
  74 # --- MUI pages ---------------------------------------------------------------
  75
  76 # Show a nice "Welcome to the ... Setup Wizard" page.
  77 !insertmacro MUI_PAGE_WELCOME
  78
  79 # Show the license of the project.
  80 !insertmacro MUI_PAGE_LICENSE "..\COPYING"
  81
  82 # Show a screen which allows the user to select which components to install.
  83 !insertmacro MUI_PAGE_COMPONENTS
  84
  85 # Allow the user to select a different install directory.
  86 !insertmacro MUI_PAGE_DIRECTORY
  87
  88 # Perform the actual installation, i.e. install the files.
  89 !insertmacro MUI_PAGE_INSTFILES
  90
  91 # Show a final "We're done, click Finish to close this wizard" message.
  92 !insertmacro MUI_PAGE_FINISH
  93
  94 # Pages used for the uninstaller.
  95 !insertmacro MUI_UNPAGE_WELCOME
  96 !insertmacro MUI_UNPAGE_CONFIRM
  97 !insertmacro MUI_UNPAGE_INSTFILES
  98 !insertmacro MUI_UNPAGE_FINISH
  99
 100
 101 # --- MUI language files ------------------------------------------------------
 102
 103 # Select an installer language (required!).
 104 !insertmacro MUI_LANGUAGE "English"
 105
 106
 107 # --- Default section ---------------------------------------------------------
 108
 109 Section "@PACKAGE_NAME@ (required)" Section1
 110
 111         # This section is gray (can't be disabled) in the component list.
 112         SectionIn RO
 113
 114         # Install the file(s) specified below into the specified directory.
 115         SetOutPath "$INSTDIR"
 116
 117         # License file
 118         File "..\COPYING"
 119
 120         # sigrok libs
 121         File "c:\MinGW\msys\1.0\local\lib\libsigrok.a"
 122         File "c:\MinGW\msys\1.0\local\lib\libsigrokdecode.a"
 123
 124         # sigrok-cli
 125         File "c:\MinGW\msys\1.0\local\bin\@PACKAGE_NAME@.exe"
 126
 127         # MinGW libs
 128         File "c:\MinGW\bin\mingwm10.dll"
 129         File "c:\MinGW\bin\libgcc_s_dw2-1.dll"
 130         File "c:\MinGW\bin\intl.dll"
 131         File "c:\MinGW\bin\libiconv-2.dll"
 132         File "c:\MinGW\bin\libstdc++-6.dll"
 133
 134         # External libs
 135         File "c:\MinGW\msys\1.0\local\bin\libglib-2.0-0.dll"
 136         File "c:\MinGW\msys\1.0\local\bin\libgthread-2.0-0.dll"
 137         File "c:\MinGW\msys\1.0\local\bin\libusb-1.0.dll"
 138         File "c:\MinGW\msys\1.0\local\bin\zlib1.dll"
 139         File "c:\MinGW\msys\1.0\local\bin\libzip-2.dll"
 140         File "c:\MinGW\msys\1.0\local\bin\libusb0.dll"
 141         File "c:\MinGW\msys\1.0\local\bin\libftdi.dll"
 142
 143         # Install the file(s) specified below into the specified directory.
 144         SetOutPath "$INSTDIR\decoders"
 145
 146         # Protocol decoders
 147         File /r /x "__pycache__" \
 148                 "c:\MinGW\msys\1.0\local\share\libsigrokdecode\decoders\*"
 149
 150         # Generate the uninstaller executable.
 151         WriteUninstaller "$INSTDIR\Uninstall.exe"
 152
 153         # Create a sub-directory in the start menu.
 154         CreateDirectory "$SMPROGRAMS\sigrok"
 155         CreateDirectory "$SMPROGRAMS\sigrok\@PACKAGE_NAME@"
 156
 157         # TODO: Create a shortcut for sigrok-cli (DOS box? README only?).
 158
 159         # Create a shortcut for the uninstaller.
 160         CreateShortCut "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\Uninstall.lnk" \
 161                 "$INSTDIR\Uninstall.exe" "" "$INSTDIR\Uninstall.exe" 0 \
 162                 SW_SHOWNORMAL "" "Uninstall @PACKAGE_NAME@"
 163
 164 SectionEnd
 165
 166
 167 # --- Python installer section ------------------------------------------------
 168
 169 Section "Python" Section2
 170
 171         # Copy the Python installer MSI file into the temporary directory.
 172         SetOutPath "$TEMP"
 173         File "c:\${PY_INST}"
 174
 175         # Run the Python installer MSI file from within our installer.
 176         ExecWait '"msiexec" /i "$TEMP\${PY_INST}" /QB- /passive ALLUSERS=1'
 177
 178         # Remove Python installer MSI file again.
 179         Delete "$TEMP\${PY_INST}"
 180
 181 SectionEnd
 182
 183
 184 # --- Uninstaller section -----------------------------------------------------
 185
 186 Section "Uninstall"
 187
 188         # Always delete the uninstaller first (yes, this really works).
 189         Delete "$INSTDIR\Uninstall.exe"
 190
 191         # Delete the application, the application data, and related libs.
 192         Delete "$INSTDIR\COPYING"
 193         Delete "$INSTDIR\libsigrok.a"
 194         Delete "$INSTDIR\libsigrokdecode.a"
 195         Delete "$INSTDIR\@PACKAGE_NAME@.exe"
 196         Delete "$INSTDIR\mingwm10.dll"
 197         Delete "$INSTDIR\libgcc_s_dw2-1.dll"
 198         Delete "$INSTDIR\intl.dll"
 199         Delete "$INSTDIR\libiconv-2.dll"
 200         Delete "$INSTDIR\libstdc++-6.dll"
 201         Delete "$INSTDIR\libglib-2.0-0.dll"
 202         Delete "$INSTDIR\libgthread-2.0-0.dll"
 203         Delete "$INSTDIR\libusb-1.0.dll"
 204         Delete "$INSTDIR\zlib1.dll"
 205         Delete "$INSTDIR\libzip-2.dll"
 206         Delete "$INSTDIR\libusb0.dll"
 207         Delete "$INSTDIR\libftdi.dll"
 208
 209         # Delete all decoders and everything else in decoders/.
 210         # There could be *.pyc files or __pycache__ subdirs and so on.
 211         RMDir /r "$INSTDIR\decoders\*"
 212
 213         # Delete the install directory and its sub-directories.
 214         RMDir "$INSTDIR\decoders"
 215         RMDir "$INSTDIR"
 216
 217         # Delete the links from the start menu.
 218         Delete "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\Uninstall.lnk"
 219
 220         # Delete the sub-directory in the start menu.
 221         RMDir "$SMPROGRAMS\sigrok\@PACKAGE_NAME@"
 222         RMDir "$SMPROGRAMS\sigrok"
 223
 224 SectionEnd
 225
 226
 227 # --- Component selection section descriptions --------------------------------
 228
 229 LangString DESC_Section1 ${LANG_ENGLISH} "This installs the sigrok command-line tool, the protocol decoders, and all required libraries."
 230 LangString DESC_Section2 ${LANG_ENGLISH} "This installs Python 3.2 in its default location of c:\Python32. If you already have Python 3.2 installed, you don't need to re-install it."
 231
 232 !insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
 233 !insertmacro MUI_DESCRIPTION_TEXT ${Section1} $(DESC_Section1)
 234 !insertmacro MUI_DESCRIPTION_TEXT ${Section2} $(DESC_Section2)
 235 !insertmacro MUI_FUNCTION_DESCRIPTION_END
 236