CMakeLists.txt

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
   5 ## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 2 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 cmake_minimum_required(VERSION 2.8.12)
  22
  23 include(GNUInstallDirs)
  24
  25 project(pulseview)
  26
  27 list(APPEND CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/CMake")
  28
  29 #===============================================================================
  30 #= User Options
  31 #-------------------------------------------------------------------------------
  32
  33 option(DISABLE_WERROR "Build without -Werror" FALSE)
  34 option(ENABLE_SIGNALS "Build with UNIX signals" TRUE)
  35 option(ENABLE_STACKTRACE "Enable stack trace when crashing" FALSE)
  36 option(ENABLE_DECODE "Build with libsigrokdecode" TRUE)
  37 option(ENABLE_TESTS "Enable unit tests" TRUE)
  38 option(STATIC_PKGDEPS_LIBS "Statically link to (pkg-config) libraries" FALSE)
  39
  40 if(WIN32)
  41         # On Windows/MinGW we need to statically link to libraries.
  42         # This option is user configurable, but enable it by default on win32.
  43         set(STATIC_PKGDEPS_LIBS TRUE)
  44
  45         # Windows does not support UNIX signals.
  46         set(ENABLE_SIGNALS FALSE)
  47 endif()
  48
  49 if(NOT CMAKE_BUILD_TYPE)
  50         set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
  51         "Choose the type of build (None, Debug, Release, RelWithDebInfo, MinSizeRel)."
  52         FORCE)
  53 endif()
  54
  55 #===============================================================================
  56 #= Dependencies
  57 #-------------------------------------------------------------------------------
  58
  59 list(APPEND PKGDEPS glib-2.0>=2.28.0)
  60 list(APPEND PKGDEPS glibmm-2.4>=2.28.0)
  61
  62 list(APPEND PKGDEPS libsigrokcxx>=0.6.0)
  63
  64 if(ENABLE_DECODE)
  65         list(APPEND PKGDEPS libsigrokdecode>=0.6.0)
  66 endif()
  67
  68 if(ANDROID)
  69         list(APPEND PKGDEPS libsigrokandroidutils>=0.1.0)
  70 endif()
  71
  72 find_package(PkgConfig)
  73 pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})
  74
  75 set(CMAKE_AUTOMOC TRUE)
  76
  77 find_package(Qt5 COMPONENTS Core Gui Widgets Svg REQUIRED)
  78
  79 if(WIN32)
  80         # MXE workaround: Use pkg-config to find Qt5 libs.
  81         # https://github.com/mxe/mxe/issues/1642
  82         # Not required (and doesn't work) on MSYS2.
  83         if(NOT DEFINED ENV{MSYSTEM})
  84                 pkg_check_modules(QT5ALL REQUIRED Qt5Widgets Qt5Gui Qt5Svg)
  85         endif()
  86 endif()
  87
  88 set(QT_LIBRARIES Qt5::Gui Qt5::Widgets Qt5::Svg)
  89
  90 set(BOOSTCOMPS filesystem serialization system)
  91 if(ENABLE_TESTS)
  92         list(APPEND BOOSTCOMPS unit_test_framework)
  93 endif()
  94
  95 if(ENABLE_STACKTRACE)
  96         find_package(Boost 1.65.1 COMPONENTS ${BOOSTCOMPS} REQUIRED)
  97 else()
  98         find_package(Boost 1.55 COMPONENTS ${BOOSTCOMPS} REQUIRED)
  99 endif()
 100
 101 # Find the platform's thread library (needed for C++11 threads).
 102 # This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
 103 find_package(Threads REQUIRED)
 104
 105 # Check for explicit link against libatomic
 106 #
 107 # Depending on the toolchain, linking a program using atomic functions may need
 108 # "-latomic" explicitly passed to the linker
 109 #
 110 # This check first tests if atomics are available in the C-library, if not and
 111 # libatomic exists, then it runs the same test with -latomic added to the
 112 # linker flags.
 113
 114 # Helper for checking for atomics
 115 function(check_working_cxx_atomics varname additional_lib)
 116   include(CheckCXXSourceCompiles)
 117   include(CMakePushCheckState)
 118   cmake_push_check_state()
 119   set(CMAKE_REQUIRED_FLAGS "-std=c++11")
 120   set(CMAKE_REQUIRED_LIBRARIES "${additional_lib}")
 121   set(CMAKE_REQUIRED_QUIET 1)
 122   CHECK_CXX_SOURCE_COMPILES("
 123 #include <atomic>
 124 std::atomic<int> x;
 125 int main() {
 126   return std::atomic_fetch_add_explicit(&x, 1, std::memory_order_seq_cst);
 127 }
 128 " ${varname})
 129   cmake_pop_check_state()
 130 endfunction(check_working_cxx_atomics)
 131
 132 # First check if atomics work without the library.
 133 # If not, check if the library exists, and atomics work with it.
 134 check_working_cxx_atomics(HAVE_CXX_ATOMICS_WITHOUT_LIB "")
 135 if(HAVE_CXX_ATOMICS_WITHOUT_LIB)
 136   message(STATUS "Atomics provided by the C-library - yes")
 137 else()
 138   message(STATUS "Atomics provided by the C-library - no")
 139   find_library(LIBATOMIC_LIBRARY NAMES atomic PATH_SUFFIXES lib)
 140   if(LIBATOMIC_LIBRARY)
 141     check_working_cxx_atomics(HAVE_CXX_ATOMICS_WITH_LIB "${LIBATOMIC_LIBRARY}")
 142     if (HAVE_CXX_ATOMICS_WITH_LIB)
 143       message(STATUS "Atomics provided by libatomic - yes")
 144     else()
 145       message(STATUS "Atomics provided by libatomic - no")
 146       message(FATAL_ERROR "Compiler must support std::atomic!")
 147     endif()
 148   else()
 149     message(FATAL_ERROR "Compiler appears to require libatomic, but cannot find it.")
 150   endif()
 151 endif()
 152
 153 #===============================================================================
 154 #= System Introspection
 155 #-------------------------------------------------------------------------------
 156
 157 include(memaccess)
 158 memaccess_check_unaligned_le(HAVE_UNALIGNED_LITTLE_ENDIAN_ACCESS)
 159
 160 #===============================================================================
 161 #= Config Header
 162 #-------------------------------------------------------------------------------
 163
 164 set(PV_TITLE PulseView)
 165 set(PV_VERSION_STRING "0.5.0")
 166
 167 set(PV_GLIBMM_VERSION ${PKGDEPS_glibmm-2.4_VERSION})
 168
 169 include(GetGitRevisionDescription)
 170
 171 # Append the revision hash unless we are exactly on a tagged release.
 172 git_describe(PV_TAG_VERSION_STRING --match "pulseview-${PV_VERSION_STRING}" --exact-match)
 173 if(NOT PV_TAG_VERSION_STRING)
 174         get_git_head_revision(PV_REVSPEC PV_HASH)
 175         if(PV_HASH)
 176                 string(SUBSTRING "${PV_HASH}" 0 7 PV_SHORTHASH)
 177                 set(PV_VERSION_STRING "${PV_VERSION_STRING}-git-${PV_SHORTHASH}")
 178         endif()
 179 endif()
 180
 181 if(PV_VERSION_STRING MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+)(-[-0-9a-z]*)?$")
 182         set(PV_VERSION_MAJOR ${CMAKE_MATCH_1})
 183         set(PV_VERSION_MINOR ${CMAKE_MATCH_2})
 184         set(PV_VERSION_MICRO ${CMAKE_MATCH_3})
 185         set(PV_VERSION_SUFFIX ${CMAKE_MATCH_4})
 186 endif()
 187
 188 message("-- ${PV_TITLE} version: ${PV_VERSION_STRING}")
 189
 190 configure_file (
 191         ${PROJECT_SOURCE_DIR}/config.h.in
 192         ${PROJECT_BINARY_DIR}/config.h
 193 )
 194
 195 #===============================================================================
 196 #= Sources
 197 #-------------------------------------------------------------------------------
 198
 199 set(pulseview_SOURCES
 200         main.cpp
 201         pv/application.cpp
 202         pv/devicemanager.cpp
 203         pv/globalsettings.cpp
 204         pv/mainwindow.cpp
 205         pv/session.cpp
 206         pv/storesession.cpp
 207         pv/util.cpp
 208         pv/binding/binding.cpp
 209         pv/binding/inputoutput.cpp
 210         pv/binding/device.cpp
 211         pv/data/analog.cpp
 212         pv/data/analogsegment.cpp
 213         pv/data/logic.cpp
 214         pv/data/logicsegment.cpp
 215         pv/data/signalbase.cpp
 216         pv/data/signaldata.cpp
 217         pv/data/segment.cpp
 218         pv/devices/device.cpp
 219         pv/devices/file.cpp
 220         pv/devices/hardwaredevice.cpp
 221         pv/devices/inputfile.cpp
 222         pv/devices/sessionfile.cpp
 223         pv/dialogs/connect.cpp
 224         pv/dialogs/inputoutputoptions.cpp
 225         pv/dialogs/settings.cpp
 226         pv/dialogs/storeprogress.cpp
 227         pv/popups/deviceoptions.cpp
 228         pv/popups/channels.cpp
 229         pv/prop/bool.cpp
 230         pv/prop/double.cpp
 231         pv/prop/enum.cpp
 232         pv/prop/int.cpp
 233         pv/prop/property.cpp
 234         pv/prop/string.cpp
 235         pv/toolbars/mainbar.cpp
 236         pv/views/trace/analogsignal.cpp
 237         pv/views/trace/cursor.cpp
 238         pv/views/trace/cursorpair.cpp
 239         pv/views/trace/flag.cpp
 240         pv/views/trace/header.cpp
 241         pv/views/trace/marginwidget.cpp
 242         pv/views/trace/logicsignal.cpp
 243         pv/views/trace/rowitem.cpp
 244         pv/views/trace/ruler.cpp
 245         pv/views/trace/signal.cpp
 246         pv/views/trace/timeitem.cpp
 247         pv/views/trace/timemarker.cpp
 248         pv/views/trace/trace.cpp
 249         pv/views/trace/tracegroup.cpp
 250         pv/views/trace/tracepalette.cpp
 251         pv/views/trace/tracetreeitem.cpp
 252         pv/views/trace/tracetreeitemowner.cpp
 253         pv/views/trace/triggermarker.cpp
 254         pv/views/trace/view.cpp
 255         pv/views/trace/viewitem.cpp
 256         pv/views/trace/viewitemowner.cpp
 257         pv/views/trace/viewitempaintparams.cpp
 258         pv/views/trace/viewport.cpp
 259         pv/views/trace/viewwidget.cpp
 260         pv/views/viewbase.cpp
 261         pv/views/trace/standardbar.cpp
 262         pv/widgets/colourbutton.cpp
 263         pv/widgets/colourpopup.cpp
 264         pv/widgets/devicetoolbutton.cpp
 265         pv/widgets/exportmenu.cpp
 266         pv/widgets/importmenu.cpp
 267         pv/widgets/popup.cpp
 268         pv/widgets/popuptoolbutton.cpp
 269         pv/widgets/sweeptimingwidget.cpp
 270         pv/widgets/timestampspinbox.cpp
 271         pv/widgets/wellarray.cpp
 272 )
 273
 274 # This list includes only QObject derived class headers.
 275 set(pulseview_HEADERS
 276         pv/globalsettings.hpp
 277         pv/mainwindow.hpp
 278         pv/session.hpp
 279         pv/storesession.hpp
 280         pv/binding/device.hpp
 281         pv/data/analog.hpp
 282         pv/data/analogsegment.hpp
 283         pv/data/logic.hpp
 284         pv/data/logicsegment.hpp
 285         pv/data/signalbase.hpp
 286         pv/dialogs/connect.hpp
 287         pv/dialogs/inputoutputoptions.hpp
 288         pv/dialogs/settings.hpp
 289         pv/dialogs/storeprogress.hpp
 290         pv/popups/channels.hpp
 291         pv/popups/deviceoptions.hpp
 292         pv/prop/bool.hpp
 293         pv/prop/double.hpp
 294         pv/prop/enum.hpp
 295         pv/prop/int.hpp
 296         pv/prop/property.hpp
 297         pv/prop/string.hpp
 298         pv/toolbars/mainbar.hpp
 299         pv/views/trace/analogsignal.hpp
 300         pv/views/trace/cursor.hpp
 301         pv/views/trace/flag.hpp
 302         pv/views/trace/header.hpp
 303         pv/views/trace/logicsignal.hpp
 304         pv/views/trace/marginwidget.hpp
 305         pv/views/trace/rowitem.hpp
 306         pv/views/trace/ruler.hpp
 307         pv/views/trace/signal.hpp
 308         pv/views/trace/timeitem.hpp
 309         pv/views/trace/timemarker.hpp
 310         pv/views/trace/trace.hpp
 311         pv/views/trace/tracegroup.hpp
 312         pv/views/trace/tracetreeitem.hpp
 313         pv/views/trace/triggermarker.hpp
 314         pv/views/trace/view.hpp
 315         pv/views/trace/viewitem.hpp
 316         pv/views/trace/viewport.hpp
 317         pv/views/trace/viewwidget.hpp
 318         pv/views/viewbase.hpp
 319         pv/views/trace/standardbar.hpp
 320         pv/widgets/colourbutton.hpp
 321         pv/widgets/colourpopup.hpp
 322         pv/widgets/devicetoolbutton.hpp
 323         pv/widgets/exportmenu.hpp
 324         pv/widgets/importmenu.hpp
 325         pv/widgets/popup.hpp
 326         pv/widgets/popuptoolbutton.hpp
 327         pv/widgets/sweeptimingwidget.hpp
 328         pv/widgets/timestampspinbox.hpp
 329         pv/widgets/wellarray.hpp
 330 )
 331
 332 set(pulseview_RESOURCES
 333         pulseview.qrc
 334 )
 335
 336 if(ENABLE_SIGNALS)
 337         list(APPEND pulseview_SOURCES signalhandler.cpp)
 338         list(APPEND pulseview_HEADERS signalhandler.hpp)
 339 endif()
 340
 341 if(ENABLE_DECODE)
 342         list(APPEND pulseview_SOURCES
 343                 pv/binding/decoder.cpp
 344                 pv/data/decodesignal.cpp
 345                 pv/data/decode/annotation.cpp
 346                 pv/data/decode/decoder.cpp
 347                 pv/data/decode/row.cpp
 348                 pv/data/decode/rowdata.cpp
 349                 pv/views/trace/decodetrace.cpp
 350                 pv/widgets/decodergroupbox.cpp
 351                 pv/widgets/decodermenu.cpp
 352         )
 353
 354         list(APPEND pulseview_HEADERS
 355                 pv/data/decodesignal.hpp
 356                 pv/views/trace/decodetrace.hpp
 357                 pv/widgets/decodergroupbox.hpp
 358                 pv/widgets/decodermenu.hpp
 359         )
 360 endif()
 361
 362 if(WIN32)
 363         # Use the sigrok icon for the pulseview.exe executable.
 364         set(CMAKE_RC_COMPILE_OBJECT "${CMAKE_RC_COMPILER} -O coff -I${CMAKE_CURRENT_SOURCE_DIR} <SOURCE> <OBJECT>")
 365         enable_language(RC)
 366         list(APPEND pulseview_SOURCES pulseviewico.rc)
 367 endif()
 368
 369 if(ANDROID)
 370         list(APPEND pulseview_SOURCES
 371                 android/assetreader.cpp
 372                 android/loghandler.cpp
 373         )
 374 endif()
 375
 376 qt5_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 377
 378 #===============================================================================
 379 #= Global Definitions
 380 #-------------------------------------------------------------------------------
 381
 382 add_definitions(-DQT_NO_KEYWORDS)
 383 add_definitions(-D__STDC_LIMIT_MACROS)
 384 add_definitions(-Wall -Wextra)
 385 add_definitions(-std=c++11)
 386 add_definitions(-DBOOST_MATH_DISABLE_FLOAT128=1)
 387
 388 if(ENABLE_DECODE)
 389         add_definitions(-DENABLE_DECODE)
 390 endif()
 391
 392 if(NOT DISABLE_WERROR)
 393         add_definitions(-Werror)
 394 endif()
 395
 396 if(ENABLE_SIGNALS)
 397         add_definitions(-DENABLE_SIGNALS)
 398 endif()
 399
 400 if(ENABLE_STACKTRACE)
 401         add_definitions(-DENABLE_STACKTRACE)
 402 endif()
 403
 404 #===============================================================================
 405 #= Global Include Directories
 406 #-------------------------------------------------------------------------------
 407
 408 include_directories(
 409         ${CMAKE_CURRENT_BINARY_DIR}
 410         ${CMAKE_CURRENT_SOURCE_DIR}
 411         ${Boost_INCLUDE_DIRS}
 412 )
 413
 414 if(STATIC_PKGDEPS_LIBS)
 415         include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
 416 else()
 417         include_directories(${PKGDEPS_INCLUDE_DIRS})
 418 endif()
 419
 420 #===============================================================================
 421 #= Linker Configuration
 422 #-------------------------------------------------------------------------------
 423
 424 link_directories(${Boost_LIBRARY_DIRS})
 425
 426 set(PULSEVIEW_LINK_LIBS
 427         ${Boost_LIBRARIES}
 428         ${QT_LIBRARIES}
 429         ${CMAKE_THREAD_LIBS_INIT}
 430         ${LIBATOMIC_LIBRARY}
 431 )
 432
 433 if(STATIC_PKGDEPS_LIBS)
 434         link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
 435         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LDFLAGS})
 436 else()
 437         link_directories(${PKGDEPS_LIBRARY_DIRS})
 438         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
 439 endif()
 440
 441 if(WIN32)
 442         # On Windows we need to statically link the libqsvg imageformat
 443         # plugin (and the QtSvg component) for SVG graphics/icons to work.
 444         # We also need QWindowsIntegrationPlugin, Qt5PlatformSupport (only for
 445         # Qt < 5.8.0), and all Qt libs and their dependencies.
 446         add_definitions(-DQT_STATICPLUGIN)
 447         list(APPEND PULSEVIEW_LINK_LIBS Qt5::QSvgPlugin)
 448         list(APPEND PULSEVIEW_LINK_LIBS Qt5::QWindowsIntegrationPlugin)
 449         if(Qt5Gui_VERSION VERSION_LESS 5.8.0)
 450                 list(APPEND PULSEVIEW_LINK_LIBS -lQt5PlatformSupport)
 451         endif()
 452         list(APPEND PULSEVIEW_LINK_LIBS ${QT5ALL_LDFLAGS})
 453 endif()
 454
 455 if(ENABLE_STACKTRACE)
 456         # Needed to resolve dladdr.
 457         list(APPEND PULSEVIEW_LINK_LIBS "-ldl")
 458 endif()
 459
 460 if(ANDROID)
 461         list(APPEND PULSEVIEW_LINK_LIBS "-llog")
 462 endif()
 463
 464 if(ANDROID)
 465         add_library(${PROJECT_NAME} SHARED ${pulseview_SOURCES} ${pulseview_RESOURCES_RCC})
 466 else()
 467         add_executable(${PROJECT_NAME} ${pulseview_SOURCES} ${pulseview_RESOURCES_RCC})
 468 endif()
 469
 470 target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
 471
 472 if(WIN32 AND NOT ${CMAKE_BUILD_TYPE} STREQUAL "Debug")
 473         # Pass -mwindows so that no "DOS box" opens when PulseView is started.
 474         set_target_properties(${PROJECT_NAME} PROPERTIES LINK_FLAGS "-mwindows")
 475 endif()
 476
 477 #===============================================================================
 478 #= Installation
 479 #-------------------------------------------------------------------------------
 480
 481 # Install the executable.
 482 install(TARGETS ${PROJECT_NAME} DESTINATION bin/)
 483
 484 # Install the manpage.
 485 install(FILES doc/pulseview.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1 COMPONENT doc)
 486
 487 # Install the desktop file.
 488 install(FILES contrib/org.sigrok.PulseView.desktop DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/applications)
 489
 490 # Install the AppData/AppStream file.
 491 install(FILES contrib/org.sigrok.PulseView.appdata.xml DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/metainfo)
 492
 493 # Install the PulseView icons.
 494 install(FILES icons/pulseview.png DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/icons/hicolor/48x48/apps)
 495 install(FILES icons/pulseview.svg DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/icons/hicolor/scalable/apps)
 496
 497 # Generate Windows installer script.
 498 configure_file(contrib/pulseview_cross.nsi.in contrib/pulseview_cross.nsi @ONLY)
 499
 500 #===============================================================================
 501 #= Packaging (handled by CPack)
 502 #-------------------------------------------------------------------------------
 503
 504 set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
 505 set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
 506 set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
 507 set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
 508 set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
 509 set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
 510 set(CPACK_SOURCE_PACKAGE_FILE_NAME "${CMAKE_PROJECT_NAME}-${PV_VERSION_STRING}")
 511 set(CPACK_SOURCE_GENERATOR "TGZ")
 512
 513 include(CPack)
 514
 515 #===============================================================================
 516 #= Tests
 517 #-------------------------------------------------------------------------------
 518
 519 if(ENABLE_TESTS)
 520         add_subdirectory(test)
 521         enable_testing()
 522         add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
 523 endif()