contrib/pulseview_cross.nsi.in

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2013-2020 Uwe Hermann <uwe@hermann-uwe.de>
   5 ##
   6 ## This program is free software; you can redistribute it and/or modify
   7 ## it under the terms of the GNU General Public License as published by
   8 ## the Free Software Foundation; either version 2 of the License, or
   9 ## (at your option) any later version.
  10 ##
  11 ## This program is distributed in the hope that it will be useful,
  12 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ## GNU General Public License for more details.
  15 ##
  16 ## You should have received a copy of the GNU General Public License
  17 ## along with this program; if not, see <http://www.gnu.org/licenses/>.
  18 ##
  19
  20 #
  21 # This file is used to create the PulseView Windows installer via NSIS.
  22 # It is meant for use in a cross-compile setup (not for native builds).
  23 # See the 'sigrok-cross-mingw' script in the sigrok-util repo for details.
  24 #
  25 # NSIS documentation:
  26 # http://nsis.sourceforge.net/Docs/
  27 # http://nsis.sourceforge.net/Docs/Modern%20UI%202/Readme.html
  28 #
  29
  30 # Include the "Modern UI" header, which gives us the usual Windows look-n-feel.
  31 !include "MUI2.nsh"
  32
  33 # Include the file association header so that we can register file extensions.
  34 !include "FileAssociation.nsh"
  35
  36
  37 # --- Global stuff ------------------------------------------------------------
  38
  39 # Installer/product name.
  40 Name "PulseView"
  41
  42 # Filename of the installer executable.
  43 OutFile "pulseview-@PV_VERSION_STRING@-installer.exe"
  44
  45 # Where to install the application.
  46 InstallDir "$PROGRAMFILES\sigrok\PulseView"
  47
  48 # Request admin privileges for Windows Vista and Windows 7.
  49 # http://nsis.sourceforge.net/Docs/Chapter4.html
  50 RequestExecutionLevel admin
  51
  52 # Local helper definitions.
  53 !define REGSTR "Software\Microsoft\Windows\CurrentVersion\Uninstall\PulseView"
  54
  55
  56 # --- MUI interface configuration ---------------------------------------------
  57
  58 # Use the following icon for the installer EXE file.
  59 !define MUI_ICON "@PROJECT_SOURCE_DIR@/icons/pulseview.ico"
  60
  61 # Show a nice image at the top of each installer page.
  62 !define MUI_HEADERIMAGE
  63
  64 # Don't automatically go to the Finish page so the user can check the log.
  65 !define MUI_FINISHPAGE_NOAUTOCLOSE
  66
  67 # Upon "cancel", ask the user if he really wants to abort the installer.
  68 !define MUI_ABORTWARNING
  69
  70 # Don't force the user to accept the license, just show it.
  71 # Details: http://trac.videolan.org/vlc/ticket/3124
  72 !define MUI_LICENSEPAGE_BUTTON $(^NextBtn)
  73 !define MUI_LICENSEPAGE_TEXT_BOTTOM "Click Next to continue."
  74
  75 # Path where the cross-compiled sigrok tools and libraries are located.
  76 # Change this to where-ever you installed libsigrok.a and so on.
  77 !define CROSS "@CMAKE_INSTALL_PREFIX@"
  78
  79 # Defines for WinAPI SHChangeNotify call.
  80 !define SHCNE_ASSOCCHANGED 0x8000000
  81 !define SHCNF_IDLIST 0
  82
  83
  84 # --- Functions/Macros --------------------------------------------------------
  85
  86 Function register_sr_files
  87         ${registerExtension} "$INSTDIR\pulseview.exe" ".sr" "sigrok session file"
  88
  89         # Force Windows to update the icon cache so that the icon for .sr files shows up.
  90         System::Call 'Shell32::SHChangeNotify(i ${SHCNE_ASSOCCHANGED}, i ${SHCNF_IDLIST}, i 0, i 0)'
  91 FunctionEnd
  92
  93 # Inspired by http://nsis.sourceforge.net/Create_Internet_Shorcuts_during_installation
  94 !Macro "CreateURL" "URLFile" "URLSite" "URLDesc"
  95         WriteINIStr "$INSTDIR\${URLFile}.URL" "InternetShortcut" "URL" "${URLSite}"
  96         CreateShortCut "$SMPROGRAMS\sigrok\PulseView\${URLFile}.lnk" "$INSTDIR\${URLFile}.url" "" \
  97                 "$INSTDIR\pulseview.exe" 0 "SW_SHOWNORMAL" "" "${URLDesc}"
  98 !MacroEnd
  99
 100 # --- MUI pages ---------------------------------------------------------------
 101
 102 # Show a nice "Welcome to the ... Setup Wizard" page.
 103 !insertmacro MUI_PAGE_WELCOME
 104
 105 # Show the license of the project.
 106 !insertmacro MUI_PAGE_LICENSE "@PROJECT_SOURCE_DIR@/COPYING"
 107
 108 # Show a screen which allows the user to select which components to install.
 109 !insertmacro MUI_PAGE_COMPONENTS
 110
 111 # Allow the user to select a different install directory.
 112 !insertmacro MUI_PAGE_DIRECTORY
 113
 114 # Perform the actual installation, i.e. install the files.
 115 !insertmacro MUI_PAGE_INSTFILES
 116
 117 # Insert the "Show Readme" button in the finish dialog. We repurpose it for
 118 # registering the .sr file extension. This way, we don't need to add in-depth
 119 # modifications to the finish page.
 120 !define MUI_FINISHPAGE_SHOWREADME ""
 121 !define MUI_FINISHPAGE_SHOWREADME_CHECKED
 122 !define MUI_FINISHPAGE_SHOWREADME_TEXT "Register .sr files with PulseView"
 123 !define MUI_FINISHPAGE_SHOWREADME_FUNCTION register_sr_files
 124
 125 # Show a final "We're done, click Finish to close this wizard" message.
 126 !insertmacro MUI_PAGE_FINISH
 127
 128 # Pages used for the uninstaller.
 129 !insertmacro MUI_UNPAGE_WELCOME
 130 !insertmacro MUI_UNPAGE_CONFIRM
 131 !insertmacro MUI_UNPAGE_INSTFILES
 132 !insertmacro MUI_UNPAGE_FINISH
 133
 134
 135 # --- MUI language files ------------------------------------------------------
 136
 137 # Select an installer language (required!).
 138 !insertmacro MUI_LANGUAGE "English"
 139
 140
 141 # --- Default section ---------------------------------------------------------
 142
 143 Section "PulseView (required)" Section1
 144         # This section is gray (can't be disabled) in the component list.
 145         SectionIn RO
 146
 147         # Install the file(s) specified below into the specified directory.
 148         SetOutPath "$INSTDIR"
 149
 150         # License file.
 151         File "@PROJECT_SOURCE_DIR@/COPYING"
 152
 153         # PulseView (statically linked, includes all libs).
 154         File "${CROSS}/bin/pulseview.exe"
 155
 156         # Zadig (used for installing WinUSB drivers).
 157         File "${CROSS}/zadig.exe"
 158         File "${CROSS}/zadig_xp.exe"
 159
 160         # Python
 161         File "${CROSS}/python34.dll"
 162         File "${CROSS}/python34.zip"
 163         File "${CROSS}/*.pyd"
 164
 165         SetOutPath "$INSTDIR\share"
 166
 167         # Protocol decoders.
 168         File /r /x "__pycache__" /x "*.pyc" "${CROSS}/share/libsigrokdecode"
 169
 170         # Firmware files.
 171         File /r "${CROSS}/share/sigrok-firmware"
 172
 173         # Generate the uninstaller executable.
 174         WriteUninstaller "$INSTDIR\Uninstall.exe"
 175
 176         # Create a sub-directory in the start menu.
 177         CreateDirectory "$SMPROGRAMS\sigrok"
 178         CreateDirectory "$SMPROGRAMS\sigrok\PulseView"
 179
 180         # Create a shortcut for the PulseView application.
 181         SetOutPath "$INSTDIR"
 182         CreateShortCut "$SMPROGRAMS\sigrok\PulseView\PulseView.lnk" \
 183                 "$INSTDIR\pulseview.exe" "" "$INSTDIR\pulseview.exe" \
 184                 0 SW_SHOWNORMAL \
 185                 "" "Open-source, portable sigrok GUI"
 186
 187         # Create a shortcut for the PulseView application running in debug mode.
 188         CreateShortCut "$SMPROGRAMS\sigrok\PulseView\PulseView (Debug).lnk" \
 189                 "$INSTDIR\pulseview.exe" "-l 5" "$INSTDIR\pulseview.exe" \
 190                 0 SW_SHOWNORMAL \
 191                 "" "Open-source, portable sigrok GUI (debug log level)"
 192
 193         # Create a shortcut for the uninstaller.
 194         CreateShortCut "$SMPROGRAMS\sigrok\PulseView\Uninstall PulseView.lnk" \
 195                 "$INSTDIR\Uninstall.exe" "" "$INSTDIR\Uninstall.exe" 0 \
 196                 SW_SHOWNORMAL "" "Uninstall PulseView"
 197
 198         # Create a shortcut for the Zadig executable.
 199         CreateShortCut "$SMPROGRAMS\sigrok\PulseView\Zadig (PulseView).lnk" \
 200                 "$INSTDIR\zadig.exe" "" "$INSTDIR\zadig.exe" 0 \
 201                 SW_SHOWNORMAL "" "Zadig (PulseView)"
 202
 203         # Create a shortcut for the Zadig executable (for Win XP).
 204         CreateShortCut "$SMPROGRAMS\sigrok\PulseView\Zadig (PulseView, Win XP).lnk" \
 205                 "$INSTDIR\zadig_xp.exe" "" "$INSTDIR\zadig_xp.exe" 0 \
 206                 SW_SHOWNORMAL "" "Zadig (PulseView, Win XP)"
 207
 208         # Create shortcuts to the HTML and PDF manuals, respectively.
 209         !InsertMacro "CreateURL" "PulseView HTML manual" "https://sigrok.org/doc/pulseview/@PV_MANUAL_VERSION@/manual.html" "PulseView HTML manual"
 210         !InsertMacro "CreateURL" "PulseView PDF manual" "https://sigrok.org/doc/pulseview/@PV_MANUAL_VERSION@/manual.pdf" "PulseView PDF manual"
 211
 212         # Create registry keys for "Add/remove programs" in the control panel.
 213         WriteRegStr HKLM "${REGSTR}" "DisplayName" "PulseView"
 214         WriteRegStr HKLM "${REGSTR}" "UninstallString" \
 215                 "$\"$INSTDIR\Uninstall.exe$\""
 216         WriteRegStr HKLM "${REGSTR}" "InstallLocation" "$\"$INSTDIR$\""
 217         WriteRegStr HKLM "${REGSTR}" "DisplayIcon" \
 218                 "$\"$INSTDIR\pulseview.ico$\""
 219         WriteRegStr HKLM "${REGSTR}" "Publisher" "sigrok"
 220         WriteRegStr HKLM "${REGSTR}" "HelpLink" \
 221                 "http://sigrok.org/wiki/PulseView"
 222         WriteRegStr HKLM "${REGSTR}" "URLUpdateInfo" \
 223                 "http://sigrok.org/wiki/Downloads"
 224         WriteRegStr HKLM "${REGSTR}" "URLInfoAbout" "http://sigrok.org"
 225         WriteRegStr HKLM "${REGSTR}" "DisplayVersion" "@PV_VERSION_STRING@"
 226         WriteRegStr HKLM "${REGSTR}" "Contact" \
 227                 "sigrok-devel@lists.sourceforge.org"
 228         WriteRegStr HKLM "${REGSTR}" "Comments" \
 229                 "This is a Qt based sigrok GUI."
 230
 231         # Display "Remove" instead of "Modify/Remove" in the control panel.
 232         WriteRegDWORD HKLM "${REGSTR}" "NoModify" 1
 233         WriteRegDWORD HKLM "${REGSTR}" "NoRepair" 1
 234 SectionEnd
 235
 236 Section /o "Example data" Section2
 237         # Example *.sr files.
 238         SetOutPath "$INSTDIR\examples"
 239
 240         File "${CROSS}/share/sigrok-dumps/arm_trace/stm32f105/trace_example.sr"
 241         File "${CROSS}/share/sigrok-dumps/am230x/am2301/am2301_1mhz.sr"
 242         File "${CROSS}/share/sigrok-dumps/avr_isp/atmega88/isp_atmega88_erase_chip.sr"
 243         File "${CROSS}/share/sigrok-dumps/can/microchip_mcp2515dm-bm/mcp2515dm-bm-125kbits_msg_222_5bytes.sr"
 244         File "${CROSS}/share/sigrok-dumps/dcf77/pollin_dcf1_module/dcf77_120s.sr"
 245         File "${CROSS}/share/sigrok-dumps/i2c/eeprom_24xx/microchip_24lc02b/hantek_6022be_powerup.sr"
 246         File "${CROSS}/share/sigrok-dumps/i2c/eeprom_24xx/microchip_24lc64/sainsmart_dds120_powerup_scl_sda_analog.sr"
 247         File "${CROSS}/share/sigrok-dumps/i2c/potentiometer/analog_devices_ad5258/ad5258_read_once_write_continuously_triangle.sr"
 248         File "${CROSS}/share/sigrok-dumps/mdio/lan8720a/lan8720a_read_write_read.sr"
 249         File "${CROSS}/share/sigrok-dumps/onewire/owfs/ds28ea00.sr"
 250         File "${CROSS}/share/sigrok-dumps/sdcard/sd_mode/rcar-h2/cmd23_cmd18.sr"
 251         File "${CROSS}/share/sigrok-dumps/spi/mx25l1605d/mx25l1605d_read.sr"
 252         File "${CROSS}/share/sigrok-dumps/uart/gps/mtk3339/mtk3339_8n1_9600.sr"
 253         File "${CROSS}/share/sigrok-dumps/usb/hid/mouse/olimex_stm32-h103_usb_hid/olimex_stm32-h103_usb_hid.sr"
 254         File "${CROSS}/share/sigrok-dumps/z80/kc85/kc85-20mhz.sr"
 255
 256         # Create a shortcut for the example data folder.
 257         CreateShortCut "$SMPROGRAMS\sigrok\PulseView\Examples (PulseView).lnk" \
 258                 "$INSTDIR\examples" "" "$INSTDIR\examples" 0 \
 259                 SW_SHOWNORMAL "" ""
 260 SectionEnd
 261
 262
 263 # --- Uninstaller section -----------------------------------------------------
 264
 265 Section "Uninstall"
 266         # Always delete the uninstaller first (yes, this really works).
 267         Delete "$INSTDIR\Uninstall.exe"
 268
 269         # Delete the application, the application data, and related libs.
 270         Delete "$INSTDIR\COPYING"
 271         Delete "$INSTDIR\pulseview.exe"
 272         Delete "$INSTDIR\zadig.exe"
 273         Delete "$INSTDIR\zadig_xp.exe"
 274         Delete "$INSTDIR\python34.dll"
 275         Delete "$INSTDIR\python34.zip"
 276         Delete "$INSTDIR\*.pyd"
 277
 278         # Delete all decoders and everything else in libsigrokdecode/.
 279         # There could be *.pyc files or __pycache__ subdirs and so on.
 280         RMDir /r "$INSTDIR\share\libsigrokdecode"
 281
 282         # Delete the firmware files.
 283         RMDir /r "$INSTDIR\share\sigrok-firmware"
 284
 285         # Delete the example *.sr files.
 286         RMDir /r "$INSTDIR\examples\*"
 287
 288         # Delete the URL files for the manual.
 289         Delete "$INSTDIR\PulseView HTML manual.url"
 290         Delete "$INSTDIR\PulseView PDF manual.url"
 291
 292         # Delete the install directory and its sub-directories.
 293         RMDir "$INSTDIR\share"
 294         RMDir "$INSTDIR\examples"
 295         RMDir "$INSTDIR"
 296
 297         # Delete the links from the start menu.
 298         Delete "$SMPROGRAMS\sigrok\PulseView\PulseView.lnk"
 299         Delete "$SMPROGRAMS\sigrok\PulseView\PulseView (Debug).lnk"
 300         Delete "$SMPROGRAMS\sigrok\PulseView\Uninstall PulseView.lnk"
 301         Delete "$SMPROGRAMS\sigrok\PulseView\Zadig (PulseView).lnk"
 302         Delete "$SMPROGRAMS\sigrok\PulseView\Zadig (PulseView, Win XP).lnk"
 303         Delete "$SMPROGRAMS\sigrok\PulseView\Examples (PulseView).lnk"
 304
 305         # Delete the links to the manual.
 306         Delete "$SMPROGRAMS\sigrok\PulseView\PulseView HTML manual.lnk"
 307         Delete "$SMPROGRAMS\sigrok\PulseView\PulseView PDF manual.lnk"
 308
 309         # Delete the sub-directory in the start menu.
 310         RMDir "$SMPROGRAMS\sigrok\PulseView"
 311         RMDir "$SMPROGRAMS\sigrok"
 312
 313         # Delete the registry key(s).
 314         DeleteRegKey HKLM "${REGSTR}"
 315
 316         # Unregister any previously registered file extension(s).
 317         ${unregisterExtension} ".sr" "sigrok session file"
 318
 319         # Force Windows to update the icon cache so that the icon for .sr files is reset.
 320         System::Call 'Shell32::SHChangeNotify(i ${SHCNE_ASSOCCHANGED}, i ${SHCNF_IDLIST}, i 0, i 0)'
 321 SectionEnd
 322
 323
 324 # --- Component selection section descriptions --------------------------------
 325
 326 LangString DESC_Section1 ${LANG_ENGLISH} "This installs the PulseView sigrok GUI, some firmware files, the protocol decoders, and all required libraries."
 327 LangString DESC_Section2 ${LANG_ENGLISH} "This installs some example files that you can use to try out the features sigrok has to offer."
 328
 329 !insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
 330         !insertmacro MUI_DESCRIPTION_TEXT ${Section1} $(DESC_Section1)
 331         !insertmacro MUI_DESCRIPTION_TEXT ${Section2} $(DESC_Section2)
 332 !insertmacro MUI_FUNCTION_DESCRIPTION_END
 333