CMakeLists.txt

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
   5 ## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 2 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 cmake_minimum_required(VERSION 2.8.6)
  22
  23 include(FindPkgConfig)
  24 include(GNUInstallDirs)
  25
  26 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/CMake")
  27
  28 project(pulseview)
  29
  30 #===============================================================================
  31 #= User Options
  32 #-------------------------------------------------------------------------------
  33
  34 option(DISABLE_WERROR "Build without -Werror" FALSE)
  35 option(ENABLE_SIGNALS "Build with UNIX signals" TRUE)
  36 option(ENABLE_DECODE "Build with libsigrokdecode" TRUE)
  37 option(ENABLE_COTIRE "Enable cotire" FALSE)
  38 option(ENABLE_TESTS "Enable unit tests" FALSE)
  39 option(STATIC_PKGDEPS_LIBS "Statically link to (pkg-config) libraries" FALSE)
  40 option(FORCE_QT4 "Force use of Qt4 even if Qt5 is available" FALSE)
  41
  42 if(WIN32)
  43         # On Windows/MinGW we need to statically link to libraries.
  44         # This option is user configurable, but enable it by default on win32.
  45         set(STATIC_PKGDEPS_LIBS TRUE)
  46
  47         # Windows does not support UNIX signals.
  48         set(ENABLE_SIGNALS FALSE)
  49 endif()
  50
  51 if(NOT CMAKE_BUILD_TYPE)
  52   set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
  53       "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  54       FORCE)
  55 endif()
  56
  57 #===============================================================================
  58 #= Dependencies
  59 #-------------------------------------------------------------------------------
  60
  61 list(APPEND PKGDEPS libsigrok>=0.3.0)
  62
  63 if(ENABLE_DECODE)
  64         list(APPEND PKGDEPS libsigrokdecode>=0.3.0)
  65 endif()
  66
  67 if(ANDROID)
  68         list(APPEND PKGDEPS libsigrokandroidutils>=0.1.0)
  69 endif()
  70
  71 find_package(PkgConfig)
  72 pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})
  73
  74 if(FORCE_QT4)
  75         set(Qt5Core_FOUND FALSE)
  76 else()
  77         find_package(Qt5Core QUIET)
  78 endif()
  79
  80 if(Qt5Core_FOUND)
  81         message("-- Using Qt5")
  82         find_package(Qt5Widgets REQUIRED)
  83         find_package(Qt5Gui REQUIRED)
  84         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${Qt5Widgets_EXECUTABLE_COMPILE_FLAGS}")
  85         set(QT_INCLUDE_DIRS ${Qt5Gui_INCLUDE_DIRS} ${Qt5Widgets_INCLUDE_DIRS})
  86         set(QT_LIBRARIES Qt5::Gui Qt5::Widgets)
  87         add_definitions(${Qt5Gui_DEFINITIONS} ${Qt5Widgets_DEFINITIONS})
  88 else()
  89         find_program(QT_QMAKE_EXECUTABLE NAMES qmake4 qmake-qt4 qmake-mac)
  90         find_package(Qt4 REQUIRED)
  91 endif()
  92
  93 find_package(Boost 1.42 COMPONENTS filesystem system REQUIRED)
  94
  95 #===============================================================================
  96 #= System Introspection
  97 #-------------------------------------------------------------------------------
  98
  99 include(memaccess)
 100 memaccess_check_unaligned_le(HAVE_UNALIGNED_LITTLE_ENDIAN_ACCESS)
 101
 102 #===============================================================================
 103 #= Config Header
 104 #-------------------------------------------------------------------------------
 105
 106 set(PV_TITLE PulseView)
 107 set(PV_DESCRIPTION "A GUI for sigrok")
 108
 109 set(PV_VERSION_MAJOR 0)
 110 set(PV_VERSION_MINOR 2)
 111 set(PV_VERSION_MICRO 0)
 112 set(PV_VERSION_STRING
 113         ${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}
 114 )
 115
 116 configure_file (
 117         ${PROJECT_SOURCE_DIR}/config.h.in
 118         ${PROJECT_BINARY_DIR}/config.h
 119 )
 120
 121 #===============================================================================
 122 #= Sources
 123 #-------------------------------------------------------------------------------
 124
 125 set(pulseview_SOURCES
 126         main.cpp
 127         pv/devicemanager.cpp
 128         pv/mainwindow.cpp
 129         pv/sigsession.cpp
 130         pv/storesession.cpp
 131         pv/util.cpp
 132         pv/data/analog.cpp
 133         pv/data/analogsnapshot.cpp
 134         pv/data/logic.cpp
 135         pv/data/logicsnapshot.cpp
 136         pv/data/signaldata.cpp
 137         pv/data/snapshot.cpp
 138         pv/device/device.cpp
 139         pv/device/file.cpp
 140         pv/device/devinst.cpp
 141         pv/device/sessionfile.cpp
 142         pv/dialogs/about.cpp
 143         pv/dialogs/connect.cpp
 144         pv/dialogs/storeprogress.cpp
 145         pv/popups/deviceoptions.cpp
 146         pv/popups/probes.cpp
 147         pv/prop/bool.cpp
 148         pv/prop/double.cpp
 149         pv/prop/enum.cpp
 150         pv/prop/int.cpp
 151         pv/prop/property.cpp
 152         pv/prop/string.cpp
 153         pv/prop/binding/binding.cpp
 154         pv/prop/binding/deviceoptions.cpp
 155         pv/toolbars/samplingbar.cpp
 156         pv/view/analogsignal.cpp
 157         pv/view/cursor.cpp
 158         pv/view/cursorheader.cpp
 159         pv/view/cursorpair.cpp
 160         pv/view/header.cpp
 161         pv/view/marginwidget.cpp
 162         pv/view/logicsignal.cpp
 163         pv/view/ruler.cpp
 164         pv/view/selectableitem.cpp
 165         pv/view/signal.cpp
 166         pv/view/timemarker.cpp
 167         pv/view/trace.cpp
 168         pv/view/tracepalette.cpp
 169         pv/view/view.cpp
 170         pv/view/viewport.cpp
 171         pv/widgets/colourbutton.cpp
 172         pv/widgets/colourpopup.cpp
 173         pv/widgets/popup.cpp
 174         pv/widgets/popuptoolbutton.cpp
 175         pv/widgets/sweeptimingwidget.cpp
 176         pv/widgets/wellarray.cpp
 177 )
 178
 179 # This list includes only QObject derived class headers.
 180 set(pulseview_HEADERS
 181         pv/mainwindow.h
 182         pv/sigsession.h
 183         pv/storesession.h
 184         pv/device/devinst.h
 185         pv/dialogs/about.h
 186         pv/dialogs/connect.h
 187         pv/dialogs/storeprogress.h
 188         pv/popups/probes.h
 189         pv/popups/deviceoptions.h
 190         pv/prop/bool.h
 191         pv/prop/double.h
 192         pv/prop/enum.h
 193         pv/prop/int.h
 194         pv/prop/property.h
 195         pv/prop/string.h
 196         pv/toolbars/samplingbar.h
 197         pv/view/cursor.h
 198         pv/view/cursorheader.h
 199         pv/view/header.h
 200         pv/view/logicsignal.h
 201         pv/view/marginwidget.h
 202         pv/view/ruler.h
 203         pv/view/selectableitem.h
 204         pv/view/signal.h
 205         pv/view/timemarker.h
 206         pv/view/trace.h
 207         pv/view/view.h
 208         pv/view/viewport.h
 209         pv/widgets/colourbutton.h
 210         pv/widgets/colourpopup.h
 211         pv/widgets/popup.h
 212         pv/widgets/popuptoolbutton.h
 213         pv/widgets/sweeptimingwidget.h
 214         pv/widgets/wellarray.h
 215 )
 216
 217 set(pulseview_FORMS
 218         pv/dialogs/about.ui
 219 )
 220
 221 set(pulseview_RESOURCES
 222         pulseview.qrc
 223 )
 224
 225 if(ENABLE_SIGNALS)
 226         list(APPEND pulseview_SOURCES signalhandler.cpp)
 227         list(APPEND pulseview_HEADERS signalhandler.h)
 228 endif()
 229
 230 if(ENABLE_DECODE)
 231         list(APPEND pulseview_SOURCES
 232                 pv/data/decoderstack.cpp
 233                 pv/data/decode/annotation.cpp
 234                 pv/data/decode/decoder.cpp
 235                 pv/data/decode/row.cpp
 236                 pv/data/decode/rowdata.cpp
 237                 pv/prop/binding/decoderoptions.cpp
 238                 pv/view/decodetrace.cpp
 239                 pv/widgets/decodergroupbox.cpp
 240                 pv/widgets/decodermenu.cpp
 241         )
 242
 243         list(APPEND pulseview_HEADERS
 244                 pv/data/decoderstack.h
 245                 pv/view/decodetrace.h
 246                 pv/widgets/decodergroupbox.h
 247                 pv/widgets/decodermenu.h
 248         )
 249 endif()
 250
 251 if(WIN32)
 252         # Use the sigrok icon for the pulseview.exe executable.
 253         set(CMAKE_RC_COMPILE_OBJECT "${CMAKE_RC_COMPILER} -O coff -I${CMAKE_CURRENT_SOURCE_DIR} <SOURCE> <OBJECT>")
 254         enable_language(RC)
 255         list(APPEND pulseview_SOURCES pulseviewico.rc)
 256 endif()
 257
 258 if(ANDROID)
 259         list(APPEND pulseview_SOURCES android/loghandler.cpp)
 260 endif()
 261
 262 if(Qt5Core_FOUND)
 263         qt5_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 264         qt5_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 265         qt5_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 266 else()
 267         qt4_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 268         qt4_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 269         qt4_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 270         include(${QT_USE_FILE})
 271 endif()
 272
 273 #===============================================================================
 274 #= Global Definitions
 275 #-------------------------------------------------------------------------------
 276
 277 add_definitions(${QT_DEFINITIONS} -DQT_NO_KEYWORDS)
 278 add_definitions(-D__STDC_LIMIT_MACROS)
 279 add_definitions(-Wall -Wextra)
 280 add_definitions(-std=c++11)
 281
 282 if(ENABLE_DECODE)
 283         add_definitions(-DENABLE_DECODE)
 284 endif()
 285
 286 if(NOT DISABLE_WERROR)
 287         add_definitions(-Werror)
 288 endif()
 289
 290 if(ENABLE_SIGNALS)
 291         add_definitions(-DENABLE_SIGNALS)
 292 endif()
 293
 294 #===============================================================================
 295 #= Global Include Directories
 296 #-------------------------------------------------------------------------------
 297
 298 include_directories(
 299         ${CMAKE_CURRENT_BINARY_DIR}
 300         ${CMAKE_CURRENT_SOURCE_DIR}
 301         ${Boost_INCLUDE_DIRS}
 302         ${QT_INCLUDE_DIRS}
 303 )
 304
 305 if(STATIC_PKGDEPS_LIBS)
 306         include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
 307 else()
 308         include_directories(${PKGDEPS_INCLUDE_DIRS})
 309 endif()
 310
 311 #===============================================================================
 312 #= Linker Configuration
 313 #-------------------------------------------------------------------------------
 314
 315 link_directories(${Boost_LIBRARY_DIRS})
 316
 317 set(PULSEVIEW_LINK_LIBS
 318         ${Boost_LIBRARIES}
 319         ${QT_LIBRARIES}
 320 )
 321
 322 if(STATIC_PKGDEPS_LIBS)
 323         link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
 324         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LIBRARIES})
 325 if(WIN32)
 326         # Workaround for a MinGW linking issue.
 327         list(APPEND PULSEVIEW_LINK_LIBS "-llzma -llcms2")
 328 endif()
 329 else()
 330         link_directories(${PKGDEPS_LIBRARY_DIRS})
 331         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
 332 endif()
 333
 334 if(WIN32)
 335         # On Windows we need to statically link the libqsvg imageformat
 336         # plugin (and the QtSvg component) for SVG graphics/icons to work.
 337         add_definitions(-DQT_STATICPLUGIN)
 338         link_directories("${QT_PLUGINS_DIR}/imageformats")
 339         list(APPEND PULSEVIEW_LINK_LIBS ${QT_QTSVG_LIBRARY})
 340         list(APPEND PULSEVIEW_LINK_LIBS "-lqsvg")
 341 endif()
 342
 343 if(ANDROID)
 344         list(APPEND PULSEVIEW_LINK_LIBS "-llog")
 345 endif()
 346
 347 if(ANDROID)
 348 add_library(${PROJECT_NAME} SHARED
 349         ${pulseview_SOURCES}
 350         ${pulseview_HEADERS_MOC}
 351         ${pulseview_FORMS_HEADERS}
 352         ${pulseview_RESOURCES_RCC}
 353 )
 354 else()
 355 add_executable(${PROJECT_NAME}
 356         ${pulseview_SOURCES}
 357         ${pulseview_HEADERS_MOC}
 358         ${pulseview_FORMS_HEADERS}
 359         ${pulseview_RESOURCES_RCC}
 360 )
 361 endif()
 362
 363 target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
 364
 365 if(WIN32)
 366         # Pass -mwindows so that no "DOS box" opens when PulseView is started.
 367         set_target_properties(${PROJECT_NAME} PROPERTIES LINK_FLAGS "-mwindows")
 368 endif()
 369
 370 if(ENABLE_COTIRE)
 371         include(cotire)
 372         cotire(${PROJECT_NAME})
 373 endif()
 374
 375 #===============================================================================
 376 #= Installation
 377 #-------------------------------------------------------------------------------
 378
 379 # Install the executable.
 380 install(TARGETS ${PROJECT_NAME} DESTINATION bin/)
 381
 382 # Install the manpage.
 383 install(FILES doc/pulseview.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1 COMPONENT doc)
 384
 385 #===============================================================================
 386 #= Packaging (handled by CPack)
 387 #-------------------------------------------------------------------------------
 388
 389 set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
 390 set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
 391 set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
 392 set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
 393 set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
 394 set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
 395 set(CPACK_SOURCE_PACKAGE_FILE_NAME
 396         "${CMAKE_PROJECT_NAME}-${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}")
 397 set(CPACK_SOURCE_GENERATOR "TGZ")
 398
 399 include(CPack)
 400
 401 #===============================================================================
 402 #= Tests
 403 #-------------------------------------------------------------------------------
 404
 405 if(ENABLE_TESTS)
 406         add_subdirectory(test)
 407         enable_testing()
 408         add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
 409 endif()