CMakeLists.txt

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
   5 ## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 2 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 cmake_minimum_required(VERSION 2.8.6)
  22
  23 include(FindPkgConfig)
  24 include(GNUInstallDirs)
  25
  26 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/CMake")
  27
  28 project(pulseview)
  29
  30 #===============================================================================
  31 #= User Options
  32 #-------------------------------------------------------------------------------
  33
  34 option(DISABLE_WERROR "Build without -Werror" FALSE)
  35 option(ENABLE_SIGNALS "Build with UNIX signals" TRUE)
  36 option(ENABLE_DECODE "Build with libsigrokdecode" TRUE)
  37 option(ENABLE_COTIRE "Enable cotire" FALSE)
  38 option(ENABLE_TESTS "Enable unit tests" FALSE)
  39 option(STATIC_PKGDEPS_LIBS "Statically link to (pkg-config) libraries" FALSE)
  40
  41 if(WIN32)
  42         # On Windows/MinGW we need to statically link to libraries.
  43         # This option is user configurable, but enable it by default on win32.
  44         set(STATIC_PKGDEPS_LIBS TRUE)
  45
  46         # For boost-thread we need two additional settings on win32:
  47         set(Boost_USE_STATIC_LIBS ON)
  48         add_definitions(-DBOOST_THREAD_USE_LIB)
  49
  50         # Windows does not support UNIX signals.
  51         set(ENABLE_SIGNALS FALSE)
  52 endif()
  53
  54 if(NOT CMAKE_BUILD_TYPE)
  55   set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
  56       "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  57       FORCE)
  58 endif()
  59
  60 #===============================================================================
  61 #= Dependencies
  62 #-------------------------------------------------------------------------------
  63
  64 list(APPEND PKGDEPS libsigrok>=0.3.0)
  65
  66 if(ENABLE_DECODE)
  67         list(APPEND PKGDEPS libsigrokdecode>=0.3.0)
  68 endif()
  69
  70 find_package(PkgConfig)
  71 pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})
  72
  73 find_program(QT_QMAKE_EXECUTABLE NAMES qmake4 qmake-qt4 qmake-mac)
  74 find_package(Qt4 REQUIRED)
  75
  76 # Find the platform's thread library (needed for boost-thread).
  77 # This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
  78 find_package(Threads)
  79
  80 if(WIN32)
  81         # On Windows/MinGW we need to use 'thread_win32' instead of 'thread'.
  82         # The library is named libboost_thread_win32* (not libboost_thread*).
  83         find_package(Boost 1.42 COMPONENTS filesystem system thread_win32 REQUIRED)
  84 else()
  85         find_package(Boost 1.42 COMPONENTS filesystem system thread REQUIRED)
  86 endif()
  87
  88 #===============================================================================
  89 #= System Introspection
  90 #-------------------------------------------------------------------------------
  91
  92 include(memaccess)
  93 memaccess_check_unaligned_le(HAVE_UNALIGNED_LITTLE_ENDIAN_ACCESS)
  94
  95 #===============================================================================
  96 #= Config Header
  97 #-------------------------------------------------------------------------------
  98
  99 set(PV_TITLE PulseView)
 100 set(PV_DESCRIPTION "A GUI for sigrok")
 101
 102 set(PV_VERSION_MAJOR 0)
 103 set(PV_VERSION_MINOR 2)
 104 set(PV_VERSION_MICRO 0)
 105 set(PV_VERSION_STRING
 106         ${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}
 107 )
 108
 109 configure_file (
 110         ${PROJECT_SOURCE_DIR}/config.h.in
 111         ${PROJECT_BINARY_DIR}/config.h
 112 )
 113
 114 #===============================================================================
 115 #= Sources
 116 #-------------------------------------------------------------------------------
 117
 118 set(pulseview_SOURCES
 119         main.cpp
 120         pv/devicemanager.cpp
 121         pv/mainwindow.cpp
 122         pv/sigsession.cpp
 123         pv/storesession.cpp
 124         pv/util.cpp
 125         pv/data/analog.cpp
 126         pv/data/analogsnapshot.cpp
 127         pv/data/logic.cpp
 128         pv/data/logicsnapshot.cpp
 129         pv/data/signaldata.cpp
 130         pv/data/snapshot.cpp
 131         pv/device/device.cpp
 132         pv/device/file.cpp
 133         pv/device/devinst.cpp
 134         pv/device/inputfile.cpp
 135         pv/device/sessionfile.cpp
 136         pv/dialogs/about.cpp
 137         pv/dialogs/connect.cpp
 138         pv/dialogs/storeprogress.cpp
 139         pv/popups/deviceoptions.cpp
 140         pv/popups/probes.cpp
 141         pv/prop/bool.cpp
 142         pv/prop/double.cpp
 143         pv/prop/enum.cpp
 144         pv/prop/int.cpp
 145         pv/prop/property.cpp
 146         pv/prop/string.cpp
 147         pv/prop/binding/binding.cpp
 148         pv/prop/binding/deviceoptions.cpp
 149         pv/toolbars/samplingbar.cpp
 150         pv/view/analogsignal.cpp
 151         pv/view/cursor.cpp
 152         pv/view/cursorpair.cpp
 153         pv/view/header.cpp
 154         pv/view/marginwidget.cpp
 155         pv/view/logicsignal.cpp
 156         pv/view/ruler.cpp
 157         pv/view/selectableitem.cpp
 158         pv/view/signal.cpp
 159         pv/view/timemarker.cpp
 160         pv/view/trace.cpp
 161         pv/view/tracepalette.cpp
 162         pv/view/view.cpp
 163         pv/view/viewport.cpp
 164         pv/widgets/colourbutton.cpp
 165         pv/widgets/colourpopup.cpp
 166         pv/widgets/popup.cpp
 167         pv/widgets/popuptoolbutton.cpp
 168         pv/widgets/sweeptimingwidget.cpp
 169         pv/widgets/wellarray.cpp
 170 )
 171
 172 # This list includes only QObject derived class headers.
 173 set(pulseview_HEADERS
 174         pv/mainwindow.h
 175         pv/sigsession.h
 176         pv/storesession.h
 177         pv/device/devinst.h
 178         pv/dialogs/about.h
 179         pv/dialogs/connect.h
 180         pv/dialogs/storeprogress.h
 181         pv/popups/probes.h
 182         pv/popups/deviceoptions.h
 183         pv/prop/bool.h
 184         pv/prop/double.h
 185         pv/prop/enum.h
 186         pv/prop/int.h
 187         pv/prop/property.h
 188         pv/prop/string.h
 189         pv/toolbars/samplingbar.h
 190         pv/view/cursor.h
 191         pv/view/header.h
 192         pv/view/logicsignal.h
 193         pv/view/marginwidget.h
 194         pv/view/ruler.h
 195         pv/view/selectableitem.h
 196         pv/view/signal.h
 197         pv/view/timemarker.h
 198         pv/view/trace.h
 199         pv/view/view.h
 200         pv/view/viewport.h
 201         pv/widgets/colourbutton.h
 202         pv/widgets/colourpopup.h
 203         pv/widgets/popup.h
 204         pv/widgets/popuptoolbutton.h
 205         pv/widgets/sweeptimingwidget.h
 206         pv/widgets/wellarray.h
 207 )
 208
 209 set(pulseview_FORMS
 210         pv/dialogs/about.ui
 211 )
 212
 213 set(pulseview_RESOURCES
 214         pulseview.qrc
 215 )
 216
 217 if(ENABLE_SIGNALS)
 218         list(APPEND pulseview_SOURCES signalhandler.cpp)
 219         list(APPEND pulseview_HEADERS signalhandler.h)
 220 endif()
 221
 222 if(ENABLE_DECODE)
 223         list(APPEND pulseview_SOURCES
 224                 pv/data/decoderstack.cpp
 225                 pv/data/decode/annotation.cpp
 226                 pv/data/decode/decoder.cpp
 227                 pv/data/decode/row.cpp
 228                 pv/data/decode/rowdata.cpp
 229                 pv/prop/binding/decoderoptions.cpp
 230                 pv/view/decodetrace.cpp
 231                 pv/widgets/decodergroupbox.cpp
 232                 pv/widgets/decodermenu.cpp
 233         )
 234
 235         list(APPEND pulseview_HEADERS
 236                 pv/data/decoderstack.h
 237                 pv/view/decodetrace.h
 238                 pv/widgets/decodergroupbox.h
 239                 pv/widgets/decodermenu.h
 240         )
 241 endif()
 242
 243 if(WIN32)
 244         # Use the sigrok icon for the pulseview.exe executable.
 245         set(CMAKE_RC_COMPILE_OBJECT "${CMAKE_RC_COMPILER} -O coff -I${CMAKE_CURRENT_SOURCE_DIR} <SOURCE> <OBJECT>")
 246         enable_language(RC)
 247         list(APPEND pulseview_SOURCES pulseviewico.rc)
 248 endif()
 249
 250 qt4_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 251 qt4_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 252 qt4_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 253
 254 include(${QT_USE_FILE})
 255
 256 #===============================================================================
 257 #= Global Definitions
 258 #-------------------------------------------------------------------------------
 259
 260 add_definitions(${QT_DEFINITIONS})
 261 add_definitions(-D__STDC_LIMIT_MACROS)
 262 add_definitions(-Wall -Wextra)
 263 add_definitions(-std=c++11)
 264
 265 if(ENABLE_DECODE)
 266         add_definitions(-DENABLE_DECODE)
 267 endif()
 268
 269 if(NOT DISABLE_WERROR)
 270         add_definitions(-Werror)
 271 endif()
 272
 273 #===============================================================================
 274 #= Global Include Directories
 275 #-------------------------------------------------------------------------------
 276
 277 include_directories(
 278         ${CMAKE_CURRENT_BINARY_DIR}
 279         ${CMAKE_CURRENT_SOURCE_DIR}
 280         ${Boost_INCLUDE_DIRS}
 281 )
 282
 283 if(STATIC_PKGDEPS_LIBS)
 284         include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
 285 else()
 286         include_directories(${PKGDEPS_INCLUDE_DIRS})
 287 endif()
 288
 289 #===============================================================================
 290 #= Linker Configuration
 291 #-------------------------------------------------------------------------------
 292
 293 link_directories(${Boost_LIBRARY_DIRS})
 294
 295 set(PULSEVIEW_LINK_LIBS
 296         ${Boost_LIBRARIES}
 297         ${CMAKE_THREAD_LIBS_INIT}
 298         ${QT_LIBRARIES}
 299 )
 300
 301 if(STATIC_PKGDEPS_LIBS)
 302         link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
 303         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LIBRARIES})
 304 if(WIN32)
 305         # Workaround for a MinGW linking issue.
 306         list(APPEND PULSEVIEW_LINK_LIBS "-llzma -llcms2")
 307 endif()
 308 else()
 309         link_directories(${PKGDEPS_LIBRARY_DIRS})
 310         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
 311 endif()
 312
 313 if(WIN32)
 314         # On Windows we need to statically link the libqsvg imageformat
 315         # plugin (and the QtSvg component) for SVG graphics/icons to work.
 316         add_definitions(-DQT_STATICPLUGIN)
 317         link_directories("${QT_PLUGINS_DIR}/imageformats")
 318         list(APPEND PULSEVIEW_LINK_LIBS ${QT_QTSVG_LIBRARY})
 319         list(APPEND PULSEVIEW_LINK_LIBS "-lqsvg")
 320 endif()
 321
 322 add_executable(${PROJECT_NAME}
 323         ${pulseview_SOURCES}
 324         ${pulseview_HEADERS_MOC}
 325         ${pulseview_FORMS_HEADERS}
 326         ${pulseview_RESOURCES_RCC}
 327 )
 328
 329 target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
 330
 331 if(WIN32)
 332         # Pass -mwindows so that no "DOS box" opens when PulseView is started.
 333         set_target_properties(${PROJECT_NAME} PROPERTIES LINK_FLAGS "-mwindows")
 334 endif()
 335
 336 if(ENABLE_COTIRE)
 337         include(cotire)
 338         cotire(${PROJECT_NAME})
 339 endif()
 340
 341 #===============================================================================
 342 #= Installation
 343 #-------------------------------------------------------------------------------
 344
 345 # Install the executable.
 346 install(TARGETS ${PROJECT_NAME} DESTINATION bin/)
 347
 348 # Install the manpage.
 349 install(FILES doc/pulseview.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1 COMPONENT doc)
 350
 351 #===============================================================================
 352 #= Packaging (handled by CPack)
 353 #-------------------------------------------------------------------------------
 354
 355 set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
 356 set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
 357 set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
 358 set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
 359 set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
 360 set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
 361 set(CPACK_SOURCE_PACKAGE_FILE_NAME
 362         "${CMAKE_PROJECT_NAME}-${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}")
 363 set(CPACK_SOURCE_GENERATOR "TGZ")
 364
 365 include(CPack)
 366
 367 #===============================================================================
 368 #= Tests
 369 #-------------------------------------------------------------------------------
 370
 371 if(ENABLE_TESTS)
 372         add_subdirectory(test)
 373         enable_testing()
 374         add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
 375 endif()