CMakeLists.txt

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
   5 ## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 2 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 cmake_minimum_required(VERSION 2.6)
  22 include(FindPkgConfig)
  23
  24 project(pulseview)
  25
  26 #===============================================================================
  27 #= User Options
  28 #-------------------------------------------------------------------------------
  29
  30 option(DISABLE_WERROR "Build without -Werror" FALSE)
  31 option(ENABLE_TESTS "Enable unit tests" FALSE)
  32 option(STATIC_PKGDEPS_LIBS "Statically link to (pkgconfig) libraries" FALSE)
  33
  34 if(WIN32)
  35         # On Windows/MinGW we need to statically link to libraries.
  36         # This option is user configurable, but enable it by default on win32.
  37         set(STATIC_PKGDEPS_LIBS TRUE)
  38
  39         # For boost-thread we need two additional settings on win32:
  40         set(Boost_USE_STATIC_LIBS on)
  41         add_definitions(-DBOOST_THREAD_USE_LIB)
  42 endif()
  43
  44 #===============================================================================
  45 #= Dependencies
  46 #-------------------------------------------------------------------------------
  47
  48 find_package(PkgConfig)
  49 pkg_check_modules(PKGDEPS REQUIRED
  50         libsigrokdecode>=0.1.0
  51         libsigrok>=0.2.0
  52 )
  53
  54 find_package(Qt4 REQUIRED)
  55
  56 # Find the platform's thread library (needed for boost-thread).
  57 # This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
  58 find_package(Threads)
  59
  60 if(WIN32)
  61 # On Windows/MinGW the we need to use 'thread_win32' instead of 'thread'.
  62 # The library is named libboost_thread_win32* (not libboost_thread*).
  63 find_package(Boost 1.42 COMPONENTS system thread_win32 REQUIRED)
  64 else()
  65 find_package(Boost 1.42 COMPONENTS system thread REQUIRED)
  66 endif()
  67
  68 #===============================================================================
  69 #= Config Header
  70 #-------------------------------------------------------------------------------
  71
  72 set(PV_TITLE PulseView)
  73 set(PV_DESCRIPTION "A GUI for sigrok")
  74
  75 set(PV_VERSION_MAJOR 0)
  76 set(PV_VERSION_MINOR 1)
  77 set(PV_VERSION_MICRO 0)
  78 set(PV_VERSION_STRING
  79         ${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}
  80 )
  81
  82 configure_file (
  83         ${PROJECT_SOURCE_DIR}/config.h.in
  84         ${PROJECT_BINARY_DIR}/config.h
  85 )
  86
  87 #===============================================================================
  88 #= Sources
  89 #-------------------------------------------------------------------------------
  90
  91 set(pulseview_SOURCES
  92         main.cpp
  93         pv/mainwindow.cpp
  94         pv/sigsession.cpp
  95         pv/data/analog.cpp
  96         pv/data/analogsnapshot.cpp
  97         pv/data/logic.cpp
  98         pv/data/logicsnapshot.cpp
  99         pv/data/signaldata.cpp
 100         pv/data/snapshot.cpp
 101         pv/dialogs/about.cpp
 102         pv/dialogs/connect.cpp
 103         pv/dialogs/deviceoptions.cpp
 104         pv/prop/double.cpp
 105         pv/prop/enum.cpp
 106         pv/prop/property.cpp
 107         pv/prop/binding/binding.cpp
 108         pv/prop/binding/deviceoptions.cpp
 109         pv/toolbars/samplingbar.cpp
 110         pv/view/analogsignal.cpp
 111         pv/view/cursor.cpp
 112         pv/view/header.cpp
 113         pv/view/logicsignal.cpp
 114         pv/view/ruler.cpp
 115         pv/view/signal.cpp
 116         pv/view/timemarker.cpp
 117         pv/view/view.cpp
 118         pv/view/viewport.cpp
 119 )
 120
 121 set(pulseview_HEADERS
 122         pv/mainwindow.h
 123         pv/sigsession.h
 124         pv/dialogs/about.h
 125         pv/dialogs/connect.h
 126         pv/dialogs/deviceoptions.h
 127         pv/toolbars/samplingbar.h
 128         pv/view/cursor.h
 129         pv/view/header.h
 130         pv/view/ruler.h
 131         pv/view/timemarker.h
 132         pv/view/view.h
 133         pv/view/viewport.h
 134 )
 135
 136 set(pulseview_FORMS
 137         pv/dialogs/about.ui
 138 )
 139
 140 set(pulseview_RESOURCES
 141         pulseview.qrc
 142 )
 143
 144 qt4_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 145 qt4_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 146 qt4_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 147
 148 include(${QT_USE_FILE})
 149
 150 #===============================================================================
 151 #= Global Definitions
 152 #-------------------------------------------------------------------------------
 153
 154 add_definitions(${QT_DEFINITIONS})
 155 add_definitions(-Wall -Wextra)
 156
 157 if(NOT DISABLE_WERROR)
 158         add_definitions(-Werror)
 159 endif()
 160
 161 #===============================================================================
 162 #= Global Include Directories
 163 #-------------------------------------------------------------------------------
 164
 165 include_directories(
 166         ${CMAKE_CURRENT_BINARY_DIR}
 167         ${CMAKE_CURRENT_SOURCE_DIR}
 168         ${Boost_INCLUDE_DIRS}
 169 )
 170
 171 if(STATIC_PKGDEPS_LIBS)
 172         include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
 173 else()
 174         include_directories(${PKGDEPS_INCLUDE_DIRS})
 175 endif()
 176
 177 #===============================================================================
 178 #= Linker Configuration
 179 #-------------------------------------------------------------------------------
 180
 181 link_directories(${Boost_LIBRARY_DIRS})
 182
 183 set(PULSEVIEW_LINK_LIBS
 184         ${Boost_LIBRARIES}
 185         ${CMAKE_THREAD_LIBS_INIT}
 186         ${QT_LIBRARIES}
 187 )
 188
 189 if(STATIC_PKGDEPS_LIBS)
 190         link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
 191         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LIBRARIES})
 192 else()
 193         link_directories(${PKGDEPS_LIBRARY_DIRS})
 194         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
 195 endif()
 196
 197 add_executable(${PROJECT_NAME}
 198         ${pulseview_SOURCES}
 199         ${pulseview_HEADERS_MOC}
 200         ${pulseview_FORMS_HEADERS}
 201         ${pulseview_RESOURCES_RCC}
 202 )
 203
 204 target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
 205
 206 #===============================================================================
 207 #= Installation
 208 #-------------------------------------------------------------------------------
 209
 210 install(TARGETS ${PROJECT_NAME} DESTINATION bin/)
 211
 212 #===============================================================================
 213 #= Packaging (handled by CPack)
 214 #-------------------------------------------------------------------------------
 215
 216 set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
 217 set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
 218 set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
 219 set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
 220 set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
 221 set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
 222 set(CPACK_SOURCE_PACKAGE_FILE_NAME
 223         "${CMAKE_PROJECT_NAME}-${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}")
 224 set(CPACK_SOURCE_GENERATOR "TGZ")
 225
 226 include(CPack)
 227
 228 #===============================================================================
 229 #= Tests
 230 #-------------------------------------------------------------------------------
 231
 232 if(ENABLE_TESTS)
 233         add_subdirectory(test)
 234         enable_testing()
 235         add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
 236 endif(ENABLE_TESTS)