contrib/pulseview_cross.nsi.in

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2013-2014 Uwe Hermann <uwe@hermann-uwe.de>
   5 ##
   6 ## This program is free software; you can redistribute it and/or modify
   7 ## it under the terms of the GNU General Public License as published by
   8 ## the Free Software Foundation; either version 2 of the License, or
   9 ## (at your option) any later version.
  10 ##
  11 ## This program is distributed in the hope that it will be useful,
  12 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ## GNU General Public License for more details.
  15 ##
  16 ## You should have received a copy of the GNU General Public License
  17 ## along with this program; if not, see <http://www.gnu.org/licenses/>.
  18 ##
  19
  20 #
  21 # This file is used to create the PulseView Windows installer via NSIS.
  22 # It is meant for use in a cross-compile setup (not for native builds).
  23 # See the 'sigrok-cross-mingw' script in the sigrok-util repo for details.
  24 #
  25 # NSIS documentation:
  26 # http://nsis.sourceforge.net/Docs/
  27 # http://nsis.sourceforge.net/Docs/Modern%20UI%202/Readme.html
  28 #
  29
  30 # Include the "Modern UI" header, which gives us the usual Windows look-n-feel.
  31 !include "MUI2.nsh"
  32
  33 # Include the file association header so that we can register file extensions.
  34 !include "FileAssociation.nsh"
  35
  36
  37 # --- Global stuff ------------------------------------------------------------
  38
  39 # Installer/product name.
  40 Name "PulseView"
  41
  42 # Filename of the installer executable.
  43 OutFile "pulseview-@PV_VERSION_STRING@-installer.exe"
  44
  45 # Where to install the application.
  46 InstallDir "$PROGRAMFILES\sigrok\PulseView"
  47
  48 # Request admin privileges for Windows Vista and Windows 7.
  49 # http://nsis.sourceforge.net/Docs/Chapter4.html
  50 RequestExecutionLevel admin
  51
  52 # Local helper definitions.
  53 !define REGSTR "Software\Microsoft\Windows\CurrentVersion\Uninstall\PulseView"
  54
  55
  56 # --- MUI interface configuration ---------------------------------------------
  57
  58 # Use the following icon for the installer EXE file.
  59 !define MUI_ICON "@PROJECT_SOURCE_DIR@/icons/sigrok-logo-notext.ico"
  60
  61 # Show a nice image at the top of each installer page.
  62 !define MUI_HEADERIMAGE
  63
  64 # Don't automatically go to the Finish page so the user can check the log.
  65 !define MUI_FINISHPAGE_NOAUTOCLOSE
  66
  67 # Upon "cancel", ask the user if he really wants to abort the installer.
  68 !define MUI_ABORTWARNING
  69
  70 # Don't force the user to accept the license, just show it.
  71 # Details: http://trac.videolan.org/vlc/ticket/3124
  72 !define MUI_LICENSEPAGE_BUTTON $(^NextBtn)
  73 !define MUI_LICENSEPAGE_TEXT_BOTTOM "Click Next to continue."
  74
  75 # Path where the cross-compiled sigrok tools and libraries are located.
  76 # Change this to where-ever you installed libsigrok.a and so on.
  77 !define CROSS "@CMAKE_INSTALL_PREFIX@"
  78
  79
  80 # --- Functions ---------------------------------------------------------------
  81
  82 Function register_sr_files
  83 ${registerExtension} "$INSTDIR\pulseview.exe" ".sr" "sigrok session file"
  84 FunctionEnd
  85
  86
  87 # --- MUI pages ---------------------------------------------------------------
  88
  89 # Show a nice "Welcome to the ... Setup Wizard" page.
  90 !insertmacro MUI_PAGE_WELCOME
  91
  92 # Show the license of the project.
  93 !insertmacro MUI_PAGE_LICENSE "@PROJECT_SOURCE_DIR@/COPYING"
  94
  95 # Show a screen which allows the user to select which components to install.
  96 !insertmacro MUI_PAGE_COMPONENTS
  97
  98 # Allow the user to select a different install directory.
  99 !insertmacro MUI_PAGE_DIRECTORY
 100
 101 # Perform the actual installation, i.e. install the files.
 102 !insertmacro MUI_PAGE_INSTFILES
 103
 104 # Insert the "Show Readme" button in the finish dialog. We repurpose it for
 105 # registering the .sr file extension. This way, we don't need to add in-depth
 106 # modifications to the finish page.
 107 !define MUI_FINISHPAGE_SHOWREADME ""
 108 !define MUI_FINISHPAGE_SHOWREADME_CHECKED
 109 !define MUI_FINISHPAGE_SHOWREADME_TEXT "Register .sr files with PulseView"
 110 !define MUI_FINISHPAGE_SHOWREADME_FUNCTION register_sr_files
 111
 112 # Show a final "We're done, click Finish to close this wizard" message.
 113 !insertmacro MUI_PAGE_FINISH
 114
 115 # Pages used for the uninstaller.
 116 !insertmacro MUI_UNPAGE_WELCOME
 117 !insertmacro MUI_UNPAGE_CONFIRM
 118 !insertmacro MUI_UNPAGE_INSTFILES
 119 !insertmacro MUI_UNPAGE_FINISH
 120
 121
 122 # --- MUI language files ------------------------------------------------------
 123
 124 # Select an installer language (required!).
 125 !insertmacro MUI_LANGUAGE "English"
 126
 127
 128 # --- Default section ---------------------------------------------------------
 129
 130 Section "PulseView (required)" Section1
 131
 132         # This section is gray (can't be disabled) in the component list.
 133         SectionIn RO
 134
 135         # Install the file(s) specified below into the specified directory.
 136         SetOutPath "$INSTDIR"
 137
 138         # License file.
 139         File "@PROJECT_SOURCE_DIR@/COPYING"
 140
 141         # PulseView (statically linked, includes all libs).
 142         File "${CROSS}/bin/pulseview.exe"
 143
 144         # Zadig (used for installing WinUSB drivers).
 145         File "${CROSS}/zadig.exe"
 146         File "${CROSS}/zadig_xp.exe"
 147
 148         # Python
 149         File "${CROSS}/python34.dll"
 150         File "${CROSS}/python34.zip"
 151
 152         SetOutPath "$INSTDIR\share"
 153
 154         # Protocol decoders.
 155         File /r /x "__pycache__" /x "*.pyc" "${CROSS}/share/libsigrokdecode"
 156
 157         # Firmware files.
 158         File /r "${CROSS}/share/sigrok-firmware"
 159
 160         # Example *.sr files.
 161         SetOutPath "$INSTDIR\examples"
 162         File /r "${CROSS}/share/sigrok-dumps/*"
 163
 164         # Generate the uninstaller executable.
 165         WriteUninstaller "$INSTDIR\Uninstall.exe"
 166
 167         # Create a sub-directory in the start menu.
 168         CreateDirectory "$SMPROGRAMS\sigrok"
 169         CreateDirectory "$SMPROGRAMS\sigrok\PulseView"
 170
 171         # Create a shortcut for the PulseView application.
 172         SetOutPath "$INSTDIR"
 173         CreateShortCut "$SMPROGRAMS\sigrok\PulseView\PulseView.lnk" \
 174                 "$INSTDIR\pulseview.exe" "" "$INSTDIR\pulseview.exe" \
 175                 0 SW_SHOWNORMAL \
 176                 "" "Open-source, portable sigrok GUI"
 177
 178         # Create a shortcut for the uninstaller.
 179         CreateShortCut "$SMPROGRAMS\sigrok\PulseView\Uninstall.lnk" \
 180                 "$INSTDIR\Uninstall.exe" "" "$INSTDIR\Uninstall.exe" 0 \
 181                 SW_SHOWNORMAL "" "Uninstall PulseView"
 182
 183         # Create a shortcut for the Zadig executable.
 184         CreateShortCut "$SMPROGRAMS\sigrok\PulseView\Zadig.lnk" \
 185                 "$INSTDIR\zadig.exe" "" "$INSTDIR\zadig.exe" 0 \
 186                 SW_SHOWNORMAL "" "Zadig"
 187
 188         # Create a shortcut for the Zadig executable (for Win XP).
 189         CreateShortCut "$SMPROGRAMS\sigrok\PulseView\Zadig (Win XP).lnk" \
 190                 "$INSTDIR\zadig_xp.exe" "" "$INSTDIR\zadig_xp.exe" 0 \
 191                 SW_SHOWNORMAL "" "Zadig (Win XP)"
 192
 193         # Create registry keys for "Add/remove programs" in the control panel.
 194         WriteRegStr HKLM "${REGSTR}" "DisplayName" "PulseView"
 195         WriteRegStr HKLM "${REGSTR}" "UninstallString" \
 196                 "$\"$INSTDIR\Uninstall.exe$\""
 197         WriteRegStr HKLM "${REGSTR}" "InstallLocation" "$\"$INSTDIR$\""
 198         WriteRegStr HKLM "${REGSTR}" "DisplayIcon" \
 199                 "$\"$INSTDIR\sigrok-logo-notext.ico$\""
 200         WriteRegStr HKLM "${REGSTR}" "Publisher" "sigrok"
 201         WriteRegStr HKLM "${REGSTR}" "HelpLink" \
 202                 "http://sigrok.org/wiki/PulseView"
 203         WriteRegStr HKLM "${REGSTR}" "URLUpdateInfo" \
 204                 "http://sigrok.org/wiki/Downloads"
 205         WriteRegStr HKLM "${REGSTR}" "URLInfoAbout" "http://sigrok.org"
 206         WriteRegStr HKLM "${REGSTR}" "DisplayVersion" "@PV_VERSION_STRING@"
 207         WriteRegStr HKLM "${REGSTR}" "Contact" \
 208                 "sigrok-devel@lists.sourceforge.org"
 209         WriteRegStr HKLM "${REGSTR}" "Comments" \
 210                 "This is a Qt based sigrok GUI."
 211
 212         # Display "Remove" instead of "Modify/Remove" in the control panel.
 213         WriteRegDWORD HKLM "${REGSTR}" "NoModify" 1
 214         WriteRegDWORD HKLM "${REGSTR}" "NoRepair" 1
 215
 216 SectionEnd
 217
 218
 219 # --- Uninstaller section -----------------------------------------------------
 220
 221 Section "Uninstall"
 222
 223         # Always delete the uninstaller first (yes, this really works).
 224         Delete "$INSTDIR\Uninstall.exe"
 225
 226         # Delete the application, the application data, and related libs.
 227         Delete "$INSTDIR\COPYING"
 228         Delete "$INSTDIR\pulseview.exe"
 229         Delete "$INSTDIR\zadig.exe"
 230         Delete "$INSTDIR\zadig_xp.exe"
 231         Delete "$INSTDIR\python34.dll"
 232         Delete "$INSTDIR\python34.zip"
 233
 234         # Delete all decoders and everything else in libsigrokdecode/.
 235         # There could be *.pyc files or __pycache__ subdirs and so on.
 236         RMDir /r "$INSTDIR\share\libsigrokdecode"
 237
 238         # Delete the firmware files.
 239         RMDir /r "$INSTDIR\share\sigrok-firmware"
 240
 241         # Delete the example *.sr files.
 242         RMDir /r "$INSTDIR\examples\*"
 243
 244         # Delete the install directory and its sub-directories.
 245         RMDir "$INSTDIR\share"
 246         RMDir "$INSTDIR\examples"
 247         RMDir "$INSTDIR"
 248
 249         # Delete the links from the start menu.
 250         Delete "$SMPROGRAMS\sigrok\PulseView\PulseView.lnk"
 251         Delete "$SMPROGRAMS\sigrok\PulseView\Uninstall.lnk"
 252         Delete "$SMPROGRAMS\sigrok\PulseView\Zadig.lnk"
 253         Delete "$SMPROGRAMS\sigrok\PulseView\Zadig (Win XP).lnk"
 254
 255         # Delete the sub-directory in the start menu.
 256         RMDir "$SMPROGRAMS\sigrok\PulseView"
 257         RMDir "$SMPROGRAMS\sigrok"
 258
 259         # Delete the registry key(s).
 260         DeleteRegKey HKLM "${REGSTR}"
 261
 262         # Unregister any previously registered file extension(s).
 263         ${unregisterExtension} ".sr" "sigrok session file"
 264
 265 SectionEnd
 266
 267
 268 # --- Component selection section descriptions --------------------------------
 269
 270 LangString DESC_Section1 ${LANG_ENGLISH} "This installs the PulseView sigrok GUI, some firmware files, the protocol decoders, some example files, and all required libraries."
 271
 272 !insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
 273 !insertmacro MUI_DESCRIPTION_TEXT ${Section1} $(DESC_Section1)
 274 !insertmacro MUI_FUNCTION_DESCRIPTION_END
 275