CMakeLists.txt

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
   5 ## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 2 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 cmake_minimum_required(VERSION 2.8.6)
  22
  23 include(FindPkgConfig)
  24 include(GNUInstallDirs)
  25
  26 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/CMake")
  27
  28 project(pulseview)
  29
  30 #===============================================================================
  31 #= User Options
  32 #-------------------------------------------------------------------------------
  33
  34 option(DISABLE_WERROR "Build without -Werror" FALSE)
  35 option(ENABLE_SIGNALS "Build with UNIX signals" TRUE)
  36 option(ENABLE_DECODE "Build with libsigrokdecode" TRUE)
  37 option(ENABLE_COTIRE "Enable cotire" FALSE)
  38 option(ENABLE_TESTS "Enable unit tests" FALSE)
  39 option(STATIC_PKGDEPS_LIBS "Statically link to (pkg-config) libraries" FALSE)
  40 option(FORCE_QT4 "Force use of Qt4 even if Qt5 is available" FALSE)
  41
  42 if(WIN32)
  43         # On Windows/MinGW we need to statically link to libraries.
  44         # This option is user configurable, but enable it by default on win32.
  45         set(STATIC_PKGDEPS_LIBS TRUE)
  46
  47         # Windows does not support UNIX signals.
  48         set(ENABLE_SIGNALS FALSE)
  49 endif()
  50
  51 if(NOT CMAKE_BUILD_TYPE)
  52   set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
  53       "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  54       FORCE)
  55 endif()
  56
  57 #===============================================================================
  58 #= Dependencies
  59 #-------------------------------------------------------------------------------
  60
  61 list(APPEND PKGDEPS libsigrok>=0.3.0)
  62
  63 if(ENABLE_DECODE)
  64         list(APPEND PKGDEPS libsigrokdecode>=0.3.0)
  65 endif()
  66
  67 if(ANDROID)
  68         list(APPEND PKGDEPS libsigrokandroidutils>=0.1.0)
  69 endif()
  70
  71 find_package(PkgConfig)
  72 pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})
  73
  74 if(FORCE_QT4)
  75         set(Qt5Core_FOUND FALSE)
  76 else()
  77         find_package(Qt5Core QUIET)
  78 endif()
  79
  80 if(Qt5Core_FOUND)
  81         message("-- Using Qt5")
  82         find_package(Qt5Widgets REQUIRED)
  83         find_package(Qt5Gui REQUIRED)
  84         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${Qt5Widgets_EXECUTABLE_COMPILE_FLAGS}")
  85         set(QT_INCLUDE_DIRS ${Qt5Gui_INCLUDE_DIRS} ${Qt5Widgets_INCLUDE_DIRS})
  86         set(QT_LIBRARIES Qt5::Gui Qt5::Widgets)
  87         add_definitions(${Qt5Gui_DEFINITIONS} ${Qt5Widgets_DEFINITIONS})
  88 else()
  89         find_program(QT_QMAKE_EXECUTABLE NAMES qmake4 qmake-qt4 qmake-mac)
  90         find_package(Qt4 REQUIRED)
  91 endif()
  92
  93 find_package(Boost 1.42 COMPONENTS filesystem system REQUIRED)
  94
  95 # Find the platform's thread library (needed for C++11 threads).
  96 # This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
  97 find_package(Threads REQUIRED)
  98
  99 #===============================================================================
 100 #= System Introspection
 101 #-------------------------------------------------------------------------------
 102
 103 include(memaccess)
 104 memaccess_check_unaligned_le(HAVE_UNALIGNED_LITTLE_ENDIAN_ACCESS)
 105
 106 #===============================================================================
 107 #= Config Header
 108 #-------------------------------------------------------------------------------
 109
 110 set(PV_TITLE PulseView)
 111 set(PV_DESCRIPTION "A GUI for sigrok")
 112
 113 set(PV_VERSION_MAJOR 0)
 114 set(PV_VERSION_MINOR 2)
 115 set(PV_VERSION_MICRO 0)
 116 set(PV_VERSION_STRING
 117         ${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}
 118 )
 119
 120 configure_file (
 121         ${PROJECT_SOURCE_DIR}/config.h.in
 122         ${PROJECT_BINARY_DIR}/config.h
 123 )
 124
 125 #===============================================================================
 126 #= Sources
 127 #-------------------------------------------------------------------------------
 128
 129 set(pulseview_SOURCES
 130         main.cpp
 131         pv/application.cpp
 132         pv/devicemanager.cpp
 133         pv/mainwindow.cpp
 134         pv/sigsession.cpp
 135         pv/storesession.cpp
 136         pv/util.cpp
 137         pv/data/analog.cpp
 138         pv/data/analogsnapshot.cpp
 139         pv/data/logic.cpp
 140         pv/data/logicsnapshot.cpp
 141         pv/data/signaldata.cpp
 142         pv/data/snapshot.cpp
 143         pv/device/device.cpp
 144         pv/device/file.cpp
 145         pv/device/devinst.cpp
 146         pv/device/sessionfile.cpp
 147         pv/dialogs/about.cpp
 148         pv/dialogs/connect.cpp
 149         pv/dialogs/storeprogress.cpp
 150         pv/popups/deviceoptions.cpp
 151         pv/popups/channels.cpp
 152         pv/prop/bool.cpp
 153         pv/prop/double.cpp
 154         pv/prop/enum.cpp
 155         pv/prop/int.cpp
 156         pv/prop/property.cpp
 157         pv/prop/string.cpp
 158         pv/prop/binding/binding.cpp
 159         pv/prop/binding/deviceoptions.cpp
 160         pv/toolbars/samplingbar.cpp
 161         pv/view/analogsignal.cpp
 162         pv/view/cursor.cpp
 163         pv/view/cursorheader.cpp
 164         pv/view/cursorpair.cpp
 165         pv/view/header.cpp
 166         pv/view/marginwidget.cpp
 167         pv/view/logicsignal.cpp
 168         pv/view/ruler.cpp
 169         pv/view/selectableitem.cpp
 170         pv/view/signal.cpp
 171         pv/view/timemarker.cpp
 172         pv/view/trace.cpp
 173         pv/view/tracepalette.cpp
 174         pv/view/view.cpp
 175         pv/view/viewport.cpp
 176         pv/widgets/colourbutton.cpp
 177         pv/widgets/colourpopup.cpp
 178         pv/widgets/popup.cpp
 179         pv/widgets/popuptoolbutton.cpp
 180         pv/widgets/sweeptimingwidget.cpp
 181         pv/widgets/wellarray.cpp
 182 )
 183
 184 # This list includes only QObject derived class headers.
 185 set(pulseview_HEADERS
 186         pv/mainwindow.h
 187         pv/sigsession.h
 188         pv/storesession.h
 189         pv/device/devinst.h
 190         pv/dialogs/about.h
 191         pv/dialogs/connect.h
 192         pv/dialogs/storeprogress.h
 193         pv/popups/channels.h
 194         pv/popups/deviceoptions.h
 195         pv/prop/bool.h
 196         pv/prop/double.h
 197         pv/prop/enum.h
 198         pv/prop/int.h
 199         pv/prop/property.h
 200         pv/prop/string.h
 201         pv/toolbars/samplingbar.h
 202         pv/view/cursor.h
 203         pv/view/cursorheader.h
 204         pv/view/header.h
 205         pv/view/logicsignal.h
 206         pv/view/marginwidget.h
 207         pv/view/ruler.h
 208         pv/view/selectableitem.h
 209         pv/view/signal.h
 210         pv/view/timemarker.h
 211         pv/view/trace.h
 212         pv/view/view.h
 213         pv/view/viewport.h
 214         pv/widgets/colourbutton.h
 215         pv/widgets/colourpopup.h
 216         pv/widgets/popup.h
 217         pv/widgets/popuptoolbutton.h
 218         pv/widgets/sweeptimingwidget.h
 219         pv/widgets/wellarray.h
 220 )
 221
 222 set(pulseview_FORMS
 223         pv/dialogs/about.ui
 224 )
 225
 226 set(pulseview_RESOURCES
 227         pulseview.qrc
 228 )
 229
 230 if(ENABLE_SIGNALS)
 231         list(APPEND pulseview_SOURCES signalhandler.cpp)
 232         list(APPEND pulseview_HEADERS signalhandler.h)
 233 endif()
 234
 235 if(ENABLE_DECODE)
 236         list(APPEND pulseview_SOURCES
 237                 pv/data/decoderstack.cpp
 238                 pv/data/decode/annotation.cpp
 239                 pv/data/decode/decoder.cpp
 240                 pv/data/decode/row.cpp
 241                 pv/data/decode/rowdata.cpp
 242                 pv/prop/binding/decoderoptions.cpp
 243                 pv/view/decodetrace.cpp
 244                 pv/widgets/decodergroupbox.cpp
 245                 pv/widgets/decodermenu.cpp
 246         )
 247
 248         list(APPEND pulseview_HEADERS
 249                 pv/data/decoderstack.h
 250                 pv/view/decodetrace.h
 251                 pv/widgets/decodergroupbox.h
 252                 pv/widgets/decodermenu.h
 253         )
 254 endif()
 255
 256 if(WIN32)
 257         # Use the sigrok icon for the pulseview.exe executable.
 258         set(CMAKE_RC_COMPILE_OBJECT "${CMAKE_RC_COMPILER} -O coff -I${CMAKE_CURRENT_SOURCE_DIR} <SOURCE> <OBJECT>")
 259         enable_language(RC)
 260         list(APPEND pulseview_SOURCES pulseviewico.rc)
 261 endif()
 262
 263 if(ANDROID)
 264         list(APPEND pulseview_SOURCES android/loghandler.cpp)
 265 endif()
 266
 267 if(Qt5Core_FOUND)
 268         qt5_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 269         qt5_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 270         qt5_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 271 else()
 272         qt4_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
 273         qt4_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
 274         qt4_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 275         include(${QT_USE_FILE})
 276 endif()
 277
 278 #===============================================================================
 279 #= Global Definitions
 280 #-------------------------------------------------------------------------------
 281
 282 add_definitions(${QT_DEFINITIONS} -DQT_NO_KEYWORDS)
 283 add_definitions(-D__STDC_LIMIT_MACROS)
 284 add_definitions(-Wall -Wextra)
 285 add_definitions(-std=c++11)
 286
 287 if(ENABLE_DECODE)
 288         add_definitions(-DENABLE_DECODE)
 289 endif()
 290
 291 if(NOT DISABLE_WERROR)
 292         add_definitions(-Werror)
 293 endif()
 294
 295 if(ENABLE_SIGNALS)
 296         add_definitions(-DENABLE_SIGNALS)
 297 endif()
 298
 299 #===============================================================================
 300 #= Global Include Directories
 301 #-------------------------------------------------------------------------------
 302
 303 include_directories(
 304         ${CMAKE_CURRENT_BINARY_DIR}
 305         ${CMAKE_CURRENT_SOURCE_DIR}
 306         ${Boost_INCLUDE_DIRS}
 307         ${QT_INCLUDE_DIRS}
 308 )
 309
 310 if(STATIC_PKGDEPS_LIBS)
 311         include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
 312 else()
 313         include_directories(${PKGDEPS_INCLUDE_DIRS})
 314 endif()
 315
 316 #===============================================================================
 317 #= Linker Configuration
 318 #-------------------------------------------------------------------------------
 319
 320 link_directories(${Boost_LIBRARY_DIRS})
 321
 322 set(PULSEVIEW_LINK_LIBS
 323         ${Boost_LIBRARIES}
 324         ${QT_LIBRARIES}
 325         ${CMAKE_THREAD_LIBS_INIT}
 326 )
 327
 328 if(STATIC_PKGDEPS_LIBS)
 329         link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
 330         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LIBRARIES})
 331 if(WIN32)
 332         # Workaround for a MinGW linking issue.
 333         list(APPEND PULSEVIEW_LINK_LIBS "-llzma -llcms2")
 334 endif()
 335 else()
 336         link_directories(${PKGDEPS_LIBRARY_DIRS})
 337         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
 338 endif()
 339
 340 if(WIN32)
 341         # On Windows we need to statically link the libqsvg imageformat
 342         # plugin (and the QtSvg component) for SVG graphics/icons to work.
 343         add_definitions(-DQT_STATICPLUGIN)
 344         link_directories("${QT_PLUGINS_DIR}/imageformats")
 345         list(APPEND PULSEVIEW_LINK_LIBS ${QT_QTSVG_LIBRARY})
 346         list(APPEND PULSEVIEW_LINK_LIBS "-lqsvg")
 347 endif()
 348
 349 if(ANDROID)
 350         list(APPEND PULSEVIEW_LINK_LIBS "-llog")
 351 endif()
 352
 353 if(ANDROID)
 354 add_library(${PROJECT_NAME} SHARED
 355         ${pulseview_SOURCES}
 356         ${pulseview_HEADERS_MOC}
 357         ${pulseview_FORMS_HEADERS}
 358         ${pulseview_RESOURCES_RCC}
 359 )
 360 else()
 361 add_executable(${PROJECT_NAME}
 362         ${pulseview_SOURCES}
 363         ${pulseview_HEADERS_MOC}
 364         ${pulseview_FORMS_HEADERS}
 365         ${pulseview_RESOURCES_RCC}
 366 )
 367 endif()
 368
 369 target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
 370
 371 if(WIN32)
 372         # Pass -mwindows so that no "DOS box" opens when PulseView is started.
 373         set_target_properties(${PROJECT_NAME} PROPERTIES LINK_FLAGS "-mwindows")
 374 endif()
 375
 376 if(ENABLE_COTIRE)
 377         include(cotire)
 378         cotire(${PROJECT_NAME})
 379 endif()
 380
 381 #===============================================================================
 382 #= Installation
 383 #-------------------------------------------------------------------------------
 384
 385 # Install the executable.
 386 install(TARGETS ${PROJECT_NAME} DESTINATION bin/)
 387
 388 # Install the manpage.
 389 install(FILES doc/pulseview.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1 COMPONENT doc)
 390
 391 #===============================================================================
 392 #= Packaging (handled by CPack)
 393 #-------------------------------------------------------------------------------
 394
 395 set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
 396 set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
 397 set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
 398 set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
 399 set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
 400 set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
 401 set(CPACK_SOURCE_PACKAGE_FILE_NAME
 402         "${CMAKE_PROJECT_NAME}-${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}")
 403 set(CPACK_SOURCE_GENERATOR "TGZ")
 404
 405 include(CPack)
 406
 407 #===============================================================================
 408 #= Tests
 409 #-------------------------------------------------------------------------------
 410
 411 if(ENABLE_TESTS)
 412         add_subdirectory(test)
 413         enable_testing()
 414         add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
 415 endif()