CMakeLists.txt

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 2 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 cmake_minimum_required(VERSION 2.6)
  22 include(FindPkgConfig)
  23
  24 project(pulseview)
  25
  26 #===============================================================================
  27 #= User Options
  28 #-------------------------------------------------------------------------------
  29
  30 option(ENABLE_TESTS "Enable unit tests" FALSE)
  31 option(STATIC_PKGDEPS_LIBS "Statically link to sigrok libraries" FALSE)
  32
  33 if(WIN32)
  34         # On Windows/MinGW we need to statically link to libraries
  35         # This option is user configurable, but enable it by default on win32
  36         set(STATIC_PKGDEPS_LIBS TRUE)
  37 endif()
  38
  39 #===============================================================================
  40 #= Dependencies
  41 #-------------------------------------------------------------------------------
  42
  43 find_package(PkgConfig)
  44 pkg_check_modules(PKGDEPS REQUIRED
  45         libsigrokdecode>=0.1.0
  46         libsigrok>=0.2.0
  47 )
  48
  49 # On Windows/MinGW we explicitly point cmake to the Boost directory.
  50 if(WIN32)
  51         set(BOOST_ROOT /usr/local)
  52 endif(WIN32)
  53
  54 find_package(Qt4 REQUIRED)
  55 find_package(Boost 1.46 COMPONENTS unit_test_framework REQUIRED)
  56
  57 set(VERSION 0.1.0)
  58
  59 #===============================================================================
  60 #= Sources
  61 #-------------------------------------------------------------------------------
  62
  63 set(pulseview_SOURCES
  64         main.cpp
  65         pv/about.cpp
  66         pv/datasnapshot.cpp
  67         pv/logicdata.cpp
  68         pv/logicdatasnapshot.cpp
  69         pv/logicsignal.cpp
  70         pv/mainwindow.cpp
  71         pv/samplingbar.cpp
  72         pv/signaldata.cpp
  73         pv/sigsession.cpp
  74         pv/signal.cpp
  75         pv/view/header.cpp
  76         pv/view/ruler.cpp
  77         pv/view/view.cpp
  78         pv/view/viewport.cpp
  79 )
  80
  81 set(pulseview_HEADERS
  82         pv/about.h
  83         pv/mainwindow.h
  84         pv/samplingbar.h
  85         pv/sigsession.h
  86         pv/view/header.h
  87         pv/view/ruler.h
  88         pv/view/view.h
  89         pv/view/viewport.h
  90 )
  91
  92 set(pulseview_FORMS
  93         pv/about.ui
  94 )
  95
  96 set(pulseview_RESOURCES
  97         pulseview.qrc
  98 )
  99
 100 set(pulseview_TEST_SOURCES
 101         pv/datasnapshot.cpp
 102         pv/logicdatasnapshot.cpp
 103         test/logicdatasnapshot.cpp
 104         test/test.cpp
 105 )
 106
 107 qt4_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 108 qt4_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 109 qt4_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 110
 111 include(${QT_USE_FILE})
 112
 113 #===============================================================================
 114 #= Global Definitions
 115 #-------------------------------------------------------------------------------
 116
 117 add_definitions(${QT_DEFINITIONS})
 118 add_definitions(-DAPP_VERSION="${VERSION}")
 119
 120 #===============================================================================
 121 #= Global Include Directories
 122 #-------------------------------------------------------------------------------
 123
 124 include_directories(
 125         ${CMAKE_CURRENT_BINARY_DIR}
 126         ${Boost_INCLUDE_DIRS}
 127 )
 128
 129 if(STATIC_PKGDEPS_LIBS)
 130         include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
 131 else()
 132         include_directories(${PKGDEPS_INCLUDE_DIRS})
 133 endif()
 134
 135 #===============================================================================
 136 #= Linker Configuration
 137 #-------------------------------------------------------------------------------
 138
 139 link_directories(${Boost_LIBRARY_DIRS})
 140
 141 set(PULSEVIEW_LINK_LIBS
 142         ${Boost_LIBRARIES}
 143         ${QT_LIBRARIES}
 144 )
 145
 146 if(STATIC_PKGDEPS_LIBS)
 147         link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
 148         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LIBRARIES})
 149 else()
 150         link_directories(${PKGDEPS_LIBRARY_DIRS})
 151         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
 152 endif()
 153
 154 add_executable(pulseview
 155         ${pulseview_SOURCES}
 156         ${pulseview_HEADERS_MOC}
 157         ${pulseview_FORMS_HEADERS}
 158         ${pulseview_RESOURCES_RCC}
 159 )
 160
 161 target_link_libraries(pulseview ${PULSEVIEW_LINK_LIBS})
 162
 163 #===============================================================================
 164 #= Installation
 165 #-------------------------------------------------------------------------------
 166
 167 install(PROGRAMS pulseview DESTINATION bin/)
 168
 169 #===============================================================================
 170 #= Tests
 171 #-------------------------------------------------------------------------------
 172
 173 if(ENABLE_TESTS)
 174
 175         add_definitions(-DBOOST_TEST_DYN_LINK)
 176
 177         add_executable(pulseview-test
 178                 ${pulseview_TEST_SOURCES}
 179         )
 180
 181         target_link_libraries(pulseview-test ${PULSEVIEW_LINK_LIBS})
 182
 183         enable_testing()
 184         add_test(test ${CMAKE_CURRENT_BINARY_DIR}/pulseview-test)
 185
 186 endif(ENABLE_TESTS)