CMakeLists.txt

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
   5 ## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 2 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 cmake_minimum_required(VERSION 2.8.6)
  22
  23 include(FindPkgConfig)
  24 include(GNUInstallDirs)
  25
  26 project(pulseview)
  27
  28 list(APPEND CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/CMake")
  29
  30 #===============================================================================
  31 #= User Options
  32 #-------------------------------------------------------------------------------
  33
  34 option(DISABLE_WERROR "Build without -Werror" FALSE)
  35 option(ENABLE_SIGNALS "Build with UNIX signals" TRUE)
  36 option(ENABLE_DECODE "Build with libsigrokdecode" TRUE)
  37 option(ENABLE_COTIRE "Enable cotire" FALSE)
  38 option(ENABLE_TESTS "Enable unit tests" FALSE)
  39 option(STATIC_PKGDEPS_LIBS "Statically link to (pkg-config) libraries" FALSE)
  40 option(FORCE_QT4 "Force use of Qt4 even if Qt5 is available" FALSE)
  41
  42 if(WIN32)
  43         # On Windows/MinGW we need to statically link to libraries.
  44         # This option is user configurable, but enable it by default on win32.
  45         set(STATIC_PKGDEPS_LIBS TRUE)
  46
  47         # For boost-thread we need two additional settings on win32:
  48         set(Boost_USE_STATIC_LIBS ON)
  49         add_definitions(-DBOOST_THREAD_USE_LIB)
  50
  51         # Windows does not support UNIX signals.
  52         set(ENABLE_SIGNALS FALSE)
  53 endif()
  54
  55 if(NOT CMAKE_BUILD_TYPE)
  56         set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
  57         "Choose the type of build (None, Debug, Release, RelWithDebInfo, MinSizeRel)."
  58         FORCE)
  59 endif()
  60
  61 #===============================================================================
  62 #= Dependencies
  63 #-------------------------------------------------------------------------------
  64
  65 list(APPEND PKGDEPS libsigrokxx>=0.3.0)
  66
  67 if(ENABLE_DECODE)
  68         list(APPEND PKGDEPS libsigrokdecode>=0.3.0)
  69 endif()
  70
  71 if(ANDROID)
  72         list(APPEND PKGDEPS libsigrokandroidutils>=0.1.0)
  73 endif()
  74
  75 find_package(PkgConfig)
  76 pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})
  77
  78 if(FORCE_QT4)
  79         set(Qt5Core_FOUND FALSE)
  80 else()
  81         find_package(Qt5Core QUIET)
  82 endif()
  83
  84 if(Qt5Core_FOUND)
  85         message("-- Using Qt5")
  86         find_package(Qt5Widgets REQUIRED)
  87         find_package(Qt5Gui REQUIRED)
  88         find_package(Qt5Svg REQUIRED)
  89         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${Qt5Widgets_EXECUTABLE_COMPILE_FLAGS}")
  90         set(QT_INCLUDE_DIRS ${Qt5Gui_INCLUDE_DIRS} ${Qt5Widgets_INCLUDE_DIRS})
  91         set(QT_LIBRARIES Qt5::Gui Qt5::Widgets Qt5::Svg)
  92         add_definitions(${Qt5Gui_DEFINITIONS} ${Qt5Widgets_DEFINITIONS})
  93 else()
  94         find_program(QT_QMAKE_EXECUTABLE NAMES qmake4 qmake-qt4 qmake-mac)
  95         find_package(Qt4 REQUIRED QtCore QtGui QtSvg)
  96 endif()
  97
  98 if(WIN32)
  99 if(ENABLE_TESTS)
 100         # On Windows/MinGW we need to use 'thread_win32' instead of 'thread'.
 101         # The library is named libboost_thread_win32* (not libboost_thread*).
 102         find_package(Boost 1.42 COMPONENTS filesystem system thread_win32 unit_test_framework REQUIRED)
 103 else()
 104         find_package(Boost 1.42 COMPONENTS filesystem system thread_win32 REQUIRED)
 105 endif()
 106 else()
 107 if(ENABLE_TESTS)
 108         find_package(Boost 1.42 COMPONENTS filesystem system thread unit_test_framework REQUIRED)
 109 else()
 110         find_package(Boost 1.42 COMPONENTS filesystem system thread REQUIRED)
 111 endif()
 112 endif()
 113
 114 # Find the platform's thread library (needed for C++11 threads).
 115 # This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
 116 find_package(Threads REQUIRED)
 117
 118 #===============================================================================
 119 #= System Introspection
 120 #-------------------------------------------------------------------------------
 121
 122 include(memaccess)
 123 memaccess_check_unaligned_le(HAVE_UNALIGNED_LITTLE_ENDIAN_ACCESS)
 124
 125 #===============================================================================
 126 #= Config Header
 127 #-------------------------------------------------------------------------------
 128
 129 set(PV_TITLE PulseView)
 130 set(PV_DESCRIPTION "A GUI for sigrok")
 131
 132 set(PV_VERSION_MAJOR 0)
 133 set(PV_VERSION_MINOR 2)
 134 set(PV_VERSION_MICRO 0)
 135 set(PV_VERSION_STRING
 136         ${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}
 137 )
 138
 139 configure_file (
 140         ${PROJECT_SOURCE_DIR}/config.h.in
 141         ${PROJECT_BINARY_DIR}/config.h
 142 )
 143
 144 #===============================================================================
 145 #= Sources
 146 #-------------------------------------------------------------------------------
 147
 148 set(pulseview_SOURCES
 149         main.cpp
 150         pv/application.cpp
 151         pv/devicemanager.cpp
 152         pv/mainwindow.cpp
 153         pv/sigsession.cpp
 154         pv/storesession.cpp
 155         pv/util.cpp
 156         pv/data/analog.cpp
 157         pv/data/analogsnapshot.cpp
 158         pv/data/logic.cpp
 159         pv/data/logicsnapshot.cpp
 160         pv/data/signaldata.cpp
 161         pv/data/snapshot.cpp
 162         pv/dialogs/about.cpp
 163         pv/dialogs/connect.cpp
 164         pv/dialogs/storeprogress.cpp
 165         pv/popups/deviceoptions.cpp
 166         pv/popups/channels.cpp
 167         pv/prop/bool.cpp
 168         pv/prop/double.cpp
 169         pv/prop/enum.cpp
 170         pv/prop/int.cpp
 171         pv/prop/property.cpp
 172         pv/prop/string.cpp
 173         pv/prop/binding/binding.cpp
 174         pv/prop/binding/deviceoptions.cpp
 175         pv/toolbars/samplingbar.cpp
 176         pv/view/analogsignal.cpp
 177         pv/view/cursor.cpp
 178         pv/view/cursorheader.cpp
 179         pv/view/cursorpair.cpp
 180         pv/view/header.cpp
 181         pv/view/marginwidget.cpp
 182         pv/view/logicsignal.cpp
 183         pv/view/rowitem.cpp
 184         pv/view/rowitemowner.cpp
 185         pv/view/ruler.cpp
 186         pv/view/selectableitem.cpp
 187         pv/view/signal.cpp
 188         pv/view/timemarker.cpp
 189         pv/view/trace.cpp
 190         pv/view/tracegroup.cpp
 191         pv/view/tracepalette.cpp
 192         pv/view/view.cpp
 193         pv/view/viewport.cpp
 194         pv/widgets/colourbutton.cpp
 195         pv/widgets/colourpopup.cpp
 196         pv/widgets/popup.cpp
 197         pv/widgets/popuptoolbutton.cpp
 198         pv/widgets/sweeptimingwidget.cpp
 199         pv/widgets/wellarray.cpp
 200 )
 201
 202 # This list includes only QObject derived class headers.
 203 set(pulseview_HEADERS
 204         pv/mainwindow.hpp
 205         pv/sigsession.hpp
 206         pv/storesession.hpp
 207         pv/dialogs/about.hpp
 208         pv/dialogs/connect.hpp
 209         pv/dialogs/storeprogress.hpp
 210         pv/popups/channels.hpp
 211         pv/popups/deviceoptions.hpp
 212         pv/prop/bool.hpp
 213         pv/prop/double.hpp
 214         pv/prop/enum.hpp
 215         pv/prop/int.hpp
 216         pv/prop/property.hpp
 217         pv/prop/string.hpp
 218         pv/prop/binding/deviceoptions.hpp
 219         pv/toolbars/samplingbar.hpp
 220         pv/view/cursor.hpp
 221         pv/view/cursorheader.hpp
 222         pv/view/header.hpp
 223         pv/view/logicsignal.hpp
 224         pv/view/marginwidget.hpp
 225         pv/view/rowitem.hpp
 226         pv/view/ruler.hpp
 227         pv/view/selectableitem.hpp
 228         pv/view/signal.hpp
 229         pv/view/timemarker.hpp
 230         pv/view/trace.hpp
 231         pv/view/tracegroup.hpp
 232         pv/view/view.hpp
 233         pv/view/viewport.hpp
 234         pv/widgets/colourbutton.hpp
 235         pv/widgets/colourpopup.hpp
 236         pv/widgets/popup.hpp
 237         pv/widgets/popuptoolbutton.hpp
 238         pv/widgets/sweeptimingwidget.hpp
 239         pv/widgets/wellarray.hpp
 240 )
 241
 242 set(pulseview_FORMS
 243         pv/dialogs/about.ui
 244 )
 245
 246 set(pulseview_RESOURCES
 247         pulseview.qrc
 248 )
 249
 250 if(ENABLE_SIGNALS)
 251         list(APPEND pulseview_SOURCES signalhandler.cpp)
 252         list(APPEND pulseview_HEADERS signalhandler.hpp)
 253 endif()
 254
 255 if(ENABLE_DECODE)
 256         list(APPEND pulseview_SOURCES
 257                 pv/data/decoderstack.cpp
 258                 pv/data/decode/annotation.cpp
 259                 pv/data/decode/decoder.cpp
 260                 pv/data/decode/row.cpp
 261                 pv/data/decode/rowdata.cpp
 262                 pv/prop/binding/decoderoptions.cpp
 263                 pv/view/decodetrace.cpp
 264                 pv/widgets/decodergroupbox.cpp
 265                 pv/widgets/decodermenu.cpp
 266         )
 267
 268         list(APPEND pulseview_HEADERS
 269                 pv/data/decoderstack.hpp
 270                 pv/view/decodetrace.hpp
 271                 pv/widgets/decodergroupbox.hpp
 272                 pv/widgets/decodermenu.hpp
 273         )
 274 endif()
 275
 276 if(WIN32)
 277         # Use the sigrok icon for the pulseview.exe executable.
 278         set(CMAKE_RC_COMPILE_OBJECT "${CMAKE_RC_COMPILER} -O coff -I${CMAKE_CURRENT_SOURCE_DIR} <SOURCE> <OBJECT>")
 279         enable_language(RC)
 280         list(APPEND pulseview_SOURCES pulseviewico.rc)
 281 endif()
 282
 283 if(ANDROID)
 284         list(APPEND pulseview_SOURCES android/loghandler.cpp)
 285 endif()
 286
 287 if(Qt5Core_FOUND)
 288         qt5_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 289         qt5_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 290         qt5_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 291 else()
 292         qt4_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 293         qt4_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 294         qt4_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 295         include(${QT_USE_FILE})
 296 endif()
 297
 298 #===============================================================================
 299 #= Global Definitions
 300 #-------------------------------------------------------------------------------
 301
 302 add_definitions(${QT_DEFINITIONS} -DQT_NO_KEYWORDS)
 303 add_definitions(-D__STDC_LIMIT_MACROS)
 304 add_definitions(-Wall -Wextra)
 305 add_definitions(-std=c++11)
 306
 307 if(ENABLE_DECODE)
 308         add_definitions(-DENABLE_DECODE)
 309 endif()
 310
 311 if(NOT DISABLE_WERROR)
 312         add_definitions(-Werror)
 313 endif()
 314
 315 if(ENABLE_SIGNALS)
 316         add_definitions(-DENABLE_SIGNALS)
 317 endif()
 318
 319 #===============================================================================
 320 #= Global Include Directories
 321 #-------------------------------------------------------------------------------
 322
 323 include_directories(
 324         ${CMAKE_CURRENT_BINARY_DIR}
 325         ${CMAKE_CURRENT_SOURCE_DIR}
 326         ${Boost_INCLUDE_DIRS}
 327         ${QT_INCLUDE_DIRS}
 328 )
 329
 330 if(STATIC_PKGDEPS_LIBS)
 331         include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
 332 else()
 333         include_directories(${PKGDEPS_INCLUDE_DIRS})
 334 endif()
 335
 336 #===============================================================================
 337 #= Linker Configuration
 338 #-------------------------------------------------------------------------------
 339
 340 link_directories(${Boost_LIBRARY_DIRS})
 341
 342 set(PULSEVIEW_LINK_LIBS
 343         ${Boost_LIBRARIES}
 344         ${QT_LIBRARIES}
 345         ${CMAKE_THREAD_LIBS_INIT}
 346 )
 347
 348 if(STATIC_PKGDEPS_LIBS)
 349         link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
 350         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LIBRARIES})
 351 if(WIN32)
 352         # Workaround for a MinGW linking issue.
 353         list(APPEND PULSEVIEW_LINK_LIBS "-llzma -llcms2")
 354 endif()
 355 else()
 356         link_directories(${PKGDEPS_LIBRARY_DIRS})
 357         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
 358 endif()
 359
 360 if(WIN32)
 361         # On Windows we need to statically link the libqsvg imageformat
 362         # plugin (and the QtSvg component) for SVG graphics/icons to work.
 363         add_definitions(-DQT_STATICPLUGIN)
 364         link_directories("${QT_PLUGINS_DIR}/imageformats")
 365         list(APPEND PULSEVIEW_LINK_LIBS "-lqsvg")
 366         list(APPEND PULSEVIEW_LINK_LIBS ${QT_QTSVG_LIBRARY})
 367 endif()
 368
 369 if(ANDROID)
 370         list(APPEND PULSEVIEW_LINK_LIBS "-llog")
 371 endif()
 372
 373 if(ANDROID)
 374 add_library(${PROJECT_NAME} SHARED
 375         ${pulseview_SOURCES}
 376         ${pulseview_HEADERS_MOC}
 377         ${pulseview_FORMS_HEADERS}
 378         ${pulseview_RESOURCES_RCC}
 379 )
 380 else()
 381 add_executable(${PROJECT_NAME}
 382         ${pulseview_SOURCES}
 383         ${pulseview_HEADERS_MOC}
 384         ${pulseview_FORMS_HEADERS}
 385         ${pulseview_RESOURCES_RCC}
 386 )
 387 endif()
 388
 389 target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
 390
 391 if(WIN32)
 392         # Pass -mwindows so that no "DOS box" opens when PulseView is started.
 393         set_target_properties(${PROJECT_NAME} PROPERTIES LINK_FLAGS "-mwindows")
 394 endif()
 395
 396 if(ENABLE_COTIRE)
 397         include(cotire)
 398         cotire(${PROJECT_NAME})
 399 endif()
 400
 401 #===============================================================================
 402 #= Installation
 403 #-------------------------------------------------------------------------------
 404
 405 # Install the executable.
 406 install(TARGETS ${PROJECT_NAME} DESTINATION bin/)
 407
 408 # Install the manpage.
 409 install(FILES doc/pulseview.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1 COMPONENT doc)
 410
 411 #===============================================================================
 412 #= Packaging (handled by CPack)
 413 #-------------------------------------------------------------------------------
 414
 415 set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
 416 set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
 417 set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
 418 set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
 419 set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
 420 set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
 421 set(CPACK_SOURCE_PACKAGE_FILE_NAME
 422         "${CMAKE_PROJECT_NAME}-${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}")
 423 set(CPACK_SOURCE_GENERATOR "TGZ")
 424
 425 include(CPack)
 426
 427 #===============================================================================
 428 #= Tests
 429 #-------------------------------------------------------------------------------
 430
 431 if(ENABLE_TESTS)
 432         add_subdirectory(test)
 433         enable_testing()
 434         add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
 435 endif()