CMakeLists.txt

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 2 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 cmake_minimum_required(VERSION 2.6)
  22 include(FindPkgConfig)
  23
  24 project(pulseview)
  25
  26 #===============================================================================
  27 #= User Options
  28 #-------------------------------------------------------------------------------
  29
  30 option(ENABLE_TESTS "Enable unit tests" FALSE)
  31 option(STATIC_PKGDEPS_LIBS "Statically link to sigrok libraries" FALSE)
  32
  33 if(WIN32)
  34         # On Windows/MinGW we need to statically link to libraries
  35         # This option is user configurable, but enable it by default on win32
  36         set(STATIC_PKGDEPS_LIBS TRUE)
  37 endif()
  38
  39 #===============================================================================
  40 #= Dependencies
  41 #-------------------------------------------------------------------------------
  42
  43 find_package(PkgConfig)
  44 pkg_check_modules(PKGDEPS REQUIRED
  45         libsigrokdecode>=0.1.0
  46         libsigrok>=0.2.0
  47 )
  48
  49 # On Windows/MinGW we explicitly point cmake to the Boost directory.
  50 if(WIN32)
  51         set(BOOST_ROOT /usr/local)
  52 endif(WIN32)
  53
  54 find_package(Qt4 REQUIRED)
  55 find_package(Boost 1.46 COMPONENTS unit_test_framework REQUIRED)
  56
  57 #===============================================================================
  58 #= Config Header
  59 #-------------------------------------------------------------------------------
  60
  61 set(PV_TITLE PulseView)
  62 set(PV_DESCRIPTION "A GUI for sigrok")
  63
  64 set(PV_VERSION_MAJOR 0)
  65 set(PV_VERSION_MINOR 1)
  66 set(PV_VERSION_MICRO 0)
  67 set(PV_VERSION_STRING
  68         ${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}
  69 )
  70
  71 configure_file (
  72         ${PROJECT_SOURCE_DIR}/config.h.in
  73         ${PROJECT_BINARY_DIR}/config.h
  74 )
  75
  76 #===============================================================================
  77 #= Sources
  78 #-------------------------------------------------------------------------------
  79
  80 set(pulseview_SOURCES
  81         main.cpp
  82         pv/about.cpp
  83         pv/datasnapshot.cpp
  84         pv/logicdata.cpp
  85         pv/logicdatasnapshot.cpp
  86         pv/logicsignal.cpp
  87         pv/mainwindow.cpp
  88         pv/samplingbar.cpp
  89         pv/signaldata.cpp
  90         pv/sigsession.cpp
  91         pv/signal.cpp
  92         pv/view/header.cpp
  93         pv/view/ruler.cpp
  94         pv/view/view.cpp
  95         pv/view/viewport.cpp
  96 )
  97
  98 set(pulseview_HEADERS
  99         pv/about.h
 100         pv/mainwindow.h
 101         pv/samplingbar.h
 102         pv/sigsession.h
 103         pv/view/header.h
 104         pv/view/ruler.h
 105         pv/view/view.h
 106         pv/view/viewport.h
 107 )
 108
 109 set(pulseview_FORMS
 110         pv/about.ui
 111 )
 112
 113 set(pulseview_RESOURCES
 114         pulseview.qrc
 115 )
 116
 117 set(pulseview_TEST_SOURCES
 118         pv/datasnapshot.cpp
 119         pv/logicdatasnapshot.cpp
 120         test/logicdatasnapshot.cpp
 121         test/test.cpp
 122 )
 123
 124 qt4_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 125 qt4_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 126 qt4_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 127
 128 include(${QT_USE_FILE})
 129
 130 #===============================================================================
 131 #= Global Definitions
 132 #-------------------------------------------------------------------------------
 133
 134 add_definitions(${QT_DEFINITIONS})
 135
 136 #===============================================================================
 137 #= Global Include Directories
 138 #-------------------------------------------------------------------------------
 139
 140 include_directories(
 141         ${CMAKE_CURRENT_BINARY_DIR}
 142         ${CMAKE_CURRENT_SOURCE_DIR}
 143         ${Boost_INCLUDE_DIRS}
 144 )
 145
 146 if(STATIC_PKGDEPS_LIBS)
 147         include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
 148 else()
 149         include_directories(${PKGDEPS_INCLUDE_DIRS})
 150 endif()
 151
 152 #===============================================================================
 153 #= Linker Configuration
 154 #-------------------------------------------------------------------------------
 155
 156 link_directories(${Boost_LIBRARY_DIRS})
 157
 158 set(PULSEVIEW_LINK_LIBS
 159         ${Boost_LIBRARIES}
 160         ${QT_LIBRARIES}
 161 )
 162
 163 if(STATIC_PKGDEPS_LIBS)
 164         link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
 165         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LIBRARIES})
 166 else()
 167         link_directories(${PKGDEPS_LIBRARY_DIRS})
 168         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
 169 endif()
 170
 171 add_executable(${PROJECT_NAME}
 172         ${pulseview_SOURCES}
 173         ${pulseview_HEADERS_MOC}
 174         ${pulseview_FORMS_HEADERS}
 175         ${pulseview_RESOURCES_RCC}
 176 )
 177
 178 target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
 179
 180 #===============================================================================
 181 #= Installation
 182 #-------------------------------------------------------------------------------
 183
 184 install(PROGRAMS ${PROJECT_NAME} DESTINATION bin/)
 185
 186 #===============================================================================
 187 #= Tests
 188 #-------------------------------------------------------------------------------
 189
 190 if(ENABLE_TESTS)
 191
 192         add_definitions(pulseview-tests
 193                 -DBOOST_TEST_DYN_LINK
 194         )
 195
 196         add_executable(pulseview-test
 197                 ${pulseview_TEST_SOURCES}
 198         )
 199
 200         target_link_libraries(pulseview-test ${PULSEVIEW_LINK_LIBS})
 201
 202         enable_testing()
 203         add_test(test ${CMAKE_CURRENT_BINARY_DIR}/pulseview-test)
 204
 205 endif(ENABLE_TESTS)