CMakeLists.txt

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
   5 ## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 2 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 cmake_minimum_required(VERSION 2.6)
  22 include(FindPkgConfig)
  23 include(GNUInstallDirs)
  24
  25 project(pulseview)
  26
  27 #===============================================================================
  28 #= User Options
  29 #-------------------------------------------------------------------------------
  30
  31 option(DISABLE_WERROR "Build without -Werror" FALSE)
  32 option(ENABLE_SIGNALS "Build with UNIX signals" TRUE)
  33 option(ENABLE_SIGROKDECODE "Build with libsigrokdecode" FALSE)
  34 option(ENABLE_TESTS "Enable unit tests" FALSE)
  35 option(STATIC_PKGDEPS_LIBS "Statically link to (pkgconfig) libraries" FALSE)
  36
  37 if(WIN32)
  38         # On Windows/MinGW we need to statically link to libraries.
  39         # This option is user configurable, but enable it by default on win32.
  40         set(STATIC_PKGDEPS_LIBS TRUE)
  41
  42         # For boost-thread we need two additional settings on win32:
  43         set(Boost_USE_STATIC_LIBS on)
  44         add_definitions(-DBOOST_THREAD_USE_LIB)
  45
  46         # Windsws does not support UNIX signals
  47         set(ENABLE_SIGNALS FALSE)
  48 endif()
  49
  50 #===============================================================================
  51 #= Dependencies
  52 #-------------------------------------------------------------------------------
  53
  54 list(APPEND PKGDEPS
  55         libsigrok>=0.2.0
  56 )
  57
  58 if(ENABLE_SIGROKDECODE)
  59         list(APPEND PKGDEPS libsigrokdecode>=0.2.0)
  60 endif()
  61
  62 find_package(PkgConfig)
  63 pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})
  64
  65 find_package(Qt4 REQUIRED)
  66
  67 # Find the platform's thread library (needed for boost-thread).
  68 # This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
  69 find_package(Threads)
  70
  71 if(WIN32)
  72 # On Windows/MinGW the we need to use 'thread_win32' instead of 'thread'.
  73 # The library is named libboost_thread_win32* (not libboost_thread*).
  74 find_package(Boost 1.42 COMPONENTS system thread_win32 REQUIRED)
  75 else()
  76 find_package(Boost 1.42 COMPONENTS system thread REQUIRED)
  77 endif()
  78
  79 #===============================================================================
  80 #= Config Header
  81 #-------------------------------------------------------------------------------
  82
  83 set(PV_TITLE PulseView)
  84 set(PV_DESCRIPTION "A GUI for sigrok")
  85
  86 set(PV_VERSION_MAJOR 0)
  87 set(PV_VERSION_MINOR 1)
  88 set(PV_VERSION_MICRO 0)
  89 set(PV_VERSION_STRING
  90         ${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}
  91 )
  92
  93 configure_file (
  94         ${PROJECT_SOURCE_DIR}/config.h.in
  95         ${PROJECT_BINARY_DIR}/config.h
  96 )
  97
  98 #===============================================================================
  99 #= Sources
 100 #-------------------------------------------------------------------------------
 101
 102 set(pulseview_SOURCES
 103         main.cpp
 104         pv/devicemanager.cpp
 105         pv/mainwindow.cpp
 106         pv/sigsession.cpp
 107         pv/data/analog.cpp
 108         pv/data/analogsnapshot.cpp
 109         pv/data/logic.cpp
 110         pv/data/logicsnapshot.cpp
 111         pv/data/signaldata.cpp
 112         pv/data/snapshot.cpp
 113         pv/dialogs/about.cpp
 114         pv/dialogs/connect.cpp
 115         pv/dialogs/deviceoptions.cpp
 116         pv/prop/bool.cpp
 117         pv/prop/double.cpp
 118         pv/prop/enum.cpp
 119         pv/prop/int.cpp
 120         pv/prop/property.cpp
 121         pv/prop/binding/binding.cpp
 122         pv/prop/binding/deviceoptions.cpp
 123         pv/toolbars/contextbar.cpp
 124         pv/toolbars/samplingbar.cpp
 125         pv/view/analogsignal.cpp
 126         pv/view/cursor.cpp
 127         pv/view/cursorpair.cpp
 128         pv/view/header.cpp
 129         pv/view/logicsignal.cpp
 130         pv/view/ruler.cpp
 131         pv/view/selectableitem.cpp
 132         pv/view/signal.cpp
 133         pv/view/timemarker.cpp
 134         pv/view/view.cpp
 135         pv/view/viewport.cpp
 136 )
 137
 138 set(pulseview_HEADERS
 139         pv/mainwindow.h
 140         pv/sigsession.h
 141         pv/dialogs/about.h
 142         pv/dialogs/connect.h
 143         pv/dialogs/deviceoptions.h
 144         pv/toolbars/contextbar.h
 145         pv/toolbars/samplingbar.h
 146         pv/view/cursor.h
 147         pv/view/header.h
 148         pv/view/ruler.h
 149         pv/view/selectableitem.h
 150         pv/view/signal.h
 151         pv/view/timemarker.h
 152         pv/view/view.h
 153         pv/view/viewport.h
 154 )
 155
 156 set(pulseview_FORMS
 157         pv/dialogs/about.ui
 158 )
 159
 160 set(pulseview_RESOURCES
 161         pulseview.qrc
 162 )
 163
 164 if(ENABLE_SIGNALS)
 165         list(APPEND pulseview_SOURCES signalhandler.cpp)
 166         list(APPEND pulseview_HEADERS signalhandler.h)
 167 endif()
 168
 169 qt4_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 170 qt4_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 171 qt4_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 172
 173 include(${QT_USE_FILE})
 174
 175 #===============================================================================
 176 #= Global Definitions
 177 #-------------------------------------------------------------------------------
 178
 179 add_definitions(${QT_DEFINITIONS})
 180 add_definitions(-Wall -Wextra)
 181
 182 if(ENABLE_SIGROKDECODE)
 183         add_definitions(-DENABLE_SIGROKDECODE)
 184 endif()
 185
 186 if(NOT DISABLE_WERROR)
 187         add_definitions(-Werror)
 188 endif()
 189
 190 #===============================================================================
 191 #= Global Include Directories
 192 #-------------------------------------------------------------------------------
 193
 194 include_directories(
 195         ${CMAKE_CURRENT_BINARY_DIR}
 196         ${CMAKE_CURRENT_SOURCE_DIR}
 197         ${Boost_INCLUDE_DIRS}
 198 )
 199
 200 if(STATIC_PKGDEPS_LIBS)
 201         include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
 202 else()
 203         include_directories(${PKGDEPS_INCLUDE_DIRS})
 204 endif()
 205
 206 #===============================================================================
 207 #= Linker Configuration
 208 #-------------------------------------------------------------------------------
 209
 210 link_directories(${Boost_LIBRARY_DIRS})
 211
 212 set(PULSEVIEW_LINK_LIBS
 213         ${Boost_LIBRARIES}
 214         ${CMAKE_THREAD_LIBS_INIT}
 215         ${QT_LIBRARIES}
 216 )
 217
 218 if(STATIC_PKGDEPS_LIBS)
 219         link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
 220         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LIBRARIES})
 221 else()
 222         link_directories(${PKGDEPS_LIBRARY_DIRS})
 223         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
 224 endif()
 225
 226 add_executable(${PROJECT_NAME}
 227         ${pulseview_SOURCES}
 228         ${pulseview_HEADERS_MOC}
 229         ${pulseview_FORMS_HEADERS}
 230         ${pulseview_RESOURCES_RCC}
 231 )
 232
 233 target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
 234
 235 if(WIN32)
 236 # Pass -mwindows so that no "DOS box" will open when PulseView is started.
 237 set_target_properties(${PROJECT_NAME} PROPERTIES LINK_FLAGS "-mwindows")
 238 endif()
 239
 240 #===============================================================================
 241 #= Installation
 242 #-------------------------------------------------------------------------------
 243
 244 # Install the executable.
 245 install(TARGETS ${PROJECT_NAME} DESTINATION bin/)
 246
 247 # Install the manpage.
 248 install(FILES doc/pulseview.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1 COMPONENT doc)
 249
 250 #===============================================================================
 251 #= Packaging (handled by CPack)
 252 #-------------------------------------------------------------------------------
 253
 254 set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
 255 set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
 256 set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
 257 set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
 258 set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
 259 set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
 260 set(CPACK_SOURCE_PACKAGE_FILE_NAME
 261         "${CMAKE_PROJECT_NAME}-${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}")
 262 set(CPACK_SOURCE_GENERATOR "TGZ")
 263
 264 include(CPack)
 265
 266 #===============================================================================
 267 #= Tests
 268 #-------------------------------------------------------------------------------
 269
 270 if(ENABLE_TESTS)
 271         add_subdirectory(test)
 272         enable_testing()
 273         add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
 274 endif(ENABLE_TESTS)