CMakeLists.txt

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
   5 ## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 2 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 cmake_minimum_required(VERSION 2.6)
  22 include(FindPkgConfig)
  23 include(GNUInstallDirs)
  24
  25 project(pulseview)
  26
  27 #===============================================================================
  28 #= User Options
  29 #-------------------------------------------------------------------------------
  30
  31 option(DISABLE_WERROR "Build without -Werror" FALSE)
  32 option(ENABLE_SIGNALS "Build with UNIX signals" TRUE)
  33 option(ENABLE_SIGROKDECODE "Build with libsigrokdecode" FALSE)
  34 option(ENABLE_TESTS "Enable unit tests" FALSE)
  35 option(STATIC_PKGDEPS_LIBS "Statically link to (pkgconfig) libraries" FALSE)
  36
  37 if(WIN32)
  38         # On Windows/MinGW we need to statically link to libraries.
  39         # This option is user configurable, but enable it by default on win32.
  40         set(STATIC_PKGDEPS_LIBS TRUE)
  41
  42         # For boost-thread we need two additional settings on win32:
  43         set(Boost_USE_STATIC_LIBS on)
  44         add_definitions(-DBOOST_THREAD_USE_LIB)
  45
  46         # Windsws does not support UNIX signals
  47         set(ENABLE_SIGNALS FALSE)
  48 endif()
  49
  50 #===============================================================================
  51 #= Dependencies
  52 #-------------------------------------------------------------------------------
  53
  54 list(APPEND PKGDEPS
  55         libsigrok>=0.2.0
  56 )
  57
  58 if(ENABLE_SIGROKDECODE)
  59         list(APPEND PKGDEPS libsigrokdecode>=0.2.0)
  60 endif()
  61
  62 find_package(PkgConfig)
  63 pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})
  64
  65 FIND_PROGRAM(QT_QMAKE_EXECUTABLE NAMES qmake4 qmake-qt4 qmake-mac)
  66 find_package(Qt4 REQUIRED)
  67
  68 # Find the platform's thread library (needed for boost-thread).
  69 # This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
  70 find_package(Threads)
  71
  72 if(WIN32)
  73 # On Windows/MinGW the we need to use 'thread_win32' instead of 'thread'.
  74 # The library is named libboost_thread_win32* (not libboost_thread*).
  75 find_package(Boost 1.42 COMPONENTS system thread_win32 REQUIRED)
  76 else()
  77 find_package(Boost 1.42 COMPONENTS system thread REQUIRED)
  78 endif()
  79
  80 #===============================================================================
  81 #= Config Header
  82 #-------------------------------------------------------------------------------
  83
  84 set(PV_TITLE PulseView)
  85 set(PV_DESCRIPTION "A GUI for sigrok")
  86
  87 set(PV_VERSION_MAJOR 0)
  88 set(PV_VERSION_MINOR 1)
  89 set(PV_VERSION_MICRO 0)
  90 set(PV_VERSION_STRING
  91         ${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}
  92 )
  93
  94 configure_file (
  95         ${PROJECT_SOURCE_DIR}/config.h.in
  96         ${PROJECT_BINARY_DIR}/config.h
  97 )
  98
  99 #===============================================================================
 100 #= Sources
 101 #-------------------------------------------------------------------------------
 102
 103 set(pulseview_SOURCES
 104         main.cpp
 105         pv/devicemanager.cpp
 106         pv/mainwindow.cpp
 107         pv/sigsession.cpp
 108         pv/data/analog.cpp
 109         pv/data/analogsnapshot.cpp
 110         pv/data/logic.cpp
 111         pv/data/logicsnapshot.cpp
 112         pv/data/signaldata.cpp
 113         pv/data/snapshot.cpp
 114         pv/dialogs/about.cpp
 115         pv/dialogs/connect.cpp
 116         pv/dialogs/deviceoptions.cpp
 117         pv/prop/bool.cpp
 118         pv/prop/double.cpp
 119         pv/prop/enum.cpp
 120         pv/prop/int.cpp
 121         pv/prop/property.cpp
 122         pv/prop/binding/binding.cpp
 123         pv/prop/binding/deviceoptions.cpp
 124         pv/toolbars/contextbar.cpp
 125         pv/toolbars/samplingbar.cpp
 126         pv/view/analogsignal.cpp
 127         pv/view/cursor.cpp
 128         pv/view/cursorpair.cpp
 129         pv/view/header.cpp
 130         pv/view/marginwidget.cpp
 131         pv/view/logicsignal.cpp
 132         pv/view/ruler.cpp
 133         pv/view/selectableitem.cpp
 134         pv/view/signal.cpp
 135         pv/view/timemarker.cpp
 136         pv/view/view.cpp
 137         pv/view/viewport.cpp
 138 )
 139
 140 # This list includes only QObject derrived class headers
 141 set(pulseview_HEADERS
 142         pv/mainwindow.h
 143         pv/sigsession.h
 144         pv/dialogs/about.h
 145         pv/dialogs/connect.h
 146         pv/dialogs/deviceoptions.h
 147         pv/toolbars/contextbar.h
 148         pv/toolbars/samplingbar.h
 149         pv/view/cursor.h
 150         pv/view/header.h
 151         pv/view/logicsignal.h
 152         pv/view/marginwidget.h
 153         pv/view/ruler.h
 154         pv/view/selectableitem.h
 155         pv/view/signal.h
 156         pv/view/timemarker.h
 157         pv/view/view.h
 158         pv/view/viewport.h
 159 )
 160
 161 set(pulseview_FORMS
 162         pv/dialogs/about.ui
 163 )
 164
 165 set(pulseview_RESOURCES
 166         pulseview.qrc
 167 )
 168
 169 if(ENABLE_SIGNALS)
 170         list(APPEND pulseview_SOURCES signalhandler.cpp)
 171         list(APPEND pulseview_HEADERS signalhandler.h)
 172 endif()
 173
 174 qt4_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 175 qt4_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 176 qt4_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 177
 178 include(${QT_USE_FILE})
 179
 180 #===============================================================================
 181 #= Global Definitions
 182 #-------------------------------------------------------------------------------
 183
 184 add_definitions(${QT_DEFINITIONS})
 185 add_definitions(-Wall -Wextra)
 186
 187 if(ENABLE_SIGROKDECODE)
 188         add_definitions(-DENABLE_SIGROKDECODE)
 189 endif()
 190
 191 if(NOT DISABLE_WERROR)
 192         add_definitions(-Werror)
 193 endif()
 194
 195 #===============================================================================
 196 #= Global Include Directories
 197 #-------------------------------------------------------------------------------
 198
 199 include_directories(
 200         ${CMAKE_CURRENT_BINARY_DIR}
 201         ${CMAKE_CURRENT_SOURCE_DIR}
 202         ${Boost_INCLUDE_DIRS}
 203 )
 204
 205 if(STATIC_PKGDEPS_LIBS)
 206         include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
 207 else()
 208         include_directories(${PKGDEPS_INCLUDE_DIRS})
 209 endif()
 210
 211 #===============================================================================
 212 #= Linker Configuration
 213 #-------------------------------------------------------------------------------
 214
 215 link_directories(${Boost_LIBRARY_DIRS})
 216
 217 set(PULSEVIEW_LINK_LIBS
 218         ${Boost_LIBRARIES}
 219         ${CMAKE_THREAD_LIBS_INIT}
 220         ${QT_LIBRARIES}
 221 )
 222
 223 if(STATIC_PKGDEPS_LIBS)
 224         link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
 225         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LIBRARIES})
 226 else()
 227         link_directories(${PKGDEPS_LIBRARY_DIRS})
 228         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
 229 endif()
 230
 231 add_executable(${PROJECT_NAME}
 232         ${pulseview_SOURCES}
 233         ${pulseview_HEADERS_MOC}
 234         ${pulseview_FORMS_HEADERS}
 235         ${pulseview_RESOURCES_RCC}
 236 )
 237
 238 target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
 239
 240 if(WIN32)
 241 # Pass -mwindows so that no "DOS box" will open when PulseView is started.
 242 set_target_properties(${PROJECT_NAME} PROPERTIES LINK_FLAGS "-mwindows")
 243 endif()
 244
 245 #===============================================================================
 246 #= Installation
 247 #-------------------------------------------------------------------------------
 248
 249 # Install the executable.
 250 install(TARGETS ${PROJECT_NAME} DESTINATION bin/)
 251
 252 # Install the manpage.
 253 install(FILES doc/pulseview.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1 COMPONENT doc)
 254
 255 #===============================================================================
 256 #= Packaging (handled by CPack)
 257 #-------------------------------------------------------------------------------
 258
 259 set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
 260 set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
 261 set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
 262 set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
 263 set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
 264 set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
 265 set(CPACK_SOURCE_PACKAGE_FILE_NAME
 266         "${CMAKE_PROJECT_NAME}-${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}")
 267 set(CPACK_SOURCE_GENERATOR "TGZ")
 268
 269 include(CPack)
 270
 271 #===============================================================================
 272 #= Tests
 273 #-------------------------------------------------------------------------------
 274
 275 if(ENABLE_TESTS)
 276         add_subdirectory(test)
 277         enable_testing()
 278         add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
 279 endif(ENABLE_TESTS)