contrib/pulseview_cross.nsi

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2013 Uwe Hermann <uwe@hermann-uwe.de>
   5 ##
   6 ## This program is free software; you can redistribute it and/or modify
   7 ## it under the terms of the GNU General Public License as published by
   8 ## the Free Software Foundation; either version 2 of the License, or
   9 ## (at your option) any later version.
  10 ##
  11 ## This program is distributed in the hope that it will be useful,
  12 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ## GNU General Public License for more details.
  15 ##
  16 ## You should have received a copy of the GNU General Public License
  17 ## along with this program; if not, write to the Free Software
  18 ## Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA  02110-1301 USA
  19 ##
  20
  21 #
  22 # This file is used to create the PulseView Windows installer via NSIS.
  23 # It is meant for use in a cross-compile setup (not for native builds).
  24 # See the 'sigrok-cross-mingw' script in the sigrok-util repo for details.
  25 #
  26 # NSIS documentation:
  27 # http://nsis.sourceforge.net/Docs/
  28 # http://nsis.sourceforge.net/Docs/Modern%20UI%202/Readme.html
  29 #
  30
  31 # Include the "Modern UI" header, which gives us the usual Windows look-n-feel.
  32 !include "MUI2.nsh"
  33
  34
  35 # --- Global stuff ------------------------------------------------------------
  36
  37 # Installer/product name.
  38 Name "PulseView"
  39
  40 # Filename of the installer executable.
  41 OutFile "pulseview-0.1.0-installer.exe"
  42
  43 # Where to install the application.
  44 InstallDir "$PROGRAMFILES\sigrok\PulseView"
  45
  46 # Request admin privileges for Windows Vista and Windows 7.
  47 # http://nsis.sourceforge.net/Docs/Chapter4.html
  48 RequestExecutionLevel admin
  49
  50 # Local helper definitions.
  51 !define REGSTR "Software\Microsoft\Windows\CurrentVersion\Uninstall\PulseView"
  52
  53
  54 # --- MUI interface configuration ---------------------------------------------
  55
  56 # Use the following icon for the installer EXE file.
  57 !define MUI_ICON "../icons/sigrok-logo-notext.ico"
  58
  59 # Show a nice image at the top of each installer page.
  60 !define MUI_HEADERIMAGE
  61
  62 # Don't automatically go to the Finish page so the user can check the log.
  63 !define MUI_FINISHPAGE_NOAUTOCLOSE
  64
  65 # Upon "cancel", ask the user if he really wants to abort the installer.
  66 !define MUI_ABORTWARNING
  67
  68 # Don't force the user to accept the license, just show it.
  69 # Details: http://trac.videolan.org/vlc/ticket/3124
  70 !define MUI_LICENSEPAGE_BUTTON $(^NextBtn)
  71 !define MUI_LICENSEPAGE_TEXT_BOTTOM "Click Next to continue."
  72
  73 # # File name of the Python installer MSI file.
  74 # !define PY_INST "python-3.2.2.msi"
  75 #
  76 # # Standard install path of the Python installer (do not change!).
  77 # !define PY_BIN "c:\Python32"
  78
  79 # Path where the cross-compiled sigrok tools and libraries are located.
  80 # Change this to where-ever you installed libsigrok.a and so on.
  81 # TODO: Figure out how to use $HOME (of the host that runs "makensis").
  82 !define CROSS "/home/uwe/sr_mingw"
  83
  84 # Path where the cross-compiled MXE tools and libraries are located.
  85 # Change this to where-ever you installed MXE (and the files it built).
  86 # TODO: Figure out how to use $HOME (of the host that runs "makensis").
  87 !define MXE "/home/uwe/mxe-git/usr/i686-pc-mingw32"
  88
  89
  90 # --- MUI pages ---------------------------------------------------------------
  91
  92 # Show a nice "Welcome to the ... Setup Wizard" page.
  93 !insertmacro MUI_PAGE_WELCOME
  94
  95 # Show the license of the project.
  96 !insertmacro MUI_PAGE_LICENSE "../COPYING"
  97
  98 # Show a screen which allows the user to select which components to install.
  99 !insertmacro MUI_PAGE_COMPONENTS
 100
 101 # Allow the user to select a different install directory.
 102 !insertmacro MUI_PAGE_DIRECTORY
 103
 104 # Perform the actual installation, i.e. install the files.
 105 !insertmacro MUI_PAGE_INSTFILES
 106
 107 # Show a final "We're done, click Finish to close this wizard" message.
 108 !insertmacro MUI_PAGE_FINISH
 109
 110 # Pages used for the uninstaller.
 111 !insertmacro MUI_UNPAGE_WELCOME
 112 !insertmacro MUI_UNPAGE_CONFIRM
 113 !insertmacro MUI_UNPAGE_INSTFILES
 114 !insertmacro MUI_UNPAGE_FINISH
 115
 116
 117 # --- MUI language files ------------------------------------------------------
 118
 119 # Select an installer language (required!).
 120 !insertmacro MUI_LANGUAGE "English"
 121
 122
 123 # --- Default section ---------------------------------------------------------
 124
 125 Section "PulseView (required)" Section1
 126
 127         # This section is gray (can't be disabled) in the component list.
 128         SectionIn RO
 129
 130         # Install the file(s) specified below into the specified directory.
 131         SetOutPath "$INSTDIR"
 132
 133         # License file
 134         File "../COPYING"
 135
 136         # PulseView (statically linked, includes all libs)
 137         File "${CROSS}/bin/pulseview.exe"
 138
 139         # Install the file(s) specified below into the specified directory.
 140         # SetOutPath "$INSTDIR\decoders"
 141
 142         # Protocol decoders
 143         # File /r /x "__pycache__" "${CROSS}/share/libsigrokdecode/decoders/*"
 144
 145         # Generate the uninstaller executable.
 146         WriteUninstaller "$INSTDIR\Uninstall.exe"
 147
 148         # Create a sub-directory in the start menu.
 149         CreateDirectory "$SMPROGRAMS\sigrok"
 150         CreateDirectory "$SMPROGRAMS\sigrok\PulseView"
 151
 152         # Create a shortcut for the PulseView application.
 153         CreateShortCut "$SMPROGRAMS\sigrok\PulseView\PulseView.lnk" \
 154                 "$INSTDIR\pulseview.exe" "" "$INSTDIR\pulseview.exe" \
 155                 0 SW_SHOWNORMAL \
 156                 "" "Open-source, portable sigrok GUI"
 157
 158         # Create a shortcut for the uninstaller.
 159         CreateShortCut "$SMPROGRAMS\sigrok\PulseView\Uninstall.lnk" \
 160                 "$INSTDIR\Uninstall.exe" "" "$INSTDIR\Uninstall.exe" 0 \
 161                 SW_SHOWNORMAL "" "Uninstall PulseView"
 162
 163         # Create registry keys for "Add/remove programs" in the control panel.
 164         WriteRegStr HKLM "${REGSTR}" "DisplayName" "PulseView"
 165         WriteRegStr HKLM "${REGSTR}" "UninstallString" \
 166                 "$\"$INSTDIR\Uninstall.exe$\""
 167         WriteRegStr HKLM "${REGSTR}" "InstallLocation" "$\"$INSTDIR$\""
 168         WriteRegStr HKLM "${REGSTR}" "DisplayIcon" \
 169                 "$\"$INSTDIR\sigrok-logo-notext.ico$\""
 170         WriteRegStr HKLM "${REGSTR}" "Publisher" "sigrok"
 171         WriteRegStr HKLM "${REGSTR}" "HelpLink" \
 172                 "http://sigrok.org/wiki/PulseView"
 173         WriteRegStr HKLM "${REGSTR}" "URLUpdateInfo" \
 174                 "http://sigrok.org/wiki/Downloads"
 175         WriteRegStr HKLM "${REGSTR}" "URLInfoAbout" "http://sigrok.org"
 176         WriteRegStr HKLM "${REGSTR}" "DisplayVersion" "0.1.0"
 177         WriteRegStr HKLM "${REGSTR}" "Contact" \
 178                 "sigrok-devel@lists.sourceforge.org"
 179         WriteRegStr HKLM "${REGSTR}" "Comments" \
 180                 "This is a Qt based sigrok GUI."
 181
 182         # Display "Remove" instead of "Modify/Remove" in the control panel.
 183         WriteRegDWORD HKLM "${REGSTR}" "NoModify" 1
 184         WriteRegDWORD HKLM "${REGSTR}" "NoRepair" 1
 185
 186 SectionEnd
 187
 188
 189 # --- Python installer section ------------------------------------------------
 190
 191 # Section "Python" Section2
 192 #
 193 #       # Copy the Python installer MSI file into the temporary directory.
 194 #       SetOutPath "$TEMP"
 195 #       File "${CROSS}/${PY_INST}"
 196 #
 197 #       # Run the Python installer MSI file from within our installer.
 198 #       ExecWait '"msiexec" /i "$TEMP\${PY_INST}" /QB- /passive ALLUSERS=1'
 199 #
 200 #       # Remove Python installer MSI file again.
 201 #       Delete "$TEMP\${PY_INST}"
 202 #
 203 # SectionEnd
 204
 205
 206 # --- Uninstaller section -----------------------------------------------------
 207
 208 Section "Uninstall"
 209
 210         # Always delete the uninstaller first (yes, this really works).
 211         Delete "$INSTDIR\Uninstall.exe"
 212
 213         # Delete the application, the application data, and related libs.
 214         Delete "$INSTDIR\COPYING"
 215         Delete "$INSTDIR\pulseview.exe"
 216
 217         # Delete all decoders and everything else in decoders/.
 218         # There could be *.pyc files or __pycache__ subdirs and so on.
 219         # RMDir /r "$INSTDIR\decoders\*"
 220
 221         # Delete the install directory and its sub-directories.
 222         # RMDir "$INSTDIR\decoders"
 223         RMDir "$INSTDIR"
 224
 225         # Delete the links from the start menu.
 226         Delete "$SMPROGRAMS\sigrok\PulseView\PulseView.lnk"
 227         Delete "$SMPROGRAMS\sigrok\PulseView\Uninstall.lnk"
 228
 229         # Delete the sub-directory in the start menu.
 230         RMDir "$SMPROGRAMS\sigrok\PulseView"
 231         RMDir "$SMPROGRAMS\sigrok"
 232
 233         # Delete the registry key(s).
 234         DeleteRegKey HKLM "${REGSTR}"
 235
 236 SectionEnd
 237
 238
 239 # --- Component selection section descriptions --------------------------------
 240
 241 LangString DESC_Section1 ${LANG_ENGLISH} "This installs the PulseView sigrok GUI."
 242 # LangString DESC_Section2 ${LANG_ENGLISH} "This installs Python 3.2 in its default location of c:\Python32. If you already have Python 3.2 installed, you don't need to re-install it."
 243
 244 !insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
 245 !insertmacro MUI_DESCRIPTION_TEXT ${Section1} $(DESC_Section1)
 246 # !insertmacro MUI_DESCRIPTION_TEXT ${Section2} $(DESC_Section2)
 247 !insertmacro MUI_FUNCTION_DESCRIPTION_END
 248