CMakeLists.txt

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
   5 ## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 2 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 cmake_minimum_required(VERSION 2.8.6)
  22
  23 include(FindPkgConfig)
  24 include(GNUInstallDirs)
  25
  26 project(pulseview)
  27
  28 list(APPEND CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/CMake")
  29
  30 #===============================================================================
  31 #= User Options
  32 #-------------------------------------------------------------------------------
  33
  34 option(DISABLE_WERROR "Build without -Werror" FALSE)
  35 option(ENABLE_SIGNALS "Build with UNIX signals" TRUE)
  36 option(ENABLE_DECODE "Build with libsigrokdecode" TRUE)
  37 option(ENABLE_TESTS "Enable unit tests" FALSE)
  38 option(STATIC_PKGDEPS_LIBS "Statically link to (pkg-config) libraries" FALSE)
  39 option(FORCE_QT4 "Force use of Qt4 even if Qt5 is available" FALSE)
  40
  41 if(WIN32)
  42         # On Windows/MinGW we need to statically link to libraries.
  43         # This option is user configurable, but enable it by default on win32.
  44         set(STATIC_PKGDEPS_LIBS TRUE)
  45
  46         # For boost-thread we need two additional settings on win32:
  47         set(Boost_USE_STATIC_LIBS ON)
  48         add_definitions(-DBOOST_THREAD_USE_LIB)
  49
  50         # On Windows/MinGW we need to use 'thread_win32' instead of 'thread'.
  51         # The library is named libboost_thread_win32* (not libboost_thread*).
  52         set(Boost_THREADAPI win32)
  53
  54         # Windows does not support UNIX signals.
  55         set(ENABLE_SIGNALS FALSE)
  56 endif()
  57
  58 if(NOT CMAKE_BUILD_TYPE)
  59         set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
  60         "Choose the type of build (None, Debug, Release, RelWithDebInfo, MinSizeRel)."
  61         FORCE)
  62 endif()
  63
  64 #===============================================================================
  65 #= Dependencies
  66 #-------------------------------------------------------------------------------
  67
  68 list(APPEND PKGDEPS libsigrokcxx>=0.3.0)
  69
  70 if(ENABLE_DECODE)
  71         list(APPEND PKGDEPS libsigrokdecode>=0.3.0)
  72 endif()
  73
  74 if(ANDROID)
  75         list(APPEND PKGDEPS libsigrokandroidutils>=0.1.0)
  76 endif()
  77
  78 find_package(PkgConfig)
  79 pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})
  80
  81 if(FORCE_QT4)
  82         set(Qt5Core_FOUND FALSE)
  83 else()
  84         find_package(Qt5Core QUIET)
  85 endif()
  86
  87 if(Qt5Core_FOUND)
  88         message("-- Using Qt5")
  89         find_package(Qt5Widgets REQUIRED)
  90         find_package(Qt5Gui REQUIRED)
  91         find_package(Qt5Svg REQUIRED)
  92         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${Qt5Widgets_EXECUTABLE_COMPILE_FLAGS}")
  93         set(QT_INCLUDE_DIRS ${Qt5Gui_INCLUDE_DIRS} ${Qt5Widgets_INCLUDE_DIRS})
  94         set(QT_LIBRARIES Qt5::Gui Qt5::Widgets Qt5::Svg)
  95         add_definitions(${Qt5Gui_DEFINITIONS} ${Qt5Widgets_DEFINITIONS})
  96 else()
  97         find_program(QT_QMAKE_EXECUTABLE NAMES qmake4 qmake-qt4 qmake-mac)
  98         find_package(Qt4 REQUIRED QtCore QtGui QtSvg)
  99 endif()
 100
 101 if(ENABLE_TESTS)
 102         find_package(Boost 1.42 COMPONENTS filesystem system thread unit_test_framework REQUIRED)
 103 else()
 104         find_package(Boost 1.42 COMPONENTS filesystem system thread REQUIRED)
 105 endif()
 106
 107 # Find the platform's thread library (needed for C++11 threads).
 108 # This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
 109 find_package(Threads REQUIRED)
 110
 111 #===============================================================================
 112 #= System Introspection
 113 #-------------------------------------------------------------------------------
 114
 115 include(memaccess)
 116 memaccess_check_unaligned_le(HAVE_UNALIGNED_LITTLE_ENDIAN_ACCESS)
 117
 118 #===============================================================================
 119 #= Config Header
 120 #-------------------------------------------------------------------------------
 121
 122 set(PV_TITLE PulseView)
 123 set(PV_DESCRIPTION "A GUI for sigrok")
 124
 125 set(PV_VERSION_MAJOR 0)
 126 set(PV_VERSION_MINOR 2)
 127 set(PV_VERSION_MICRO 0)
 128 set(PV_VERSION_STRING
 129         ${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}
 130 )
 131
 132 configure_file (
 133         ${PROJECT_SOURCE_DIR}/config.h.in
 134         ${PROJECT_BINARY_DIR}/config.h
 135 )
 136
 137 #===============================================================================
 138 #= Sources
 139 #-------------------------------------------------------------------------------
 140
 141 set(pulseview_SOURCES
 142         main.cpp
 143         pv/application.cpp
 144         pv/devicemanager.cpp
 145         pv/mainwindow.cpp
 146         pv/session.cpp
 147         pv/storesession.cpp
 148         pv/util.cpp
 149         pv/data/analog.cpp
 150         pv/data/analogsegment.cpp
 151         pv/data/logic.cpp
 152         pv/data/logicsegment.cpp
 153         pv/data/signaldata.cpp
 154         pv/data/segment.cpp
 155         pv/dialogs/about.cpp
 156         pv/dialogs/connect.cpp
 157         pv/dialogs/storeprogress.cpp
 158         pv/popups/deviceoptions.cpp
 159         pv/popups/channels.cpp
 160         pv/prop/bool.cpp
 161         pv/prop/double.cpp
 162         pv/prop/enum.cpp
 163         pv/prop/int.cpp
 164         pv/prop/property.cpp
 165         pv/prop/string.cpp
 166         pv/prop/binding/binding.cpp
 167         pv/prop/binding/deviceoptions.cpp
 168         pv/toolbars/mainbar.cpp
 169         pv/view/analogsignal.cpp
 170         pv/view/cursor.cpp
 171         pv/view/cursorpair.cpp
 172         pv/view/flag.cpp
 173         pv/view/header.cpp
 174         pv/view/marginwidget.cpp
 175         pv/view/logicsignal.cpp
 176         pv/view/rowitem.cpp
 177         pv/view/rowitemowner.cpp
 178         pv/view/ruler.cpp
 179         pv/view/signal.cpp
 180         pv/view/timeitem.cpp
 181         pv/view/timemarker.cpp
 182         pv/view/trace.cpp
 183         pv/view/tracegroup.cpp
 184         pv/view/tracepalette.cpp
 185         pv/view/view.cpp
 186         pv/view/viewitem.cpp
 187         pv/view/viewitempaintparams.cpp
 188         pv/view/viewport.cpp
 189         pv/view/viewwidget.cpp
 190         pv/widgets/colourbutton.cpp
 191         pv/widgets/colourpopup.cpp
 192         pv/widgets/devicetoolbutton.cpp
 193         pv/widgets/hidingmenubar.cpp
 194         pv/widgets/popup.cpp
 195         pv/widgets/popuptoolbutton.cpp
 196         pv/widgets/sweeptimingwidget.cpp
 197         pv/widgets/wellarray.cpp
 198 )
 199
 200 # This list includes only QObject derived class headers.
 201 set(pulseview_HEADERS
 202         pv/mainwindow.hpp
 203         pv/session.hpp
 204         pv/storesession.hpp
 205         pv/dialogs/about.hpp
 206         pv/dialogs/connect.hpp
 207         pv/dialogs/storeprogress.hpp
 208         pv/popups/channels.hpp
 209         pv/popups/deviceoptions.hpp
 210         pv/prop/bool.hpp
 211         pv/prop/double.hpp
 212         pv/prop/enum.hpp
 213         pv/prop/int.hpp
 214         pv/prop/property.hpp
 215         pv/prop/string.hpp
 216         pv/prop/binding/deviceoptions.hpp
 217         pv/toolbars/mainbar.hpp
 218         pv/view/cursor.hpp
 219         pv/view/flag.hpp
 220         pv/view/header.hpp
 221         pv/view/logicsignal.hpp
 222         pv/view/marginwidget.hpp
 223         pv/view/rowitem.hpp
 224         pv/view/ruler.hpp
 225         pv/view/signal.hpp
 226         pv/view/timeitem.hpp
 227         pv/view/timemarker.hpp
 228         pv/view/trace.hpp
 229         pv/view/tracegroup.hpp
 230         pv/view/view.hpp
 231         pv/view/viewitem.hpp
 232         pv/view/viewport.hpp
 233         pv/view/viewwidget.hpp
 234         pv/widgets/colourbutton.hpp
 235         pv/widgets/colourpopup.hpp
 236         pv/widgets/devicetoolbutton.hpp
 237         pv/widgets/hidingmenubar.hpp
 238         pv/widgets/popup.hpp
 239         pv/widgets/popuptoolbutton.hpp
 240         pv/widgets/sweeptimingwidget.hpp
 241         pv/widgets/wellarray.hpp
 242 )
 243
 244 set(pulseview_FORMS
 245         pv/dialogs/about.ui
 246 )
 247
 248 set(pulseview_RESOURCES
 249         pulseview.qrc
 250 )
 251
 252 if(ENABLE_SIGNALS)
 253         list(APPEND pulseview_SOURCES signalhandler.cpp)
 254         list(APPEND pulseview_HEADERS signalhandler.hpp)
 255 endif()
 256
 257 if(ENABLE_DECODE)
 258         list(APPEND pulseview_SOURCES
 259                 pv/data/decoderstack.cpp
 260                 pv/data/decode/annotation.cpp
 261                 pv/data/decode/decoder.cpp
 262                 pv/data/decode/row.cpp
 263                 pv/data/decode/rowdata.cpp
 264                 pv/prop/binding/decoderoptions.cpp
 265                 pv/view/decodetrace.cpp
 266                 pv/widgets/decodergroupbox.cpp
 267                 pv/widgets/decodermenu.cpp
 268         )
 269
 270         list(APPEND pulseview_HEADERS
 271                 pv/data/decoderstack.hpp
 272                 pv/view/decodetrace.hpp
 273                 pv/widgets/decodergroupbox.hpp
 274                 pv/widgets/decodermenu.hpp
 275         )
 276 endif()
 277
 278 if(WIN32)
 279         # Use the sigrok icon for the pulseview.exe executable.
 280         set(CMAKE_RC_COMPILE_OBJECT "${CMAKE_RC_COMPILER} -O coff -I${CMAKE_CURRENT_SOURCE_DIR} <SOURCE> <OBJECT>")
 281         enable_language(RC)
 282         list(APPEND pulseview_SOURCES pulseviewico.rc)
 283 endif()
 284
 285 if(ANDROID)
 286         list(APPEND pulseview_SOURCES android/loghandler.cpp)
 287 endif()
 288
 289 if(Qt5Core_FOUND)
 290         qt5_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 291         qt5_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 292         qt5_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 293 else()
 294         qt4_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 295         qt4_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 296         qt4_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 297         include(${QT_USE_FILE})
 298 endif()
 299
 300 #===============================================================================
 301 #= Global Definitions
 302 #-------------------------------------------------------------------------------
 303
 304 add_definitions(${QT_DEFINITIONS} -DQT_NO_KEYWORDS)
 305 add_definitions(-D__STDC_LIMIT_MACROS)
 306 add_definitions(-Wall -Wextra)
 307 add_definitions(-std=c++11)
 308
 309 if(ENABLE_DECODE)
 310         add_definitions(-DENABLE_DECODE)
 311 endif()
 312
 313 if(NOT DISABLE_WERROR)
 314         add_definitions(-Werror)
 315 endif()
 316
 317 if(ENABLE_SIGNALS)
 318         add_definitions(-DENABLE_SIGNALS)
 319 endif()
 320
 321 #===============================================================================
 322 #= Global Include Directories
 323 #-------------------------------------------------------------------------------
 324
 325 include_directories(
 326         ${CMAKE_CURRENT_BINARY_DIR}
 327         ${CMAKE_CURRENT_SOURCE_DIR}
 328         ${Boost_INCLUDE_DIRS}
 329         ${QT_INCLUDE_DIRS}
 330 )
 331
 332 if(STATIC_PKGDEPS_LIBS)
 333         include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
 334 else()
 335         include_directories(${PKGDEPS_INCLUDE_DIRS})
 336 endif()
 337
 338 #===============================================================================
 339 #= Linker Configuration
 340 #-------------------------------------------------------------------------------
 341
 342 link_directories(${Boost_LIBRARY_DIRS})
 343
 344 set(PULSEVIEW_LINK_LIBS
 345         ${Boost_LIBRARIES}
 346         ${QT_LIBRARIES}
 347         ${CMAKE_THREAD_LIBS_INIT}
 348 )
 349
 350 if(STATIC_PKGDEPS_LIBS)
 351         link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
 352         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LIBRARIES})
 353 if(WIN32)
 354         # Workaround for a MinGW linking issue.
 355         list(APPEND PULSEVIEW_LINK_LIBS "-llzma -llcms2")
 356 endif()
 357 else()
 358         link_directories(${PKGDEPS_LIBRARY_DIRS})
 359         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
 360 endif()
 361
 362 if(WIN32)
 363         # On Windows we need to statically link the libqsvg imageformat
 364         # plugin (and the QtSvg component) for SVG graphics/icons to work.
 365         add_definitions(-DQT_STATICPLUGIN)
 366         link_directories("${QT_PLUGINS_DIR}/imageformats")
 367         list(APPEND PULSEVIEW_LINK_LIBS "-lqsvg")
 368         list(APPEND PULSEVIEW_LINK_LIBS ${QT_QTSVG_LIBRARY})
 369 endif()
 370
 371 if(ANDROID)
 372         list(APPEND PULSEVIEW_LINK_LIBS "-llog")
 373 endif()
 374
 375 if(ANDROID)
 376 add_library(${PROJECT_NAME} SHARED
 377         ${pulseview_SOURCES}
 378         ${pulseview_HEADERS_MOC}
 379         ${pulseview_FORMS_HEADERS}
 380         ${pulseview_RESOURCES_RCC}
 381 )
 382 else()
 383 add_executable(${PROJECT_NAME}
 384         ${pulseview_SOURCES}
 385         ${pulseview_HEADERS_MOC}
 386         ${pulseview_FORMS_HEADERS}
 387         ${pulseview_RESOURCES_RCC}
 388 )
 389 endif()
 390
 391 target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
 392
 393 if(WIN32)
 394         # Pass -mwindows so that no "DOS box" opens when PulseView is started.
 395         set_target_properties(${PROJECT_NAME} PROPERTIES LINK_FLAGS "-mwindows")
 396 endif()
 397
 398 #===============================================================================
 399 #= Installation
 400 #-------------------------------------------------------------------------------
 401
 402 # Install the executable.
 403 install(TARGETS ${PROJECT_NAME} DESTINATION bin/)
 404
 405 # Install the manpage.
 406 install(FILES doc/pulseview.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1 COMPONENT doc)
 407
 408 #===============================================================================
 409 #= Packaging (handled by CPack)
 410 #-------------------------------------------------------------------------------
 411
 412 set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
 413 set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
 414 set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
 415 set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
 416 set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
 417 set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
 418 set(CPACK_SOURCE_PACKAGE_FILE_NAME
 419         "${CMAKE_PROJECT_NAME}-${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}")
 420 set(CPACK_SOURCE_GENERATOR "TGZ")
 421
 422 include(CPack)
 423
 424 #===============================================================================
 425 #= Tests
 426 #-------------------------------------------------------------------------------
 427
 428 if(ENABLE_TESTS)
 429         add_subdirectory(test)
 430         enable_testing()
 431         add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
 432 endif()