contrib/pulseview_cross.nsi.in

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2013-2020 Uwe Hermann <uwe@hermann-uwe.de>
   5 ##
   6 ## This program is free software; you can redistribute it and/or modify
   7 ## it under the terms of the GNU General Public License as published by
   8 ## the Free Software Foundation; either version 2 of the License, or
   9 ## (at your option) any later version.
  10 ##
  11 ## This program is distributed in the hope that it will be useful,
  12 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ## GNU General Public License for more details.
  15 ##
  16 ## You should have received a copy of the GNU General Public License
  17 ## along with this program; if not, see <http://www.gnu.org/licenses/>.
  18 ##
  19
  20 #
  21 # This file is used to create the PulseView Windows installer via NSIS.
  22 # It is meant for use in a cross-compile setup (not for native builds).
  23 # See the 'sigrok-cross-mingw' script in the sigrok-util repo for details.
  24 #
  25 # NSIS documentation:
  26 # http://nsis.sourceforge.net/Docs/
  27 # http://nsis.sourceforge.net/Docs/Modern%20UI%202/Readme.html
  28 #
  29
  30 # Include the "Modern UI" header, which gives us the usual Windows look-n-feel.
  31 !include "MUI2.nsh"
  32
  33 # Include the file association header so that we can register file extensions.
  34 !include "FileAssociation.nsh"
  35
  36
  37 # --- Global stuff ------------------------------------------------------------
  38
  39 # Installer/product name.
  40 Name "PulseView"
  41
  42 # Filename of the installer executable.
  43 OutFile "pulseview-@PV_VERSION_STRING@-installer.exe"
  44
  45 # Where to install the application.
  46 !ifdef PE64
  47         InstallDir "$PROGRAMFILES64\sigrok\PulseView"
  48 !else
  49         InstallDir "$PROGRAMFILES\sigrok\PulseView"
  50 !endif
  51
  52 # Request admin privileges for Windows Vista and Windows 7.
  53 # http://nsis.sourceforge.net/Docs/Chapter4.html
  54 RequestExecutionLevel admin
  55
  56 # Local helper definitions.
  57 !define REGSTR "Software\Microsoft\Windows\CurrentVersion\Uninstall\PulseView"
  58
  59
  60 # --- MUI interface configuration ---------------------------------------------
  61
  62 # Use the following icon for the installer EXE file.
  63 !define MUI_ICON "@PROJECT_SOURCE_DIR@/icons/pulseview.ico"
  64
  65 # Show a nice image at the top of each installer page.
  66 !define MUI_HEADERIMAGE
  67
  68 # Don't automatically go to the Finish page so the user can check the log.
  69 !define MUI_FINISHPAGE_NOAUTOCLOSE
  70
  71 # Upon "cancel", ask the user if he really wants to abort the installer.
  72 !define MUI_ABORTWARNING
  73
  74 # Don't force the user to accept the license, just show it.
  75 # Details: http://trac.videolan.org/vlc/ticket/3124
  76 !define MUI_LICENSEPAGE_BUTTON $(^NextBtn)
  77 !define MUI_LICENSEPAGE_TEXT_BOTTOM "Click Next to continue."
  78
  79 # Path where the cross-compiled sigrok tools and libraries are located.
  80 # Change this to where-ever you installed libsigrok.a and so on.
  81 !define CROSS "@CMAKE_INSTALL_PREFIX@"
  82
  83 # Defines for WinAPI SHChangeNotify call.
  84 !define SHCNE_ASSOCCHANGED 0x8000000
  85 !define SHCNF_IDLIST 0
  86
  87
  88 # --- Functions/Macros --------------------------------------------------------
  89
  90 Function register_sr_files
  91         ${registerExtension} "$INSTDIR\pulseview.exe" ".sr" "sigrok session file"
  92
  93         # Force Windows to update the icon cache so that the icon for .sr files shows up.
  94         System::Call 'Shell32::SHChangeNotify(i ${SHCNE_ASSOCCHANGED}, i ${SHCNF_IDLIST}, i 0, i 0)'
  95 FunctionEnd
  96
  97 # Inspired by http://nsis.sourceforge.net/Create_Internet_Shorcuts_during_installation
  98 !Macro "CreateURL" "URLFile" "URLSite" "URLDesc"
  99         WriteINIStr "$INSTDIR\${URLFile}.URL" "InternetShortcut" "URL" "${URLSite}"
 100         CreateShortCut "$SMPROGRAMS\sigrok\PulseView\${URLFile}.lnk" "$INSTDIR\${URLFile}.url" "" \
 101                 "$INSTDIR\pulseview.exe" 0 "SW_SHOWNORMAL" "" "${URLDesc}"
 102 !MacroEnd
 103
 104 # --- MUI pages ---------------------------------------------------------------
 105
 106 # Show a nice "Welcome to the ... Setup Wizard" page.
 107 !insertmacro MUI_PAGE_WELCOME
 108
 109 # Show the license of the project.
 110 !insertmacro MUI_PAGE_LICENSE "@PROJECT_SOURCE_DIR@/COPYING"
 111
 112 # Show a screen which allows the user to select which components to install.
 113 !insertmacro MUI_PAGE_COMPONENTS
 114
 115 # Allow the user to select a different install directory.
 116 !insertmacro MUI_PAGE_DIRECTORY
 117
 118 # Perform the actual installation, i.e. install the files.
 119 !insertmacro MUI_PAGE_INSTFILES
 120
 121 # Insert the "Show Readme" button in the finish dialog. We repurpose it for
 122 # registering the .sr file extension. This way, we don't need to add in-depth
 123 # modifications to the finish page.
 124 !define MUI_FINISHPAGE_SHOWREADME ""
 125 !define MUI_FINISHPAGE_SHOWREADME_CHECKED
 126 !define MUI_FINISHPAGE_SHOWREADME_TEXT "Register .sr files with PulseView"
 127 !define MUI_FINISHPAGE_SHOWREADME_FUNCTION register_sr_files
 128
 129 # Show a final "We're done, click Finish to close this wizard" message.
 130 !insertmacro MUI_PAGE_FINISH
 131
 132 # Pages used for the uninstaller.
 133 !insertmacro MUI_UNPAGE_WELCOME
 134 !insertmacro MUI_UNPAGE_CONFIRM
 135 !insertmacro MUI_UNPAGE_INSTFILES
 136 !insertmacro MUI_UNPAGE_FINISH
 137
 138
 139 # --- MUI language files ------------------------------------------------------
 140
 141 # Select an installer language (required!).
 142 !insertmacro MUI_LANGUAGE "English"
 143
 144
 145 # --- Default section ---------------------------------------------------------
 146
 147 Section "PulseView (required)" Section1
 148         # This section is gray (can't be disabled) in the component list.
 149         SectionIn RO
 150
 151         # Install the file(s) specified below into the specified directory.
 152         SetOutPath "$INSTDIR"
 153
 154         # License file.
 155         File "@PROJECT_SOURCE_DIR@/COPYING"
 156
 157         # PulseView (statically linked, includes all libs).
 158         File "${CROSS}/bin/pulseview.exe"
 159
 160         # Zadig (used for installing WinUSB drivers).
 161         File "${CROSS}/zadig.exe"
 162         File "${CROSS}/zadig_xp.exe"
 163
 164         # Python
 165         File "${CROSS}/python34.dll"
 166         File "${CROSS}/python34.zip"
 167         File "${CROSS}/*.pyd"
 168
 169         SetOutPath "$INSTDIR\share"
 170
 171         # Protocol decoders.
 172         File /r /x "__pycache__" /x "*.pyc" "${CROSS}/share/libsigrokdecode"
 173
 174         # Firmware files.
 175         File /r "${CROSS}/share/sigrok-firmware"
 176
 177         # Generate the uninstaller executable.
 178         WriteUninstaller "$INSTDIR\Uninstall.exe"
 179
 180         # Create a sub-directory in the start menu.
 181         CreateDirectory "$SMPROGRAMS\sigrok"
 182         CreateDirectory "$SMPROGRAMS\sigrok\PulseView"
 183
 184         # Create a shortcut for the PulseView application.
 185         SetOutPath "$INSTDIR"
 186         CreateShortCut "$SMPROGRAMS\sigrok\PulseView\PulseView.lnk" \
 187                 "$INSTDIR\pulseview.exe" "" "$INSTDIR\pulseview.exe" \
 188                 0 SW_SHOWNORMAL \
 189                 "" "Open-source, portable sigrok GUI"
 190
 191         # Create a shortcut for the PulseView application in "safe mode".
 192         CreateShortCut "$SMPROGRAMS\sigrok\PulseView\PulseView (Safe Mode).lnk" \
 193                 "$INSTDIR\pulseview.exe" "-c -D" "$INSTDIR\pulseview.exe" \
 194                 0 SW_SHOWNORMAL \
 195                 "" "Open-source, portable sigrok GUI (Safe Mode)"
 196
 197         # Create a shortcut for the PulseView application running in debug mode.
 198         CreateShortCut "$SMPROGRAMS\sigrok\PulseView\PulseView (Debug).lnk" \
 199                 "$INSTDIR\pulseview.exe" "-l 5" "$INSTDIR\pulseview.exe" \
 200                 0 SW_SHOWNORMAL \
 201                 "" "Open-source, portable sigrok GUI (debug log level)"
 202
 203         # Create a shortcut for the uninstaller.
 204         CreateShortCut "$SMPROGRAMS\sigrok\PulseView\Uninstall PulseView.lnk" \
 205                 "$INSTDIR\Uninstall.exe" "" "$INSTDIR\Uninstall.exe" 0 \
 206                 SW_SHOWNORMAL "" "Uninstall PulseView"
 207
 208         # Create a shortcut for the Zadig executable.
 209         CreateShortCut "$SMPROGRAMS\sigrok\PulseView\Zadig (PulseView).lnk" \
 210                 "$INSTDIR\zadig.exe" "" "$INSTDIR\zadig.exe" 0 \
 211                 SW_SHOWNORMAL "" "Zadig (PulseView)"
 212
 213         # Create a shortcut for the Zadig executable (for Win XP).
 214         CreateShortCut "$SMPROGRAMS\sigrok\PulseView\Zadig (PulseView, Win XP).lnk" \
 215                 "$INSTDIR\zadig_xp.exe" "" "$INSTDIR\zadig_xp.exe" 0 \
 216                 SW_SHOWNORMAL "" "Zadig (PulseView, Win XP)"
 217
 218         # Create shortcuts to the HTML and PDF manuals, respectively.
 219         !InsertMacro "CreateURL" "PulseView HTML manual" "https://sigrok.org/doc/pulseview/@PV_MANUAL_VERSION@/manual.html" "PulseView HTML manual"
 220         !InsertMacro "CreateURL" "PulseView PDF manual" "https://sigrok.org/doc/pulseview/@PV_MANUAL_VERSION@/manual.pdf" "PulseView PDF manual"
 221
 222         # Create registry keys for "Add/remove programs" in the control panel.
 223         WriteRegStr HKLM "${REGSTR}" "DisplayName" "PulseView"
 224         WriteRegStr HKLM "${REGSTR}" "UninstallString" \
 225                 "$\"$INSTDIR\Uninstall.exe$\""
 226         WriteRegStr HKLM "${REGSTR}" "InstallLocation" "$\"$INSTDIR$\""
 227         WriteRegStr HKLM "${REGSTR}" "DisplayIcon" \
 228                 "$\"$INSTDIR\pulseview.ico$\""
 229         WriteRegStr HKLM "${REGSTR}" "Publisher" "sigrok"
 230         WriteRegStr HKLM "${REGSTR}" "HelpLink" \
 231                 "http://sigrok.org/wiki/PulseView"
 232         WriteRegStr HKLM "${REGSTR}" "URLUpdateInfo" \
 233                 "http://sigrok.org/wiki/Downloads"
 234         WriteRegStr HKLM "${REGSTR}" "URLInfoAbout" "http://sigrok.org"
 235         WriteRegStr HKLM "${REGSTR}" "DisplayVersion" "@PV_VERSION_STRING@"
 236         WriteRegStr HKLM "${REGSTR}" "Contact" \
 237                 "sigrok-devel@lists.sourceforge.org"
 238         WriteRegStr HKLM "${REGSTR}" "Comments" \
 239                 "This is a Qt based sigrok GUI."
 240
 241         # Display "Remove" instead of "Modify/Remove" in the control panel.
 242         WriteRegDWORD HKLM "${REGSTR}" "NoModify" 1
 243         WriteRegDWORD HKLM "${REGSTR}" "NoRepair" 1
 244 SectionEnd
 245
 246 Section /o "Example data" Section2
 247         # Example *.sr files.
 248         SetOutPath "$INSTDIR\examples"
 249
 250         File "${CROSS}/share/sigrok-dumps/arm_trace/stm32f105/trace_example.sr"
 251         File "${CROSS}/share/sigrok-dumps/am230x/am2301/am2301_1mhz.sr"
 252         File "${CROSS}/share/sigrok-dumps/avr_isp/atmega88/isp_atmega88_erase_chip.sr"
 253         File "${CROSS}/share/sigrok-dumps/can/microchip_mcp2515dm-bm/mcp2515dm-bm-125kbits_msg_222_5bytes.sr"
 254         File "${CROSS}/share/sigrok-dumps/dcf77/pollin_dcf1_module/dcf77_120s.sr"
 255         File "${CROSS}/share/sigrok-dumps/i2c/eeprom_24xx/microchip_24lc02b/hantek_6022be_powerup.sr"
 256         File "${CROSS}/share/sigrok-dumps/i2c/eeprom_24xx/microchip_24lc64/sainsmart_dds120_powerup_scl_sda_analog.sr"
 257         File "${CROSS}/share/sigrok-dumps/i2c/potentiometer/analog_devices_ad5258/ad5258_read_once_write_continuously_triangle.sr"
 258         File "${CROSS}/share/sigrok-dumps/mdio/lan8720a/lan8720a_read_write_read.sr"
 259         File "${CROSS}/share/sigrok-dumps/onewire/owfs/ds28ea00.sr"
 260         File "${CROSS}/share/sigrok-dumps/sdcard/sd_mode/rcar-h2/cmd23_cmd18.sr"
 261         File "${CROSS}/share/sigrok-dumps/spi/mx25l1605d/mx25l1605d_read.sr"
 262         File "${CROSS}/share/sigrok-dumps/uart/gps/mtk3339/mtk3339_8n1_9600.sr"
 263         File "${CROSS}/share/sigrok-dumps/usb/hid/mouse/olimex_stm32-h103_usb_hid/olimex_stm32-h103_usb_hid.sr"
 264         File "${CROSS}/share/sigrok-dumps/z80/kc85/kc85-20mhz.sr"
 265
 266         # Create a shortcut for the example data folder.
 267         CreateShortCut "$SMPROGRAMS\sigrok\PulseView\Examples (PulseView).lnk" \
 268                 "$INSTDIR\examples" "" "$INSTDIR\examples" 0 \
 269                 SW_SHOWNORMAL "" ""
 270 SectionEnd
 271
 272
 273 # --- Uninstaller section -----------------------------------------------------
 274
 275 Section "Uninstall"
 276         # Always delete the uninstaller first (yes, this really works).
 277         Delete "$INSTDIR\Uninstall.exe"
 278
 279         # Delete the application, the application data, and related libs.
 280         Delete "$INSTDIR\COPYING"
 281         Delete "$INSTDIR\pulseview.exe"
 282         Delete "$INSTDIR\zadig.exe"
 283         Delete "$INSTDIR\zadig_xp.exe"
 284         Delete "$INSTDIR\python34.dll"
 285         Delete "$INSTDIR\python34.zip"
 286         Delete "$INSTDIR\*.pyd"
 287
 288         # Delete all decoders and everything else in libsigrokdecode/.
 289         # There could be *.pyc files or __pycache__ subdirs and so on.
 290         RMDir /r "$INSTDIR\share\libsigrokdecode"
 291
 292         # Delete the firmware files.
 293         RMDir /r "$INSTDIR\share\sigrok-firmware"
 294
 295         # Delete the example *.sr files.
 296         RMDir /r "$INSTDIR\examples\*"
 297
 298         # Delete the URL files for the manual.
 299         Delete "$INSTDIR\PulseView HTML manual.url"
 300         Delete "$INSTDIR\PulseView PDF manual.url"
 301
 302         # Delete the install directory and its sub-directories.
 303         RMDir "$INSTDIR\share"
 304         RMDir "$INSTDIR\examples"
 305         RMDir "$INSTDIR"
 306
 307         # Delete the links from the start menu.
 308         Delete "$SMPROGRAMS\sigrok\PulseView\PulseView.lnk"
 309         Delete "$SMPROGRAMS\sigrok\PulseView\PulseView (Safe Mode).lnk"
 310         Delete "$SMPROGRAMS\sigrok\PulseView\PulseView (Debug).lnk"
 311         Delete "$SMPROGRAMS\sigrok\PulseView\Uninstall PulseView.lnk"
 312         Delete "$SMPROGRAMS\sigrok\PulseView\Zadig (PulseView).lnk"
 313         Delete "$SMPROGRAMS\sigrok\PulseView\Zadig (PulseView, Win XP).lnk"
 314         Delete "$SMPROGRAMS\sigrok\PulseView\Examples (PulseView).lnk"
 315
 316         # Delete the links to the manual.
 317         Delete "$SMPROGRAMS\sigrok\PulseView\PulseView HTML manual.lnk"
 318         Delete "$SMPROGRAMS\sigrok\PulseView\PulseView PDF manual.lnk"
 319
 320         # Delete the sub-directory in the start menu.
 321         RMDir "$SMPROGRAMS\sigrok\PulseView"
 322         RMDir "$SMPROGRAMS\sigrok"
 323
 324         # Delete the registry key(s).
 325         DeleteRegKey HKLM "${REGSTR}"
 326
 327         # Unregister any previously registered file extension(s).
 328         ${unregisterExtension} ".sr" "sigrok session file"
 329
 330         # Force Windows to update the icon cache so that the icon for .sr files is reset.
 331         System::Call 'Shell32::SHChangeNotify(i ${SHCNE_ASSOCCHANGED}, i ${SHCNF_IDLIST}, i 0, i 0)'
 332 SectionEnd
 333
 334
 335 # --- Component selection section descriptions --------------------------------
 336
 337 LangString DESC_Section1 ${LANG_ENGLISH} "This installs the PulseView sigrok GUI, some firmware files, the protocol decoders, and all required libraries."
 338 LangString DESC_Section2 ${LANG_ENGLISH} "This installs some example files that you can use to try out the features sigrok has to offer."
 339
 340 !insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
 341         !insertmacro MUI_DESCRIPTION_TEXT ${Section1} $(DESC_Section1)
 342         !insertmacro MUI_DESCRIPTION_TEXT ${Section2} $(DESC_Section2)
 343 !insertmacro MUI_FUNCTION_DESCRIPTION_END
 344