CMakeLists.txt

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
   5 ## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 2 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 cmake_minimum_required(VERSION 2.6)
  22 include(FindPkgConfig)
  23 include(GNUInstallDirs)
  24
  25 project(pulseview)
  26
  27 #===============================================================================
  28 #= User Options
  29 #-------------------------------------------------------------------------------
  30
  31 option(DISABLE_WERROR "Build without -Werror" FALSE)
  32 option(ENABLE_SIGNALS "Build with UNIX signals" TRUE)
  33 option(ENABLE_SIGROKDECODE "Build with libsigrokdecode" FALSE)
  34 option(ENABLE_TESTS "Enable unit tests" FALSE)
  35 option(STATIC_PKGDEPS_LIBS "Statically link to (pkgconfig) libraries" FALSE)
  36
  37 if(WIN32)
  38         # On Windows/MinGW we need to statically link to libraries.
  39         # This option is user configurable, but enable it by default on win32.
  40         set(STATIC_PKGDEPS_LIBS TRUE)
  41
  42         # For boost-thread we need two additional settings on win32:
  43         set(Boost_USE_STATIC_LIBS on)
  44         add_definitions(-DBOOST_THREAD_USE_LIB)
  45
  46         # Windsws does not support UNIX signals
  47         set(ENABLE_SIGNALS FALSE)
  48 endif()
  49
  50 #===============================================================================
  51 #= Dependencies
  52 #-------------------------------------------------------------------------------
  53
  54 list(APPEND PKGDEPS
  55         libsigrok>=0.2.0
  56 )
  57
  58 if(ENABLE_SIGROKDECODE)
  59         list(APPEND PKGDEPS libsigrokdecode>=0.2.0)
  60 endif()
  61
  62 find_package(PkgConfig)
  63 pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})
  64
  65 find_package(Qt4 REQUIRED)
  66
  67 # Find the platform's thread library (needed for boost-thread).
  68 # This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
  69 find_package(Threads)
  70
  71 if(WIN32)
  72 # On Windows/MinGW the we need to use 'thread_win32' instead of 'thread'.
  73 # The library is named libboost_thread_win32* (not libboost_thread*).
  74 find_package(Boost 1.42 COMPONENTS system thread_win32 REQUIRED)
  75 else()
  76 find_package(Boost 1.42 COMPONENTS system thread REQUIRED)
  77 endif()
  78
  79 #===============================================================================
  80 #= Config Header
  81 #-------------------------------------------------------------------------------
  82
  83 set(PV_TITLE PulseView)
  84 set(PV_DESCRIPTION "A GUI for sigrok")
  85
  86 set(PV_VERSION_MAJOR 0)
  87 set(PV_VERSION_MINOR 1)
  88 set(PV_VERSION_MICRO 0)
  89 set(PV_VERSION_STRING
  90         ${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}
  91 )
  92
  93 configure_file (
  94         ${PROJECT_SOURCE_DIR}/config.h.in
  95         ${PROJECT_BINARY_DIR}/config.h
  96 )
  97
  98 #===============================================================================
  99 #= Sources
 100 #-------------------------------------------------------------------------------
 101
 102 set(pulseview_SOURCES
 103         main.cpp
 104         pv/devicemanager.cpp
 105         pv/mainwindow.cpp
 106         pv/sigsession.cpp
 107         pv/data/analog.cpp
 108         pv/data/analogsnapshot.cpp
 109         pv/data/logic.cpp
 110         pv/data/logicsnapshot.cpp
 111         pv/data/signaldata.cpp
 112         pv/data/snapshot.cpp
 113         pv/dialogs/about.cpp
 114         pv/dialogs/connect.cpp
 115         pv/dialogs/deviceoptions.cpp
 116         pv/prop/bool.cpp
 117         pv/prop/double.cpp
 118         pv/prop/enum.cpp
 119         pv/prop/int.cpp
 120         pv/prop/property.cpp
 121         pv/prop/binding/binding.cpp
 122         pv/prop/binding/deviceoptions.cpp
 123         pv/toolbars/samplingbar.cpp
 124         pv/view/analogsignal.cpp
 125         pv/view/cursor.cpp
 126         pv/view/cursorpair.cpp
 127         pv/view/header.cpp
 128         pv/view/logicsignal.cpp
 129         pv/view/ruler.cpp
 130         pv/view/signal.cpp
 131         pv/view/timemarker.cpp
 132         pv/view/view.cpp
 133         pv/view/viewport.cpp
 134 )
 135
 136 set(pulseview_HEADERS
 137         pv/mainwindow.h
 138         pv/sigsession.h
 139         pv/dialogs/about.h
 140         pv/dialogs/connect.h
 141         pv/dialogs/deviceoptions.h
 142         pv/toolbars/samplingbar.h
 143         pv/view/cursor.h
 144         pv/view/header.h
 145         pv/view/ruler.h
 146         pv/view/timemarker.h
 147         pv/view/view.h
 148         pv/view/viewport.h
 149 )
 150
 151 set(pulseview_FORMS
 152         pv/dialogs/about.ui
 153 )
 154
 155 set(pulseview_RESOURCES
 156         pulseview.qrc
 157 )
 158
 159 if(ENABLE_SIGNALS)
 160         list(APPEND pulseview_SOURCES signalhandler.cpp)
 161         list(APPEND pulseview_HEADERS signalhandler.h)
 162 endif()
 163
 164 qt4_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 165 qt4_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 166 qt4_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 167
 168 include(${QT_USE_FILE})
 169
 170 #===============================================================================
 171 #= Global Definitions
 172 #-------------------------------------------------------------------------------
 173
 174 add_definitions(${QT_DEFINITIONS})
 175 add_definitions(-Wall -Wextra)
 176
 177 if(ENABLE_SIGROKDECODE)
 178         add_definitions(-DENABLE_SIGROKDECODE)
 179 endif()
 180
 181 if(NOT DISABLE_WERROR)
 182         add_definitions(-Werror)
 183 endif()
 184
 185 #===============================================================================
 186 #= Global Include Directories
 187 #-------------------------------------------------------------------------------
 188
 189 include_directories(
 190         ${CMAKE_CURRENT_BINARY_DIR}
 191         ${CMAKE_CURRENT_SOURCE_DIR}
 192         ${Boost_INCLUDE_DIRS}
 193 )
 194
 195 if(STATIC_PKGDEPS_LIBS)
 196         include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
 197 else()
 198         include_directories(${PKGDEPS_INCLUDE_DIRS})
 199 endif()
 200
 201 #===============================================================================
 202 #= Linker Configuration
 203 #-------------------------------------------------------------------------------
 204
 205 link_directories(${Boost_LIBRARY_DIRS})
 206
 207 set(PULSEVIEW_LINK_LIBS
 208         ${Boost_LIBRARIES}
 209         ${CMAKE_THREAD_LIBS_INIT}
 210         ${QT_LIBRARIES}
 211 )
 212
 213 if(STATIC_PKGDEPS_LIBS)
 214         link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
 215         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LIBRARIES})
 216 else()
 217         link_directories(${PKGDEPS_LIBRARY_DIRS})
 218         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
 219 endif()
 220
 221 add_executable(${PROJECT_NAME}
 222         ${pulseview_SOURCES}
 223         ${pulseview_HEADERS_MOC}
 224         ${pulseview_FORMS_HEADERS}
 225         ${pulseview_RESOURCES_RCC}
 226 )
 227
 228 target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
 229
 230 if(WIN32)
 231 # Pass -mwindows so that no "DOS box" will open when PulseView is started.
 232 set_target_properties(${PROJECT_NAME} PROPERTIES LINK_FLAGS "-mwindows")
 233 endif()
 234
 235 #===============================================================================
 236 #= Installation
 237 #-------------------------------------------------------------------------------
 238
 239 # Install the executable.
 240 install(TARGETS ${PROJECT_NAME} DESTINATION bin/)
 241
 242 # Install the manpage.
 243 install(FILES doc/pulseview.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1 COMPONENT doc)
 244
 245 #===============================================================================
 246 #= Packaging (handled by CPack)
 247 #-------------------------------------------------------------------------------
 248
 249 set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
 250 set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
 251 set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
 252 set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
 253 set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
 254 set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
 255 set(CPACK_SOURCE_PACKAGE_FILE_NAME
 256         "${CMAKE_PROJECT_NAME}-${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}")
 257 set(CPACK_SOURCE_GENERATOR "TGZ")
 258
 259 include(CPack)
 260
 261 #===============================================================================
 262 #= Tests
 263 #-------------------------------------------------------------------------------
 264
 265 if(ENABLE_TESTS)
 266         add_subdirectory(test)
 267         enable_testing()
 268         add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
 269 endif(ENABLE_TESTS)