CMakeLists.txt

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
   5 ## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 2 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 cmake_minimum_required(VERSION 2.6)
  22 include(FindPkgConfig)
  23
  24 project(pulseview)
  25
  26 #===============================================================================
  27 #= User Options
  28 #-------------------------------------------------------------------------------
  29
  30 option(DISABLE_WERROR "Build without -Werror" FALSE)
  31 option(ENABLE_SIGROKDECODE "Build with libsigrokdecode" FALSE)
  32 option(ENABLE_TESTS "Enable unit tests" FALSE)
  33 option(STATIC_PKGDEPS_LIBS "Statically link to (pkgconfig) libraries" FALSE)
  34
  35 if(WIN32)
  36         # On Windows/MinGW we need to statically link to libraries.
  37         # This option is user configurable, but enable it by default on win32.
  38         set(STATIC_PKGDEPS_LIBS TRUE)
  39
  40         # For boost-thread we need two additional settings on win32:
  41         set(Boost_USE_STATIC_LIBS on)
  42         add_definitions(-DBOOST_THREAD_USE_LIB)
  43 endif()
  44
  45 #===============================================================================
  46 #= Dependencies
  47 #-------------------------------------------------------------------------------
  48
  49 list(APPEND PKGDEPS
  50         libsigrok>=0.2.0
  51 )
  52
  53 if(ENABLE_SIGROKDECODE)
  54         list(APPEND PKGDEPS libsigrokdecode>=0.1.0)
  55 endif()
  56
  57 find_package(PkgConfig)
  58 pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})
  59
  60 find_package(Qt4 REQUIRED)
  61
  62 # Find the platform's thread library (needed for boost-thread).
  63 # This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
  64 find_package(Threads)
  65
  66 if(WIN32)
  67 # On Windows/MinGW the we need to use 'thread_win32' instead of 'thread'.
  68 # The library is named libboost_thread_win32* (not libboost_thread*).
  69 find_package(Boost 1.42 COMPONENTS system thread_win32 REQUIRED)
  70 else()
  71 find_package(Boost 1.42 COMPONENTS system thread REQUIRED)
  72 endif()
  73
  74 #===============================================================================
  75 #= Config Header
  76 #-------------------------------------------------------------------------------
  77
  78 set(PV_TITLE PulseView)
  79 set(PV_DESCRIPTION "A GUI for sigrok")
  80
  81 set(PV_VERSION_MAJOR 0)
  82 set(PV_VERSION_MINOR 1)
  83 set(PV_VERSION_MICRO 0)
  84 set(PV_VERSION_STRING
  85         ${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}
  86 )
  87
  88 configure_file (
  89         ${PROJECT_SOURCE_DIR}/config.h.in
  90         ${PROJECT_BINARY_DIR}/config.h
  91 )
  92
  93 #===============================================================================
  94 #= Sources
  95 #-------------------------------------------------------------------------------
  96
  97 set(pulseview_SOURCES
  98         main.cpp
  99         signalhandler.cpp
 100         pv/mainwindow.cpp
 101         pv/sigsession.cpp
 102         pv/data/analog.cpp
 103         pv/data/analogsnapshot.cpp
 104         pv/data/logic.cpp
 105         pv/data/logicsnapshot.cpp
 106         pv/data/signaldata.cpp
 107         pv/data/snapshot.cpp
 108         pv/dialogs/about.cpp
 109         pv/dialogs/connect.cpp
 110         pv/dialogs/deviceoptions.cpp
 111         pv/prop/bool.cpp
 112         pv/prop/double.cpp
 113         pv/prop/enum.cpp
 114         pv/prop/int.cpp
 115         pv/prop/property.cpp
 116         pv/prop/binding/binding.cpp
 117         pv/prop/binding/deviceoptions.cpp
 118         pv/toolbars/samplingbar.cpp
 119         pv/view/analogsignal.cpp
 120         pv/view/cursor.cpp
 121         pv/view/header.cpp
 122         pv/view/logicsignal.cpp
 123         pv/view/ruler.cpp
 124         pv/view/signal.cpp
 125         pv/view/timemarker.cpp
 126         pv/view/view.cpp
 127         pv/view/viewport.cpp
 128 )
 129
 130 set(pulseview_HEADERS
 131         signalhandler.h
 132         pv/mainwindow.h
 133         pv/sigsession.h
 134         pv/dialogs/about.h
 135         pv/dialogs/connect.h
 136         pv/dialogs/deviceoptions.h
 137         pv/toolbars/samplingbar.h
 138         pv/view/cursor.h
 139         pv/view/header.h
 140         pv/view/ruler.h
 141         pv/view/timemarker.h
 142         pv/view/view.h
 143         pv/view/viewport.h
 144 )
 145
 146 set(pulseview_FORMS
 147         pv/dialogs/about.ui
 148 )
 149
 150 set(pulseview_RESOURCES
 151         pulseview.qrc
 152 )
 153
 154 qt4_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 155 qt4_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 156 qt4_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 157
 158 include(${QT_USE_FILE})
 159
 160 #===============================================================================
 161 #= Global Definitions
 162 #-------------------------------------------------------------------------------
 163
 164 add_definitions(${QT_DEFINITIONS})
 165 add_definitions(-Wall -Wextra)
 166
 167 if(ENABLE_SIGROKDECODE)
 168         add_definitions(-DENABLE_SIGROKDECODE)
 169 endif()
 170
 171 if(NOT DISABLE_WERROR)
 172         add_definitions(-Werror)
 173 endif()
 174
 175 #===============================================================================
 176 #= Global Include Directories
 177 #-------------------------------------------------------------------------------
 178
 179 include_directories(
 180         ${CMAKE_CURRENT_BINARY_DIR}
 181         ${CMAKE_CURRENT_SOURCE_DIR}
 182         ${Boost_INCLUDE_DIRS}
 183 )
 184
 185 if(STATIC_PKGDEPS_LIBS)
 186         include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
 187 else()
 188         include_directories(${PKGDEPS_INCLUDE_DIRS})
 189 endif()
 190
 191 #===============================================================================
 192 #= Linker Configuration
 193 #-------------------------------------------------------------------------------
 194
 195 link_directories(${Boost_LIBRARY_DIRS})
 196
 197 set(PULSEVIEW_LINK_LIBS
 198         ${Boost_LIBRARIES}
 199         ${CMAKE_THREAD_LIBS_INIT}
 200         ${QT_LIBRARIES}
 201 )
 202
 203 if(STATIC_PKGDEPS_LIBS)
 204         link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
 205         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LIBRARIES})
 206 else()
 207         link_directories(${PKGDEPS_LIBRARY_DIRS})
 208         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
 209 endif()
 210
 211 add_executable(${PROJECT_NAME}
 212         ${pulseview_SOURCES}
 213         ${pulseview_HEADERS_MOC}
 214         ${pulseview_FORMS_HEADERS}
 215         ${pulseview_RESOURCES_RCC}
 216 )
 217
 218 target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
 219
 220 #===============================================================================
 221 #= Installation
 222 #-------------------------------------------------------------------------------
 223
 224 install(TARGETS ${PROJECT_NAME} DESTINATION bin/)
 225
 226 #===============================================================================
 227 #= Packaging (handled by CPack)
 228 #-------------------------------------------------------------------------------
 229
 230 set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
 231 set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
 232 set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
 233 set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
 234 set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
 235 set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
 236 set(CPACK_SOURCE_PACKAGE_FILE_NAME
 237         "${CMAKE_PROJECT_NAME}-${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}")
 238 set(CPACK_SOURCE_GENERATOR "TGZ")
 239
 240 include(CPack)
 241
 242 #===============================================================================
 243 #= Tests
 244 #-------------------------------------------------------------------------------
 245
 246 if(ENABLE_TESTS)
 247         add_subdirectory(test)
 248         enable_testing()
 249         add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
 250 endif(ENABLE_TESTS)