contrib/pulseview_cross.nsi.in

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2013-2020 Uwe Hermann <uwe@hermann-uwe.de>
   5 ##
   6 ## This program is free software; you can redistribute it and/or modify
   7 ## it under the terms of the GNU General Public License as published by
   8 ## the Free Software Foundation; either version 2 of the License, or
   9 ## (at your option) any later version.
  10 ##
  11 ## This program is distributed in the hope that it will be useful,
  12 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ## GNU General Public License for more details.
  15 ##
  16 ## You should have received a copy of the GNU General Public License
  17 ## along with this program; if not, see <http://www.gnu.org/licenses/>.
  18 ##
  19
  20 #
  21 # This file is used to create the PulseView Windows installer via NSIS.
  22 # It is meant for use in a cross-compile setup (not for native builds).
  23 # See the 'sigrok-cross-mingw' script in the sigrok-util repo for details.
  24 #
  25 # NSIS documentation:
  26 # http://nsis.sourceforge.net/Docs/
  27 # http://nsis.sourceforge.net/Docs/Modern%20UI%202/Readme.html
  28 #
  29
  30 # Fix warning 7998: ANSI targets are deprecated
  31 Unicode True
  32
  33 # Include the "Modern UI" header, which gives us the usual Windows look-n-feel.
  34 !include "MUI2.nsh"
  35
  36 # Include the file association header so that we can register file extensions.
  37 !include "FileAssociation.nsh"
  38
  39
  40 # --- Global stuff ------------------------------------------------------------
  41
  42 # Installer/product name.
  43 Name "PulseView"
  44
  45 # Filename of the installer executable.
  46 OutFile "pulseview-@PV_VERSION_STRING@-installer.exe"
  47
  48 # Where to install the application.
  49 !ifdef PE64
  50         InstallDir "$PROGRAMFILES64\sigrok\PulseView"
  51 !else
  52         InstallDir "$PROGRAMFILES\sigrok\PulseView"
  53 !endif
  54
  55 # Request admin privileges for Windows Vista and Windows 7.
  56 # http://nsis.sourceforge.net/Docs/Chapter4.html
  57 RequestExecutionLevel admin
  58
  59 # Local helper definitions.
  60 !define REGSTR "Software\Microsoft\Windows\CurrentVersion\Uninstall\PulseView"
  61
  62
  63 # --- MUI interface configuration ---------------------------------------------
  64
  65 # Use the following icon for the installer EXE file.
  66 !define MUI_ICON "@PROJECT_SOURCE_DIR@/icons/pulseview.ico"
  67
  68 # Show a nice image at the top of each installer page.
  69 !define MUI_HEADERIMAGE
  70
  71 # Don't automatically go to the Finish page so the user can check the log.
  72 !define MUI_FINISHPAGE_NOAUTOCLOSE
  73
  74 # Upon "cancel", ask the user if he really wants to abort the installer.
  75 !define MUI_ABORTWARNING
  76
  77 # Don't force the user to accept the license, just show it.
  78 # Details: http://trac.videolan.org/vlc/ticket/3124
  79 !define MUI_LICENSEPAGE_BUTTON $(^NextBtn)
  80 !define MUI_LICENSEPAGE_TEXT_BOTTOM "Click Next to continue."
  81
  82 # Path where the cross-compiled sigrok tools and libraries are located.
  83 # Change this to where-ever you installed libsigrok.a and so on.
  84 !define CROSS "@CMAKE_INSTALL_PREFIX@"
  85
  86 # Defines for WinAPI SHChangeNotify call.
  87 !define SHCNE_ASSOCCHANGED 0x8000000
  88 !define SHCNF_IDLIST 0
  89
  90
  91 # --- Functions/Macros --------------------------------------------------------
  92
  93 Function register_sr_files
  94         ${registerExtension} "$INSTDIR\pulseview.exe" ".sr" "sigrok session file"
  95
  96         # Force Windows to update the icon cache so that the icon for .sr files shows up.
  97         System::Call 'Shell32::SHChangeNotify(i ${SHCNE_ASSOCCHANGED}, i ${SHCNF_IDLIST}, i 0, i 0)'
  98 FunctionEnd
  99
 100 # Inspired by http://nsis.sourceforge.net/Create_Internet_Shorcuts_during_installation
 101 !Macro "CreateURL" "URLFile" "URLSite" "URLDesc"
 102         WriteINIStr "$INSTDIR\${URLFile}.URL" "InternetShortcut" "URL" "${URLSite}"
 103         CreateShortCut "$SMPROGRAMS\sigrok\PulseView\${URLFile}.lnk" "$INSTDIR\${URLFile}.url" "" \
 104                 "$INSTDIR\pulseview.exe" 0 "SW_SHOWNORMAL" "" "${URLDesc}"
 105 !MacroEnd
 106
 107 # --- MUI pages ---------------------------------------------------------------
 108
 109 # Show a nice "Welcome to the ... Setup Wizard" page.
 110 !insertmacro MUI_PAGE_WELCOME
 111
 112 # Show the license of the project.
 113 !insertmacro MUI_PAGE_LICENSE "@PROJECT_SOURCE_DIR@/COPYING"
 114
 115 # Show a screen which allows the user to select which components to install.
 116 !insertmacro MUI_PAGE_COMPONENTS
 117
 118 # Allow the user to select a different install directory.
 119 !insertmacro MUI_PAGE_DIRECTORY
 120
 121 # Perform the actual installation, i.e. install the files.
 122 !insertmacro MUI_PAGE_INSTFILES
 123
 124 # Insert the "Show Readme" button in the finish dialog. We repurpose it for
 125 # registering the .sr file extension. This way, we don't need to add in-depth
 126 # modifications to the finish page.
 127 !define MUI_FINISHPAGE_SHOWREADME ""
 128 !define MUI_FINISHPAGE_SHOWREADME_CHECKED
 129 !define MUI_FINISHPAGE_SHOWREADME_TEXT "Register .sr files with PulseView"
 130 !define MUI_FINISHPAGE_SHOWREADME_FUNCTION register_sr_files
 131
 132 # Show a final "We're done, click Finish to close this wizard" message.
 133 !insertmacro MUI_PAGE_FINISH
 134
 135 # Pages used for the uninstaller.
 136 !insertmacro MUI_UNPAGE_WELCOME
 137 !insertmacro MUI_UNPAGE_CONFIRM
 138 !insertmacro MUI_UNPAGE_INSTFILES
 139 !insertmacro MUI_UNPAGE_FINISH
 140
 141
 142 # --- MUI language files ------------------------------------------------------
 143
 144 # Select an installer language (required!).
 145 !insertmacro MUI_LANGUAGE "English"
 146
 147
 148 # --- Default section ---------------------------------------------------------
 149
 150 Section "PulseView (required)" Section1
 151         # This section is gray (can't be disabled) in the component list.
 152         SectionIn RO
 153
 154         # Install the file(s) specified below into the specified directory.
 155         SetOutPath "$INSTDIR"
 156
 157         # License file.
 158         File "@PROJECT_SOURCE_DIR@/COPYING"
 159
 160         # PulseView (statically linked, includes all libs).
 161         File "${CROSS}/bin/pulseview.exe"
 162
 163         # Zadig (used for installing WinUSB drivers).
 164         File "${CROSS}/zadig.exe"
 165         File "${CROSS}/zadig_xp.exe"
 166
 167         # Python
 168         File "${CROSS}/python34.dll"
 169         File "${CROSS}/python34.zip"
 170         File "${CROSS}/*.pyd"
 171
 172         SetOutPath "$INSTDIR\share"
 173
 174         # Protocol decoders.
 175         File /r /x "__pycache__" /x "*.pyc" "${CROSS}/share/libsigrokdecode"
 176
 177         # Firmware files.
 178         File /r "${CROSS}/share/sigrok-firmware"
 179
 180         # Generate the uninstaller executable.
 181         WriteUninstaller "$INSTDIR\Uninstall.exe"
 182
 183         # Create a sub-directory in the start menu.
 184         CreateDirectory "$SMPROGRAMS\sigrok"
 185         CreateDirectory "$SMPROGRAMS\sigrok\PulseView"
 186
 187         # Create a shortcut for the PulseView application.
 188         SetOutPath "$INSTDIR"
 189         CreateShortCut "$SMPROGRAMS\sigrok\PulseView\PulseView.lnk" \
 190                 "$INSTDIR\pulseview.exe" "" "$INSTDIR\pulseview.exe" \
 191                 0 SW_SHOWNORMAL \
 192                 "" "Open-source, portable sigrok GUI"
 193
 194         # Create a shortcut for the PulseView application in "safe mode".
 195         CreateShortCut "$SMPROGRAMS\sigrok\PulseView\PulseView (Safe Mode).lnk" \
 196                 "$INSTDIR\pulseview.exe" "-c -D" "$INSTDIR\pulseview.exe" \
 197                 0 SW_SHOWNORMAL \
 198                 "" "Open-source, portable sigrok GUI (Safe Mode)"
 199
 200         # Create a shortcut for the PulseView application running in debug mode.
 201         CreateShortCut "$SMPROGRAMS\sigrok\PulseView\PulseView (Debug).lnk" \
 202                 "$INSTDIR\pulseview.exe" "-l 5" "$INSTDIR\pulseview.exe" \
 203                 0 SW_SHOWNORMAL \
 204                 "" "Open-source, portable sigrok GUI (debug log level)"
 205
 206         # Create a shortcut for the uninstaller.
 207         CreateShortCut "$SMPROGRAMS\sigrok\PulseView\Uninstall PulseView.lnk" \
 208                 "$INSTDIR\Uninstall.exe" "" "$INSTDIR\Uninstall.exe" 0 \
 209                 SW_SHOWNORMAL "" "Uninstall PulseView"
 210
 211         # Create a shortcut for the Zadig executable.
 212         CreateShortCut "$SMPROGRAMS\sigrok\PulseView\Zadig (PulseView).lnk" \
 213                 "$INSTDIR\zadig.exe" "" "$INSTDIR\zadig.exe" 0 \
 214                 SW_SHOWNORMAL "" "Zadig (PulseView)"
 215
 216         # Create a shortcut for the Zadig executable (for Win XP).
 217         CreateShortCut "$SMPROGRAMS\sigrok\PulseView\Zadig (PulseView, Win XP).lnk" \
 218                 "$INSTDIR\zadig_xp.exe" "" "$INSTDIR\zadig_xp.exe" 0 \
 219                 SW_SHOWNORMAL "" "Zadig (PulseView, Win XP)"
 220
 221         # Create shortcuts to the HTML and PDF manuals, respectively.
 222         !InsertMacro "CreateURL" "PulseView HTML manual" "https://sigrok.org/doc/pulseview/@PV_MANUAL_VERSION@/manual.html" "PulseView HTML manual"
 223         !InsertMacro "CreateURL" "PulseView PDF manual" "https://sigrok.org/doc/pulseview/@PV_MANUAL_VERSION@/manual.pdf" "PulseView PDF manual"
 224
 225         # Create registry keys for "Add/remove programs" in the control panel.
 226         WriteRegStr HKLM "${REGSTR}" "DisplayName" "PulseView"
 227         WriteRegStr HKLM "${REGSTR}" "UninstallString" \
 228                 "$\"$INSTDIR\Uninstall.exe$\""
 229         WriteRegStr HKLM "${REGSTR}" "InstallLocation" "$\"$INSTDIR$\""
 230         WriteRegStr HKLM "${REGSTR}" "DisplayIcon" \
 231                 "$\"$INSTDIR\pulseview.ico$\""
 232         WriteRegStr HKLM "${REGSTR}" "Publisher" "sigrok"
 233         WriteRegStr HKLM "${REGSTR}" "HelpLink" \
 234                 "http://sigrok.org/wiki/PulseView"
 235         WriteRegStr HKLM "${REGSTR}" "URLUpdateInfo" \
 236                 "http://sigrok.org/wiki/Downloads"
 237         WriteRegStr HKLM "${REGSTR}" "URLInfoAbout" "http://sigrok.org"
 238         WriteRegStr HKLM "${REGSTR}" "DisplayVersion" "@PV_VERSION_STRING@"
 239         WriteRegStr HKLM "${REGSTR}" "Contact" \
 240                 "sigrok-devel@lists.sourceforge.org"
 241         WriteRegStr HKLM "${REGSTR}" "Comments" \
 242                 "This is a Qt based sigrok GUI."
 243
 244         # Display "Remove" instead of "Modify/Remove" in the control panel.
 245         WriteRegDWORD HKLM "${REGSTR}" "NoModify" 1
 246         WriteRegDWORD HKLM "${REGSTR}" "NoRepair" 1
 247 SectionEnd
 248
 249 Section /o "Example data" Section2
 250         # Example *.sr files.
 251         SetOutPath "$INSTDIR\examples"
 252
 253         File "${CROSS}/share/sigrok-dumps/arm_trace/stm32f105/trace_example.sr"
 254         File "${CROSS}/share/sigrok-dumps/am230x/am2301/am2301_1mhz.sr"
 255         File "${CROSS}/share/sigrok-dumps/avr_isp/atmega88/isp_atmega88_erase_chip.sr"
 256         File "${CROSS}/share/sigrok-dumps/can/microchip_mcp2515dm-bm/mcp2515dm-bm-125kbits_msg_222_5bytes.sr"
 257         File "${CROSS}/share/sigrok-dumps/dcf77/pollin_dcf1_module/dcf77_120s.sr"
 258         File "${CROSS}/share/sigrok-dumps/i2c/eeprom_24xx/microchip_24lc02b/hantek_6022be_powerup.sr"
 259         File "${CROSS}/share/sigrok-dumps/i2c/eeprom_24xx/microchip_24lc64/sainsmart_dds120_powerup_scl_sda_analog.sr"
 260         File "${CROSS}/share/sigrok-dumps/i2c/potentiometer/analog_devices_ad5258/ad5258_read_once_write_continuously_triangle.sr"
 261         File "${CROSS}/share/sigrok-dumps/mdio/lan8720a/lan8720a_read_write_read.sr"
 262         File "${CROSS}/share/sigrok-dumps/onewire/owfs/ds28ea00.sr"
 263         File "${CROSS}/share/sigrok-dumps/sdcard/sd_mode/rcar-h2/cmd23_cmd18.sr"
 264         File "${CROSS}/share/sigrok-dumps/spi/mx25l1605d/mx25l1605d_read.sr"
 265         File "${CROSS}/share/sigrok-dumps/uart/gps/mtk3339/mtk3339_8n1_9600.sr"
 266         File "${CROSS}/share/sigrok-dumps/usb/hid/mouse/olimex_stm32-h103_usb_hid/olimex_stm32-h103_usb_hid.sr"
 267         File "${CROSS}/share/sigrok-dumps/z80/kc85/kc85-20mhz.sr"
 268
 269         # Create a shortcut for the example data folder.
 270         CreateShortCut "$SMPROGRAMS\sigrok\PulseView\Examples (PulseView).lnk" \
 271                 "$INSTDIR\examples" "" "$INSTDIR\examples" 0 \
 272                 SW_SHOWNORMAL "" ""
 273 SectionEnd
 274
 275
 276 # --- Uninstaller section -----------------------------------------------------
 277
 278 Section "Uninstall"
 279         # Always delete the uninstaller first (yes, this really works).
 280         Delete "$INSTDIR\Uninstall.exe"
 281
 282         # Delete the application, the application data, and related libs.
 283         Delete "$INSTDIR\COPYING"
 284         Delete "$INSTDIR\pulseview.exe"
 285         Delete "$INSTDIR\zadig.exe"
 286         Delete "$INSTDIR\zadig_xp.exe"
 287         Delete "$INSTDIR\python34.dll"
 288         Delete "$INSTDIR\python34.zip"
 289         Delete "$INSTDIR\*.pyd"
 290
 291         # Delete all decoders and everything else in libsigrokdecode/.
 292         # There could be *.pyc files or __pycache__ subdirs and so on.
 293         RMDir /r "$INSTDIR\share\libsigrokdecode"
 294
 295         # Delete the firmware files.
 296         RMDir /r "$INSTDIR\share\sigrok-firmware"
 297
 298         # Delete the example *.sr files.
 299         RMDir /r "$INSTDIR\examples\*"
 300
 301         # Delete the URL files for the manual.
 302         Delete "$INSTDIR\PulseView HTML manual.url"
 303         Delete "$INSTDIR\PulseView PDF manual.url"
 304
 305         # Delete the install directory and its sub-directories.
 306         RMDir "$INSTDIR\share"
 307         RMDir "$INSTDIR\examples"
 308         RMDir "$INSTDIR"
 309
 310         # Delete the links from the start menu.
 311         Delete "$SMPROGRAMS\sigrok\PulseView\PulseView.lnk"
 312         Delete "$SMPROGRAMS\sigrok\PulseView\PulseView (Safe Mode).lnk"
 313         Delete "$SMPROGRAMS\sigrok\PulseView\PulseView (Debug).lnk"
 314         Delete "$SMPROGRAMS\sigrok\PulseView\Uninstall PulseView.lnk"
 315         Delete "$SMPROGRAMS\sigrok\PulseView\Zadig (PulseView).lnk"
 316         Delete "$SMPROGRAMS\sigrok\PulseView\Zadig (PulseView, Win XP).lnk"
 317         Delete "$SMPROGRAMS\sigrok\PulseView\Examples (PulseView).lnk"
 318
 319         # Delete the links to the manual.
 320         Delete "$SMPROGRAMS\sigrok\PulseView\PulseView HTML manual.lnk"
 321         Delete "$SMPROGRAMS\sigrok\PulseView\PulseView PDF manual.lnk"
 322
 323         # Delete the sub-directory in the start menu.
 324         RMDir "$SMPROGRAMS\sigrok\PulseView"
 325         RMDir "$SMPROGRAMS\sigrok"
 326
 327         # Delete the registry key(s).
 328         DeleteRegKey HKLM "${REGSTR}"
 329
 330         # Unregister any previously registered file extension(s).
 331         ${unregisterExtension} ".sr" "sigrok session file"
 332
 333         # Force Windows to update the icon cache so that the icon for .sr files is reset.
 334         System::Call 'Shell32::SHChangeNotify(i ${SHCNE_ASSOCCHANGED}, i ${SHCNF_IDLIST}, i 0, i 0)'
 335 SectionEnd
 336
 337
 338 # --- Component selection section descriptions --------------------------------
 339
 340 LangString DESC_Section1 ${LANG_ENGLISH} "This installs the PulseView sigrok GUI, some firmware files, the protocol decoders, and all required libraries."
 341 LangString DESC_Section2 ${LANG_ENGLISH} "This installs some example files that you can use to try out the features sigrok has to offer."
 342
 343 !insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
 344         !insertmacro MUI_DESCRIPTION_TEXT ${Section1} $(DESC_Section1)
 345         !insertmacro MUI_DESCRIPTION_TEXT ${Section2} $(DESC_Section2)
 346 !insertmacro MUI_FUNCTION_DESCRIPTION_END
 347