CMakeLists.txt

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
   5 ## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 2 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 cmake_minimum_required(VERSION 2.6)
  22 include(FindPkgConfig)
  23
  24 project(pulseview)
  25
  26 #===============================================================================
  27 #= User Options
  28 #-------------------------------------------------------------------------------
  29
  30 option(DISABLE_WERROR "Build without -Werror" FALSE)
  31 option(ENABLE_TESTS "Enable unit tests" FALSE)
  32 option(STATIC_PKGDEPS_LIBS "Statically link to (pkgconfig) libraries" FALSE)
  33
  34 if(WIN32)
  35         # On Windows/MinGW we need to statically link to libraries.
  36         # This option is user configurable, but enable it by default on win32.
  37         set(STATIC_PKGDEPS_LIBS TRUE)
  38
  39         # For boost-thread we need two additional settings on win32:
  40         set(Boost_USE_STATIC_LIBS on)
  41         add_definitions(-DBOOST_THREAD_USE_LIB)
  42 endif()
  43
  44 #===============================================================================
  45 #= Dependencies
  46 #-------------------------------------------------------------------------------
  47
  48 find_package(PkgConfig)
  49 pkg_check_modules(PKGDEPS REQUIRED
  50         libsigrokdecode>=0.1.0
  51         libsigrok>=0.2.0
  52 )
  53
  54 find_package(Qt4 REQUIRED)
  55
  56 # Find the platform's thread library (needed for boost-thread).
  57 # This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
  58 find_package(Threads)
  59
  60 if(WIN32)
  61 # On Windows/MinGW the we need to use 'thread_win32' instead of 'thread'.
  62 # The library is named libboost_thread_win32* (not libboost_thread*).
  63 find_package(Boost 1.42 COMPONENTS system thread_win32 REQUIRED)
  64 else()
  65 find_package(Boost 1.42 COMPONENTS system thread REQUIRED)
  66 endif()
  67
  68 #===============================================================================
  69 #= Config Header
  70 #-------------------------------------------------------------------------------
  71
  72 set(PV_TITLE PulseView)
  73 set(PV_DESCRIPTION "A GUI for sigrok")
  74
  75 set(PV_VERSION_MAJOR 0)
  76 set(PV_VERSION_MINOR 1)
  77 set(PV_VERSION_MICRO 0)
  78 set(PV_VERSION_STRING
  79         ${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}
  80 )
  81
  82 configure_file (
  83         ${PROJECT_SOURCE_DIR}/config.h.in
  84         ${PROJECT_BINARY_DIR}/config.h
  85 )
  86
  87 #===============================================================================
  88 #= Sources
  89 #-------------------------------------------------------------------------------
  90
  91 set(pulseview_SOURCES
  92         main.cpp
  93         pv/mainwindow.cpp
  94         pv/samplingbar.cpp
  95         pv/sigsession.cpp
  96         pv/data/analog.cpp
  97         pv/data/analogsnapshot.cpp
  98         pv/data/logic.cpp
  99         pv/data/logicsnapshot.cpp
 100         pv/data/signaldata.cpp
 101         pv/data/snapshot.cpp
 102         pv/dialogs/about.cpp
 103         pv/dialogs/deviceoptions.cpp
 104         pv/prop/enum.cpp
 105         pv/prop/property.cpp
 106         pv/prop/binding/binding.cpp
 107         pv/prop/binding/deviceoptions.cpp
 108         pv/view/analogsignal.cpp
 109         pv/view/cursor.cpp
 110         pv/view/header.cpp
 111         pv/view/logicsignal.cpp
 112         pv/view/ruler.cpp
 113         pv/view/signal.cpp
 114         pv/view/timemarker.cpp
 115         pv/view/view.cpp
 116         pv/view/viewport.cpp
 117 )
 118
 119 set(pulseview_HEADERS
 120         pv/mainwindow.h
 121         pv/samplingbar.h
 122         pv/sigsession.h
 123         pv/dialogs/about.h
 124         pv/view/cursor.h
 125         pv/view/header.h
 126         pv/view/ruler.h
 127         pv/view/timemarker.h
 128         pv/view/view.h
 129         pv/view/viewport.h
 130 )
 131
 132 set(pulseview_FORMS
 133         pv/dialogs/about.ui
 134 )
 135
 136 set(pulseview_RESOURCES
 137         pulseview.qrc
 138 )
 139
 140 qt4_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 141 qt4_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 142 qt4_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 143
 144 include(${QT_USE_FILE})
 145
 146 #===============================================================================
 147 #= Global Definitions
 148 #-------------------------------------------------------------------------------
 149
 150 add_definitions(${QT_DEFINITIONS})
 151 add_definitions(-Wall -Wextra)
 152
 153 if(NOT DISABLE_WERROR)
 154         add_definitions(-Werror)
 155 endif()
 156
 157 #===============================================================================
 158 #= Global Include Directories
 159 #-------------------------------------------------------------------------------
 160
 161 include_directories(
 162         ${CMAKE_CURRENT_BINARY_DIR}
 163         ${CMAKE_CURRENT_SOURCE_DIR}
 164         ${Boost_INCLUDE_DIRS}
 165 )
 166
 167 if(STATIC_PKGDEPS_LIBS)
 168         include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
 169 else()
 170         include_directories(${PKGDEPS_INCLUDE_DIRS})
 171 endif()
 172
 173 #===============================================================================
 174 #= Linker Configuration
 175 #-------------------------------------------------------------------------------
 176
 177 link_directories(${Boost_LIBRARY_DIRS})
 178
 179 set(PULSEVIEW_LINK_LIBS
 180         ${Boost_LIBRARIES}
 181         ${CMAKE_THREAD_LIBS_INIT}
 182         ${QT_LIBRARIES}
 183 )
 184
 185 if(STATIC_PKGDEPS_LIBS)
 186         link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
 187         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LIBRARIES})
 188 else()
 189         link_directories(${PKGDEPS_LIBRARY_DIRS})
 190         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
 191 endif()
 192
 193 add_executable(${PROJECT_NAME}
 194         ${pulseview_SOURCES}
 195         ${pulseview_HEADERS_MOC}
 196         ${pulseview_FORMS_HEADERS}
 197         ${pulseview_RESOURCES_RCC}
 198 )
 199
 200 target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
 201
 202 #===============================================================================
 203 #= Installation
 204 #-------------------------------------------------------------------------------
 205
 206 install(TARGETS ${PROJECT_NAME} DESTINATION bin/)
 207
 208 #===============================================================================
 209 #= Packaging (handled by CPack)
 210 #-------------------------------------------------------------------------------
 211
 212 set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
 213 set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
 214 set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
 215 set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
 216 set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
 217 set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
 218 set(CPACK_SOURCE_PACKAGE_FILE_NAME
 219         "${CMAKE_PROJECT_NAME}-${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}")
 220 set(CPACK_SOURCE_GENERATOR "TGZ")
 221
 222 include(CPack)
 223
 224 #===============================================================================
 225 #= Tests
 226 #-------------------------------------------------------------------------------
 227
 228 if(ENABLE_TESTS)
 229         add_subdirectory(test)
 230         enable_testing()
 231         add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
 232 endif(ENABLE_TESTS)