contrib/pulseview_cross.nsi

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2013-2014 Uwe Hermann <uwe@hermann-uwe.de>
   5 ##
   6 ## This program is free software; you can redistribute it and/or modify
   7 ## it under the terms of the GNU General Public License as published by
   8 ## the Free Software Foundation; either version 2 of the License, or
   9 ## (at your option) any later version.
  10 ##
  11 ## This program is distributed in the hope that it will be useful,
  12 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ## GNU General Public License for more details.
  15 ##
  16 ## You should have received a copy of the GNU General Public License
  17 ## along with this program; if not, write to the Free Software
  18 ## Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA  02110-1301 USA
  19 ##
  20
  21 #
  22 # This file is used to create the PulseView Windows installer via NSIS.
  23 # It is meant for use in a cross-compile setup (not for native builds).
  24 # See the 'sigrok-cross-mingw' script in the sigrok-util repo for details.
  25 #
  26 # NSIS documentation:
  27 # http://nsis.sourceforge.net/Docs/
  28 # http://nsis.sourceforge.net/Docs/Modern%20UI%202/Readme.html
  29 #
  30
  31 # Include the "Modern UI" header, which gives us the usual Windows look-n-feel.
  32 !include "MUI2.nsh"
  33
  34
  35 # --- Global stuff ------------------------------------------------------------
  36
  37 # Installer/product name.
  38 Name "PulseView"
  39
  40 # Filename of the installer executable.
  41 OutFile "pulseview-0.1.0-installer.exe"
  42
  43 # Where to install the application.
  44 InstallDir "$PROGRAMFILES\sigrok\PulseView"
  45
  46 # Request admin privileges for Windows Vista and Windows 7.
  47 # http://nsis.sourceforge.net/Docs/Chapter4.html
  48 RequestExecutionLevel admin
  49
  50 # Local helper definitions.
  51 !define REGSTR "Software\Microsoft\Windows\CurrentVersion\Uninstall\PulseView"
  52
  53
  54 # --- MUI interface configuration ---------------------------------------------
  55
  56 # Use the following icon for the installer EXE file.
  57 !define MUI_ICON "../icons/sigrok-logo-notext.ico"
  58
  59 # Show a nice image at the top of each installer page.
  60 !define MUI_HEADERIMAGE
  61
  62 # Don't automatically go to the Finish page so the user can check the log.
  63 !define MUI_FINISHPAGE_NOAUTOCLOSE
  64
  65 # Upon "cancel", ask the user if he really wants to abort the installer.
  66 !define MUI_ABORTWARNING
  67
  68 # Don't force the user to accept the license, just show it.
  69 # Details: http://trac.videolan.org/vlc/ticket/3124
  70 !define MUI_LICENSEPAGE_BUTTON $(^NextBtn)
  71 !define MUI_LICENSEPAGE_TEXT_BOTTOM "Click Next to continue."
  72
  73 # File name of the Python installer MSI file.
  74 !define PY_INST "python-3.2.3.msi"
  75
  76 # Standard install path of the Python installer (do not change!).
  77 !define PY_BIN "c:\Python32"
  78
  79 # Path where the cross-compiled sigrok tools and libraries are located.
  80 # Change this to where-ever you installed libsigrok.a and so on.
  81 !define CROSS "$%HOME%/sr_mingw"
  82
  83 # Path where the cross-compiled MXE tools and libraries are located.
  84 # Change this to where-ever you installed MXE (and the files it built).
  85 !define MXE "$%HOME%/mxe-git/usr/i686-pc-mingw32"
  86
  87
  88 # --- MUI pages ---------------------------------------------------------------
  89
  90 # Show a nice "Welcome to the ... Setup Wizard" page.
  91 !insertmacro MUI_PAGE_WELCOME
  92
  93 # Show the license of the project.
  94 !insertmacro MUI_PAGE_LICENSE "../COPYING"
  95
  96 # Show a screen which allows the user to select which components to install.
  97 !insertmacro MUI_PAGE_COMPONENTS
  98
  99 # Allow the user to select a different install directory.
 100 !insertmacro MUI_PAGE_DIRECTORY
 101
 102 # Perform the actual installation, i.e. install the files.
 103 !insertmacro MUI_PAGE_INSTFILES
 104
 105 # Show a final "We're done, click Finish to close this wizard" message.
 106 !insertmacro MUI_PAGE_FINISH
 107
 108 # Pages used for the uninstaller.
 109 !insertmacro MUI_UNPAGE_WELCOME
 110 !insertmacro MUI_UNPAGE_CONFIRM
 111 !insertmacro MUI_UNPAGE_INSTFILES
 112 !insertmacro MUI_UNPAGE_FINISH
 113
 114
 115 # --- MUI language files ------------------------------------------------------
 116
 117 # Select an installer language (required!).
 118 !insertmacro MUI_LANGUAGE "English"
 119
 120
 121 # --- Default section ---------------------------------------------------------
 122
 123 Section "PulseView (required)" Section1
 124
 125         # This section is gray (can't be disabled) in the component list.
 126         SectionIn RO
 127
 128         # Install the file(s) specified below into the specified directory.
 129         SetOutPath "$INSTDIR"
 130
 131         # License file.
 132         File "../COPYING"
 133
 134         # PulseView (statically linked, includes all libs).
 135         File "${CROSS}/bin/pulseview.exe"
 136
 137         # libusb0.dll (needed for libusb-0.1).
 138         File "${CROSS}/libusb0.dll"
 139
 140         # Zadig (used for installing libusb-win32 and WinUSB drivers).
 141         File "${CROSS}/zadig.exe"
 142         File "${CROSS}/zadig_xp.exe"
 143
 144         # Install the file(s) specified below into the specified directory.
 145         SetOutPath "$INSTDIR\decoders"
 146
 147         # Protocol decoders.
 148         File /r /x "__pycache__" "${CROSS}/share/libsigrokdecode/decoders/*"
 149
 150         # Install the file(s) specified below into the specified directory.
 151         SetOutPath "$INSTDIR\firmware"
 152
 153         # Firmware files.
 154         File /r "${CROSS}/share/sigrok-firmware/*"
 155
 156         # Generate the uninstaller executable.
 157         WriteUninstaller "$INSTDIR\Uninstall.exe"
 158
 159         # Create a sub-directory in the start menu.
 160         CreateDirectory "$SMPROGRAMS\sigrok"
 161         CreateDirectory "$SMPROGRAMS\sigrok\PulseView"
 162
 163         # Create a shortcut for the PulseView application.
 164         SetOutPath "$INSTDIR"
 165         CreateShortCut "$SMPROGRAMS\sigrok\PulseView\PulseView.lnk" \
 166                 "$INSTDIR\pulseview.exe" "" "$INSTDIR\pulseview.exe" \
 167                 0 SW_SHOWNORMAL \
 168                 "" "Open-source, portable sigrok GUI"
 169
 170         # Create a shortcut for the uninstaller.
 171         CreateShortCut "$SMPROGRAMS\sigrok\PulseView\Uninstall.lnk" \
 172                 "$INSTDIR\Uninstall.exe" "" "$INSTDIR\Uninstall.exe" 0 \
 173                 SW_SHOWNORMAL "" "Uninstall PulseView"
 174
 175         # Create registry keys for "Add/remove programs" in the control panel.
 176         WriteRegStr HKLM "${REGSTR}" "DisplayName" "PulseView"
 177         WriteRegStr HKLM "${REGSTR}" "UninstallString" \
 178                 "$\"$INSTDIR\Uninstall.exe$\""
 179         WriteRegStr HKLM "${REGSTR}" "InstallLocation" "$\"$INSTDIR$\""
 180         WriteRegStr HKLM "${REGSTR}" "DisplayIcon" \
 181                 "$\"$INSTDIR\sigrok-logo-notext.ico$\""
 182         WriteRegStr HKLM "${REGSTR}" "Publisher" "sigrok"
 183         WriteRegStr HKLM "${REGSTR}" "HelpLink" \
 184                 "http://sigrok.org/wiki/PulseView"
 185         WriteRegStr HKLM "${REGSTR}" "URLUpdateInfo" \
 186                 "http://sigrok.org/wiki/Downloads"
 187         WriteRegStr HKLM "${REGSTR}" "URLInfoAbout" "http://sigrok.org"
 188         WriteRegStr HKLM "${REGSTR}" "DisplayVersion" "0.1.0"
 189         WriteRegStr HKLM "${REGSTR}" "Contact" \
 190                 "sigrok-devel@lists.sourceforge.org"
 191         WriteRegStr HKLM "${REGSTR}" "Comments" \
 192                 "This is a Qt based sigrok GUI."
 193
 194         # Display "Remove" instead of "Modify/Remove" in the control panel.
 195         WriteRegDWORD HKLM "${REGSTR}" "NoModify" 1
 196         WriteRegDWORD HKLM "${REGSTR}" "NoRepair" 1
 197
 198 SectionEnd
 199
 200
 201 # --- Python installer section ------------------------------------------------
 202
 203 Section "Python" Section2
 204
 205         # Copy the Python installer MSI file into the temporary directory.
 206         SetOutPath "$TEMP"
 207         File "${CROSS}/${PY_INST}"
 208
 209         # Run the Python installer MSI file from within our installer.
 210         ExecWait '"msiexec" /i "$TEMP\${PY_INST}" /QB- /passive ALLUSERS=1'
 211
 212         # Remove Python installer MSI file again.
 213         Delete "$TEMP\${PY_INST}"
 214
 215 SectionEnd
 216
 217
 218 # --- Uninstaller section -----------------------------------------------------
 219
 220 Section "Uninstall"
 221
 222         # Always delete the uninstaller first (yes, this really works).
 223         Delete "$INSTDIR\Uninstall.exe"
 224
 225         # Delete the application, the application data, and related libs.
 226         Delete "$INSTDIR\COPYING"
 227         Delete "$INSTDIR\pulseview.exe"
 228         Delete "$INSTDIR\libusb0.dll"
 229         Delete "$INSTDIR\zadig.exe"
 230         Delete "$INSTDIR\zadig_xp.exe"
 231
 232         # Delete all decoders and everything else in decoders/.
 233         # There could be *.pyc files or __pycache__ subdirs and so on.
 234         RMDir /r "$INSTDIR\decoders\*"
 235
 236         # Delete the firmware files.
 237         RMDir /r "$INSTDIR\firmware\*"
 238
 239         # Delete the install directory and its sub-directories.
 240         RMDir "$INSTDIR\decoders"
 241         RMDir "$INSTDIR\firmware"
 242         RMDir "$INSTDIR"
 243
 244         # Delete the links from the start menu.
 245         Delete "$SMPROGRAMS\sigrok\PulseView\PulseView.lnk"
 246         Delete "$SMPROGRAMS\sigrok\PulseView\Uninstall.lnk"
 247
 248         # Delete the sub-directory in the start menu.
 249         RMDir "$SMPROGRAMS\sigrok\PulseView"
 250         RMDir "$SMPROGRAMS\sigrok"
 251
 252         # Delete the registry key(s).
 253         DeleteRegKey HKLM "${REGSTR}"
 254
 255 SectionEnd
 256
 257
 258 # --- Component selection section descriptions --------------------------------
 259
 260 LangString DESC_Section1 ${LANG_ENGLISH} "This installs the PulseView sigrok GUI, some firmware files, the protocol decoders, and all required libraries."
 261 LangString DESC_Section2 ${LANG_ENGLISH} "This installs Python 3.2 in its default location of c:\Python32. If you already have Python 3.2 installed, you don't need to re-install it."
 262
 263 !insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
 264 !insertmacro MUI_DESCRIPTION_TEXT ${Section1} $(DESC_Section1)
 265 !insertmacro MUI_DESCRIPTION_TEXT ${Section2} $(DESC_Section2)
 266 !insertmacro MUI_FUNCTION_DESCRIPTION_END
 267