contrib/pulseview_cross.nsi.in

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2013-2014 Uwe Hermann <uwe@hermann-uwe.de>
   5 ##
   6 ## This program is free software; you can redistribute it and/or modify
   7 ## it under the terms of the GNU General Public License as published by
   8 ## the Free Software Foundation; either version 2 of the License, or
   9 ## (at your option) any later version.
  10 ##
  11 ## This program is distributed in the hope that it will be useful,
  12 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ## GNU General Public License for more details.
  15 ##
  16 ## You should have received a copy of the GNU General Public License
  17 ## along with this program; if not, write to the Free Software
  18 ## Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA  02110-1301 USA
  19 ##
  20
  21 #
  22 # This file is used to create the PulseView Windows installer via NSIS.
  23 # It is meant for use in a cross-compile setup (not for native builds).
  24 # See the 'sigrok-cross-mingw' script in the sigrok-util repo for details.
  25 #
  26 # NSIS documentation:
  27 # http://nsis.sourceforge.net/Docs/
  28 # http://nsis.sourceforge.net/Docs/Modern%20UI%202/Readme.html
  29 #
  30
  31 # Include the "Modern UI" header, which gives us the usual Windows look-n-feel.
  32 !include "MUI2.nsh"
  33
  34
  35 # --- Global stuff ------------------------------------------------------------
  36
  37 # Installer/product name.
  38 Name "PulseView"
  39
  40 # Filename of the installer executable.
  41 OutFile "pulseview-@PV_VERSION_STRING@-installer.exe"
  42
  43 # Where to install the application.
  44 InstallDir "$PROGRAMFILES\sigrok\PulseView"
  45
  46 # Request admin privileges for Windows Vista and Windows 7.
  47 # http://nsis.sourceforge.net/Docs/Chapter4.html
  48 RequestExecutionLevel admin
  49
  50 # Local helper definitions.
  51 !define REGSTR "Software\Microsoft\Windows\CurrentVersion\Uninstall\PulseView"
  52
  53
  54 # --- MUI interface configuration ---------------------------------------------
  55
  56 # Use the following icon for the installer EXE file.
  57 !define MUI_ICON "@PROJECT_SOURCE_DIR@/icons/sigrok-logo-notext.ico"
  58
  59 # Show a nice image at the top of each installer page.
  60 !define MUI_HEADERIMAGE
  61
  62 # Don't automatically go to the Finish page so the user can check the log.
  63 !define MUI_FINISHPAGE_NOAUTOCLOSE
  64
  65 # Upon "cancel", ask the user if he really wants to abort the installer.
  66 !define MUI_ABORTWARNING
  67
  68 # Don't force the user to accept the license, just show it.
  69 # Details: http://trac.videolan.org/vlc/ticket/3124
  70 !define MUI_LICENSEPAGE_BUTTON $(^NextBtn)
  71 !define MUI_LICENSEPAGE_TEXT_BOTTOM "Click Next to continue."
  72
  73 # Path where the cross-compiled sigrok tools and libraries are located.
  74 # Change this to where-ever you installed libsigrok.a and so on.
  75 !define CROSS "@CMAKE_INSTALL_PREFIX@"
  76
  77
  78 # --- MUI pages ---------------------------------------------------------------
  79
  80 # Show a nice "Welcome to the ... Setup Wizard" page.
  81 !insertmacro MUI_PAGE_WELCOME
  82
  83 # Show the license of the project.
  84 !insertmacro MUI_PAGE_LICENSE "@PROJECT_SOURCE_DIR@/COPYING"
  85
  86 # Show a screen which allows the user to select which components to install.
  87 !insertmacro MUI_PAGE_COMPONENTS
  88
  89 # Allow the user to select a different install directory.
  90 !insertmacro MUI_PAGE_DIRECTORY
  91
  92 # Perform the actual installation, i.e. install the files.
  93 !insertmacro MUI_PAGE_INSTFILES
  94
  95 # Show a final "We're done, click Finish to close this wizard" message.
  96 !insertmacro MUI_PAGE_FINISH
  97
  98 # Pages used for the uninstaller.
  99 !insertmacro MUI_UNPAGE_WELCOME
 100 !insertmacro MUI_UNPAGE_CONFIRM
 101 !insertmacro MUI_UNPAGE_INSTFILES
 102 !insertmacro MUI_UNPAGE_FINISH
 103
 104
 105 # --- MUI language files ------------------------------------------------------
 106
 107 # Select an installer language (required!).
 108 !insertmacro MUI_LANGUAGE "English"
 109
 110
 111 # --- Default section ---------------------------------------------------------
 112
 113 Section "PulseView (required)" Section1
 114
 115         # This section is gray (can't be disabled) in the component list.
 116         SectionIn RO
 117
 118         # Install the file(s) specified below into the specified directory.
 119         SetOutPath "$INSTDIR"
 120
 121         # License file.
 122         File "@PROJECT_SOURCE_DIR@/COPYING"
 123
 124         # PulseView (statically linked, includes all libs).
 125         File "${CROSS}/bin/pulseview.exe"
 126
 127         # Zadig (used for installing WinUSB drivers).
 128         File "${CROSS}/zadig.exe"
 129         File "${CROSS}/zadig_xp.exe"
 130
 131         # Python
 132         File "${CROSS}/python32.dll"
 133         File "${CROSS}/python32.zip"
 134
 135         # Protocol decoders.
 136         SetOutPath "$INSTDIR\decoders"
 137         File /r /x "__pycache__" "${CROSS}/share/libsigrokdecode/decoders/*"
 138
 139         # Firmware files.
 140         SetOutPath "$INSTDIR\firmware"
 141         File /r "${CROSS}/share/sigrok-firmware/*"
 142
 143         # Example *.sr files.
 144         SetOutPath "$INSTDIR\examples"
 145         File /r "${CROSS}/share/sigrok-dumps/*"
 146
 147         # Generate the uninstaller executable.
 148         WriteUninstaller "$INSTDIR\Uninstall.exe"
 149
 150         # Create a sub-directory in the start menu.
 151         CreateDirectory "$SMPROGRAMS\sigrok"
 152         CreateDirectory "$SMPROGRAMS\sigrok\PulseView"
 153
 154         # Create a shortcut for the PulseView application.
 155         SetOutPath "$INSTDIR"
 156         CreateShortCut "$SMPROGRAMS\sigrok\PulseView\PulseView.lnk" \
 157                 "$INSTDIR\pulseview.exe" "" "$INSTDIR\pulseview.exe" \
 158                 0 SW_SHOWNORMAL \
 159                 "" "Open-source, portable sigrok GUI"
 160
 161         # Create a shortcut for the uninstaller.
 162         CreateShortCut "$SMPROGRAMS\sigrok\PulseView\Uninstall.lnk" \
 163                 "$INSTDIR\Uninstall.exe" "" "$INSTDIR\Uninstall.exe" 0 \
 164                 SW_SHOWNORMAL "" "Uninstall PulseView"
 165
 166         # Create a shortcut for the Zadig executable.
 167         CreateShortCut "$SMPROGRAMS\sigrok\PulseView\Zadig.lnk" \
 168                 "$INSTDIR\zadig.exe" "" "$INSTDIR\zadig.exe" 0 \
 169                 SW_SHOWNORMAL "" "Zadig"
 170
 171         # Create a shortcut for the Zadig executable (for Win XP).
 172         CreateShortCut "$SMPROGRAMS\sigrok\PulseView\Zadig (Win XP).lnk" \
 173                 "$INSTDIR\zadig_xp.exe" "" "$INSTDIR\zadig_xp.exe" 0 \
 174                 SW_SHOWNORMAL "" "Zadig (Win XP)"
 175
 176         # Create registry keys for "Add/remove programs" in the control panel.
 177         WriteRegStr HKLM "${REGSTR}" "DisplayName" "PulseView"
 178         WriteRegStr HKLM "${REGSTR}" "UninstallString" \
 179                 "$\"$INSTDIR\Uninstall.exe$\""
 180         WriteRegStr HKLM "${REGSTR}" "InstallLocation" "$\"$INSTDIR$\""
 181         WriteRegStr HKLM "${REGSTR}" "DisplayIcon" \
 182                 "$\"$INSTDIR\sigrok-logo-notext.ico$\""
 183         WriteRegStr HKLM "${REGSTR}" "Publisher" "sigrok"
 184         WriteRegStr HKLM "${REGSTR}" "HelpLink" \
 185                 "http://sigrok.org/wiki/PulseView"
 186         WriteRegStr HKLM "${REGSTR}" "URLUpdateInfo" \
 187                 "http://sigrok.org/wiki/Downloads"
 188         WriteRegStr HKLM "${REGSTR}" "URLInfoAbout" "http://sigrok.org"
 189         WriteRegStr HKLM "${REGSTR}" "DisplayVersion" "@PV_VERSION_STRING@"
 190         WriteRegStr HKLM "${REGSTR}" "Contact" \
 191                 "sigrok-devel@lists.sourceforge.org"
 192         WriteRegStr HKLM "${REGSTR}" "Comments" \
 193                 "This is a Qt based sigrok GUI."
 194
 195         # Display "Remove" instead of "Modify/Remove" in the control panel.
 196         WriteRegDWORD HKLM "${REGSTR}" "NoModify" 1
 197         WriteRegDWORD HKLM "${REGSTR}" "NoRepair" 1
 198
 199 SectionEnd
 200
 201
 202 # --- Uninstaller section -----------------------------------------------------
 203
 204 Section "Uninstall"
 205
 206         # Always delete the uninstaller first (yes, this really works).
 207         Delete "$INSTDIR\Uninstall.exe"
 208
 209         # Delete the application, the application data, and related libs.
 210         Delete "$INSTDIR\COPYING"
 211         Delete "$INSTDIR\pulseview.exe"
 212         Delete "$INSTDIR\zadig.exe"
 213         Delete "$INSTDIR\zadig_xp.exe"
 214         Delete "$INSTDIR\python32.dll"
 215         Delete "$INSTDIR\python32.zip"
 216
 217         # Delete all decoders and everything else in decoders/.
 218         # There could be *.pyc files or __pycache__ subdirs and so on.
 219         RMDir /r "$INSTDIR\decoders\*"
 220
 221         # Delete the firmware files.
 222         RMDir /r "$INSTDIR\firmware\*"
 223
 224         # Delete the example *.sr files.
 225         RMDir /r "$INSTDIR\examples\*"
 226
 227         # Delete the install directory and its sub-directories.
 228         RMDir "$INSTDIR\decoders"
 229         RMDir "$INSTDIR\firmware"
 230         RMDir "$INSTDIR\examples"
 231         RMDir "$INSTDIR"
 232
 233         # Delete the links from the start menu.
 234         Delete "$SMPROGRAMS\sigrok\PulseView\PulseView.lnk"
 235         Delete "$SMPROGRAMS\sigrok\PulseView\Uninstall.lnk"
 236         Delete "$SMPROGRAMS\sigrok\PulseView\Zadig.lnk"
 237         Delete "$SMPROGRAMS\sigrok\PulseView\Zadig (Win XP).lnk"
 238
 239         # Delete the sub-directory in the start menu.
 240         RMDir "$SMPROGRAMS\sigrok\PulseView"
 241         RMDir "$SMPROGRAMS\sigrok"
 242
 243         # Delete the registry key(s).
 244         DeleteRegKey HKLM "${REGSTR}"
 245
 246 SectionEnd
 247
 248
 249 # --- Component selection section descriptions --------------------------------
 250
 251 LangString DESC_Section1 ${LANG_ENGLISH} "This installs the PulseView sigrok GUI, some firmware files, the protocol decoders, some example files, and all required libraries."
 252
 253 !insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
 254 !insertmacro MUI_DESCRIPTION_TEXT ${Section1} $(DESC_Section1)
 255 !insertmacro MUI_FUNCTION_DESCRIPTION_END
 256